home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol146 / whatsnew.a86 < prev    next >
Encoding:
Text File  |  1984-04-29  |  19.2 KB  |  1,033 lines
  1.  
  2.     TITLE    'WHATSNEW version 2.1A'
  3. ; DATE 10/06/83  18:10
  4. ; by: H.M. Van Tassell  120 Hill Hollow Rd, Watchung NJ 07060 (201)755-5372
  5. ;
  6. ; This is a slightly modified version of D.A86 
  7. ;    1. Name changed
  8. ;    2. Help file called if WHATSNEW //
  9. ;    3. Clock read routine supported
  10.  
  11.  
  12. ;                         D.A86 Version 2.1
  13. ;                 Restricted Directory List Program
  14. ; 
  15. ;        Originally written for CP/M-80, by Ward Christensen
  16. ; 
  17. ;                   (Revised from D.ASM 05/17/82)
  18. ; 
  19. ; This  program produces a directory listing.   It also maintains a 
  20. ; list of names not to display.   Thus it can be used to keep track 
  21. ; of  the "non standard" files on a disk.   CP/M attribute bits are 
  22. ; not considered part of the file name for comparison purposes.
  23. ; 
  24. ;                           - Examples -
  25. ;        NOTE: read D as WHATSNEW in examples
  26. ; 
  27. ; D *.*<cr>      Prints all names, 5 across
  28. ; 
  29. ; D *.A86<cr>    Prints selected files just like DIR
  30. ; 
  31. ; D  SET<cr>     Builds a table (in D.CMD) of all names  currently 
  32. ;                on the disk
  33. ; 
  34. ; D  SET  <date><cr>     Adds the date for printing whenever  D  is 
  35. ; called by 'A>D<cr>' with no options.   If the date field is  left 
  36. ; blank,  it  will  be  ignored.    Note that the date  must  be  8 
  37. ; characters or less.
  38. ; 
  39. ; D  ADD  fn.ft<cr>  Adds a name to the table in  D.CMD,  so  fn.ft 
  40. ; won't be listed by the 'D' command
  41. ; 
  42. ; D  DEL fn.ft<cr>  Deletes a name from the table in D.CMD,  so  if 
  43. ; fn.ft is in the directory, it will be listed by 'D'
  44. ; 
  45. ; D<cr>     Lists the directory 5 across,  listing only those files 
  46. ; not in D.CMD, as put there by 'D SET' or 'D ADD fn.ft' command
  47. ; 
  48. ;              - Special Notes For Remote System Use -
  49. ; 
  50. ; If  you  keep a dedicated copy of this program on each  drive  of 
  51. ; your remote system,  you can 'dedicate' each copy of this program 
  52. ; to  a drive by filling in the byte at 104h with the drive number.  
  53. ; 
  54. ; This prevents such things as:
  55. ; 
  56. ; A>D B:<cr>
  57. ; 
  58. ; or
  59. ; 
  60. ; B>A:D<cr>
  61. ; 
  62. ; Do this by using the command:
  63. ; 
  64. ; A>D LOK A:<cr>    To lock to a drive
  65. ; 
  66. ; or
  67. ; 
  68. ; A>D LOK<cr>     To unlock
  69. ; 
  70. ; If the conditional 'NOSYS' is set true,  $SYS files in CP/M  will 
  71. ; be  ignored in both directory listings and when the "ADD"  option 
  72. ; is invoked,  unless the override char is specified.   This allows 
  73. ; D.CMD  to  be used as a "what's new" program for  remote  CP/M-86 
  74. ; systems, where the $SYS files must not be listed.
  75. ; 
  76. ;                           - Examples -
  77. ; 
  78. ; A>D *.* S<cr>     Displays everything
  79. ; 
  80. ; A>D SET S<cr>     Puts all files in table
  81. ; 
  82. ; A>D  SET 05/17/82<cr>     Sets date for reference (if you use  'D 
  83. ; SET S<cr>', you lose the date option....sorry about that).
  84. ; 
  85. ; If you use this program on a remote system,  you will likely want 
  86. ; to  change the commands (ADD,  DEL,  and SET) for security.   You 
  87. ; will  also want to change the $SYS suppress  override  character.  
  88. ; 
  89. ; You  may also want to change the name of the program to make  the 
  90. ; name itself more informative (e.g. "WHATSNEW.CMD").
  91. ; 
  92. ; If  you  want the program to be 'tag'ed after every D SET (so  it 
  93. ; cannot  be taken by xmodem),  see the note at label "WRBACK"  for 
  94. ; setting the F1 bit in the filename itself.
  95. ; 
  96. ; Note  that  this  program defines its  own  name  for  write-back 
  97. ; purposes under the label "WRBACK".
  98. ; 
  99. ;                     - Modification History -
  100. ; 
  101. ; 05/17/82:  Revised and translated for CP/M-86 operation, by Kelly 
  102. ; Smith.
  103. ; 
  104. ; 12/23/80:  Changed  sign-on message,  revised  documentation,  by 
  105. ; Keith Petersen, W8SDZ.
  106. ; 
  107. ; 12/22/80:  Fixed stack and file extent problems.   Fully expanded 
  108. ; macros  so  ASM may be used.   Fixed problem in LOK  routine,  by 
  109. ; Keith Petersen, W8SDZ.
  110. ; 
  111. ; 12/07/80:  Added  drive  select byte and expanded move  macro  in 
  112. ; WRBACK routine.  Also added "LOK" command, by Ron Fowler.
  113. ; 
  114. ; 12/02/80:  Added "NOSYS" equate to ignore system files,  code  to 
  115. ; strip attributes from files for CP/M 2.x,  added date display and 
  116. ; print options.  fixed up display format, by Ron Fowler.
  117. ; 
  118. ; 12/01/80:  Added  "files  not found" feature of updated D.ASM  of 
  119. ; Ward Christensen.  By Ron Fowler.
  120. ; 
  121. ; 11/23/78: Originally written by Ward Christensen.
  122. ; 
  123. ;
  124. ; 
  125. false    EQU    0
  126. true    EQU    not false
  127. ; 
  128. CLOCK    EQU    TRUE        ;set true if you supply system clock read
  129.                 ;... read routine RDTIME
  130. ; bdos equates
  131. ; 
  132. rdcon    EQU    1
  133. print    EQU    9
  134. const    EQU    11
  135. close    EQU    16
  136. srchf    EQU    17
  137. srchn    EQU    18
  138. erase    EQU    19
  139. read    EQU    20
  140. write    EQU    21
  141. make    EQU    22
  142. curdsk    EQU    25
  143. setdma    EQU    26
  144. ; 
  145. ; 
  146. bdos    EQU    5
  147. fcb    EQU    5ch
  148. fcbrno    EQU    fcb+32
  149. ;
  150. g_form        EQU    80h    ; base of group descriptor for D.CMD file
  151. g_length    EQU    81h    ; group length
  152. g_min        EQU    85h    ; group minimum size
  153. ;
  154. M    EQU    Byte Ptr 0[BX]
  155. ;
  156. cr    EQU    13            ; carriage return
  157. lf    EQU    10            ; line feed
  158. tab    equ    09
  159. cls    equ    1ah
  160. ; 
  161. nosys    EQU    false            ; set true to ignore system files
  162. fence    EQU    '|'            ; filename separator
  163. npl    EQU    4            ; names per line
  164. sysok    EQU    'S'            ; override char for sys suppression
  165. ; 
  166.     ORG    100h
  167. ; 
  168. dentry:    JMPS    around
  169. ; 
  170. drive    DB    0            ; <---drv # is put here if dedicated
  171. ; 
  172. ; init local stack
  173. ; 
  174. around:    CALL    start
  175. ;
  176.     DB    'WHATSNEW version 2.1A',cr,lf,'$'
  177. ; 
  178. ; print id message
  179. ; 
  180. start:    POP    DX            ; get id address
  181.     MOV    CL,print        ; get print fnc
  182.     INT    224            ; print id msg
  183. ; 
  184. ; set file control block
  185. ; 
  186.     MOV    AL,Byte Ptr drive
  187.     OR    AL,AL            ; non-dedicated?
  188.     JZ    nond            ; jump if so
  189.     MOV    Byte Ptr .fcb,AL
  190. ; 
  191. nond:    MOV    AL,Byte Ptr .fcb+17    ; get sys override char
  192.     MOV    Byte Ptr systoo,AL    ; save for later
  193. ; 
  194. ; see if request for help
  195. ; 
  196.     MOV    BX,fcb+1
  197.     CALL    hlpcm1
  198. hlpcm    DB    '//         '
  199. ; 
  200. hlpcm1:    POP    DX            ; get to
  201.     MOV    CX,(Offset hlpcm1)-(Offset hlpcm)
  202.     CALL    compr
  203.     JNZ    nohlp
  204.  
  205.     MOV    DX,OFFSET HELPMSG
  206.     MOV    CL,print
  207.     INT    224
  208.     MOV    CL,0    
  209.     MOV    DL,0
  210.     INT    224
  211. ; 
  212. ; see if request to add name to list
  213. ; 
  214. nohlp:    MOV    BX,fcb+1
  215.     CALL    addcm2
  216. addcm    DB    'ADD        '
  217. ; 
  218. addcm2:    POP    DX            ; get to
  219.     MOV    CX,(Offset addcm2)-(Offset addcm)
  220.     CALL    compr
  221.     JNZ    noadd
  222. ; 
  223. ; got request to add name to table
  224. ; 
  225.     CALL    delnam            ; first, delete the name
  226.     CALL    findff            ; find end of table
  227.     XCHG    BX,DX            ; addr to de
  228. ; 
  229. ; move name to table
  230. ; 
  231.     MOV    BX,fcb+17
  232.     MOV    CX,11
  233.     CALL    mover
  234.     MOV    AL,0ffh
  235.     MOV    SI,DX            ; set new end
  236.     MOV    [SI],AL
  237.     JMP    wrback            ; write program back
  238. ; 
  239. ; see if request to lock D.CMD to a drive
  240. ; 
  241. noadd:    MOV    BX,fcb+1
  242.     CALL    noadd3
  243. noadd2    DB    'LOK        '
  244. ; 
  245. noadd3:    POP    DX            ; get to
  246.     MOV    CX,(Offset noadd3)-(Offset noadd2)
  247.     CALL    compr
  248.     JNZ    nolok
  249. ; 
  250. ; got request to lock
  251. ; 
  252.     MOV    AL,Byte Ptr .fcb+16
  253.     MOV    Byte Ptr drive,AL
  254.     MOV    Byte Ptr .fcb,AL
  255.     JMP    wrback
  256. ; 
  257. ; see if request to del name from list
  258. ; 
  259. nolok:    MOV    BX,fcb+1
  260.     CALL    nolok3
  261. nolok2    DB    'DEL        '
  262. ; 
  263. nolok3:    POP    DX            ; get to
  264.     MOV    CX,(Offset nolok3)-(Offset nolok2)
  265.     CALL    compr
  266.     JNZ    nodel
  267. ; 
  268. ; got request to delete a name from the file
  269. ; 
  270.     CALL    delnam            ; delete the name
  271.     JNAE    L_3    
  272.     JMP    wrback            ; write back if ok
  273. L_3:
  274.     CALL    msgxit
  275.     DB    '++Name Not In Table++$'
  276. ; 
  277. ; see if request to setup table from directory
  278. ; 
  279. nodel:    MOV    BX,fcb+1
  280.     CALL    nodel3
  281. nodel2    DB    'SET        '
  282. ; 
  283. nodel3:    POP    DX            ; get to
  284.     MOV    CX,(Offset nodel3)-(Offset nodel2)
  285.     CALL    compr
  286.     JNZ    noset
  287. ; 
  288. ; got request to setup table.  move the date (may be blank).
  289. ; 
  290.     IF  NOT CLOCK
  291.     MOV    BX,fcb+17
  292.     MOV    DX,(Offset date)
  293.     MOV    CX,8
  294.     CALL    mover
  295.     ENDIF    ;NOT CLOCK
  296.  
  297.  
  298. RDTIME:    ;PUT YOUR CLOCK ROUTINE HERE AND SET CLOCK EQUATE TRUE
  299.     IF    CLOCK            ;COMPUPRO CLOCK ROUTINE
  300. CLKCP    EQU    50H+10            ;CLOCK COMMAND PORT
  301.  
  302.     MOV    BX,OFFSET DATE         ;POINT TO DATE STRING
  303.     MOV    SI,OFFSET DIGTAB     ;POINT TO DIGIT TABLE
  304.     MOV    CL,3            ;READ TWO COUNTER
  305. RTWO:    MOV    CH,2            ;READ ONE COUNTER
  306. ;
  307. ; READ A DIGIT FROM CLOCK CHIP
  308. ; ENTRY: SI => DIGIT TABLE DATA ENTRY
  309. ;        BX => STRING POSITION
  310. ; EXIT:  ASCII DIGIT LOADED IN STRING
  311. ;        SI & BX INCREMENTED
  312. ;
  313. RONE:    MOV    AL,[SI]        ;GET DIGIT TABLE DATA
  314.     INC    SI        ;BUMP TO NEXT ENTRY
  315.     ADD    AL,10H        ;SET READ BIT
  316.     OUT    CLKCP,AL    ;OUTPUT DIGIT DATA
  317.     CMP    AL,15H        ;CHECK FOR HOURS 10 DIGIT
  318.     IN    AL,CLKCP+1    ;READ BCD DIGIT FROM CLOCK
  319.     JNE    NOHOUR
  320.     SUB    AL,8
  321. NOHOUR:    ADD    AL,'0'        ;MAKE ASCII
  322.     MOV    [BX],AL
  323.     INC    BX        ;POINT TO NEXT STR POSITION
  324.     DEC    CH
  325.     JNZ    RONE        ;GET SECOND DIGIT
  326.     INC    BX        ;BUMP OVER SEPERATOR
  327.     DEC    CL
  328.     JNZ    RTWO        ;READ TWO MORE DIGITS
  329.     JMPS    GOTOIT        ;GO TO IT
  330.  
  331. DIGTAB    DB    10,9,8,7,12,11    ;CLOCK DIGIT TABLE
  332.     ENDIF    ;CLOCK
  333.  
  334. GOTOIT:    MOV    AL,1            ; turn on..
  335.     MOV    Byte Ptr setflg,AL    ; ..set flag
  336.     MOV    AL,0ffh            ; clear..
  337.     MOV    Byte Ptr names,AL    ; ..names table
  338.     CALL    fillq            ; make fcb '????????.???'
  339. ; 
  340. noset:    MOV    AL,Byte Ptr .fcb+1
  341.     SUB    AL,' '
  342.     MOV    Byte Ptr prtflg,AL
  343.     LAHF
  344.     XCHG    AL,AH
  345.     PUSH    AX
  346.     JNZ    L_4    
  347.     CALL    head1
  348. L_4:
  349.     POP    AX
  350.     XCHG    AL,AH
  351.     SAHF
  352.     JNZ    gotnam
  353.     CALL    fillq            ; make name ????????.???
  354. ; 
  355. gotnam:    MOV    AL,Byte Ptr .fcb
  356.     OR    AL,AL
  357.     JZ    nodisk
  358.     DEC    AL
  359.     MOV    DL,AL
  360.     MOV    CL,0eh
  361.     INT    224
  362. ; 
  363. nodisk:    MOV    CH,npl            ; names per line
  364.     CALL    linmrk
  365.     MOV    CL,srchf
  366.     JMPS    callit
  367. ; 
  368. line:    MOV    CH,npl            ; names per line
  369.     CALL    linmrk
  370. ; 
  371. next:    MOV    CL,srchn
  372. ; 
  373. callit:    PUSH    CX
  374.     PUSH    CX
  375.     MOV    CL,const
  376.     INT    224
  377.     OR    AL,AL
  378.     POP    CX
  379.     JZ    L_5    
  380.     JMP    cexit
  381. L_5:
  382.     MOV    DX,fcb
  383.     INT    224
  384.     INC    AL
  385.     JNZ    L_6    
  386.     JMP    cknone
  387. L_6:
  388.     DEC    AL
  389.     AND    AL,03h
  390.     MOV    BL,AL
  391.     MOV    BH,00h
  392.     SHL    BX,1
  393.     SHL    BX,1
  394.     SHL    BX,1
  395.     SHL    BX,1
  396.     SHL    BX,1
  397.     MOV    DX,81h
  398.     ADD    BX,DX
  399. ; 
  400. ; check for $sys attribute, then clear all attributes
  401. ; 
  402.     PUSH    BX
  403.     MOV    DX,9            ; sys att offset
  404.     ADD    BX,DX
  405.     MOV    AL,M
  406.     AND    AL,80h
  407.     MOV    Byte Ptr sysflg,AL
  408.     POP    BX            ; retrieve filename ptr
  409.     PUSH    BX
  410.     MOV    DL,11            ; 11 chars in filename
  411. ; 
  412. attlp:    MOV    AL,M            ; pick up char
  413.     AND    AL,7fh            ; kill attribute
  414.     MOV    M,AL            ; put back down
  415.     INC    BX
  416.     DEC    DL
  417.     JNZ    attlp
  418.     POP    BX
  419. ; 
  420. ; see if name is to be printed
  421. ; 
  422.     XCHG    BX,DX            ; name pointer to de
  423.     MOV    AL,Byte Ptr setflg    ; request to setup table?
  424.     OR    AL,AL
  425.     JZ    L_7    
  426.     JMP    setup            ; go set entry into table
  427. L_7:
  428.     MOV    AL,Byte Ptr prtflg
  429.     OR    AL,AL
  430.     JNZ    goprnt            ; explicit request for all
  431.     PUSH    DX
  432.     MOV    BX,(Offset names)
  433. ; 
  434. cknext:    POP    DX            ; get name pointer
  435.     POP    CX
  436.     PUSH    CX
  437.     MOV    AL,M            ; end of table?
  438.     INC    AL            ; was it 0ffh?
  439.     JZ    goprnt
  440.     MOV    CH,0
  441.     MOV    CL,11            ; name length
  442.     PUSH    DX
  443. ; 
  444. cklp:    MOV    SI,DX
  445.     MOV    AL,[SI]
  446.     CMP    AL,M
  447.     JNZ    nomach
  448.     INC    DX
  449.     INC    BX
  450.     DEC    CL
  451.     JNZ    cklp            ; loop for 11 chars
  452. ; 
  453. ; got match, mark it found and don't print it
  454. ; 
  455.     MOV    DX,-11            ; point back to name
  456.     ADD    BX,DX
  457.     MOV    M,0            ; mark it found
  458.     POP    DX            ; pop pointer
  459.     POP    CX
  460.     JMP    next            ; skip the name
  461. ; 
  462. ; name didn't match, try next
  463. ; 
  464. nomach:    ADD    BX,CX            ; point to next name
  465.     JMPS    cknext
  466. ; 
  467. ; print the name
  468. ; 
  469. goprnt:
  470.     if    nosys
  471.     MOV    AL,Byte Ptr systoo
  472.     CMP    AL,sysok
  473.     JZ    doname
  474.     MOV    AL,Byte Ptr sysflg
  475.     RCL    AL,1
  476.     POP    CX
  477.     JNB    L_8    
  478.     JMP    next
  479. L_8:
  480.     PUSH    CX
  481.     endif
  482. ; 
  483. doname:    MOV    AL,1            ; say we got one
  484.     MOV    Byte Ptr gotflg,AL
  485.     MOV    CL,8
  486.     XCHG    BX,DX            ; name back to hl
  487. ; 
  488. namelp:    MOV    AL,M
  489.     CALL    display
  490.     LAHF
  491.     INC    BX
  492.     SAHF
  493.     DEC    CL
  494.     JNZ    namelp
  495.     MOV    AL,'.'
  496.     CALL    display
  497.     MOV    CL,3
  498. ; 
  499. nlp2:    MOV    AL,M
  500.     CALL    display
  501.     LAHF
  502.     INC    BX
  503.     SAHF
  504.     DEC    CL
  505.     JNZ    nlp2
  506.     POP    CX
  507.     MOV    AL,' '
  508.     CALL    display
  509.     MOV    AL,fence
  510.     DEC    CH
  511.     LAHF
  512.     XCHG    AL,AH
  513.     PUSH    AX
  514.     XCHG    AL,AH
  515.     JZ    L_9    
  516.     CALL    display
  517. L_9:
  518.     MOV    AL,' '
  519.     CALL    display
  520.     POP    AX
  521.     XCHG    AL,AH
  522.     SAHF
  523.     JZ    L_10    
  524.     JMP    next
  525. L_10:
  526.     CALL    crlf
  527.     JMP    line
  528. ; 
  529. cknone:    MOV    AL,Byte Ptr gotflg
  530.     OR    AL,AL
  531.     JNZ    notfnd
  532.     MOV    AL,Byte Ptr prtflg
  533.     OR    AL,AL
  534.     JNZ    notfnd
  535.     MOV    DX,(Offset nonmsg)    ; print "none"
  536.     MOV    CL,print
  537.     INT    224
  538. ; 
  539. ; print the files not found
  540. ; 
  541. notfnd:    MOV    AL,Byte Ptr setflg    ; is this 'd set'?
  542.     OR    AL,AL
  543.     JZ    L_11    
  544.     JMP    fini            ; done if so
  545. L_11:
  546.     MOV    AL,Byte Ptr prtflg    ; are we printing?
  547.     OR    AL,AL
  548.     JZ    L_12    
  549.     JMP    cknon2            ; done if not
  550. L_12:
  551. ; 
  552. ; if this D.CMD is dedicated ("drive" is non-zero),
  553. ; then be sure to print the "files not found"
  554. ; 
  555.     MOV    AL,Byte Ptr drive
  556.     OR    AL,AL
  557.     JNZ    nochk
  558.     MOV    AL,Byte Ptr .fcb    ; drive specified?
  559.     OR    AL,AL
  560.     JZ    L_13    
  561.     JMP    fini            ; skip not found if so
  562. L_13:
  563. ; 
  564. nochk:    CALL    head2            ; print not fnd header
  565.     MOV    BX,(Offset names)    ; start of table
  566.     MOV    DX,11
  567. ; 
  568. line2:    CALL    linmrk
  569.     MOV    CL,npl
  570. ; 
  571. next2:    MOV    AL,M            ; first char of name
  572.     OR    AL,AL            ; marked found?
  573.     JZ    noprnt            ; jump if so
  574.     INC    AL            ; check for table end
  575.     JNZ    L_14    
  576.     JMP    cknon2            ; jump if end
  577. L_14:
  578.     MOV    AL,1
  579.     MOV    Byte Ptr gotnf,AL
  580.     MOV    CH,8
  581. ; 
  582. namlp2:    MOV    AL,M
  583.     CALL    display
  584.     LAHF
  585.     INC    BX
  586.     SAHF
  587.     DEC    CH
  588.     JNZ    namlp2
  589.     MOV    AL,'.'
  590.     CALL    display
  591.     MOV    CH,3
  592. ; 
  593. nlp3:    MOV    AL,M
  594.     CALL    display
  595.     LAHF
  596.     INC    BX
  597.     SAHF
  598.     DEC    CH
  599.     JNZ    nlp3
  600.     MOV    AL,' '
  601.     CALL    display
  602.     MOV    AL,fence
  603.     DEC    CL
  604.     LAHF
  605.     XCHG    AL,AH
  606.     PUSH    AX
  607.     XCHG    AL,AH
  608.     JZ    L_15    
  609.     CALL    display
  610. L_15:
  611.     MOV    AL,' '
  612.     CALL    display
  613.     POP    AX
  614.     XCHG    AL,AH
  615.     SAHF
  616.     JNZ    next2
  617.     CALL    crlf
  618.     JMPS    line2
  619. ; 
  620. noprnt:    ADD    BX,DX
  621.     JMPS    next2
  622. ; 
  623. ; print header
  624. ; 
  625. head1:    MOV    DX,(Offset newmsg)
  626.     JMPS    hedprt
  627. ; 
  628. head2:    MOV    DX,(Offset delmsg)
  629. ; 
  630. hedprt:    MOV    CL,print
  631.     INT    224
  632.     MOV    AL,Byte Ptr date
  633.     CMP    AL,' '
  634.     JZ    nodate
  635.     CMP    AL,sysok
  636.     JZ    nodate
  637.     MOV    DX,(Offset asof)
  638.     MOV    CL,print
  639.     INT    224
  640. ; 
  641. nodate:    MOV    AL,':'
  642.     CALL    display
  643.     JMPS    crlf
  644. ; 
  645. cknon2:    MOV    AL,Byte Ptr gotnf
  646.     OR    AL,AL
  647.     JZ    L_16    
  648.     JMP    fini            ; jmp if got no 'not found's
  649. L_16:
  650.     MOV    AL,Byte Ptr prtflg
  651.     OR    AL,AL
  652.     JZ    L_17    
  653.     JMP    fini
  654. L_17:
  655.     MOV    DX,(Offset nonmsg)
  656.     MOV    CL,print        ; else print 'none'
  657.     INT    224
  658.     JMP    fini
  659. ; 
  660. ; set up the name in the table
  661. ; 
  662. setup:
  663.     if    nosys
  664.     MOV    AL,Byte Ptr systoo
  665.     CMP    AL,sysok
  666.     JZ    setu2
  667.     MOV    AL,Byte Ptr sysflg
  668.     RCL    AL,1
  669.     JB    setskp
  670.     endif
  671. ; 
  672. setu2:    CALL    findff            ; find end of table
  673.     XCHG    BX,DX            ; setup for move
  674. ; 
  675. ; (hl = name, de = end of table)
  676. ; 
  677.     MOV    CX,11
  678.     CALL    mover
  679.     MOV    AL,0ffh            ; get table end flag
  680.     MOV    SI,DX            ; store it
  681.     MOV    [SI],AL
  682. ; 
  683. setskp:    POP    CX            ; delete stack garbage
  684.     JMP    next            ; get next entry
  685. ; 
  686. crlf:    MOV    AL,cr
  687.     CALL    display
  688.     MOV    AL,lf
  689. ; 
  690. display:
  691. ;
  692.     PUSH    CX
  693.     PUSH    DX
  694.     PUSH    BX
  695.     MOV    DL,AL
  696.     MOV    CL,02h
  697.     INT    224
  698.     POP    BX
  699.     POP    DX
  700.     POP    CX
  701.     RET
  702. ; 
  703. ; move routine
  704. ; 
  705. mover:    MOV    AL,M
  706.     MOV    SI,DX
  707.     MOV    [SI],AL
  708.     INC    DX
  709.     INC    BX
  710.     DEC    CX
  711.     MOV    AL,CH
  712.     OR    AL,CL
  713.     JNZ    mover
  714.     RET
  715. ; 
  716. ; compare routine
  717. ; 
  718. compr:    MOV    SI,DX
  719.     MOV    AL,[SI]
  720.     CMP    AL,M
  721.     JZ    L_18
  722.     RET
  723. L_18:
  724.     INC    DX
  725.     INC    BX
  726.     DEC    CX
  727.     MOV    AL,CH
  728.     OR    AL,CL
  729.     JNZ    compr
  730.     RET                ; equal
  731. ; 
  732. ; routine to find 0ffh at end of table
  733. ; 
  734. findff:    MOV    BX,(Offset names)
  735. ; 
  736. findlp:    MOV    AL,M
  737.     LAHF
  738.     INC    BX
  739.     SAHF
  740.     INC    AL            ; 0ffh?
  741.     JNZ    findlp
  742.     LAHF                ; back up to table end
  743.     DEC    BX
  744.     SAHF
  745.     RET
  746. ; 
  747. ; delete the name from the table
  748. ; 
  749. delnam:    MOV    BX,(Offset names)
  750. ; 
  751. dellp:    MOV    AL,M
  752.     CMP    AL,0ffh
  753.     STC
  754.     JNZ    L_19    
  755.     RET                ; not found
  756. L_19:
  757.     MOV    DX,fcb+17
  758.     MOV    CX,11
  759.     CALL    compr
  760.     JZ    delete
  761.     ADD    BX,CX            ; calc next
  762.     JMPS    dellp
  763. ; 
  764. ; delete the name
  765. ; 
  766. delete:    XCHG    BX,DX            ; next name to de
  767.     MOV    BX,-11            ; to back up..
  768.     ADD    BX,DX            ; ..to name to del
  769. ; 
  770. delch:    MOV    SI,DX
  771.     MOV    AL,[SI]
  772.     MOV    M,AL
  773.     INC    BX
  774.     INC    DX
  775.     INC    AL            ; moved the 0ffh?
  776.     JNZ    delch
  777.     OR    AL,AL            ; show found
  778.     RET
  779. ; 
  780. ; fill fcb with all '?'
  781. ; 
  782. fillq:    MOV    BX,fcb+1
  783.     MOV    CH,8+3
  784.     MOV    AL,'?'
  785. ; 
  786. qmloop:    MOV    M,AL
  787.     LAHF
  788.     INC    BX
  789.     SAHF
  790.     DEC    CH
  791.     JNZ    qmloop
  792.     RET
  793. ; 
  794. ; 
  795. ; write back the program - note that you may set any of the
  796. ; cp/m 2.x attribute bits in the file name (be sure to define
  797. ; all 11 characters of the name).
  798. ; 
  799. wrback:    MOV    DX,fcb+1
  800.     CALL    wrbk2
  801. wrbk1    DB    'WHATSNEW'        ; <--put 'd'+80h here to set tag
  802.     DB    'CMD'            ; see comment above
  803.     DB    0            ; extent number
  804. ; 
  805. wrbk2:    POP    BX
  806.     MOV    CX,(Offset wrbk2)-(Offset wrbk1)
  807.     CALL    mover
  808.     MOV    CL,erase
  809.     MOV    DX,fcb
  810.     INT    224
  811.     XOR    AL,AL            ; get 0
  812.     MOV    Byte Ptr setflg,AL    ; clear the flags..
  813.     MOV    Byte Ptr gotflg,AL
  814.     MOV    Byte Ptr gotnf,AL
  815.     MOV    Byte Ptr systoo,AL
  816.     MOV    Byte Ptr .fcbrno,AL    ; zero record number
  817.     MOV    CL,make
  818.     MOV    DX,fcb
  819.     INT    224
  820. ;
  821. ; clear group descriptor
  822. ;
  823.     CALL    clr_grp
  824. ; 
  825. ; before writing back, find end of table
  826. ; 
  827.     CALL    findff
  828.     MOV    CH,BH            ; b=end page
  829.     INC    CH            ; for compare
  830. ;
  831. ; convert page value to paragraph value
  832. ;
  833.     MOV    BH,CH            ; back to whence we came
  834.     MOV    BL,0            ; clear low byte
  835.     SHR    BX,1            ; /2
  836.     SHR    BX,1            ; /4
  837.     SHR    BX,1            ; /8
  838.     SHR    BX,1            ; /16
  839. ;
  840. ; initialze G-FORM, G-LENGTH, G-MIN
  841. ;
  842.     MOV    Word Ptr .g_length,BX
  843.     MOV    Word Ptr .g_min,BX
  844.     MOV    Byte Ptr .g_form,1    ; make G-FORM = Code Group
  845. ;
  846. ; set starting address at base of group descriptor
  847. ;
  848.     MOV    DX,g_form        ; set starting address
  849.     CALL    wrt_grp            ; write first group
  850.     CALL    clr_grp            ; clear group descriptor
  851.     CALL    wrt_grp            ; write second group (all zeros)
  852.     CALL    wrt_grp            ; write third group (all zeros)
  853. ;
  854. ; group descriptor header written, now do the code segment
  855. ;
  856.     MOV    DX,100h            ; set starting address
  857. ; 
  858. wrlp:    PUSH    CX
  859.     PUSH    DX
  860.     PUSH    BX
  861.     MOV    CL,setdma
  862.     INT    224
  863.     MOV    CL,write
  864.     MOV    DX,fcb
  865.     INT    224
  866.     POP    BX
  867.     POP    DX
  868.     POP    CX
  869.     OR    AL,AL            ; successful write?
  870.     JNZ    wrerr            ; ..no
  871.     MOV    BX,80h            ; point to..
  872.     ADD    BX,DX            ; ..next block
  873.     XCHG    BX,DX            ; addr to de
  874.     MOV    AL,DH            ; get page
  875.     CMP    AL,CH            ; past table end?
  876.     JB    wrlp            ; loop until done
  877.     MOV    CL,close
  878.     MOV    DX,fcb
  879.     INT    224
  880.     INC    AL            ; successful close?
  881.     JZ    badcls            ; ..no, print err msg
  882.     CALL    msgxit            ; ok, exit w/msg
  883. ;
  884.     DB    '++Done++$'
  885. ; 
  886. wrerr:    CALL    msgxit
  887. ;
  888.     DB    '++Write Error++$'
  889. ; 
  890. badcls:    CALL    msgxit
  891. ;
  892.     DB    '++Bad Close, D.CMD Clobbered!!++$'
  893. ; 
  894. cexit:    MOV    CL,rdcon        ; clear keyboard char
  895.     INT    224
  896.     JMPS    exit            ; then exit
  897. ; 
  898. ; finished.  if building table, write back
  899. ; 
  900. fini:    MOV    AL,Byte Ptr setflg
  901.     OR    AL,AL
  902.     JZ    exit            ; not writing
  903.     JMP    wrback
  904. ; 
  905. ; exit with message (error or informational)
  906. ; 
  907. msgxit:    POP    DX            ; get msg
  908.     MOV    CL,print
  909.     INT    224
  910. ; 
  911. ; exit, via warm boot...
  912. ; 
  913. exit:    MOV    CL,0            ; warm boot CP/M-86 to return
  914.     MOV    DL,0
  915.     INT    224
  916. ;
  917. ; initialize group descriptor for D.CMD with proper file information
  918. ;
  919. clr_grp:
  920. ;
  921.     PUSH    CX            ; save registers
  922.     PUSH    DX
  923.     PUSH    BX
  924.     MOV    BX,g_form        ; point to base of group descriptor
  925.     MOV    CH,128            ; need to clear 128 bytes
  926.     MOV    AL,0            ; clear with 0's
  927. ;
  928. clr_grp_loop:
  929. ;
  930.     MOV    M,AL            ; zero a byte
  931.     LAHF
  932.     INC    BX            ; bump pointer to next byte
  933.     SAHF
  934.     DEC    CH            ; de-bump count of bytes
  935.     JNZ    clr_grp_loop        ; loop until done
  936.     POP    BX            ; restore registers
  937.     POP    DX
  938.     POP    CX
  939.     RET                ; return from 'clr_grp'
  940. ;
  941. ; write 128 bytes of group descriptor with header information
  942. ; 
  943. wrt_grp:
  944. ;
  945.     PUSH    CX
  946.     PUSH    DX
  947.     PUSH    BX
  948.     MOV    CL,setdma
  949.     INT    224
  950.     MOV    CL,write
  951.     MOV    DX,fcb
  952.     INT    224
  953.     POP    BX
  954.     POP    DX
  955.     POP    CX
  956.     OR    AL,AL            ; successful write?
  957.     JNZ    wrerr            ; ..no
  958.     RET                ; return from 'wrt_grp'
  959. ; 
  960. linmrk:    PUSH    CX
  961.     PUSH    DX
  962.     PUSH    BX
  963.     MOV    AL,Byte Ptr .fcb    ; get drive name from fcb
  964.     OR    AL,AL            ; any there?
  965.     JNZ    gotdrv            ; yes, go print it
  966.     MOV    CL,curdsk        ; else get current disk
  967.     INT    224
  968.     INC    AL            ; make 'a'=1
  969. ; 
  970. gotdrv:    ADD    AL,40h            ; make ascii
  971.     CALL    display            ; print drive name
  972.     CALL    gotdr2            ; then ': '
  973.     DB    ': $'
  974. ; 
  975. gotdr2:    POP    DX            ; get msg adr
  976.     MOV    CL,print        ; print it
  977.     INT    224
  978.     POP    BX
  979.     POP    DX
  980.     POP    CX
  981.     RET
  982. L_20    EQU    $
  983.     DSEG
  984.     ORG    Offset L_20
  985. ; 
  986. newmsg    DB    cr,lf,'-->New Files$'
  987. ; 
  988. delmsg    DB    cr,lf,cr,lf,'-->Deleted Files$'
  989. ;
  990. HELPMSG    DB    CLS,'USAGE:'
  991.     DB    'A>WHATSNEW  {option}',CR,LF,LF
  992.     DB    'Without option, shows listing of new and deleted files',CR,LF,LF
  993.     DB    TAB,'OPTIONS:',CR,LF
  994.     DB    TAB,TAB,'//   display this help message',CR,LF,LF
  995.     DB    TAB,TAB,'*.*  display all files on disk',CR,LF,LF
  996.     DB    TAB,TAB,'*.A86  display all files of type A86',CR,LF,LF
  997.     DB    TAB,TAB,'ADD  filename.typ  adds file to table',CR,LF,LF
  998.     DB    TAB,TAB,'DEL  filename.typ  deletes file from table',CR,LF,LF
  999.     DB    TAB,TAB,'LOK A: to lock program to drive A:',CR,LF,LF
  1000.     DB    TAB,TAB,'LOK  to unlock from specific drive',CR,LF,LF
  1001.     DB    TAB,TAB,'SET  will build table of current files on the',CR,LF
  1002.     DB    TAB,TAB,'     disk and generate a new WHATSNEW.CMD',CR,LF,LF
  1003.     IF  NOT CLOCK
  1004.     DB    TAB,TAB.'SET MM/DD/YY  will build a table with the date',CR,LF
  1005.     ENDIF
  1006.     DB    '$'
  1007. ; 
  1008. ;
  1009. gotflg    DB    0
  1010. gotnf    DB    0
  1011. systoo    DB    0
  1012. nonmsg    DB    '++None++',cr,lf,'$'
  1013. asof    DB    ' since '
  1014.     IF    CLOCK
  1015. date    DB    'MM/DD/YY'
  1016.     ENDIF
  1017.     IF  NOT  CLOCK
  1018. date    DB    '        '
  1019.     ENDIF
  1020.     DB    '$'
  1021. setflg    DB    0            ; 1 => setup table
  1022. prtflg    DB    0            ; print only some
  1023. sysflg    DB    0            ; $sys attrib indicator
  1024. ; 
  1025. ; note the names are initially built by: D SET<cr>
  1026. ; 
  1027. names    DB    0ffh            ; end of table, for filenames
  1028. ; 
  1029.     rs    04000h            ; reserve a bunch
  1030.     db    0            ; mark the end for GENCMD
  1031. ;
  1032.     END
  1033.