home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol167 / cnvrt.rec < prev    next >
Encoding:
Text File  |  1984-04-29  |  13.3 KB  |  395 lines
  1.  
  2. { [CNVRT.REC]
  3. [Compile a set of CNVRT rules into a REC program]
  4. [format: ((p)(s)(v) (
  5.      (pattern, skeleton):    [repeating]
  6.   [or]     (pattern, skeleton);    [terminal]
  7.      )) x]
  8. [(p) is a list of pattern definitions ((P1) p1 (P2) p2 ...)]
  9. [(s) is a list of skeleton definitions ((S1) s1 (S2) s2 ...)]
  10. [(v) is a list of variables (v1 v2 ...): digits separated by spaces]
  11. [Patterns may have one of the forms
  12.     all patterns P1,..Pn        (AND,P1,P2,...,Pn)
  13.     first of P1,...Pn to match    (OR,P1,P2,...,Pn)
  14.     pattern does not start w/P    (NOT,P)
  15.     P using P1 as p1 etc        (DEF,P1,p1,...,PN,pn,P)
  16.     Repeat P as much as possible    (ITR,P)
  17.     Repeat P as little as possible    (itr,P)
  18.     ... with delimiters /        (QUO/.../)
  19.     the decimal number n        (DEC,n)
  20.     the hexadecimal number n    (HEX,n)
  21.     control characters xxx        (^xxx)
  22.     lexicographic interval m,n    (IVL,m,n,)
  23.     print remaining workspace    (PWS)
  24.     print value of variable n    (PVR,n)
  25.     wait for keystroke        (HLT)
  26.     print mssg, wait        (HLT,mssg)
  27.     nothing - edit to PWS or HLT    (NOP)
  28.     left angle bracket        (<)
  29.     right angle bracket        (>)
  30.     left parenthesis        <(>
  31.     right parenthesis        <)>
  32.     single quote            <'>
  33.     double quote            <">
  34.     comma                <,>
  35.     balanced parentheses        <()>
  36.     defined pattern a        <:a:>
  37.     interval of length n        <[n]>
  38.     indefinite interval        <-->
  39.     variable n            <n>
  40.     no free space left        <>
  41.     ]
  42. [Skeletons may take any one of the following forms
  43.     left parenthesis        <(>
  44.     right parenthesis        <)>
  45.     comma [not necessary]        <,>
  46.     single quote            <'>
  47.     double quote            <">
  48.     left bracket            (<)
  49.     right bracket            (>)
  50.     variable n            <n>
  51.     function f, no argument        (f)
  52.     function f, argument xxx    (f,xxx)
  53.     control characters        (^xxx)
  54.     ]
  55. [Since all spaces, tabs, and similar characters are taken literally
  56.   in patterns and skeletons, the pair <<...>> may be used to format
  57.   programs into lines and columns. It is preferable to enclose all
  58.   comments in square brackets at the appropriate place, so that they
  59.   can appear in the compiled program; text between angular brackets,
  60.   on the other hand, will be ignored.]
  61. [Skeletons exploiting CP/M's input-output mechanisms:
  62.     open file            (%O[r|w],D:FILENAME.EXT)
  63.     read file            (%R,D:FILENAME.EXT)
  64.     write file            (%W,D:FILENAME.EXT,xxx)
  65.     close file            (%C,D:FILENAME.EXT)
  66.     close all files            (%E)
  67.     read                (%R)
  68.     type, preserve            (%T,xxx)
  69.     type CR,LF            (%&)
  70.     insert CR,LF            (%|)
  71.     ]
  72. [CNVRT is a chain oriented adaptation of the LISP based CONVERT in
  73.  
  74.         Adolfo Guzman and Harold V. McIntosh
  75.         CONVERT
  76.         Communications of the ACM 9 604-615 (1966).]
  77.  
  78. [Harold V. McIntosh, 25 December 1980]
  79. [Harold V. McIntosh, 22 February 1981]
  80. [Harold V. McIntosh and Gerardo Cisneros, 28 December 1983]
  81. [10 January 1984 - automatic mode reads single function - GC]
  82. [10 January 1984 - (^K) is a skeleton for ^K - HVM]
  83. [14 January 1984 - shorten pattern (CTL,xxx) to (^xxx) - HVM]
  84. [14 January 1984 - (,xxx) evaluates, discards xxx - HVM]
  85. [16 January 1984 - initial workspace is "command line" - HVM]
  86. [17 Jan 1984 - %C closes explicit file or default - GC]
  87. [17 Jan 1984 - 3-state FCBs: not open, open-R, open-W.  GC]
  88. [19 Jan 1984 - # supports negative results - GC]
  89. [23 Jan 1984 - CTR: pseudodevice included - GC]
  90.  
  91. [30$ - input FCB]
  92. [31$ - output FCB]
  93.  
  94. [display w/cursor]        (248%I26%TLJZqt248%FD;;) D
  95.  
  96. [erase cursors]            (J(248%FD:JZ;);) E
  97.  
  98. [zero file control block]    ($m33cmpw0%(f:;)wnnS;) F
  99.  
  100. [create input, output FCB's]    ('5C'H12wA' 'Ew;B
  101.   [generate file name]         9aQpG'REC'|m (Z3b' 'E'CNV';Q;)|m w
  102.   [open input file]         n30$rS 30@f
  103.   [open output file]         n31$rS 31@g31@e
  104.                 ;) G
  105.  
  106. [close file]            (
  107.   [clear wkspace, inp file]     @p:L@y:(@p:0=;e26%(f:;)@p;;)
  108.   [close fil.REC]         31$r16k
  109.                 ;) H
  110.  
  111. [initialize]            (J@Wj@!;@!;) I
  112.  
  113. [read, with rubout]        (R26%='';T127%(=)(@J|;L@J;);) J
  114.  
  115. [WS up to cursor to disk]    (jJ<(@p:L;)Zz>;) P
  116.  
  117. [15-line window]        (AB(10%Fz;Zz;)qL
  118.                   15(d(10%FA;L(26%Fj;Z;)):;)Y<;<) W
  119.  
  120. [compile one rule]        {
  121.   [insert single quote]          (39%I;) q
  122.   [find comma, pass parens]    (zZ<(','E;'<(>'Ez:'<)>'Ez:'<,>'Ez:
  123.                  '(QUO'EzABQzFzA:'('Ez@d:A:)jJ>;J>) r
  124.   [advance to (, <, or end]    ('('E;'<'E;','E;A:) h
  125.  
  126.     [(..., holds pattern]     ('('F'J'Iz@r<(
  127.     [compile pattern, skeleton]      @bZ>zZ','FDZ<@dBjJ><j'JZD'I@c ';'I>z')'Fz;)
  128.                  ;) a
  129.  
  130. [Duplicate and test for null]    (pG''=;L) s
  131. [CNVRT rule set]        ('('FD'{'I  
  132.   [defined patterns]          '('FDZ<@dBDJ><(@hzZ<@dBj';'IjJ<@b>>:;)>
  133.   [defined skeletons]          '('FDZ<@dBDJ><(@hzZ<@dBj';'IjJ<j@c>>:;)>
  134.   [variable list - save & init]      '('FzZ<@dBDJ><Qj(A'@( 'Iz' 'ED:;)>
  135.   [variable list - reinitialize]  '('F(@s;D'{('I;)zpG(''=;I<' 'IJj
  136.                 (' 'FD'@: 'Iz:;)>;) (@s;';); ('Iz;)
  137.   [one single rule]          ('('Ej(@s;'@;'Iz;)Z<A@dJ><@aZz>:
  138.                     ')'ED';)'Iz;A:;)
  139.   [variable list - undefine]      (@s;'} 'Iz;) pG(''=;I<' 'IJ
  140.                     (' 'FD'@) 'Iz:;)>;)
  141.   [variable list - restore]      ' 'II<j(ABD' nn$S'Iz' 'ED:;)>
  142.                   ')'FD';)}'I 13%Fj
  143.                  ;) } t
  144.  
  145. [parse pattern]            {
  146.                  (1b39%ED;39%I'Ez'Iz;) E
  147.                  (1b39%ED;39%I'(Fz;Zz<)'Iz;) F
  148.                 (z
  149.   [suppress extraneous intvl]     '<<'E'>>'VD:
  150.   [variable is interval]     '<['ED @E']>'FD'(a;L)z'I@q :
  151.   [defined pattern]         '<:'ED @E '@'I':>'FD@q :
  152.   [skip]             '<-->'ED @E '(('I@qzZ
  153.                     <(@hj;;)>@F 'Z<'Iz
  154.                     @b '>;J>);A:)'I ;
  155.   [left paren]             '<(>'ED '('I :
  156.   [right paren]             '<)>'ED ')'I :
  157.   [comma]             '<,>'ED ','I :
  158.   [balanced parentheses]     '<()>'ED @E
  159.                    '"("E{(A")"Ez;"("E@*::)*(@*;)}'I
  160.                    @q :
  161.   [single quote]         10044[<']ED'>'ED@E'39%Ez'I@q :
  162.   [double quote]         8764[<"] ED'>'ED@E'34%Ez'I@q :
  163.   [physical end]         '<>'ED @E'(A)'I ;
  164.   [variable follows]         '<'ED @E
  165.                     '>'UQD'>'ED Z<((@hjJ>Qj)J>Qj
  166.                     ''=I'@]'I;
  167.                     ' {[vbl] ('Iz @b ';) = ('I
  168.                     (''=I'@<'I;@qI@qI'@>'I;)
  169.                     ';)}[vbl] 'I ;) ;
  170.   [DEF follows]             '(DEF,'ED @E
  171.                     zZ<@dBDJQD>' {[def] ('Iz
  172.                     (I<j@rzABDZQDJ<@b>';) 'I>
  173.                     I<j@rzABDZQDJ>' ('I:
  174.                         <@b>';)}[def] 'Iz>;)@q :
  175.   [ITR follows]             '(ITR,'ED @E '([ITR] Z<'I
  176.                     zZ<@dBDJ><@b>'>:J>;)[ITR] 'I@q :
  177.   [itr follows]             '(itr,'ED @E
  178.                     zZ<@dBDJQD>' ([itr] Z<'IzZ <@b>
  179.                     '>; J>'II <@b> ':) [itr] 'I ;
  180.   [AND follows]             '(AND,'ED @E
  181.                     zZ<@dBDZQDJj@rz','EDZQDJj
  182.                     ' {[AND] ('IzZ<j';) ` (Z<'Iz
  183.                     Z<@b>'@`>;>)}[AND] 'I
  184.                     (Jj>' {('IzZ<j';) ` (jJ><'II
  185.                     <(j@rz','EDZQD;)
  186.                     J<@b>'(A)@`;)} 'I>:
  187.                     J<@b>'(A)@`;)} 'I>;)
  188.                     Jj'>('II<@b>'<;<)'I>>Zz ;
  189.   [OR follows]             '(OR)'ED @E '()'I@q:
  190.                  '(OR,'ED @E  zZ<@dBDJQD>
  191.                     ' {[OR] ('IzZ <@b> ';) \ (Z<('I
  192.                     (I<j@rzABD'<:\:>'IzZQDJ<@b>'; J'I>:
  193.                     <'<:\:>'IJ@b>';)>;>)} [OR] 'Iz>;) ;
  194.   [and follows]             '(and)'ED @E @q:
  195.                  '(and,'ED @E  zZ<@dBDJQD>
  196.                     ' [and] Z<('I
  197.                     I<j@rzABDZQDJ<@b>' jJ><'I>
  198.                     (I<j@rzABDZQDJ<@b>' (A)J><'I>:
  199.                     <@b>'(A);>)> [and] 'Iz>;) @q:
  200.   [or follows]             '(or)'ED @E '()'I@q:
  201.                  '(or,'ED @E  zZ<@dBDJQD>
  202.                     ' [or] Z<('I
  203.                     (I<j@rzABDZQDJ<@b>'; J'I>:
  204.                     <@b>';>)> [or] 'Iz>;) @q:
  205.   [NOT follows]             '(NOT,'ED @E'[not] (Z< 'I
  206.                     zZ<@dBDJ><@b>
  207.                     'J>)J>[not] 'I(zABj;'Zz'I;)@q :
  208.   [nor follows]             '(nor,'ED Z<j'(NOT,(or,'Iz@d')'IJj> :
  209.   [QUO follows]             '(QUO'ED @E zABQD@qFD')'ED@E@q :
  210.   [DEC follows]             '(DEC,'ED @E ')'FD'%Ez'I@q :
  211.   [HEX follows]             '(HEX,'ED @E ')'UQD')'EDHI'%Ez'I@q :
  212.   [^ follows]             '(^)'ED @E'0%31%Mz'I@q :
  213.                  '(^'ED @E ')'UQD')'ED
  214.                     I<j(ABQD\64['@']-#'%Ez'|Iz:;)>@q :
  215.   [IVL follows]             '(IVL'ED @E ABQQD@qFD@q
  216.                     @qFD')'ED@q'Mz'I@q :
  217.   [PWS follows]             '(PWS)'ED @E'2573TLZqtj'I@q :
  218.                  '(PWS,'ED @E'2573TL'I@q')'FD@q'TLZqtj'I@q :
  219.   [HLT follows]             '(HLT)'ED @E'RL'I@q :
  220.                  '(HLT,'ED @E'2573TL'I@q')'FD@q'TLRL'I@q :
  221.   [NOP follows]             '(NOP)'ED :
  222.                  '(NOP,'E ')'VD :
  223.   [PVR follows]             '(PVR,'ED @E ')'FD"'_'@%"I@q:
  224.   [left angle bracket]         '(<)'ED '<'I :
  225.   [right angle bracket]         '(>)'ED '>'I :
  226.                  A:@E;) B (j@q@Bz;)} b
  227.  
  228. [parse skeleton]        {(1b39%ED;39%I'I'I;) Q
  229.                  (z@q3bjA@qZQ|D:DJj'@'IZQ|D'Z>'|I;) h
  230.                  (z
  231.                   '<<'E'>>'VD:
  232.                   '<(>'ED'('I:
  233.                   '<)>'ED')'I:
  234.                   '<,>'ED','I:
  235.                   10044[<']ED'>'ED@Q'39%I'I@q:
  236.                    8764[<"]ED'>'ED@Q'34%I'I@q:
  237.   [variable]              '<'ED@Q'>'FD'@['I@q:
  238.   [left angle]              '(<)'ED'<'I:
  239.   [right angle]              '(>)'ED'>'I:
  240.   [control char]          '(^'ED')'UQD')'ED@QI
  241.                     <j(ABQD\64['@']-#'%I'|Iz:;)>@q:
  242.   [function]              '('ED@Qz')'V
  243.     [insert argument]             (<j','UQD','ED>'z<'I@c
  244.     [function name]             (''='JZD>'I;I<''@h>;);
  245.     [if no argument]             j'z<'Iz')'U<''@h>')'FD>;)@q:
  246.                   ')'ED;
  247.                   A:;) C (@q@C@Q;)} c
  248.  
  249. [rparen, pass pairs, (QUO's]    (')'Ez;'<(>'Ez:'<)>'Ez:
  250.                  '(QUO'EzABQzFzA:'('Ez@d:A:)d
  251. [rbracket, pass pairs]        (']'Ez;'['Ez@j:A:)j
  252. [open file or create it]    (@h$r15K(255=22K;;)LL;)e
  253. [open file or report absence]    (@h$r15K(255='new file 'T;;)LL;)f
  254. [delete file if present]    (@h$r19k;)g
  255. [CP/M's DMA address]        ('80'H26k;)h
  256. [write one record]        (@Ej26%EZD0;128aqL26k31$r21kD'.'TL;) p
  257.  
  258. [CNVRT subroutines]        ("{
  259.                    {
  260.     [find/make FCB]        (Jj'TTY:'EQZD;('CTR:'Ez(8azZD;@b;)JZ;
  261.                  (':'UQD':'ED\64-%;0%;)
  262.                  ('.'U<(8a;@b;)Q|D>;Z'.DAT'IJj:)
  263.                   '.'FJDZ(3a;@b;)Q|JZDI;)
  264.                  32(dpGm$r0=npGpGd0&$Sm('CTR:'EZ
  265.                  $m16@`nS;@z;)npGQ&$rrS0;
  266.                  r12wQmwnEn;n:)D;) f
  267.     [form CTR and TTY block]    (@0n0|0|pL;) `
  268.     [blank fill by count]    (Zz(d' 'I:;)JZ;) b
  269.     [zero fill]            (cmpw0%(f:;)w;) 0
  270.     [zero FCB & buffer]        ($m33@0130@0nn&0||pLnS;) z
  271.     [set default input file]    (0,30$S'5C'H12GIA' 'E4@`
  272.                  31$S'TTY:'31$rrS; B9aQz(3a'   'E
  273.                  'DAT';Q;)|m31@zn31$rrS;) i
  274.     [open for read]        ($rpGr32+0&SpG^^pGr0&S^^-1&Sr15K
  275.                  (255='No File'I;L;)L;) r
  276.     [open for write]        ($rpGpG4+1&SrpG19k22k^^r128&S;) w
  277.     [open]            (pG('r'=-1mm;L1mm;)@q
  278.                  ('CTR:'=@f(0=;;)@!0&S;);L;) O
  279.     [get name]            ('CTR:'pGEnLnL;L''(AL@f(0=;'TTY:'(='T');))
  280.                  ('T'='';L31pG$rr12w'TTY:'Ew;w)nLnL;
  281.                  (pG$r4+r0=pGn@@nL;nLn=;L'R/W err'T_)) q
  282.     [counter default]        ($rr14+pGm1nSdd;) !
  283.     [signed # string]        (pG(32767N'';0&-'-';)&#|I;) n
  284.     [read]            (-1m'r'm@q('CTR:'=(@f0=@!0pGm1;$rr14+pGr
  285.                  mddpGrpGn&m;)+&Sn@n;L@&'> 'TL(@#I;:););
  286.                  $r(pG^^rpGmr(0=(npGpGm128&S^^26kpGr
  287.                  20K0=L;LL1npGpGm129+26%&SS;)npGmr;;)
  288.                  pG130&-n+&dm(u13%=;10%(=)pGI(26%=;
  289.                  L);ndm:)L^^rn&S;LpG^^r0&S:);) R
  290.     [write]            (Jj','U<1m'w'm@q('CTR:'=@f@j(0=;;)$rr
  291.                  12+pGj(','U<@l;Z','IJj:)@j&S^^@l
  292.                  (0=1;;)&S;L@jqtD;);@j<@g;) W
  293.     [get CTR const]        (('-'EQD;'';)(ZQDO;L0;)(&'-'=~;L;);) l
  294.     [comma in write]        (>','EDZ;) j
  295.     [write to disk]        ($r(pG^^rpGpGmrpGm- 130+n&maQD>Z<nSn^^
  296.                  26kpGr21kpG^^r128&S:JZQD>nSnSL;);) g
  297.     [close by number]        (pGm$rpG4+pGrm0&Sn(0=LnL;-1=nLr16k;LJj
  298.                  26%I<npGm@gpG^^rpGr127(N^^26kpGr21k;L;)
  299.                  r16k;);) c
  300.     [close all files]        (31pGm(pG$r0=L;L@cndpGm:)nL;;) E
  301.     [close by name]        ((A)31@c;@f'TTY:'=;0=L;@c;) C
  302.     [PVR]            (pG@&#'= '|TL$r(0='undef';yG;)TL;) _
  303.     [cr, lf]            (2573TL;)&
  304.     [insert cr, lf]        (2573I;)|
  305.     [read console]        (R13%='';08%(=)(T@#|;08%T' 'TLTLL@#;);)#
  306.     [display at logon]        ('[[]]'TL@&;)D
  307.     [write workspace]        (@&JZqt;)T
  308.                 (@@;) }%
  309.     [integer arithmetic]    {(+;)+ (-;)- (*;)* (/&L;)/
  310.                 (pGm/L1=nL1;0=n;n&:)|
  311.                  ((pGmJj(U);QD(O)I;npGmEDZQD(O)IjnpGmI;
  312.                  n@@'n'@%)nLJZ;;) } #
  313.     [save & init variables]    (pGpGm$rm0&$S;) (
  314.     [reinitialize variable]    (pG$r0=L;LnL0&$S;) :
  315.     [undefine variable]        ($r0=;LnL;) )
  316.     [compare/define variable]    (pG$r0=ZQzml&$S;&LyGEz;) ]
  317.     [body of variable search]    (pG$r(0=)yG(E;&L)z&L@=L;pG$r(0=;LL)
  318.                   Z<((&pGm&n(F;''mZz<)jJQmpGl&$S
  319.                   zZ<@=>;J>);nLA:0&$SL>)>LL;) >
  320.     [body of variable search]    (pG$r(0=)yGEz@=L;pG$r(0=;LL)
  321.                   Z<((jJQmpGl&$S
  322.                   zZ<@=>;J>);nLA:0&$S>)>L;) <
  323.     [insert variable]        ($ryGI;) [
  324.                 "I;) s
  325.  
  326. [CNVRT postscript]        (' ~'I 2573I
  327.                   "('i'@%'D'@%"I
  328.                   "(JA' 'EJZD 'R'@%;8a'.'IJj"I
  329.                   "1aQD0%=Z;\64+%I':'IJZ;)"I
  330.                   "@~JZqt'E'@%;)  }"I
  331.                 ;) u
  332.  
  333. [compile a CNVRT file]        (
  334.   [read max 1K from disk]      8(d(@y;;):;)
  335.   [change file extension]      J('.CNV]'FD'.REC]'Iz;;)
  336.   [find display message]      ('[['F']]'UQD;'cnvrt/icuap/1983';)
  337.   [look for code gap]          ('('Ej;2573pG|pG|E4b2aD;'['Ej;A:;)
  338.   [insert preface; to disk]      's'TL@s<'[[]]'FDIZ>z@P
  339.   [print comments, skip]      ('['E@&qtzZ<(@jJqtz;@kJ:)>:
  340.   [find prog, compile]           '('EzZ<(@d;@kJ:)J>B't'TL@t@P:
  341.                    A:@y:;)
  342.   [insert postscript]          J(26%Fj;Zz;)((B);'}'Ez;:)'u'TL@u@P
  343.   [close file]                @H
  344.                 ;) w
  345.  
  346. [append a record]        (128(e)L;qL26k30$r20K0=L;DLL@h) y
  347. [append, stop on eof]        (@y;'Stx err'TL_;) k
  348. [back to line feed]        (10%Ez;B:j;) 0
  349. [bracket a line]        (@010%V;Z;) 1
  350. [back to preceding line]    (@0BB@0;;) 2
  351. [cr,lf]                (2573TL;) &
  352. [read w/error correction]    (RT95%=127%;13%=2573;26%(=);) $
  353. [clear screen]            (26%TL;) !
  354. [erase on ro, insert others]    (127%=z(B;;)D;I;) :
  355. [form next window]        (Zz>@W@!;) >
  356. [cancel line]            (24%TL;) ^
  357.  
  358. (    'd' [delete] =        (ABD;;);
  359.     'i' [insert] =        (@D@$@::;)@!;
  360.     'j' [beginning] =    Jj;
  361.     'x' [exchange] =    (ABD;;)RTI;
  362.     'z' [to end] =        Z;
  363.     127%[delete] =        @1D@!;
  364.     10% [down arrow] =    (10%FA;J>(10%FA;;)@Wz@!;;)@!;
  365.     13% [carr ret] =    @0;
  366.     11% [up arrow] =    (BA@2;J>@2@Wj@!;;);
  367.     08% [left arrow] =    (Bj;;);
  368.     'n' [next record] =    >(@p;L;)(@y;;)J(@W;;);
  369.     'p' [write 1 record] =    >(@p;L;)J(@W;;);
  370.     'P' [dump to cursor] =    >@P248%I@2(@W;;)J248%FD;
  371.     'y' [read 1 record] =    >(@y;'eof:'TL;)J(@W;;);
  372.     'Y' [read file] =    >(@y:;)J(@W;;)Jj;
  373.     ' ' [advance] =        (A;;);
  374.     '>' [next window] =    (@>j;>@I;);
  375.     '<' [beg window] =    >@I;
  376.     ',' [end of line] =    (2573Fj;Zz;)@!;
  377.     '.' [refresh screen] =    @!;
  378.     's'            = @s;
  379.     't'            = >@t@!(@W;;)Jj;
  380.     'u'            = @u;
  381.     'w'            = >@wJ<(26%Fj;Z;)J><;
  382.     ) ?
  383.  
  384. [main program]            (
  385.     [create FCB's, open files]     30@F 31@F @G
  386.     [sign-on message]         'cnvrt.rec> 'TL
  387.     [automatic compilation]     ('5C'H12wAqt@&3b' 'Ew@w;w);
  388.     [wait, initialize, loop]     RTL @I (@DR
  389.     [exit at once]             ';'=;
  390.     [close, exit]             'e'=>@H;
  391.     [read menu]             @?:
  392.     [ignore unknown]         L:);)}
  393.  
  394. [end]
  395.