home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol157 / settime.a86 < prev    next >
Encoding:
Text File  |  1985-03-14  |  4.2 KB  |  181 lines
  1. ; DATE 12/07/83  17:20         last revision
  2.  
  3.     TITLE    'Set System Time v1.0'
  4. ; SETTIME.A86
  5. ; H. M. Van Tassell 120 Hill Hollow Road, Watchung, NJ 07060 201-755-5372
  6. ; A program to set the MP/M or CP/M Plus clock and print time on screen
  7. ; Intended to be run at system start-up.
  8.  
  9. ; This program reads the Compupro System Support Clock but can
  10. ; be used with any similar clock. The hard part is the date conversion
  11. ; to Julian.
  12.  
  13. ; This get time routine was first written to be included in the
  14. ; BIOS or XIOS to set system clock and keep time using a one sec tick
  15. ; interrupt from a timer or some other tick generator
  16.  
  17. ; RASM86 SETTIME $SZPZ
  18. ; LINK86 SETTIME
  19.  
  20. ; if you dont have RASM86 you may use ASM86 and GENCMD.
  21.  
  22.  
  23. CR        equ    0Dh
  24. LF        equ    0Ah
  25.  
  26. PORT_BASE    equ    050h
  27. CLKCMD        equ    PORT_BASE + 10
  28. CLKDATA        equ    PORT_BASE + 11
  29.  
  30.     
  31.     CSEG
  32.  
  33.     call gettime        ;read system support clock
  34.     mov dx,offset ascii_str ;print time on the screen
  35.     mov cl,9
  36.     int 224
  37.     mov dx,offset bin_str    ;send time to system storage
  38.     mov cl,104
  39.     int 224
  40.     mov cl,0        ;quit
  41.     mov dl,0
  42.     int 224
  43.  
  44. ;****************************************
  45. ;*                    *
  46. ;*    Routine to get    time        *
  47. ;*                    *
  48. ;****************************************
  49. ;-------
  50. gettime:
  51. ;-------
  52. ;
  53. ; read time from system support clock and put into both
  54. ; a date string in ascii and the sysdata block
  55. ; the datestr can be used to print time on console
  56. ; 
  57.     mov    si,0        ;start reading at seconds
  58.     mov    di,17        ; into datestr
  59.     call    rtwo
  60.     mov    tod_sec,ah
  61. ;    cmp    ah,0        ;is sec=0?
  62. ;    jne    get_exit
  63. ;    call    rtwo
  64. ;    mov    tod_min,ah
  65. ;    cmp    ah,0        ;is min=0?
  66. ;    jne    get_exit
  67. ;    call    rtwo
  68. ;    mov    tod_hr,ah
  69. ;    cmp    ah,0        ;if hr=0 it's midnite
  70. ;    jne    get_exit
  71. ;
  72. ; get date into date string and convert calender
  73. ; date to julian date (1/1/78)
  74. ;
  75. set_date:
  76.     mov    si,2        ;ptr to min in digtab
  77.     mov    di,14        ;ptr to min in datestr
  78.     call    rtwo        ;set min & hr for init. call
  79.     mov    tod_min,ah
  80.     call    rtwo
  81.     mov    tod_hr,ah
  82.     dec    di        ;skip over space
  83. ctoj:    call    rtwo        ;convert date to julian
  84.     mov    bh,0        ;get yr as bin in al
  85.     mov    bl,al        ;bx=year-1900
  86.     mov    di,1        ;point to month
  87.     call    rtwo        ;get month into al
  88.     sub    al,3        ;is month in mar-feb of "year"
  89.     jnc    ctoj1
  90.     add    al,12        ;jan or feb become 10,11
  91.     dec    bx        ;...of prior year
  92. ctoj1:    xor    ah,ah        ;bx="year"
  93.     push    ax        ;ax="month",save it
  94.     mov    ax,1461        ;mult "year" by leap year cycle
  95.     mul    bx        ;bx*ax=[dx,ax]
  96.     mov    cx,4        ;divide by 4
  97.     xor    dh,dh
  98.     div    cx        ;[dx,ax]/cx=ax (quotient)
  99.     mov    bx,ax        ;save quotient in bx
  100.     pop    ax        ;restore "month"
  101.     push    bx        ;save ("year"*1461)/4
  102.     mov    bx,153        ;mult "month" by 153
  103.     mul    bx        ;bx*ax=[dx,ax]
  104.     inc    ax
  105.     inc    ax        ;add 2 to low order bits
  106.     mov    cx,5        ;divide by 5
  107.     xor    dh,dh
  108.     div    cx        ;ax=("month"*153+2)/5
  109.     pop    bx        ;bx=("year"*1461)/4
  110.     add    bx,ax        ;add em
  111.     mov    di,4        ;point to days
  112.     call    rtwo        ;get days into al
  113.     mov    ah,0
  114.     add    ax,bx        ;add days
  115.     sub    ax,28429+1    ;convert to 1/1/78
  116.     mov    tod_day,ax    ;stash it away
  117. get_exit: ret
  118.  
  119. ;
  120. ; get 2 bcd clock digits and update string
  121. ; and convert to binary & bcd time digits
  122. ;
  123. rtwo:    call    rone        ;get lo order digit in al
  124.     mov    dl,al        ;save it in reg dl
  125.     add    al,'0'        ;convert to ascii
  126.     mov    datestr[di],al ;and put in buffer
  127.     dec    di        ;backup in string
  128.     call    rone        ;get hi order digit
  129.     mov    dh,al        ;save it in dh
  130.     add    al,'0'
  131.     mov    datestr[di],al
  132.     dec di! dec di        ;backup over sepr
  133.     mov    al,dh        ;recover hi digit
  134.     mov    cl,10        ;mult by 10
  135.     mul    cl        ;al=10*digit
  136.     add    al,dl        ;add lo digit
  137.     mov    cl,4        ;rotate hi order bcd
  138.     rol    dh,cl        ;...into hi nibble
  139.     add    dh,dl        ;and add low order bcd
  140.     mov    ah,dh        ;ah=bcd time digit
  141.     ret            ;al=binary time digit
  142. ;
  143. ; get a bcd clock digit into al
  144. ; enter: si  point to digtab
  145. ;
  146. rone:    mov    al,digtab[si]        ;get the digit number
  147.     inc    si            ;bump to next digit
  148.     add    al,10h            ;add read mask
  149.     out    clkcmd,al    
  150.     cmp    al,15h            ;is it hours 10 digit
  151.     in    al,clkdata
  152.     jnz    rone9
  153.     sub    al,08h            ;yes-kill 24 hour bit
  154. rone9:    and    al,0fh            ;strip irrelevant bits
  155.     ret                ;al=bcd clock digit
  156.  
  157.  
  158.     eject
  159.     DSEG
  160. ;********************************
  161. ;*                *
  162. ;*    data for routine    *
  163. ;*                *
  164. ;********************************
  165.  
  166. bin_str        rs    0
  167. tod_day        rw    1
  168. tod_hr        rb    1
  169. tod_min        rb    1
  170. tod_sec        db    0
  171.  
  172. ascii_str    db    CR,LF
  173.         db    'System time set '
  174. datestr        db    'MM/DD/YY  '     ;date string
  175. timestr        db    'HH:MM:00'     ;time string
  176.         db    CR,LF,'$'
  177.  
  178. digtab    db    0,1,2,3,4,5,11,12,9,10,7,8
  179. ;        ss  mm  hh   yy   mm   dd
  180.  
  181.     end