home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol134 / checks.z80 < prev    next >
Encoding:
Text File  |  1984-04-29  |  49.0 KB  |  3,215 lines
  1.     .Z80
  2.     PAGE 60
  3. ;
  4. ; Checking program for the Big Board
  5. ; Written by Ralph Sherman , 15 Hydaway Drive , Forest , Va. 24551
  6. ; 
  7. ; Rev 1.0   --  3/27/1982       ;FIRST REVISION RELEASED
  8. ; REV 1.1   --  3/28/1982       ;ADDED SPACE BETWEEN DAY AND CHECKS
  9. ;                ; DURING UNPACK...CMAX NOW $83000
  10. ; REV 1.2   --  3/29/1982    COMPUTED CONSOLE INPUT FOR CPM 1.4 
  11. ;                NOP'S ADDED FOR WARM START AT 100H
  12. ;                CTRL-X RESETS CURSOR TO BEGINNING
  13. ;                FIXED BUG IN FWD SPACE CURSOR
  14. ;                SEND FORM FEEDS WHEN PRINTING TALLY
  15. ; REV 1.3   --  4/1/82        ADDED AUTO NUMBER COMMAND
  16. ;                RING BELL WHEN INPUTLINE OVERFLOW
  17. ;                CTRL X CANCELS COMMAND
  18. ;                CTRL B PUTS CURSOR AT BEGINNING
  19. ;                ADDED C,D,W INDICATION ON LIST
  20. ;                ADDED OUTSTANDING INDICATION
  21. ; REV 1.4   --  4/3/82        ADDED W TO HELP COMMAND
  22. ;                FIXED BUG IN NAME ENTRY
  23. ;
  24. ;
  25. ;
  26.     ASEG
  27. ;
  28. ;
  29. ; SYSTEM DEFINITIONS
  30. ;
  31. BELL    EQU    7        ;BELL CONTROL CODE
  32. CANCEL    EQU    18H        ;CONTROL CODE TO CANCEL COMMAND
  33. MOVE    EQU    2        ;CTRL CODE TO PUT CURSOR AT BEGINNING
  34. CLRSCR    EQU    1AH        ;CONSOLE CLEAR SCREEN
  35. BS    EQU    8        ;CONSOLE BACKSPACE
  36. FWDSP    EQU    0CH        ;FORWARD SPACE CONSOLE CURSOR
  37. DELCHAR    EQU    4        ;CONSOLE DELETE CHAR AT CURSOR
  38. ADDCHAR    EQU    1        ;CONSOLE ADD CHAR AT CURSOR
  39. FORMFD    EQU    0CH        ;PRINTER FORM FEED CONTROL CHAR
  40. ;
  41. DFTUNT    EQU    4        ;DEFAULT DRIVE NUMBER
  42. BDOS    EQU    5
  43. COLD    EQU    0
  44. DMA    EQU    80H
  45. FCB    EQU    5CH
  46. FCB2    EQU    6CH
  47. OPENFC    EQU    15        ;BDOS FUNCTION #
  48. CLSFC    EQU    16        ;BDOS FUNCTION #
  49. DELFC    EQU    19        ;BDOS FUNCTION #
  50. READFC    EQU    20        ;BDOS READ SEQUENTIAL
  51. WRTFC    EQU    21        ;BDOS WRITE SEQUENTIAL
  52. MAKEFC    EQU    22        ;BDOS CREATE FUNCTION #
  53. RENAFC    EQU    23        ;BDOS RENAME FILE FUNCTION #
  54. ;
  55. CFILE    EQU    3000H        ;START OF CHECK FILE
  56. NFILE    EQU    5000H        ;START OF THE NAME FILE
  57. CKLOC    EQU    CFILE
  58. NAMLOC    EQU    NFILE
  59. CCPBAS    EQU    8000H        ;CAN BE UP TO CCP BASE
  60. ;
  61.     ORG 0100H
  62. ;
  63. START:    JP    START1
  64. ;
  65. GETCMD:    LD    SP,STACK+128    ;RESET STACK JUST IN CASE
  66.     CALL    CRLF
  67.     XOR    A        ;ACC. = 0
  68.     LD    (PTRFLG),A    ;TURN PRINTER OFF
  69. CMD2:    CALL    PRINT
  70.     DEFB    'COMMAND',0H
  71.     CALL    INPUT        ;GET CHARACTER FROM CONSOLE
  72.     LD    (CMD),A        ;SAVE THE COMMAND AWAY
  73.     PUSH    AF
  74.     CALL    CCRLF
  75.     POP    AF
  76.     LD    B,0
  77.     LD    C,NCMDS
  78.     LD    HL,CMDS+NCMDS-1
  79.     CPDR            ;HUNT FOR A MATCH IN CMDS
  80.     JR    Z,CMD1        ;IF MATCH FOUND, INDEX IN TABLE IS C
  81.     CALL    PRINT
  82.     DEFB    '   NO SUCH COMMAND',0H
  83.     JP    GETCMD
  84. CMD1:    LD    IX,CMDADR
  85.     SLA    C        ;DOUBLE THE INDEX
  86.     ADD    IX,BC        ;ADD INDEX TO POINTER TO CMD ADDR'S.
  87.     LD    L,(IX+0)    ;LSB FIRST
  88.     LD    H,(IX+1)
  89.     JP    (HL)        ;JUMP TO THE COMMAND
  90. ;
  91. ;
  92. ; COMMANDS
  93. ;
  94. CMDS:    DEFB     'BCDFILMNOPQRSTWVG?A'
  95. CMDEND    EQU    $
  96. NCMDS     EQU    CMDEND-CMDS    ;NUMBER OF COMMANDS
  97. ;
  98. CMDADR:    DEFW BALANC,CHECK,DEPOS,FIX,CATSRC,PRNT
  99.     DEFW MATCH,LIST,OUTSTD,TOGGLE,QUIT,RETURN,SAVE
  100.     DEFW TALLY,WITHDR,VALUE,GET,HELP,AUTO
  101. ;
  102. ; INSERT AUTO NUMBER ON CHECKS
  103. ;
  104. AUTO:    LD    A,'C'        ;FAKE CHECK LOOKUP
  105.     LD    (CMD),A
  106.     CALL    PROMPT
  107.     CALL    GETINP
  108.     CALL    PACKNO
  109.     CALL    FIXFLG        ;SET W FLAG IF SPECIFIED
  110.     LD    A,(CNUM)
  111.     LD    (AUTOCN),A
  112.     LD    A,(CNUM+1)
  113.     LD    (AUTOCN+1),A
  114.     LD    A,1
  115.     LD    (AUTFLG),A    ;SET THE AUTO LINENUMBER FLAG
  116.     JP    GETCMD
  117. ;
  118. ; HELP- LIST COMMAND SUMMARY
  119. ;
  120. HELP:    CALL    TPRINT
  121.     DEFB 13,10,'A-AUTONUMBER CHECK ENTRIES'
  122.     DEFB 13,10,'B-LIST CHECK BOOK BALANCE'
  123.     DEFB 13,10,'C-ENTER A NEW CHECK'
  124.     DEFB 13,10,'D-ENTER A DEPOSIT'
  125.     DEFB 13,10,'F-FIX CHECK,WITHDRAWAL,DEPOSIT,OR NAME ENTRY'
  126.     DEFB 13,10,'G-GET A NEW CHECK FILE FROM DISK'
  127.     DEFB 13,10,'I-INTERROGATE BY FLAG'
  128.     DEFB 13,10,'L-LIST CHECKS,DEPOSITS,WITHDRAWALS, OR NAMES'
  129.     DEFB 13,10,'M-LIST MATCH BY NAME'
  130.     DEFB 13,10,'O-LIST OUTSTANDING CHECKS'
  131.     DEFB 13,10,'P-PRINT NEXT COMMAND ON PRINTER'
  132.     DEFB 13,10,'Q-QUIT TO CPM'
  133.     DEFB 13,10,'R-RETURN A CHECK'
  134.     DEFB 13,10,'S-SAVE CURRENT FILE'
  135.     DEFB 13,10,'T-LIST MONTHLY TALLY SHEET'
  136.     DEFB 13,10,'V-LIST BANK BALANCE'
  137.     DEFB 13,10,'W-ENTER A WITHDRAWAL',0DH,0AH,0H    ;REV 1.4
  138. ;
  139.     CALL    PRTNUM
  140.     JP    GETCMD
  141. ;
  142. BALANC:    CALL    YRSTRT
  143.     CALL    GOTOP
  144.     CALL    END
  145. BAL2:    CALL    GETNXT
  146.     JR    C,BALDON
  147.     LD    HL,DAY
  148.     BIT     7,(HL)        ;MINUS IF DEPOSIT
  149.     JP    NZ,BAL1        ;IF BIT 7=1 THEN NZ
  150.     CALL    SUBTR
  151.     JP    BAL2
  152. BAL1:    CALL    ADD
  153.     JP    BAL2
  154. BALDON:    LD    BC,02H
  155.     LD    HL,SUM            
  156.     LD    DE,BAL            
  157.     LDIR
  158.     CALL    PRBAL
  159.     JP    GETCMD
  160. ;
  161. CHECK:    LD    A,0
  162.     LD    (PTRFLG),A     ; PRINTER OFF
  163.     CALL    HEAD
  164.     CALL    TABON
  165.     LD    A,(AUTFLG)    ;CHECK IF AUTO NUMBER IS ON
  166.     OR    A
  167.     JR    Z,CHK1
  168. ;
  169. ; GET THE CHECK NUMBER AND UNPACK IT INTO BUFIN
  170. ;
  171.     LD    A,(AUTOCN)
  172.     LD    (BINARY),A
  173.     LD    DE,BUFIN    ;TELL PUTBIN WHERE TO PUT ANSWER
  174.     LD    A,(AUTOCN+1)
  175.     OR    A        ;BIT 8 SET IF WIFE'S CHECKS
  176.     JP    P,CHK11
  177.     LD    A,'W'        ;PUT W IF CHECK NUMBER
  178.     LD    (DE),A
  179.     CALL    OUTPUT        ;PUT IT ON SCREEN AND BUFIN
  180.     INC    DE
  181.     LD    A,(INPTR)
  182.     INC    A
  183.     LD    (INPTR),A
  184.     LD    (INNUM),A
  185.     LD    A,(AUTOCN+1)
  186. CHK11:    AND    3FH        ;STRIP WIFE FLAG IF THERE
  187.     LD    (BINARY+1),A    
  188.     LD    A,0
  189.     LD    (BINARY+2),A
  190.     CALL    BTOD
  191.     LD    B,4
  192.     CALL    PUTBIN
  193. ;
  194. ; NOW UPDATE INPTR AND INNUM
  195. ;
  196.     PUSH    DE
  197.     POP    HL        ; PUT DE INTO HL
  198.     LD    BC,BUFIN
  199.     OR    A
  200.     SBC    HL,BC
  201.     LD    A,L        ;L HAS VALUE FOR POINTER
  202.     LD    (INPTR),A
  203.     LD    (INNUM),A
  204.     JP    CHK2
  205. CHK1:    CALL    GETNUM
  206. CHK2:    CALL    GETIN
  207.     CALL    TABOFF
  208.     CALL    PACK
  209.     CALL    CRLF
  210.     CALL    SAVNXT
  211. ;
  212. ; NOW UPDATE AUTOCN JUST IN CASE IT IS AUTO NUMBERING
  213. ;
  214.     LD    A,(AUTOCN)
  215.     INC    A
  216.     LD    (AUTOCN),A
  217.     JP    NC,CHK3
  218.     LD    A,(AUTOCN+1)
  219.     INC    A
  220.     LD    (AUTOCN+1),A
  221. CHK3:    JP    GETCMD
  222. ;
  223. DEPOS:    LD    A,0
  224.     LD    (PTRFLG),A    ; PRINTER OFF
  225.     CALL    HEAD
  226.     CALL    TABON
  227.     CALL    GETNUM
  228.     CALL    GETIN
  229.     CALL    TABOFF
  230.     CALL    PACK
  231.     CALL    CRLF
  232.     CALL    SAVNXT
  233.     LD    HL,DEPNO
  234.     INC    (HL)
  235.     JP    GETCMD
  236. CATSRC:    CALL    PRINT
  237.     DEFB    CLRSCR,'WHAT CATEGORY FLAG',0
  238.     CALL    .SYINP
  239.     CALL    CONOUT
  240.     CALL    CCRLF
  241.     CP    'I'
  242.     JR    NZ,SRCH1
  243.     JP    ITAX
  244. SRCH1:    CP    'W'
  245.     JR    NZ,SRCH2
  246.     JP    WSRC
  247. SRCH2:    CP    'R'
  248.     JR    NZ,SRCH3
  249.     JP    RSRC
  250. SRCH3:    CALL    PAKCAT
  251.     LD    (MASK),A
  252.     CALL    CRLF
  253.     LD    A,'C'
  254.     LD    (CMD),A
  255.     CALL    HEAD
  256.     CALL    ZSUM
  257.     CALL    GOTOP
  258.     CALL    END
  259. SRC1:    CALL    GETNXT
  260.     JR    C,SRCDON
  261.     LD    A,(MONTH)
  262.     AND    0F0H 
  263.     LD    HL,MASK
  264.     CP    (HL)
  265.     JR    NZ,SRC1
  266.     CALL    UNPACK
  267.     CALL    CRLF
  268.     CALL    ADD
  269.     JP    SRC1
  270. SRCDON:    CALL    PRTOT
  271.     JP    GETCMD
  272. CDWARG:    CALL    PRINT
  273.     DEFB    0DH,0AH,' C,D,N OR W ?',0
  274.     CALL    INPUT 
  275. CCRLF:    PUSH    AF        ;SAVE THE COMMAND
  276.     LD    A,NEWLIN    ;AND SEND CRLF TO CONSOLE
  277.     CALL    CONOUT
  278.     LD    A,LINEFD
  279.     CALL    CONOUT
  280.     POP    AF
  281.     RET
  282. ;
  283. FIX:    LD    A,0
  284.     LD    (PTRFLG),A     ; INSURE PRINTER IS OFF
  285.     CALL    CDWARG
  286.     CP    'C'
  287.     JR    Z,FIX1
  288.     CP    'D'
  289.     JR    Z,FIX1
  290.     CP    'W'
  291.     JR    Z,FIX1
  292.     CP    'N'
  293.     JR    NZ,CMDERR
  294.     JP    NAMFIX
  295. CMDERR:    CALL    PRINT
  296.     DEFB    0DH,0AH,'ONLY C,D,N,OR W ALLOWED',0DH,0AH,0
  297.     JP    GETCMD
  298. FIX1:    LD    (CMD),A
  299.     CALL    PROMPT
  300.     CALL    GETINP
  301.     CALL    PACKNO
  302.     CALL    FIXFLG        ;SET W FLAG
  303.     CALL    FINDNO
  304.     CALL    HEAD
  305.     CALL    UNPACK
  306.     CALL    GETIN        ;EDIT BUFIN
  307.     CALL    PACK
  308.     CALL    REPLAC
  309.     JP    GETCMD
  310. LIST:    LD    A,CLRSCR
  311.     CALL    OUTPUT        ;CLR SCREEN
  312.     CALL    PRINT
  313.     DEFB    13,10,'TYPE MATCH CHAR. OR CR ',0
  314.     LD    A,'%'
  315.     LD    (CMNEM),A    
  316.     LD    (CMNEM+1),A
  317.     LD    (CMNEM+2),A
  318. ;
  319.     LD    HL,CMNEM
  320.     LD    B,3H
  321. ;
  322. LL3:    CALL    INPUT
  323.     CP    BLANK
  324.     JR    Z,LL10
  325.     CP    NEWLIN
  326.     JR    Z,LL10
  327.     LD    (HL),A        ;STA
  328.     INC    HL
  329.     DJNZ    LL3        ;B IS NOW 0
  330. LL10:    LD    BC,0000H
  331.     CALL    CCRLF
  332. LLOOP:    LD    A,(NIND)
  333.     CP    C
  334.     JR    NZ,LL11
  335.     JP    GETCMD
  336. LL11:    LD    A,0
  337.     LD    (INPTR),A
  338. LL5:    LD    A,(CMNEM)
  339.     CP    '%'
  340.     JR    Z,LL6
  341.     LD    HL,(NB1)
  342.     ADD    HL,BC        ;INDEX DOWN BC ENTRIES
  343.     CP    (HL)
  344.     JR    NZ,LL9
  345. LL6:    LD    A,(CMNEM+1)
  346.     CP    '%'
  347.     JR    Z,LL7
  348.     LD    HL,(NB2)
  349.     ADD    HL,BC
  350.     CP    (HL)
  351.     JR    NZ,LL9
  352. LL7:    LD    A,(CMNEM+2)
  353.     CP    '%'
  354.     JR    Z,LL8
  355.     LD    HL,(NB3)
  356.     ADD    HL,BC
  357.     CP    (HL)
  358.     JR    NZ,LL9
  359. LL8:    LD    DE,BUFIN
  360.     PUSH    BC
  361.     CALL    GETNAM
  362.     PUSH    AF
  363.     CALL    SLOW
  364.     POP    AF
  365.     POP    BC
  366.     CALL    PRNAM
  367.     CALL    CRLF
  368.     CALL    KBDTST        ;REV 1.4 CHECK ABORT
  369. LL9:    INC    BC
  370.     LD    A,C
  371.     OR    A
  372.     JR    NZ,LLOOP
  373.     CALL    PRINT
  374.     DEFB    'NAME FILE IS FULL',0DH,0AH,00H
  375.     JP    GETCMD
  376. ;
  377. ; PRINT NAME POINTED TO BY BC
  378. ;
  379. PRNAM:    LD    HL,OFFL        ;REV 1.4 CHANGED PRNAM: TO LL1:
  380.     ADD    HL,BC        ;GET THE LOW BYTE OFFSET
  381.     LD    E,(HL)        ;PUT IT IN E
  382.     LD    HL,OFFH        ;NOT THE HIGH BYTE OFFSET
  383.     ADD    HL,BC        ;INDEXED BY BC ALSO
  384.     LD    D,(HL)        ;DE NOW HAS OFFSET
  385.     LD    HL,(NTABLE)    ;HL HAS BASE ADDR. OF NAME TABLE
  386.     ADD    HL,DE        ;NOW HL HAS OFFSET ADDED
  387.     LD    (NPTR),HL    ;STORE ADDRESS OF FULL NAME IN NPTR
  388. LL1:    LD    A,(HL)
  389.     CP    EOL
  390.     JR    Z,LL2
  391.     CALL    OUTPUT
  392.     INC    HL
  393.     JR    NZ,LL1
  394. LL2:    RET
  395. ;
  396. ; GET POINTER TO NAME
  397. ;
  398. NAMPTR:    CALL    PRINT
  399.     DEFB    CLRSCR,'TYPE MNEMONIC NAME',0DH,0AH,0
  400.     CALL    GETINP
  401.     CALL    CRLF
  402.     LD    A,0H
  403.     LD    (INPTR),A
  404.     CALL    NAMBYT
  405.     JR    NC,NP1
  406.     CALL    PRINT
  407.     DEFB    0DH,0AH,'NAME NOT FOUND',0DH,0AH,0
  408.     JP    GETCMD
  409. NP1:    LD    (MASK),A
  410.     RET
  411. ;
  412. ; PRINT CHECKS BY NAME MATCH
  413. ;
  414. MATCH:    CALL    NAMPTR
  415.     LD    A,'C'
  416.     LD    (CMD),A
  417.     CALL    HEAD
  418.     CALL    ZSUM
  419.     CALL    GOTOP
  420.     CALL    END
  421. MAT2:    CALL    GETNXT
  422.     JR    C,MATRET
  423.     LD    A,(NAME)
  424.     LD    HL,MASK
  425.     CP     (HL)
  426.     JR    NZ,MAT2         ;WRONG NAME
  427.     CALL    UNPACK
  428.     CALL    CRLF
  429.     CALL    ADD
  430.     JP    MAT2             ;LOOP AGN
  431. MATRET:    CALL    PRTOT
  432.     JP    GETCMD
  433. ;
  434. ; PRINT OUTSTANDING CHECKS
  435. ;
  436. OUTSTD:    LD    A,'C'
  437.     LD    (CMD),A
  438.     CALL    HEAD
  439.     CALL    ZSUM
  440.     CALL    GOTOP
  441.     CALL    END
  442. OUTS1:    CALL    GETNXT
  443.     JR    C,OUTS2     ;DONE
  444.     LD    A,(DAY)
  445.     AND    0C0H
  446.     JR    NZ,OUTS1 ; SKIP D & W
  447.     LD    HL,CNUM+1
  448.     BIT    6,(HL)
  449.     JR    NZ,OUTS1    ;R FLAG SET
  450.     CALL    UNPACK
  451.     CALL    CRLF
  452.     CALL    ADD
  453.     JP    OUTS1
  454. OUTS2:    CALL    TPRINT
  455.     DEFB    0DH,0AH,'OUTSTANDING',0H
  456.     CALL    PRTOT
  457.     JP    GETCMD
  458.     JP    GETCMD
  459. ;
  460. ; LIST CHECKS, DEPOSITS OR WITHDRAWALS
  461. ;
  462. PRNT:    CALL    CDWARG
  463.     CP    'N'
  464.     JR    NZ,PRNT1
  465.     JP    LIST
  466. PRNT1:    LD    (CMD),A
  467.     CALL    GETMO
  468.     CALL    HEAD
  469.     LD    A,(CMD)
  470.     CP    'W'
  471.     JR    NZ,PR1
  472.     LD    A,40H             ;W FLAG
  473.     JR    Z,PR3
  474. PR1:    CP    'D'
  475.     JR    NZ,PR2
  476.     LD    A,80H            ;D FLAG
  477.     JR    Z,PR3
  478. PR2:    LD    A,0              ; NOT W OR D
  479. PR3:    LD    (MASK),A
  480.     CALL    GOTOP
  481.     CALL    END
  482.     CALL    ZSUM
  483. PR4:    CALL    KBDTST            ;REV 1.4 CHECK ABORT
  484.     CALL    GETNXT
  485.     JR    C,PDDONE 
  486.     CALL    MTEST
  487.     JR    NZ,PR4
  488.     LD    A,(DAY)
  489.     AND    0C0H
  490.     LD    HL,MASK
  491.     CP     (HL)
  492.     JR    NZ,PR4
  493.     CALL    UNPACK
  494.     CALL    CRLF
  495.     CALL    ADD
  496.     JP    PR4
  497. PDDONE:    CALL    PRTYP
  498.     CALL    PRTOT
  499.     LD    A,0    ; RESET DEFAULT MONTH
  500.     LD    (OUTMO),A
  501.     JP    GETCMD
  502. ;
  503. ; PRINT TYPE OF LISTING DONE
  504. ;
  505. PRTYP:    LD    A,(CMD)
  506.     CP    'C'
  507.     JR    NZ,PRTYP1
  508.     CALL    TPRINT
  509.     DEFB    0DH,0AH,'CHECKS',0H
  510.     RET
  511. PRTYP1:    CP    'D'
  512.     JR    NZ,PRTYP2
  513.     CALL    TPRINT
  514.     DEFB    0DH,0AH,'DEPOSITS',0H
  515.     RET
  516. PRTYP2:    CALL    TPRINT
  517.     DEFB    0DH,0AH,'WITHDRAWALS',0H
  518.     RET
  519. ;
  520. ; QUIT AND RETURN TO CP/M
  521. ;
  522. QUIT:    CALL    PRINT
  523.     DEFB    CLRSCR,'SAVE CHECKS FIRST? (Y/N)',0
  524.     CALL    .SYINP
  525.     CP    'Y'
  526.     JR    NZ,QU1
  527.     CALL    PRTNAM
  528.     CALL    SAVCHK
  529.     CALL    SAVNAM
  530.     JP    QU2
  531. QU1:    CP    'N'
  532.     JR    NZ,QUIT
  533. QU2:    LD    HL,(OLDSP)
  534.     LD    SP,HL
  535.     JP    COLD
  536. ;
  537. ; RETURN AN OUTSTANDING CHECK
  538. ;
  539. RETURN:    CALL    PRINT
  540.     DEFB    CLRSCR,'RETURN WHAT CHECK #',0
  541.     LD    A,'C'
  542.     LD    (CMD),A
  543.     CALL    GETINP
  544.     CALL    PACKNO
  545.     CALL    FIXFLG
  546.     CALL    FINDNO
  547.     CALL    HEAD
  548.     CALL    UNPACK
  549.     LD    DE,0000H
  550.     LD    A,(INPTR)
  551.     LD    E,A
  552.     LD    HL,BUFIN
  553.     ADD    HL,DE
  554.     LD    A,'R'
  555.     LD    (HL),A
  556.     CALL    OUTPUT
  557.     LD    HL,INPTR
  558.     INC     (HL)
  559.     LD    HL,INNUM
  560.     INC     (HL)
  561.     CALL    CRLF
  562.     CALL    PACK
  563.     CALL    REPLAC
  564.     JP    GETCMD
  565. ;
  566. ; SAVE THE CURRENT DATA ON THE DISK
  567. ;
  568. SAVE:    CALL    PRTNAM
  569.     CALL    SAVCHK
  570.     CALL    SAVNAM
  571.     JP    GETCMD
  572. ;
  573. ; PRINT OUT A MONTHLY TALLY SHEET
  574. ;
  575. TALLY:    CALL    TALPR
  576.     JP    GETCMD
  577. ;
  578. ; ENTER A WITHDRAWAL
  579. ;
  580. WITHDR:    LD    A,0
  581.     LD    (PTRFLG),A
  582.     CALL    HEAD
  583.     CALL    TABON
  584.     CALL    GETNUM
  585.     CALL    GETIN
  586.     CALL    PACK
  587.     CALL    CRLF
  588.     CALL    SAVNXT
  589.     LD    HL,WITHNO
  590.     INC     (HL)
  591.     CALL    TABOFF
  592.     JP    GETCMD
  593. ;
  594. ; PRINT OUT THE BANK BALANCE
  595. ;
  596. VALUE:    CALL    YRSTRT
  597.     CALL    GOTOP
  598.     CALL    END
  599. VAL2:    CALL    GETNXT
  600.     JR    C,VALDON
  601.     LD    HL,DAY
  602.     BIT    7,(HL)
  603.     JR    NZ,VAL1        ;DEPOSIT ADD
  604.     BIT    6,(HL)
  605.     JR    NZ,VAL3
  606.     LD    HL,CNUM+1    ;IGNORE OUTSTD
  607.     BIT    6,(HL)
  608.     JR    Z,VAL2
  609. VAL3:    CALL    SUBTR
  610.     JP    VAL2
  611. VAL1:    CALL    ADD
  612.     JP    VAL2
  613. VALDON:    CALL    TPRINT
  614.     DEFB    CLRSCR,'BANK BALANCE',0DH,0AH,0
  615.     JP    BALDON
  616. ;
  617. ; GET A NEW DATA FILE FROM DISK
  618. ;
  619. GET:    CALL    PUTNAM
  620. GETX:    CALL    LDCHK
  621.     CALL    LDNAM
  622.     JP    GETCMD
  623. ;
  624. ; SEND CRLF TO CONSOLE AND RESET OUTPOS
  625. ;
  626. CRLF:    LD    A,00H        
  627.     LD    (OUTPOS),A
  628.     LD    A,NEWLIN
  629.     CALL    OUTPUT
  630.     LD    A,LINEFD
  631.     JP    OUTPUT
  632. ;
  633. ; GET A CONSOLE INPUT WITHOUT ECHO, SET UPPER CASE
  634. ; RETURN TO COMMAND MODE IF CTRL C
  635. ;
  636. .SYINP:    CALL    SYSINP
  637.     CALL    CASE
  638.     CP    CANCEL
  639.     RET    NZ
  640.     LD    A,0
  641.     LD    (AUTFLG),A    ;TURN AUTO NUMBER MODE OFF
  642.     JP    GETCMD
  643. ;
  644. ; PRINT HEADERS
  645. ;
  646. HEAD:    LD    A,(CMD)
  647.     CP    'C'
  648.     JR    Z,CHEAD
  649.     CP    'D'
  650.     JR    Z,DHEAD
  651.     CP    'W'
  652.     JR    Z,WHEAD
  653.     POP    AF        ;CLEAN UP THE STACK
  654.     JP    CMDERR
  655. ;
  656. ; PRINT CHECK HEADER
  657. ;
  658. CHEAD:    CALL    TPRINT
  659.     DEFB    CLRSCR,'CHK#  ',0
  660.     JP    HDR
  661. ;
  662. ; PRINT WITHDRAW HEADER
  663. ;
  664. WHEAD:    CALL    TPRINT
  665.     DEFB    CLRSCR,'WITH# ',0
  666.     JP    HDR
  667. ;
  668. ; PRINT DEPOSIT HEADER
  669. ;
  670. DHEAD:    CALL    TPRINT
  671.     DEFB    CLRSCR,'DEP#  ',0
  672. HDR:    CALL    TPRINT
  673.     DEFB    'MO DA  AMOUNT NAME FLAGS',0DH,0AH,0
  674.     RET 
  675. ;
  676. ;
  677. ;  CONVERTS BINARY NUMBER TO ASCII DECIMAL STRING
  678. ;  BINARY NUMBER IN BINARY
  679. ;  DECIMAL IN STRING
  680. ;
  681. BTOD:    PUSH    HL
  682.     LD    C,7H
  683. BT.10:    CALL    .DIVI0
  684.     LD    B,0        ;SET UP POINTER TO STRING
  685.     LD    A,(REMAIN)
  686.     ADD    A,30H
  687.     LD    HL,STRING
  688.     ADD    HL,BC
  689.     LD    (HL),A
  690.     LD    B,C        ;SET LOOP COUNTER TO C
  691.     DEC    C
  692.     DJNZ    BT.10
  693.     POP    HL
  694.     RET
  695. .DIVI0:    LD    A,0
  696.     LD    (REMAIN),A
  697.     LD    HL,REMAIN
  698.     LD    B,25    
  699.     JR    DI.10    
  700. DI.05:    RL    (HL)    
  701. DI.10:    OR    A    
  702.     LD    A,(REMAIN)
  703.     SUB    0AH    
  704.     JR    C,DI.21    
  705.     LD    (REMAIN),A
  706. DI.21:    CCF
  707. DI.20:    LD    IX,BINARY
  708.     RL    (IX+0)        
  709.     RL    (IX+1)        
  710.     RL    (IX+2)        
  711.     DJNZ    DI.05    
  712.     RET
  713. ;
  714. ; CONVERTS A DECIMAL ASCII STRING TO A BINARY NUMBER
  715. ; DEC ASCII IN STRING
  716. ; BINARY  NUMBER IN BINARY
  717. ;
  718. ;
  719. DTOB:    LD    A,0
  720.     LD    (XIND),A
  721.     LD    (REMAIN),A
  722.     LD    (REMAIN+1),A
  723.     LD    (REMAIN+2),A
  724.     LD    (BINARY),A
  725.     LD    (BINARY+1),A
  726.     LD    (BINARY+2),A
  727.     LD    HL,STRING
  728. DTOB1:    LD    A,(HL)
  729.     CALL    DIGIT
  730.     JR    Z,DTOB10
  731.     CALL    PRINT
  732.     DEFB    0DH,0AH,'ALPHA IN NUMERIC INPUT',0DH,0AH,0
  733.     JP    GETCMD
  734. DTOB10:    CALL    MPY10
  735.     LD    A,B
  736.     LD    IY,BINARY
  737.     ADD    A,(IY+0)
  738.     LD    (BINARY),A
  739.     JR    NC,DTOB2
  740.     INC     (IY+1)
  741.     JR    NZ,DTOB2
  742.     INC     (IY+2)
  743.     LD    A,(BINARY+2)
  744.     CP    7FH
  745.     JR    C,DTOB2         ; CHK VAL OK
  746.     CALL    PRINT
  747.     DEFB    0DH,0AH,'CHECK VALUE TOO BIG',0DH,0AH
  748.     JP    GETCMD
  749. DTOB2:    LD    IX,XIND
  750.     INC     (IX+0)
  751.     INC    HL
  752.     LD    A,(IX+0)
  753.     CP    08H
  754.     JR    NZ,DTOB1
  755.     RET                 ; CONVERSION COMPLETE
  756. ;
  757. ;  MULTIPLY BINARY BY 10
  758. ;
  759. MPY10:    PUSH    BC
  760.     LD    B,10
  761.     LD    A,0
  762.     LD    (REMAIN),A
  763.     LD    (REMAIN+1),A
  764.     LD    (REMAIN+2),A
  765.     LD    IX,BINARY
  766. MP.10:    LD    A,(REMAIN)
  767.     ADC     A,(IX+0)
  768.     LD    (REMAIN),A
  769.     LD    A,(REMAIN+1)
  770.     ADC     A,(IX+1)
  771.     LD    (REMAIN+1),A
  772.     LD    A,(REMAIN+2)
  773.     ADC     A,(IX+2)
  774.     LD    (REMAIN+2),A
  775.     DJNZ    MP.10
  776.     POP    BC
  777.     LD    (BINARY+2),A
  778.     LD    A,(REMAIN+1)
  779.     LD    (BINARY+1),A
  780.     LD    A,(REMAIN)
  781.     LD    (BINARY),A
  782.     RET
  783. ;
  784. ; CHECK FOR DECIMAL DIGIT
  785. ; B RETURNS VALUE OF DIGIT IN HEX
  786. ;
  787. DIGIT:    PUSH    HL
  788.     LD    HL,DIG+9
  789.     LD    B,9
  790. DIG.10:    CP     (HL)        
  791.     JR    Z,DIG.20
  792.     DEC    HL
  793.     DEC    B
  794.     JP    P,DIG.10
  795. DIG.20:    POP    HL
  796.     RET             ; Z=1 IF DIGIT
  797. ;
  798. DIG:        DEFB    '0123456789ABCDEF'
  799. ;
  800. ;
  801. ;
  802. ; RESET INNUM AND INPTR
  803. ; IF WITHDRAWAL OR DEPOSIT GET NUMBER
  804. ; IF AUTO-NUMBER, THEN GET THE CHECK NUMBER
  805. ; ELSE RETURN
  806. ;
  807. GETNUM:    LD    A,0
  808.     LD    (INNUM),A
  809.     LD    (INPTR),A
  810.     LD    A,(CMD)
  811.     CP    'C'
  812.     RET    Z
  813.     CP    'D'
  814.     JR    Z,GETDEP
  815. ; ELSE GET WITHDRAWAL #
  816.     LD    A,(WITHNO)
  817.     JP    GN2
  818. GETDEP:    LD    A,(DEPNO)
  819. GN2:    LD    (BINARY),A
  820.     LD    A,0
  821.     LD    (BINARY+1),A
  822.     LD    (BINARY+2),A
  823.     CALL    BTOD
  824.     LD    B,3            ;LOOP COUNTER
  825.     LD    IX,STRING+5
  826.     LD    IY,BUFIN
  827. GN3:    LD    A,(IX+0)
  828.     LD    (IY+0),A
  829.     INC    IX
  830.     INC    IY
  831.     CALL    OUTPUT
  832.     LD    HL,INNUM
  833.     INC     (HL)
  834.     LD    HL,INPTR
  835.     INC     (HL)
  836.     DJNZ    GN3
  837.     RET
  838. ;
  839. ; FILL BUFIN FROM KBD
  840. ; RETURN ON CR OR #LINEFD
  841. ; GETINP RESETS INPTR & INNUM TO 0
  842. ; GETIN ASSUMES INPTR & INNUM VALID
  843. ;
  844. GETINP:    LD    A,0H
  845.     LD    (INNUM),A
  846.     LD    (INPTR),A
  847. ;
  848. GETIN:    CALL    .SYINP
  849. ;
  850. ; IF INPUT WILL GO TO PRINTER THEN PRINT CHAR ON CONSOLE
  851. ;
  852.     PUSH    AF        ;SAVE THE CHAR
  853.     LD    A,(PTRFLG)
  854.     OR    A
  855.     JR    Z,NOTPTR
  856.     POP    AF
  857.     PUSH    AF
  858.     CALL    CONOUT
  859. NOTPTR:    POP    AF
  860. ;
  861.     CALL    TABNXT
  862.     CP    BS
  863.     JR    NZ,GI1
  864. ;
  865. ; BACKSPACE
  866. ;
  867.     PUSH    AF        ;SAVE THE BACKSPACE CHAR
  868.     LD    A,(INPTR)    ;CHECK IF AT THE BEGINNING
  869.     OR    A        ;IS INPTR ZERO
  870.     JR    NZ,NOTBEG    ;NOT AT BEGINNING, NOW BACKSPACE
  871.     POP    AF
  872.     JP    GETIN        ;ELSE IGNORE THE BACKSPACE
  873. NOTBEG:    DEC    A        ;UPDATE INPTR
  874.     LD    (INPTR),A
  875.     POP    AF        ;NOW SEND BACKSPACE TO VIDEO
  876.     CALL    OUTPUT
  877.     JP    GETIN        ;AND GET NEXT CHARACTER
  878. ;
  879. ; INSERT
  880. ;
  881. GI1:    CP    ADDCHAR        ; CTRL A ADD SPACE AT CURSOR?
  882.     JR    NZ,GI2
  883.     LD    BC,0000H    ;SET IT TO ZERO
  884.     LD    DE,INPTR    ;DE POINTS TO INPTR
  885.     LD    HL,INNUM    ;HL POINTS TO INNUM
  886.     LD    A,(HL)
  887.     CP    BUFSIZ-1    ;MAKE SURE INSERT DOES NOT
  888.     JR    Z,GETIN        ;OVERFLOW THE BUFFER
  889.     LD    A,(DE)        ;GET VALUE OF INPTR
  890.     CP    (HL)        ;IS IT AT THE END OF THE BUFFER
  891.     JR    Z,GETIN        ;IF SO IGNORE INSERT
  892.     INC    (HL)        ;BUFIN WILL HAVE ONE MORE CHAR
  893.     LD    A,(HL)        ;GET INNUM
  894.     LD    C,A        ;PUT IT INTO INDEX
  895.     LD    IY,BUFIN
  896.     ADD    IY,BC        ;START AT THE OLD END OF BUFIN
  897. GI10:    LD    A,(IY-1)    ;GET A CHAR
  898.     LD    (IY+0),A    ;AND MOVE IT TO RIGHT ONE CHAR
  899.     DEC    IY        ;NEXT CHAR DOWN
  900.     DEC     C        ;DEC POINTER
  901.     LD    A,(DE)        ;GET INPTR
  902.     CP    C        ;IS POINTER AT INPTR
  903.     JR    NZ,GI10        ;CONTINUE MOVING UNTIL EQUAL
  904.     LD    A,BLANK
  905.     LD    (IY+0),A    ;PUT BLANK AT INPTR POSITION
  906.     CALL    FIXVID
  907. GI11:    JP    GETIN
  908. ;
  909. ; DELETE CHARACTER AT CURSOR
  910. ;
  911. GI2:    CP    DELCHAR
  912.     JR    NZ,GI3
  913.     LD    DE,INPTR    ;DE POINTS TO INPTR
  914.     LD    A,(DE)
  915.     LD    HL,INNUM    ;HL POINTS TO INNUM
  916.     CP    (HL)
  917.     JR    Z,GETIN        ;ABORT IF INPTR=INNUM
  918.     LD    BC,0000H    ;INITIALIZE BC
  919.     LD    C,A        ;BC NOW INDEX INTO BUFIN
  920.     LD    IX,BUFIN
  921.     ADD    IX,BC        ;IX NOW POINTS INTO BUFIN
  922. GI20:    LD    A,(IX+1)    ;MOVE NEXT CHARACTER
  923.     LD    (IX+0),A    ;DOWN TO REPLACE ONE POINTED TO
  924.     INC    C        ;C IS INPTR + 1
  925.     INC    IX        ;MOVE UP ONE CHARACTER
  926.     LD    A,C        ;AND IF INPTR + 1 IS NOT
  927.     CP    (HL)        ;EQUAL TO INNUM MOVE ANOTHER
  928.     JR    NZ,GI20
  929.     DEC     (HL)        ;DEC INNUM BECUZ ONE CHAR IS GONE
  930.     CALL    FIXVID        ;AND UPDATE THE DISPLAY
  931.     JP    GETIN
  932. ;
  933. ; FWD SPACE
  934. ;
  935. GI3:    CP    FWDSP         ; FWD SPACE
  936.     JR    NZ,GI4
  937.     LD    A,(INPTR)
  938.     LD    HL,INNUM
  939.     CP    (HL)
  940.     JR    NZ,GI40
  941.     JP    GETIN
  942. GI40:    INC     A
  943.     LD    (INPTR),A
  944.     LD    A,FWDSP        ;NOW FORWARD SPACE CURSOR
  945.     CALL    OUTPUT
  946.     JP    GETIN
  947. ;
  948. ; TEST FOR MOVE TO SET CURSOR AT BEGINNING OF BUFFER
  949. ;
  950. GI4:    CP    MOVE        ;MOVE THE CURSOR?
  951.     JR    NZ,GI41
  952.     LD    A,0DH
  953.     CALL    OUTPUT        ;SET CURSOR AT BEGINNING
  954.     LD    A,0
  955.     LD    (INPTR),A    ;RESET INPTR
  956.     JP    GETIN
  957. ;
  958. ; RETURN FROM GETIN ON LINE FEED OR CARRIAGE RETURN
  959. ;
  960. GI41:    CP    LINEFD
  961.     RET    Z
  962.     CP    NEWLIN
  963.     RET    Z
  964. ;
  965. ; IGNORE OTHER CONTROL CODES AND PUT VALID CHAR. IN BUFFER
  966. ;
  967. GI5:    CP    20H        ;IGNORE REST OF CONTROL CODES
  968.     JP    C,GETIN
  969.     LD    HL,BUFIN
  970.     LD    BC,0000H
  971.     PUSH    AF
  972.     LD    A,(INPTR)
  973.     LD    C,A
  974.     ADD    HL,BC
  975.     POP    AF
  976.     LD    (HL),A
  977.     CALL    OUTPUT
  978.     LD    A,(INPTR)
  979.     INC    A
  980.     LD    (INPTR),A
  981.     LD    HL,INNUM
  982.     CP    (HL)
  983.     JP    C,GETIN     ; INPTR<INNUM
  984.     JP    Z,GETIN        
  985.     LD    (HL),A
  986.     CP    32
  987.     JP    NZ,GETIN
  988. INERR:    LD    A,BELL
  989.     CALL    OUTPUT
  990.     CALL    PRINT
  991.     DEFB    0DH,0AH,'INPUT BUFFER OVERFLOW',0DH,0AH,0
  992.     JP    GETCMD
  993. ;
  994. ; UPDATE VIDEO DISPLAY
  995. ; RESET CURSOR TO INPTR
  996. ;
  997. FIXVID:    LD    A,(INNUM)    ;WRITE OUT BUFIN
  998.     LD    C,A
  999.     CALL    OVRWRT
  1000. ;
  1001. ; NOW WRITE SPACES UNTIL BUFSIZ TO ERASE EVERYTHING
  1002. ;
  1003. FV1:    CP    BUFSIZ
  1004.     JR    Z,FV2
  1005.     LD    A,BLANK
  1006.     CALL    OUTPUT
  1007.     INC    B
  1008.     LD    A,B
  1009.     JP    FV1
  1010. ;
  1011. ; NOW OVERWRITE UNTIL INPTR
  1012. ;
  1013. FV2:    LD    A,(INPTR)
  1014.     LD    C,A
  1015.     CALL    OVRWRT
  1016.     RET
  1017. ;
  1018. OVRWRT:    LD    A,NEWLIN    ;START AT THE BEGINNING
  1019.     CALL    OUTPUT
  1020.     LD    B,0        ;B IS CHAR. COUNTER
  1021.     LD    IX,BUFIN    ;IX IS POINTER INTO BUFIN
  1022. WRTNXT:    LD    A,(IX+0)    ;GET A CHARACTER
  1023.     CALL    OUTPUT        ;AND OUTPUT IT TO CONSOLE
  1024.     INC    B        ;BUMP THE CHAR. COUNTER
  1025.     INC    IX        ;AND THE POINTER
  1026.     LD    A,B
  1027.     CP    C        ;COMPARE CHAR. CNTR TO LIMIT
  1028.     JR    NZ,WRTNXT    ;AND LOOP UNTIL END
  1029.     RET
  1030. ;
  1031. ; PACK BUFIN INTO BUFFER
  1032. ;
  1033. PACKNO:    LD    A,0
  1034.     LD    (WIFE),A    ; RESET FLAG
  1035.     LD    (INPTR),A     ; GETCMDNING OF BUFIN
  1036.     LD    A,(BUFIN)
  1037.     CP    'W'
  1038.     JR    NZ,P1
  1039.     LD    A,1
  1040.     LD    (WIFE),A
  1041.     LD    IY,INPTR
  1042.     INC     (IY+0)
  1043. ;
  1044. ; GET CK,WITHDR,OR DEPOSIT #
  1045. ;
  1046. P1:    CALL    GETDEC ; PUT # INTO STRING
  1047.     CALL    DTOB
  1048.     LD    A,(BINARY)
  1049.     LD    (CNUM),A
  1050.     LD    A,(BINARY+1)
  1051.     AND    3FH 
  1052.     LD    (CNUM+1),A
  1053.     RET
  1054. ;
  1055. ; PACK TAKES THE CONTENTS OF BUFIN AND PACKS THE DATA
  1056. ; INTO 8 BYTES AND STORES IT IN THE BUFFER
  1057. ;
  1058. PACK:    CALL    PACKNO
  1059. ;
  1060. ; GET MONTH
  1061. ;
  1062.     CALL    GETDEC
  1063.     CALL    DTOB
  1064.     LD    A,(BINARY)
  1065.     AND    0FH
  1066.     LD    (MONTH),A
  1067. ;
  1068. ; GET DAY
  1069. ;
  1070.     CALL    GETDEC
  1071.     CALL    DTOB
  1072.     LD    A,(BINARY)
  1073.     AND    3FH 
  1074.     LD    (DAY),A
  1075. ;
  1076. ; GET CHECK VALUE
  1077. ;
  1078.     CALL    GETVAL
  1079.     CALL    DTOB
  1080.     LD    A,(BINARY+2)
  1081.     LD    (CVAL+2),A
  1082.     LD    A,(BINARY+1)
  1083.     LD    (CVAL+1),A
  1084.     LD    A,(BINARY)
  1085.     LD    (CVAL),A
  1086. ;
  1087. ; GET NAME
  1088. ;
  1089.     CALL    NAMBYT
  1090.     JR    C,P3         ; NAME NOT FOUND
  1091.     LD    (NAME),A
  1092. ;
  1093. ; FIX FLAGS
  1094. ;
  1095.     JP    FIXFLG ; RETURN
  1096. ;
  1097. P3:    LD    (NAME),A     ; PUT 0 IN TEMPORARILY
  1098.     CALL    FIXFLG
  1099.     CALL    PRINT
  1100.     DEFB    0DH,0AH,'NEW NAME (Y/N)',0DH,0AH,0
  1101.     CALL    INPUT
  1102.     CP    'Y'
  1103.     JR    Z,P4
  1104.     JP    GETCMD
  1105. P4:    CALL    FIXNAM
  1106.     LD    (NAME),A
  1107.     RET
  1108. ;
  1109. ; PUT NEXT BUFIN ENTRY INTO STRING
  1110. ;
  1111. GETDEC:    LD    B,8 ; CLEAR STRING
  1112.     LD    A,'0'
  1113.     LD    HL,STRING+7
  1114. PD1:    LD    (HL),A
  1115.     DEC    HL
  1116.     DJNZ    PD1
  1117. PD2:    CALL    SETHL        ;HL=BUFIN+INPTR
  1118.     LD    A,(HL)
  1119.     CP    BLANK ; IGNORE LEADING SPACES
  1120.     JR    NZ,PD3
  1121.     LD    A,(INPTR)
  1122.     INC    A
  1123.     LD    (INPTR),A
  1124.     JR    NZ,PD2
  1125. PD3:    LD    A,(HL)
  1126.     CP    BLANK         ; RETURN ON NEXT SPACE
  1127.     JR    NZ,PD4
  1128. PDRET:    RET
  1129. PD4:    CP    '.'
  1130.     JR    Z,PDRET
  1131.     CALL    PUTSTR
  1132. NXTNUM:    LD    A,(INPTR)
  1133.     INC    A
  1134.     LD    (INPTR),A
  1135.     CALL    SETHL
  1136.     LD    IX,INNUM
  1137.     CP    (IX+0)
  1138.     JR    NZ,PD3
  1139.     RET
  1140. ;
  1141. ; SET HL TO BUFIN+INPTR
  1142. ;
  1143. SETHL:    PUSH    AF        ;DON'T DESTROY IT
  1144.     LD    A,(INPTR)
  1145.     LD    E,A
  1146.     LD    D,0
  1147.     LD    HL,BUFIN
  1148.     ADD    HL,DE
  1149.     POP    AF
  1150.     RET
  1151. ;
  1152. ;
  1153. ; GET CHECK VALUE
  1154. ; ALL DOLLARS UNLESS . FOUND
  1155. ;
  1156. GETVAL:    CALL    GETDEC
  1157.     CP    '.'
  1158.     JR    Z,CENTS
  1159.     LD    A,'0'            ; AMOUNT IN DOLLARS
  1160.     CALL    PUTSTR
  1161.     LD    A,'0'
  1162.     JP    PUTSTR             ; RETURN
  1163. CENTS:    INC    HL
  1164.     LD    A,(HL)
  1165.     CP    BLANK
  1166.     JR    Z,VALERR
  1167.     INC    HL
  1168.     LD    A,(HL)
  1169.     CP    BLANK
  1170.     JR    Z,VALERR
  1171.     INC    HL
  1172.     LD    A,(HL)
  1173.     CP    BLANK
  1174.     JR    NZ,VALERR
  1175.     JP    NXTNUM             ; CENTS OK
  1176. VALERR:    CALL    PRINT
  1177.     DEFB    0DH,0AH,'CHECK VALUE ERROR',0DH,0AH,0
  1178.     JP    GETCMD
  1179. ;
  1180. ; PUT ACC INTO STRING
  1181. ;
  1182. PUTSTR:    LD    B,8
  1183.     PUSH    AF
  1184.     LD    IY,STRING
  1185. PS1:    LD    A,(IY+1)
  1186.     LD    (IY+0),A
  1187.     INC    IY
  1188.     DJNZ    PS1
  1189.     POP    AF
  1190.     LD    (IY-1),A
  1191.     RET
  1192. ;
  1193. ; SET FLAG BITS
  1194. ;
  1195. FIXFLG:    LD    A,(WIFE)
  1196.     OR    A        ;SET THE FLAG
  1197.     JR    Z,FF0
  1198.     LD    A,(CNUM+1)    ;SET WIFE FLAG
  1199.     OR    080H
  1200.     LD    (CNUM+1),A
  1201. FF0:    LD    A,(CMD)
  1202.     CP    'C'
  1203.     JR    Z,FF1
  1204.     CP    'W'
  1205.     JR    Z,FW1
  1206.     CP    'D'
  1207.     JR    NZ,FXERR
  1208. ;
  1209. ; SET DEPOSIT FLAG
  1210. ;
  1211.     LD    A,(DAY)
  1212.     OR    080H
  1213.     LD    (DAY),A
  1214.     JR    NZ,FF1 ; JUMP
  1215. FXERR:    CALL    PRINT
  1216.     DEFB    0DH,0AH,'CMD ERROR IN FIXFLG',0DH,0AH,0
  1217.     JP    GETCMD
  1218. ;  
  1219. ; SET WITHDRAW FLAG
  1220. ;
  1221. FW1:    LD    A,(DAY)
  1222.     OR    040H
  1223.     LD    (DAY),A
  1224. FF1:    LD    A,(INPTR)
  1225.     LD    B,A
  1226.     LD    A,(INNUM)
  1227.     CP    B
  1228.     JR    NZ,FF4
  1229.     RET             ; NO MORE FLAGS
  1230. FF4:    LD    HL,BUFIN
  1231.     LD    DE,0000H
  1232.     LD    A,(INPTR)
  1233.     LD    E,A
  1234.     ADD    HL,DE
  1235.     LD    A,(HL)
  1236.     CP    BLANK
  1237.     JR    Z,NXTFLG
  1238.     CP    'R'
  1239.     JR    NZ,FF2
  1240.     LD    A,(CNUM+1)    ;SET RETURNED FLAG
  1241.     OR    040H
  1242.     LD    (CNUM+1),A
  1243.     JP    NXTFLG
  1244. FF2:    CP    'I'
  1245.     JR    NZ,FF3
  1246.     LD    A,(CVAL+2)    ;SET I TAX FLAG
  1247.     OR    80H
  1248.     LD    (CVAL+2),A
  1249.     JP    NXTFLG
  1250. FF3:    CP    'W'
  1251.     JR    NZ,FF6
  1252.     LD    A,(CNUM+1)
  1253.     OR    80H        ; SET WIFE FLG
  1254.     LD    (CNUM+1),A
  1255.     JP    NXTFLG
  1256. FF6:    CALL    PAKCAT
  1257.     LD    B,A
  1258.     LD    A,(MONTH)
  1259.     OR    B
  1260.     LD    (MONTH),A
  1261. NXTFLG:    LD    A,(INPTR)
  1262.     INC    A
  1263.     LD     (INPTR),A
  1264.     INC    HL
  1265.     JP    FF1
  1266. ;
  1267. ; INVALID CAT FLAGS ARE W,I,R
  1268. CAT:        DEFB    'NCDEFGHMPSU%%%%%'
  1269. ; % ARE SPARES
  1270. ;
  1271. ;
  1272. ; UNPACK BUFFER INTO BUFIN
  1273. ; INPTR AND INNUM SET TO END OF BUFIN
  1274. ;
  1275. UNPACK:    LD    A,0
  1276.     LD    HL,BUFFER
  1277.     LD    DE,BUFIN
  1278.     LD    A,(BUFFER)
  1279.     LD    (BINARY),A
  1280.     LD    A,(BUFFER+1)
  1281.     AND    3FH 
  1282.     LD    (BINARY+1),A     ; UNPACK CHECK #    
  1283.     LD    A,0
  1284.     LD    (BINARY+2),A        
  1285.     CALL    BTOD
  1286.     LD    B,4
  1287.     CALL    PUTBIN
  1288. ;
  1289. ; UNPACK MONTH
  1290. ;
  1291.     LD    A,(MONTH)
  1292.     AND    0FH 
  1293.     LD    (BINARY),A
  1294.     CALL    BTOD
  1295.     LD    B,4
  1296.     CALL    PUTBIN
  1297. ;
  1298. ; UNAPCK DAY
  1299. ;
  1300.     LD    A,(DAY)
  1301.     AND    3FH 
  1302.     LD    (BINARY),A
  1303.     CALL    BTOD
  1304.     LD    B,5
  1305.     CALL    PUTBIN
  1306. ;
  1307. ; INSERT SPACE BETWEEN DAY AND CHECK VALUE FOR LARGE CHECKS
  1308. ;
  1309.     LD    A,20H
  1310.     LD    (DE),A
  1311.     INC    DE
  1312.     CALL    OUTPUT
  1313. ;
  1314. ; UNPACK VALUE
  1315. ;
  1316.     LD    A,(CVAL)
  1317.     LD    (BINARY),A
  1318.     LD    A,(CVAL+1)
  1319.     LD    (BINARY+1),A
  1320.     LD    A,(CVAL+2)
  1321.     AND    7FH
  1322.     LD    (BINARY+2),A
  1323.     CALL    BTOD
  1324.     LD    A,1
  1325.     LD    (V),A        ;SET UP FOR CENTS MODE
  1326.     LD    B,1        ;SET UP FOR ALL OUTPUT
  1327.     CALL    PUTBIN
  1328.     LD    A,0
  1329.     LD    (V),A
  1330. ;
  1331. ; UNPACK NAME
  1332. ;
  1333.     LD    A,(NAME)
  1334.     LD    C,A
  1335.     CALL    GETNAM
  1336. ;
  1337. ; UNPACK FLAGS
  1338. ;
  1339. UPFLG:    LD    HL,CNUM+1
  1340.     BIT    7,(HL)
  1341.     JR    Z,UP2
  1342.     LD    A,'W'
  1343.     CALL    OUTPUT
  1344.     LD    (DE),A
  1345.     INC    DE        ;DE IS POINTER INTO BUFIN
  1346. UP2:    LD    IY,CNUM+1
  1347.     BIT    6,(IY+0)
  1348.     JR    Z,UP3
  1349.     LD    A,'R'
  1350.     CALL    OUTPUT
  1351.     LD    (DE),A        ;PUT R INTO BUFIN
  1352.     INC    DE
  1353. UP3:    LD    IY,CVAL+2
  1354.     BIT    7,(IY+0)
  1355.     JR    Z,UP4
  1356.     LD    A,'I'
  1357.     CALL    OUTPUT
  1358.     LD    (DE),A        ;PUT I INTO BUFIN 
  1359.     INC    DE
  1360. ;
  1361. ; UNPACK CATEGORY
  1362. ;
  1363. UP4:    LD    A,(MONTH)
  1364.     AND     0F0H
  1365.     RRCA
  1366.     RRCA
  1367.     RRCA
  1368.     RRCA
  1369.     LD    C,A        ;C IS OFFSET INTO CAT STRING
  1370.     LD    B,0
  1371.     LD    IY,CAT
  1372.     ADD    IY,BC        ;IY NOW POINTS TO C'TH ENTRY IN CAT
  1373.     LD    A,(IY+0)
  1374.     CP    '%'
  1375.     JR    Z,UPRET
  1376.     CP    'N'
  1377.     JR    Z,UPRET
  1378.     CALL    OUTPUT
  1379.     LD    (DE),A
  1380.     INC    DE        ;DE POINTS TO BUFIN
  1381. UPRET:    PUSH    DE
  1382.     POP    HL        ;EXCHANGE DE AND HL
  1383.     LD    BC,BUFIN
  1384.     OR    A        ;CLEAR CARRY JUST TO BE SURE
  1385.     SBC     HL,BC        ;COMPUTE INDEX INTO BUFFER
  1386.     LD    A,L
  1387.     LD    (INPTR),A
  1388.     LD    (INNUM),A
  1389. ;
  1390. ; NOW PRINT THE FULL NAME ON THE SCREEN
  1391. ;    RETURN IF THIS IS A TALLY COMMAND ELSE
  1392. ;    TAB TO COLUMN 40 THEN PRINT THE NAME
  1393. ;
  1394.     LD    B,A
  1395.     LD    A,(CMD)
  1396.     CP    'T'
  1397.     LD    A,B        ;RESTORE A=INPTR,INNUM
  1398.     RET    Z
  1399.     LD    B,A
  1400.     LD    A,40
  1401.     SUB    B
  1402.     LD    B,A
  1403. UPLP:    LD    A,BLANK
  1404.     CALL    OUTPUT
  1405.     DJNZ     UPLP
  1406.     LD    A,(NAME)
  1407.     LD    C,A
  1408.     CALL    PRNAM
  1409. ;
  1410. ; NOW RETURN THE CURSOR TO COLUMN SET BY INPTR
  1411. ;
  1412.     LD    A,0DH        ;RETURN CURSOR TO BEGINNING
  1413.     CALL    OUTPUT
  1414.     LD    A,(INPTR)
  1415.     LD    B,A
  1416. UPLP1:    LD    A,FWDSP
  1417.     CALL    OUTPUT
  1418.     DJNZ    UPLP1
  1419.     LD    A,(INPTR)
  1420.     RET
  1421. ;
  1422. ; B CONTAINS POINTER TO STRING
  1423. ; HL POINTS TO BUFFER
  1424. ; LEADING 'S REPLACED BY SPACES
  1425. ; IF V=1 THEN (.) INSERTED
  1426. ;
  1427. PUTBIN:    PUSH    BC
  1428.     LD    C,B
  1429.     LD    B,0
  1430. PTB2:    LD    IY,STRING
  1431.     ADD    IY,BC        ;IY POINTS TO B'TH ENTRY IN STRING
  1432.     LD    A,(IY+0)
  1433.     CP    '0'
  1434.     JR    NZ,PTB1
  1435.     LD    A,BLANK
  1436.     CALL    OUTPUT
  1437.     LD    (DE),A
  1438.     INC    DE        ;INCREMENT BUFFER POINTER
  1439.     INC    C        ;INCREMENT INDEX INTO STRING
  1440.     LD    A,C
  1441.     CP    6
  1442.     JR    NZ,PB3
  1443.     LD    A,(V)
  1444.     OR    A        ;SET THE FLAGS
  1445.     JR    NZ,PTB1
  1446. PB3:    CP    8
  1447.     JR    NZ,PTB2
  1448.     POP    BC
  1449.     LD    A,E
  1450.     LD    (INPTR),A
  1451.     RET
  1452. PTB1:    LD    A,C
  1453.     CP    6
  1454.     JR    NZ,PB2
  1455.     LD    A,(V)
  1456.     OR    A
  1457.     JR    Z,PB2
  1458.     LD    A,'.'
  1459.     CALL    OUTPUT
  1460.     LD    (DE),A
  1461.     INC    DE
  1462. PB2:    LD    IY,STRING
  1463.     OR    A        ;CLEAR CARRY
  1464.     ADD    IY,BC
  1465.     LD    A,(IY+0)
  1466.     CALL    OUTPUT
  1467.     LD    (DE),A
  1468.     INC    DE
  1469.     INC    C
  1470.     LD    A,C
  1471.     CP    8
  1472.     JR    NZ,PTB1
  1473.     POP    BC
  1474.     LD    A,E
  1475.     LD    (INPTR),A
  1476.     RET
  1477. ;
  1478. ; GET INPUT FROM CONSOLE WITH ECHO, COMMAND MODE ON CTRL C
  1479. ;
  1480. INPUT:     CALL    SYSIN
  1481.     CP    CANCEL        ;CANCEL THE COMMAND IN PROCESS?
  1482.     JP    NZ,CASE
  1483.     LD    A,0
  1484.     LD    (AUTFLG),A    ;CANCEL THE AUTO NUMBER MODE
  1485.     JP    GETCMD
  1486. ;
  1487. ;
  1488. ; ENTER CHECK BUFFER INTO CFILE AT END
  1489. ;
  1490. SAVNXT:    LD    HL,(CKSTRT)
  1491.     LD    DE,(FILSIZ)
  1492.     ADD    HL,DE
  1493.     LD    (TPTR),HL
  1494.     LD    A,E
  1495.     ADD    A,08H        ;INCREMENT BY 8 BYTES
  1496.     LD    E,A
  1497.     JR    NC,SAV1
  1498.     INC    D
  1499. SAV1:    LD    (FILSIZ),DE    ;UPDATE FILE SIZE
  1500. ;
  1501. ;NOW CHECK IF CHECK FILE WILL OVER WRITE NAME FILE
  1502. ;
  1503.     LD    HL,(NAMES)
  1504.     LD    DE,(TPTR)
  1505.     OR    A        ;CLEAR THE CARRY
  1506.     SBC    HL,DE
  1507.     JR    NC,REPLAC    ;TPTR<NAMES
  1508. ;
  1509. ;IF NAMES WOULD BE OVERWRITTEN THEN DEC FILSIZ BY 8
  1510. ;AND RETURN TO GET CMD AFTER ERROR MESSAGE
  1511. ;
  1512.     LD    HL,(FILSIZ)
  1513.     LD    B,0
  1514.     LD    C,8
  1515.     OR    A        ;CLEAR THE CARRY
  1516.     SBC    HL,BC
  1517.     LD    (FILSIZ),HL
  1518.     CALL    PRINT
  1519.     DEFB CLRSCR,'CHECK FILE FULL',0DH,0AH,0
  1520.     JP    GETCMD
  1521. ;
  1522. ; ENTER HERE WITH TPTR SET FOR REPLACE
  1523. ;
  1524. REPLAC:    LD    B,8        ;SET UP TO MOVE 8 BYTES
  1525.     LD    HL,BUFFER
  1526.     LD    IY,(TPTR)
  1527. REP1:    LD    A,(HL)
  1528.     LD    (IY+0),A
  1529.     INC    HL
  1530.     INC     IY
  1531.     DJNZ    REP1
  1532.     RET
  1533.  
  1534. PROMPT:    CALL    PRINT
  1535.     DEFB 0DH,0AH,'ENTER # (W # FOR WIFES CHECK)',0
  1536.     RET
  1537. ;
  1538. ; FIND # MATCH IN CFILE
  1539. ; RETURN LOAD ENTRY INTO BUFFER
  1540. ; TPTR SET TO LOCATION TO REPLACE
  1541. ;
  1542. FINDNO:    CALL    END
  1543.     LD    HL,(CKSTRT)
  1544.     LD    (TPTR),HL
  1545. F2:    LD    HL,(TPTR)
  1546.     LD    IY,BUFFER
  1547.     LD    A,(HL)
  1548.     CP    (IY+0)
  1549.     JR    NZ,F1
  1550.     INC    HL
  1551.     LD    A,(HL)
  1552.     AND     0BFH     ;CLEAR RETURN FLAG
  1553.     CP    (IY+1)
  1554.     JR    Z,FOUND
  1555. F1:    CALL    INCNXT
  1556. ;
  1557. ; NOW CHECK IF TPTR IS AT THE END OF THE CHECK FILE
  1558. ;
  1559.     LD    HL,(BUFEND)
  1560.     LD    DE,(TPTR)
  1561.     OR    A
  1562.     SBC    HL,DE
  1563.     JR    NC,F2        ;TPTR<BUFEND
  1564.     CALL    PRINT
  1565.     DEFB 0DH,0AH,'ENTRY NOT FOUND',0DH,0AH,0
  1566.     JP    GETCMD
  1567. FOUND:    LD    A,(CMD)
  1568.     CP    'W'
  1569.     JR    NZ,F5
  1570.     LD    HL,(TPTR)
  1571.     LD    BC,0006        ;LOOK AT 6TH ENTRY
  1572.     ADD    HL,BC
  1573.     LD    A,(HL)
  1574.     AND     40H         ;IS W FLAG SET
  1575.     JR    Z,F1         ; NO GOTO NEXT ENTRY
  1576.     JR    NZ,F4
  1577. F5:    CP     'D'
  1578.     JR    NZ,F6
  1579.     LD    HL,(TPTR)
  1580.     LD    BC,0006H    ;LOOK AT 6TH ENTRY
  1581.     ADD    HL,BC
  1582.     LD    A,(HL)        
  1583.     AND     080H        ;IS D FLAG SET
  1584.     JR    Z,F1         ; NO GOTO NEXT ENTRY
  1585.     JR    NZ,F4
  1586. F6:    CP    'C'
  1587.     JR    Z,F7 ; OK
  1588. F8:    POP    AF        ;CLEAN UP THE STACK
  1589.     JP    CMDERR
  1590. F7:    LD    HL,(TPTR)
  1591.     LD    BC,0006H    ;LOOK AT 6TH ENTRY
  1592.     ADD    HL,BC
  1593.     LD    A,(HL)
  1594.     AND     0C0H
  1595.     CP     0
  1596.     JR    NZ,F1
  1597. F4:    LD    B,8        ;TRANSFER ENTRY TO BUFFER
  1598.     LD    HL,(TPTR)
  1599.     LD    IY,BUFFER
  1600. F9:    LD    A,(HL)
  1601.     LD    (IY+0),A
  1602.     INC    HL
  1603.     INC    IY
  1604.     DJNZ    F9
  1605.     RET             ;TPTR AT ENTRY LOC.
  1606. ;
  1607. ; INC TPTR TO NEXT ENTER
  1608. ;
  1609. INCNXT:    LD    HL,(TPTR)
  1610.     LD    BC,0008
  1611.     ADD    HL,BC
  1612.     LD    (TPTR),HL
  1613.     RET
  1614. ;
  1615. ; COMPUTE CFILE END
  1616. ;
  1617. END:    LD    HL,(CKSTRT)
  1618.     LD    DE,(FILSIZ)
  1619.     ADD    HL,DE
  1620.     LD    (BUFEND),HL
  1621.     RET
  1622. ;
  1623. ; SET TPTR TO GETCMD OF CFILE
  1624. ;
  1625. GOTOP:    LD    HL,(CKSTRT)
  1626.     LD    (TPTR),HL
  1627.     RET
  1628. ;
  1629. ; FIRST TEST DONE ELSE
  1630. ; TRANSFER TPTR ENTRY TO BUFFER
  1631. ; THEN INCREMENT TPTR TO NEXT
  1632. ;
  1633. GETNXT:    LD    HL,(TPTR)
  1634.     LD    BC,(BUFEND)
  1635.     OR    A
  1636.     SBC    HL,BC
  1637.     JR    NZ,GTNXT1
  1638.     SCF
  1639.     RET             ;CARRY SET WHEN EOF
  1640. ;
  1641. ; NOW MOVE 8 BYTES FROM TPTR TO BUFFER
  1642. ;
  1643. GTNXT1:    LD    B,8
  1644.     LD    IY,BUFFER
  1645.     LD    HL,(TPTR)
  1646. GTNXT2:    LD    A,(HL)
  1647.     LD    (IY+0),A
  1648.     INC    HL
  1649.     INC    IY
  1650.     DJNZ    GTNXT2
  1651.     CALL    INCNXT
  1652.     SCF
  1653.     CCF
  1654.     RET
  1655. ;
  1656. ; ZERO SUM
  1657. ;
  1658. ZSUM:    LD    A,0
  1659.     LD    (SUM),A
  1660.     LD    (SUM+1),A
  1661.     LD    (SUM+2),A
  1662.     RET
  1663. ;
  1664. ; ADD CVAL TO SUM
  1665. ;
  1666. ADD:    LD    A,(CVAL+2)
  1667.     AND    7FH
  1668.     LD    (CVAL+2),A
  1669. ADD0:    OR    A        ;CLEAR THE CARRY FLAG
  1670. ADD1:    LD    A,(CVAL)
  1671.     LD    B,A
  1672.     LD    A,(SUM)
  1673.     ADC    A,B
  1674.     LD    (SUM),A
  1675.     LD    A,(CVAL+1)
  1676.     LD    B,A
  1677.     LD    A,(SUM+1)
  1678.     ADC    A,B
  1679.     LD    (SUM+1),A
  1680.     LD    A,(CVAL+2)
  1681.     LD    B,A
  1682.     LD    A,(SUM+2)
  1683.     ADC    A,B
  1684.     LD    (SUM+2),A
  1685.     RET
  1686. ;
  1687. ; SUBTRACT CVAL FROM SUM
  1688. ; FORM 2'S COMPLEMENT THEN ADD
  1689. ;
  1690. SUBTR:    LD    A,(CVAL)
  1691.     XOR    0FFH
  1692.     LD    (CVAL),A
  1693.     LD    A,(CVAL+1)
  1694.     XOR    0FFH
  1695.     LD    (CVAL+1),A
  1696.     LD    A,(CVAL+2)
  1697.     AND    7FH        ;CLR I FLAG
  1698.     XOR    0FFH
  1699.     LD    (CVAL+2),A
  1700.     SCF
  1701.     JP    ADD1
  1702. ;
  1703. ; PRINT BALANCE/TOTAL
  1704. ; SEND 2'S COMPLEMENT IF NEGATIVE
  1705. ;
  1706. PRTOT:    CALL    TPRINT
  1707.     DEFB     ' TOTAL IS     ',0
  1708.     JP    TOTAL
  1709. PRBAL:    CALL    TPRINT
  1710.     DEFB 0DH,0AH,'BALANCE ',0
  1711. TOTAL:    LD    HL,SUM+2
  1712.     BIT    7,(HL)
  1713.     JR    Z,PBA2        ;NOT NEGATIVE
  1714.     LD    A,'-'
  1715.     CALL    OUTPUT
  1716. ;
  1717. ; FORM THE TWO'S COMPLEMENT OF SUM
  1718. ;
  1719.     LD    A,(SUM+2)
  1720.     XOR    0FFH
  1721.     LD    (SUM+2),A
  1722.     LD    A,(SUM+1)
  1723.     XOR    0FFH
  1724.     LD    (SUM+1),A
  1725.     LD    A,(SUM)
  1726.     XOR    0FFH
  1727.     ADD    A,1
  1728.     LD    (SUM),A
  1729.     LD    A,(SUM+1)
  1730.     ADC    A,0
  1731.     LD    (SUM+1),A
  1732.     LD    A,(SUM+2)
  1733.     ADC    A,0
  1734.     LD    (SUM+2),A
  1735. PBA2:    LD    A,'$'
  1736.     CALL    OUTPUT
  1737. ;
  1738. ; NOW MOVE SUM TO BINARY
  1739. ;
  1740.     LD    B,3        ;MOVE 3 BYTES
  1741.     LD    HL,SUM  
  1742.     LD    IX,BINARY  
  1743. PBA4:    LD    A,(HL)
  1744.     LD    (IX+0),A
  1745.     INC    HL
  1746.     INC    IX
  1747.     DJNZ    PBA4
  1748.     CALL    BTOD
  1749.     LD     A,1         ; WRITE INTO BUFIN BUT NOT USED
  1750.     LD    DE,BUFIN    ;SO PUTBIN KNOWS WHERE TO WRITE
  1751.     LD    (V),A
  1752.     LD    B,1
  1753.     LD    HL,BUFIN
  1754.     INC    HL
  1755.     CALL    PUTBIN
  1756.     LD    A,0
  1757.     LD    (V),A
  1758.     RET
  1759. ;
  1760. ; TRANSFER BAL AT GETCMDNING OF YEAR TO SUM
  1761. ;
  1762. YRSTRT:    LD    A,(BEGYR)
  1763.     LD    (SUM),A
  1764.     LD    A,(BEGYR+1)
  1765.     LD    (SUM+1),A
  1766.     LD    A,(BEGYR+2)
  1767.     LD    (SUM+2),A
  1768.     RET
  1769. ;
  1770. ; PACK CATEGORY FLAG
  1771. ;
  1772. PAKCAT:    LD    HL,CAT+15
  1773.     LD    BC,16         
  1774.     CPDR
  1775.     JP    PE,PKC5
  1776.     CALL    PRINT
  1777.     DEFB 0DH,0AH,'INVALID CATEGORY',0DH,0AH,0
  1778.     JP    GETCMD
  1779. PKC5:    LD    A,C
  1780.     SLA    A
  1781.     SLA    A
  1782.     SLA    A
  1783.     SLA    A
  1784.     RET
  1785. ;
  1786. ; UNPACK ON SCREEN IN PAGE LENGTHS
  1787. ;
  1788. ;
  1789. ; FIND NAME
  1790. ; RETURN A=NAME INDEX,CARRY=0 IF FOUND
  1791. ; RETURN A=0,CARRY=1 IF NOT FOUND
  1792. ;
  1793. FINDNA:    LD    A,(NIND)
  1794. FN2:    CP    0 
  1795.     JR    NZ,FN1
  1796. NONAME:    LD     A,0
  1797.     SCF
  1798.     RET
  1799. FN1:    LD    BC,0000H
  1800.     LD    C,A        ;BC NOW HAS NIND OFFSET
  1801.     DEC    C
  1802. FN7:    LD    IX,(NB1)
  1803.     ADD    IX,BC
  1804.     LD    A,(IX+0)
  1805.     LD    HL,CMNEM
  1806.     CP    (HL)
  1807.     JR    Z,FN3
  1808.     JR    NZ,FN5 ; NO MATCH
  1809. FN3:    LD    IX,(NB2)
  1810.     ADD    IX,BC
  1811.     LD    A,(IX+0)
  1812.     LD    HL,CMNEM+1
  1813.     CP    (HL)
  1814.     JR    Z,FN4
  1815.     JR    NZ,FN5 ; NO MATCH
  1816. FN4:    LD    IX,(NB3)
  1817.     ADD    IX,BC
  1818.     LD    A,(IX+0)
  1819.     LD    HL,CMNEM+2
  1820.     CP    (HL)
  1821.     JR    Z,FN6 ; FOUND IT
  1822.     JR    NZ,FN5 ; NO MATCH
  1823. FN5:    DEC    C
  1824.     JP    P,FN7
  1825.     INC    C
  1826.     JP    NONAME
  1827. FN6:    LD    A,C         ; NAME FOUND
  1828.     SCF
  1829.     CCF
  1830.     RET
  1831. ;
  1832. ; GET NAME INDEX EQUIV TO NAME
  1833. ; RETURN A=0,C=1 IF NOT FOUND
  1834. ;
  1835. NAMBYT:    LD    DE,0000H
  1836.     LD    A,(INPTR)
  1837.     LD    E,A
  1838.     LD    A,(INNUM)
  1839.     CP    E
  1840.     JR    NC,NBYT4
  1841.     JR    Z,NBYT4
  1842. NBYT2:    CALL    PRINT
  1843.     DEFB 0DH,0AH,'3 CHARACTER NAME NOT SPECIFIED',0DH,0AH,0
  1844.     JP    GETCMD
  1845. NBYT4:    LD    B,3
  1846.     LD    IY,CMNEM
  1847.     LD    HL,BUFIN
  1848.     ADD    HL,DE
  1849.     LD    A,(HL)        ;LOAD C'TH ENTRY IN BUFIN
  1850.     CP    BLANK
  1851.     JR    NZ,NBYT3
  1852.     LD    HL,INPTR
  1853.     INC    (HL)
  1854.     JR    NZ,NAMBYT ; IGNORE LEADING SPC'S
  1855. ; TRANSFER NAME TO CMNEM
  1856. NBYT1:    LD    A,(INPTR)
  1857.     INC    A
  1858.     LD    (INPTR),A
  1859.     LD    E,A        ;INCREMENT INPTR LOCAL VAR.
  1860.     LD    A,(INNUM)
  1861.     CP    E
  1862.     JR    Z,NBYT2 ; ERROR RETURN
  1863. NBYT3:    LD    HL,BUFIN
  1864.     ADD    HL,DE
  1865.     LD    A,(HL)
  1866.     LD    (IY+0),A
  1867.     INC    IY
  1868.     DJNZ    NBYT1
  1869.     LD    A,(INPTR)
  1870.     INC    A
  1871.     LD    (INPTR),A
  1872.     JP    FINDNA ; RETURN
  1873. ;
  1874. ; PUT NAME IN NAME FILE
  1875. ;
  1876. FIXNAM:    LD    A,(NIND)
  1877.     CP    0FFH
  1878.     JR    NZ,NAMADD
  1879. NBFULL:    CALL    PRINT
  1880.     DEFB 0DH,0AH,'NAME BUFFER FULL',0DH,0AH,0
  1881.     JP    GETCMD
  1882. NAMADD:    LD    BC,0000H
  1883.     LD    C,A        ;C IS NOW INDEX
  1884.     LD    A,(CMNEM)
  1885.     LD    IY,(NB1)
  1886.     ADD    IY,BC
  1887.     LD    (IY+0),A
  1888.     LD    A,(CMNEM+1)
  1889.     LD    IY,(NB2)
  1890.     ADD    IY,BC
  1891.     LD    (IY+0),A
  1892.     LD    A,(CMNEM+2)
  1893.     LD    IY,(NB3)
  1894.     ADD    IY,BC
  1895.     LD    (IY+0),A
  1896.     LD    A,(OFFST)
  1897.     LD    IY,(OL)
  1898.     ADD    IY,BC
  1899.     LD    (IY+0),A
  1900.     LD    A,(OFFST+1)
  1901.     LD    IY,(OH)
  1902.     ADD    IY,BC
  1903.     LD    (IY+0),A
  1904. NADD:    CALL    PRINT
  1905.     DEFB 0DH,0AH,'TYPE FULL CHECK NAME',0DH,0AH,0
  1906.     CALL    TABOFF
  1907.     LD    A,0
  1908.     LD    (INPTR),A
  1909.     LD    (INNUM),A     ; USE BUFIN TO GET NAME
  1910.     CALL    GETIN
  1911. ; COMPUTE ADR FOR NAME IN NTABLE
  1912.     OR    A        ;CLR CARRY
  1913.     LD    HL,(NTABLE)
  1914.     LD    DE,(OFFST)
  1915.     ADD    HL,DE
  1916.     LD    (NPTR),HL
  1917. ;
  1918. ;CHECK FOR NAME FILE FULL
  1919. ;
  1920.     LD    BC,0000H
  1921.     LD    A,(INNUM)
  1922.     LD    C,A
  1923.     LD    HL,(NPTR)
  1924.     ADD    HL,BC
  1925.     LD    (NTEMP),HL
  1926.     LD    HL,(TOP)
  1927.     LD    BC,(NTEMP)
  1928.     SBC    HL,BC
  1929.     JP    C,NBFULL
  1930. ; TRANSFER NAME FROM BUFIN TO NTABLE
  1931. NCONT:    LD    HL,BUFIN
  1932.     LD    DE,(NPTR)
  1933.     LD    BC,000H
  1934.     LD    A,(INNUM)
  1935.     LD    C,A
  1936.     LDIR
  1937. MOVDON:    LD    A,EOL ; MARK END OF LINE
  1938.     LD    (DE),A
  1939. ; UPDATE OFFST
  1940.     LD    A,(INNUM)
  1941.     INC    A
  1942.     LD    (INNUM),A    ;TO ACCOUNT FOR EOL
  1943.     LD    B,A
  1944.     LD    A,(OFFST)
  1945.     ADD    A,B
  1946.     LD    (OFFST),A
  1947.     JR    NC,MVD1
  1948.     LD    HL,OFFST+1
  1949.     INC    (HL)
  1950. MVD1:    LD    A,(NIND)
  1951.     INC    A
  1952.     LD    (NIND),A
  1953.     DEC    A
  1954.     RET
  1955. ;
  1956. ; PRINT THE NUMBER OF NAMES IN THE NAME FILE
  1957. ;
  1958. PRTNUM:    CALL    PRINT
  1959.     DEFB    '     ',0DH,0AH,0H
  1960.     LD    A,(NIND)
  1961.     LD    (BINARY),A
  1962.     CALL    BTOD
  1963.     LD    B,3
  1964.     LD    DE,BUFIN    ;PUTBIN WILL WRITE DATA
  1965.     CALL    PUTBIN        ;SOMEWHERE SO PUT IT IN BUFIN
  1966.     CALL    PRINT
  1967.     DEFB    ' NAMES IN THE NAME FILE (255 MAX.)',0DH,0AH,0H
  1968.     LD    A,0
  1969.     LD    (INPTR),A
  1970.     LD    (INNUM),A
  1971.     RET
  1972. ;
  1973. ; PRINT NAME MNEUMONIC
  1974. ; BC CONTAINS INDEX TO NAME FILE
  1975. ; DE POINTS TO INPUT LOCATION IN BUFIN
  1976. ;
  1977. GETNAM:    LD    B,0
  1978.     LD    A,BLANK
  1979.     CALL    OUTPUT
  1980.     LD    (DE),A
  1981.     INC    DE
  1982.     LD    HL,(NB1)
  1983.     ADD    HL,BC
  1984.     LD    A,(HL)
  1985.     CALL    OUTPUT
  1986.     LD    (DE),A
  1987.     INC    DE 
  1988.     LD    HL,(NB2)
  1989.     ADD    HL,BC
  1990.     LD    A,(HL)
  1991.     CALL    OUTPUT
  1992.     LD    (DE),A
  1993.     INC    DE
  1994.     LD    HL,(NB3)
  1995.     ADD    HL,BC
  1996.     LD    A,(HL)
  1997.     CALL    OUTPUT
  1998.     LD    (DE),A
  1999.     INC    DE
  2000.     LD    A,BLANK
  2001.     CALL    OUTPUT
  2002.     LD    (DE),A
  2003.     INC    DE
  2004.     CALL    OUTPUT
  2005.     LD    (DE),A
  2006.     INC    DE
  2007.     PUSH    DE        
  2008.     POP    HL        ;PUT DE IN HL
  2009.     LD    BC,BUFIN
  2010.     OR    A
  2011.     SBC    HL,BC
  2012.     LD    A,L
  2013.     LD    (INPTR),A
  2014.     RET
  2015. ;
  2016. ; TAB INPUT ON SPACE
  2017. ; RETURN TO GETIN IF SPACE
  2018. ; AFTER TABING TO NEXT FIELD
  2019. ;
  2020. TABNXT:    PUSH    AF
  2021.     CP    BLANK
  2022.     JR    NZ,TABRET
  2023.     LD    A,(TABFLG)
  2024.     OR    A
  2025.     JR    Z,TABRET
  2026.     LD    BC,0000H
  2027.     LD    A,(INPTR)
  2028.     LD    C,A
  2029.     LD    HL,TABS
  2030.     ADD    HL,BC
  2031.     LD    A,(HL)
  2032.     OR    A
  2033.     JR    NZ,TABRET
  2034. ; MOVE INPTR FORWARD TO NEXT TAB
  2035. ; INSERTING SPACES WHILE MOVING
  2036. TABMOV:    LD    IY,BUFIN
  2037.     LD    A,(INPTR)
  2038.     LD    C,A
  2039.     LD    A,BLANK
  2040.     ADD    IY,BC
  2041.     LD    (IY+0),A
  2042.     CALL    OUTPUT
  2043.     INC    C
  2044.     LD    A,C
  2045.     LD    (INPTR),A
  2046.     LD    HL,TABS
  2047.     ADD    HL,BC
  2048.     LD    A,(HL)
  2049.     OR    A
  2050.     JR    Z,TABMOV
  2051.     LD    A,(INNUM)
  2052.     CP    C
  2053.     JR    NC,TBM1
  2054.     POP    AF
  2055. TBM1:    POP    AF
  2056.     JP    GETIN
  2057. TABRET:    POP    AF        ; VALID INPUT
  2058.     RET
  2059. ;
  2060. TABS:    DEFB 0,0,0,0,0,0,1,0,0,1
  2061.     DEFB 0,0,0,1,0,0,0,0,0,0
  2062.     DEFB 0,1,1,1,0,0,1,0,0,0,0,0,0
  2063. ;
  2064. ; TURN TABBING ON AND OFF
  2065. ;
  2066. TABON:    LD    A,0FFH
  2067.     LD    (TABFLG),A
  2068.     RET
  2069. TABOFF:    LD    A,0
  2070.     LD    (TABFLG),A
  2071.     RET
  2072. ;
  2073. ; OUTPUT SELECTOR
  2074. ;
  2075. OUTPUT:    PUSH    AF
  2076.     LD    A,(OUTPOS)
  2077.     INC    A
  2078.     LD    (OUTPOS),A
  2079.     PUSH    HL
  2080.     LD    HL,PTRFLG
  2081.     BIT    7,(HL)
  2082.     POP    HL
  2083.     JR    Z,CONOU1
  2084.     POP    AF
  2085. ; 
  2086. ; DO NOT PASS FWDSP ON TO PRINTER
  2087. ;
  2088.     CP    FWDSP
  2089.     RET    Z
  2090. ;
  2091. PRTOUT:    PUSH    AF
  2092.     PUSH    BC
  2093.     PUSH    DE
  2094.     PUSH    HL
  2095.     LD    E,A
  2096.     LD    C,5
  2097.     CALL    BDOS
  2098.     POP    HL
  2099.     POP    DE
  2100.     POP    BC
  2101.     POP    AF
  2102.     RET
  2103. CONOU1:    POP    AF
  2104. CONOUT:    PUSH    AF
  2105.     PUSH    BC
  2106.     PUSH    DE
  2107.     PUSH    HL
  2108.     LD    E,A
  2109.     LD    C,2
  2110.     CALL    BDOS
  2111.     POP    HL
  2112.     POP    DE
  2113.     POP    BC
  2114.     POP    AF
  2115.     RET
  2116. ;
  2117. ; TOGGLE PRINTER ON
  2118. ;
  2119. TOGGLE:    LD    A,0FFH
  2120.     LD    (PTRFLG),A
  2121.     JP    CMD2
  2122. ;
  2123. ; ASSUME VALID FCB HAS BEEN SET UPON ENTRY OR MODIFIED
  2124. ; BY MOVNAM OR PUTNAM, SAVE CURRENT CHECK FILE ON DISK
  2125. ;
  2126. SAVCHK:    LD    A,(FCB)        ;SEE IF DEFAULT DRIVE
  2127.     CP    0H
  2128.     JR    NZ,S1        ;IF DRIVE SPECIFIED, IGNORE FOLLOWING
  2129.     LD    A,(DFTUNT)    ;ELSE GET THE DEFAULT UNIT
  2130.     INC    A
  2131.     LD    (FCB),A        ;AND PUT IT IN FCB
  2132. S1:    LD    DE,FCB        ;AMBIGUOUS NOT PERMITTED IN DELETE
  2133.     LD    C,DELFC
  2134.     CALL    BDOS
  2135.     LD    DE,FCB
  2136.     LD    C,MAKEFC
  2137.     CALL    BDOS
  2138.     INC    A
  2139.     JR    NZ,SAVCK1
  2140.     CALL    PRINT
  2141.     DEFB    0DH,0AH,'UNABLE TO SAVE CHECKS',0DH,0AH,0H
  2142.     POP    AF
  2143.     JP    GETCMD
  2144. SAVCK1:    LD    A,0H
  2145.     LD    (FCB+32),A
  2146.     LD    HL,BEGYR
  2147.     LD    BC,(FILSIZ)
  2148.     ADD    HL,BC        ;COMPUTES ADR. OF LAST CHECK DATA
  2149.     LD    (CHKEND),HL
  2150.     LD    HL,CKLOC
  2151. SLOOP:    LD    DE,DMA
  2152.     LD    BC,128
  2153.     LDIR            ;FILL BUFFER WITH 128 BYTES
  2154.     LD    DE,FCB
  2155.     LD    C,WRTFC
  2156.     PUSH    HL        ;IT GETS DESTROYED OTHERWISE
  2157.     CALL    BDOS        ;WRITE IT ON DISK
  2158.     POP    HL
  2159.     OR    A
  2160.     JR    Z,SAVOK
  2161.     CALL    PRINT
  2162.     DEFB    0DH,0AH,'WRITE ERROR SAVING CHECKS',0DH,0AH,0H
  2163.     POP    AF        ;CLEAN UP STACK
  2164.     JP    GETCMD
  2165. SAVOK:    PUSH    HL
  2166.     LD    BC,(CHKEND)
  2167.     OR    A
  2168.     SBC    HL,BC
  2169.     POP    HL
  2170.     JR    C,SLOOP        ;LOOP UNTIL HL>CHKEND
  2171.     LD    DE,FCB        ;ELSE CLOSE THE FILE & RETURN
  2172.     LD    C,CLSFC
  2173.     CALL    BDOS
  2174.     RET
  2175. ;
  2176. ; SAVE EXISTING NAME FILE ON THE DISK
  2177. ; ASSUME THAT NFCB HAS BEEN PREVIOUSLY UPDATED
  2178. ;
  2179. SAVNAM:    LD    A,(NFCB)    ;CHECK FOR AMBIGUOUS UNIT NUMBER
  2180.     CP    0H        ;IF NOT AMBIGUOUS THEN IGNORE
  2181.     JR    NZ,S2
  2182.     LD    A,(DFTUNT)    ;ELSE GET THE DEFAULT DRIVE NUMBER
  2183.     INC    A
  2184.     LD    (NFCB),A    ;AND PUT IT IN NFCB
  2185. S2:    LD    DE,NFCB
  2186.     LD    C,DELFC
  2187.     CALL    BDOS
  2188.     LD    DE,NFCB
  2189.     LD    C,MAKEFC
  2190.     CALL    BDOS
  2191.     INC    A
  2192.     JR    NZ,SAVNA1
  2193.     CALL    PRINT
  2194.     DEFB    0DH,0AH,'UNABLE TO SAVE NAMES',0DH,0AH,0H
  2195.     POP    AF        ;CLEAN UP STACK
  2196.     JP    GETCMD
  2197. SAVNA1:    LD    A,0H
  2198.     LD    (NFCB+32),A
  2199.     LD    HL,NTABL
  2200.     LD    BC,(OFFST)
  2201.     ADD    HL,BC        ;COMPUTES END OF NAME FILE
  2202.     LD    (NAMEND),HL
  2203.     LD    HL,NIND        ;HL POINTS TO START OF NAMES FILE
  2204. NLOOP:    LD    DE,DMA
  2205.     LD    BC,128
  2206.     LDIR            ;FILLS DMA BUFFER WITH 128 BYTES
  2207.     LD    DE,NFCB
  2208.     LD    C,WRTFC
  2209.     PUSH    HL        ;IT GETS DESTROYED
  2210.     CALL    BDOS        ;SAVES DMA BUFFER ON DISK
  2211.     POP    HL
  2212.     OR    A
  2213.     JR    Z,NSAVOK
  2214.     CALL    PRINT
  2215.     DEFB    0DH,0AH,'WRITE ERROR SAVING NAMES',0DH,0AH,0H
  2216.     POP    AF        ;CLEAN UP THE STACK
  2217.     JP    GETCMD
  2218. NSAVOK:    PUSH    HL
  2219.     LD    BC,(NAMEND)
  2220.     OR    A
  2221.     SBC    HL,BC
  2222.     POP    HL
  2223.     JR    C,NLOOP        ;LOOP UNTIL HL>NAMEND
  2224.     LD    DE,NFCB
  2225.     LD    C,CLSFC        ;NOW CLOSE NAME FILE
  2226.     CALL    BDOS
  2227.     RET
  2228. ;
  2229. ;
  2230. ; LOAD CHECK FILE WHOSE NAME IS IN FCB
  2231. ; ASSUME NAME IS VALID--SET BY MOVNAM OR PUTNAM
  2232. ; IF READ IS SUCCESSFUL, THEN CLOSE THE FILE AND
  2233. ; MAKE THE OLD COPY A BACK UP COPY
  2234. ;
  2235. LDCHK:    LD    DE,FCB
  2236.     LD    C,OPENFC
  2237.     CALL    BDOS
  2238.     INC    A        ;CHECK IF OPEN ERROR
  2239.     JR    NZ,LDC1
  2240.     CALL    PRINT
  2241.     DEFB    0DH,0AH,'CHECK NAME DOES NOT EXIST',0DH,0AH,0H
  2242.     POP    AF
  2243.     JP    GETCMD
  2244. LDC1:    LD    DE,CKLOC
  2245.     LD    A,0H
  2246.     LD    (FCB+32),A
  2247. LDC2:    PUSH    DE
  2248.     LD    DE,FCB
  2249.     LD    C,READFC
  2250.     CALL    BDOS
  2251.     POP    DE
  2252.     OR    A        ;RETURNS NZ IF END OF FILE
  2253.     JR    NZ,CLSCHK
  2254.     LD    HL,DMA
  2255.     LD    BC,128
  2256.     LDIR
  2257.     JP    LDC2
  2258. ;
  2259. CLSCHK:    LD    C,CLSFC
  2260.     LD    DE,FCB
  2261.     CALL    BDOS        ;CLOSE THE CHECK FILE
  2262.     RET
  2263. ;
  2264. ; LOAD NAME FILE WHOSE NAME IS IN NFCB
  2265. ; ASSUME NAME IS VALID AND SET BY MOVNAM OR PUTNAM
  2266. LDNAM:    LD    DE,NFCB
  2267.     LD    C,OPENFC
  2268.     CALL    BDOS
  2269.     INC    A        ;RETURNS FFH IF SUCCESSFUL
  2270.     JR    NZ,LDN1
  2271.     CALL    PRINT
  2272.     DEFB     0DH,0AH,'CAN NOT FIND NAME FILE',0DH,0AH,0H
  2273.     JP    GETCMD
  2274. LDN1:    LD    DE,NAMLOC
  2275.     LD    A,0H
  2276.     LD    (NFCB+32),A
  2277. LDN2:    PUSH    DE
  2278.     LD    DE,NFCB
  2279.     LD    C,READFC
  2280.     CALL    BDOS
  2281.     POP    DE
  2282.     OR    A        ;RETURNS NZ IF EOF
  2283.     JR    NZ,CLSNAM
  2284.     LD    HL,DMA
  2285.     LD    BC,128
  2286.     LDIR
  2287.     JP    LDN2
  2288. ;
  2289. CLSNAM:    LD    C,CLSFC
  2290.     LD    DE,NFCB
  2291.     CALL    BDOS        ;CLOSE THE NAME FILE
  2292.     RET
  2293. ;
  2294. ; PRINT/FIX NAME OF CHECK FILE
  2295. ; TO BE SAVED
  2296. ;
  2297. PRTNAM:    CALL    PRINT
  2298.     DEFB 0DH,0AH,'CHECKS AND NAMES TO BE SAVED AS',0DH,0AH,0
  2299.     LD    B,8
  2300.     LD    HL,FCB+1
  2301. PRTN1:    LD    A,(HL)
  2302.     CALL    OUTPUT
  2303.     INC    HL
  2304.     DJNZ    PRTN1
  2305.     LD    A,20H        ;SEND A SPACE
  2306.     CALL    OUTPUT
  2307.     LD    B,8
  2308.     LD    HL,NFCB+1
  2309. PRTN2:    LD    A,(HL)
  2310.     CALL    OUTPUT
  2311.     INC    HL
  2312.     DJNZ    PRTN2
  2313.     CALL    PRINT
  2314.     DEFB 0DH,0AH,'OK? (Y/N)',0
  2315.     CALL    INPUT
  2316.     PUSH    AF
  2317.     CALL    CRLF
  2318.     POP    AF
  2319.     CP    'Y'
  2320.     JR    NZ,PRN2
  2321.     RET
  2322. PRN2:    CP    'N'
  2323.     JR    NZ,PRTNAM
  2324.     CALL    PUTNAM
  2325.     RET
  2326. ;
  2327. ; GET NEW FILENAME
  2328. ;
  2329. PUTNAM:    CALL    PRINT
  2330.     DEFB 0DH,0AH,'NAME OF CHECK FILE :    ',0DH,0AH,0
  2331.     CALL    GETINP
  2332.     CALL    FXFCB
  2333.     CALL    FXNFCB        ;CLEAR THE FILE CONTROL BLOCKS
  2334.     LD    HL,BUFIN
  2335. PTN1:    LD    A,(HL)
  2336.     INC    HL
  2337.     CP    20H
  2338.     JR    Z,PTN1        ;READ FORWARD TO FIRST CHAR
  2339.     LD    A,(HL)        ;IS THE NEXT CHAR A ':'
  2340.     CP    ':'
  2341.     DEC    HL        ;RESET HL TO FIRST CHAR
  2342.     JR    NZ,PTN2
  2343.     CALL    MAKFNO        ;IF SO MAKE THE DISK NUMBER
  2344.     LD    (FCB),A        ;AND PUT IT INTO THE FCB
  2345. PTN2:    LD    DE,BUFIN    ;NOW LETS COMPUTE INPTR
  2346.     PUSH    HL
  2347.     OR    A
  2348.     SBC    HL,DE        ; HAS VALUE OF INPTR
  2349.     LD    C,L
  2350.     POP    HL
  2351.     LD    DE,FCB+1    ;DE POINTS TO FCB NAME
  2352. ;
  2353. ; NOW MOVE THE NAME POINTED TO BY HL TO FCB UNTIL A SPACE
  2354. ; IS ENCOUNTERED OR UNTIL INPTR EQUALS INNUN
  2355. ;
  2356. PTN3:    LD    A,(INNUM)
  2357.     CP    C
  2358.     JP    Z,COPYN2    ;IF EQUAL WERE DONE 
  2359.     LD    A,(HL)
  2360.     CP    20H        ;IS IT DONE?
  2361.     JR    Z,PTN4
  2362.     CP    '.'
  2363.     JR    Z,PTN5
  2364.     LD    (DE),A        ;ELSE MOVE THE CHARACTER
  2365.     INC    DE
  2366.     INC    HL
  2367.     INC    C
  2368.     JP    PTN3
  2369. ;
  2370. PTN5:    CALL    PRINT
  2371.     DEFB    0DH,0AH,'DO NOT INCLUDE FILE TYPE',0DH,0AH,0H
  2372.     JP    PUTNAM
  2373. ;
  2374. ; CHECK NAME SUCCESSFULLY TRANSFERRED , NOW CHECK FOR NAME FILE
  2375. ;
  2376. PTN4:    LD    A,(HL)
  2377.     INC    HL
  2378.     INC    C
  2379.     CP    20H
  2380.     JR    Z,PTN4        ;READ FORWARD TO FIRST NON BLANK CHAR.
  2381.     LD    A,(INNUM)
  2382.     CP    C
  2383.     JP    Z,DONPTN
  2384.     LD    A,(HL)        ;IS THE NEXT CHAR A ':'
  2385.     DEC    HL
  2386.     CP    ':'
  2387.     JR    NZ,PTN6        ;IF NOT TRANSFER NAME TO NFCB
  2388.     CALL    MAKFNO
  2389.     LD    (NFCB),A    ;PUT DISK NUMBER IN NFCB
  2390. PTN6:    LD    DE,BUFIN
  2391.     PUSH    HL
  2392.     OR    A
  2393.     SBC    HL,DE
  2394.     LD    C,L
  2395.     POP    HL
  2396.     LD    DE,NFCB+1
  2397. ;
  2398. ; NOW MOVE THE NAME POINTED TO BY HL TO NFCB UNTIL A SPACE
  2399. ; IS ENCOUNTERED OR UNTIL INPTR EQUALS INNUN
  2400. ;
  2401. PTN7:    LD    A,(INNUM)
  2402.     CP    C
  2403.     JP    Z,DONPTN
  2404.     LD    A,(HL)
  2405.     CP    20H        ;NAME DONE IF TRAILING SPACE
  2406.     JP    Z,DONPTN
  2407.     CP    '.'
  2408.     JP    Z,DONPTN    ;IGNORE ANY NAME TYPE GIVEN
  2409.     LD    (DE),A        ;ELSE MOVE THE CHARACTER
  2410.     INC    DE
  2411.     INC    HL
  2412.     INC    C
  2413.     JP    PTN7
  2414. ;
  2415. ; IF ONLY ONE NAME IS GIVEN, THEN ASSUME THAT NAME FILE
  2416. ; IS THE SAME AS THE CHECK FILE
  2417. ;
  2418. COPYN2:    LD    HL,FCB
  2419.     LD    DE,NFCB
  2420.     LD    BC,9
  2421.     LDIR
  2422. ;
  2423. ; NOW ALL NAMES HAVE BEEN MOVED, FIX UP THE TYPES AND
  2424. ; RETURN FROM THIS SUBROUTINE CALL
  2425. ;
  2426. DONPTN:    CALL    FIXTYP
  2427.     RET
  2428. ;
  2429. ; GET THE DISK UNIT NUMBER AND CONVERT IT TO A BINARY
  2430. ; NUMBER AND RETURN IT IN THE ACC.  
  2431. ; SET HL TO THE FIRST VALID CHARACTER IN THE NAME
  2432. ; BEFORE RETURNING
  2433. ;
  2434. MAKFNO:    LD    A,(HL)        ;HL POINTS TO UNIT NUMBER ASCII CHAR
  2435.     INC    HL
  2436.     INC    HL        ;LEAVE WITH HL AT NXT CHAR AFTER ':'
  2437.     SUB    40H
  2438.     CP    1
  2439.     RET    Z
  2440.     CP    2
  2441.     RET    Z        ;FOR NOW ONLY 2 DRIVES
  2442.     CALL    PRINT
  2443.     DEFB    0DH,0AH,'INVALID DRIVE SPECIFIED',0DH,0AH,0
  2444.     POP    AF        ;CLEAN UP THE STACK
  2445.     JP    PUTNAM        ;ASK IT AGAIN
  2446. ;
  2447. ; TEXT PRINTER ON SELECTED OUTPUT DEVICE
  2448. ;
  2449. TPRINT:    POP    HL    ;HL POINTS TO TEXT TO BE PRINTED
  2450. PRI10:    LD    A,(HL)
  2451.     OR    A
  2452.     JR    Z,PRI20
  2453.     CALL    OUTPUT
  2454.     INC    HL
  2455.     JP    PRI10
  2456. PRI20:    INC    HL
  2457.     PUSH    HL
  2458.     RET
  2459. ;
  2460. ;
  2461. ; TEXT PRINTER ON CONSOLE ONLY
  2462. ;
  2463. PRINT:    POP    HL    ;HL POINTS TO TEXT TO BE PRINTED
  2464. PR10:    LD    A,(HL)
  2465.     OR    A
  2466.     JR    Z,PR20
  2467.     PUSH    BC
  2468.     PUSH    DE
  2469.     PUSH    HL
  2470.     LD    C,2
  2471.     LD    E,A
  2472.     CALL    BDOS
  2473.     POP    HL
  2474.     POP    DE
  2475.     POP    BC
  2476.     INC    HL
  2477.     JP    PR10
  2478. PR20:    INC    HL
  2479.     PUSH    HL
  2480.     RET
  2481. ;
  2482. ; CHECK KEYBOARD INPUT--IF CANCEL THEN JUMP TO COMMAND MODE
  2483. ; ELSE IGNORE THE INPUT AND RETURN----DESTROYS AF
  2484. ;
  2485. KBDTST:    PUSH    BC        ;ADDED ROUTINE IN REV 1.4
  2486.     PUSH    DE
  2487.     PUSH    HL
  2488.     LD     C,11        ;GET CONSOLE STATUS
  2489.     CALL    BDOS
  2490.     OR    A
  2491.     POP    HL
  2492.     POP    DE
  2493.     POP    BC
  2494.     RET    Z        
  2495.     CALL    SYSIN        ; READ KEYBOARD
  2496.     CP    CANCEL
  2497.     JP    Z,GETCMD
  2498.     RET
  2499. ;
  2500. ;
  2501. ; PRINT INCOME TAX DEDUCTIBLE CHECKS
  2502. ;
  2503. ITAX:    CALL    CRLF
  2504.     LD    A,'C'
  2505.     LD    (CMD),A
  2506.     CALL    HEAD
  2507.     CALL    ZSUM
  2508.     CALL    GOTOP
  2509.     CALL    END
  2510. ITAX1:    CALL    GETNXT
  2511.     JR    C,TAXDON
  2512.     LD    HL,CVAL+2
  2513.     BIT    7,(HL)        ;TEST I FLAG
  2514.     JP    Z,ITAX1
  2515.     LD    HL,DAY
  2516.     BIT    7,(HL)
  2517.     JR    NZ,ITAX1    ;IGNORE DEPOSITS
  2518.     CALL    UNPACK
  2519.     CALL    CRLF
  2520.     CALL    ADD
  2521.     JP    ITAX1
  2522. TAXDON:    CALL    PRTOT
  2523.     JP    GETCMD
  2524. ;
  2525. ; PRINT WIFES / RETURNED CHECKS
  2526. ;
  2527. WSRC:    LD    A,080H
  2528.     JP    RC1
  2529. RSRC:    LD    A,040H
  2530. RC1:    LD    (MASK),A
  2531.     LD    A,'C'
  2532.     LD    (CMD),A
  2533.     CALL    HEAD
  2534.     CALL    CRLF
  2535.     CALL    ZSUM
  2536.     CALL    GOTOP
  2537.     CALL    END
  2538. WRLOOP:    CALL    GETNXT
  2539.     JP    C,WRDONE
  2540.     LD    HL,DAY
  2541.     BIT    7,(HL)        ;IGNORE DEPOSITS
  2542.     JR    NZ,WRLOOP
  2543.     LD    A,(CNUM+1)
  2544.     LD    B,A
  2545.     LD    A,(MASK)
  2546.     AND    B
  2547.     JR    Z,WRLOOP
  2548.     CALL    UNPACK
  2549.     CALL    CRLF
  2550.     CALL    ADD
  2551.     JP    WRLOOP
  2552. WRDONE:    CALL    PRTOT
  2553.     JP    GETCMD
  2554. ;
  2555. ;************************************************************
  2556. ;
  2557. ;    PROGRAM STARTS HERE
  2558. ;
  2559. ;************************************************************
  2560. ;
  2561. START1:    LD    HL,000H
  2562.     ADD    HL,SP
  2563.     LD    (OLDSP),HL
  2564.     LD    SP,STACK+128    ;CREATE LOCAL STACK
  2565.     XOR    A
  2566.     LD    (PTRFLG),A    ;START WITH PRINTER OFF
  2567. ;
  2568. ; IN ORDER FOR REV 1.4 TO WORK, BIOS LOCATION FOR SYSTEM INPUT
  2569. ; WILL BE COMPUTED AND STORED IN INPADR FOR INPUT WITHOUT ECHO
  2570. ;
  2571.     LD    HL,(1)        ;GET ADDRESS OF BIOS+3
  2572.     LD    BC,6        ;INPUT ADDRESS IS 6 BYTES HIGHER
  2573.     ADD    HL,BC
  2574.     LD    (INPADR+1),HL    ;STORE ADDRESS THERE
  2575. ;
  2576. ; NOW PUT NOP'S IN 100-103H SO WARM START CAN BE DONE AT 100H
  2577. ;
  2578.     LD    A,0        ;NOP INSTRUCTION
  2579.     LD    (100H),A
  2580.     LD    (101H),A
  2581.     LD    (102H),A
  2582. ;
  2583. ; SIGN ON MESSAGE
  2584. ;
  2585.     LD    A,CLRSCR
  2586.     CALL    OUTPUT
  2587.     CALL    PRINT
  2588.     DEFB    'CHECKING PROGRAM',0DH,0AH
  2589.     DEFB    'RALPH SHERMAN',0DH,0AH
  2590.     DEFB    '15 HYDAWAY DR',0DH,0AH
  2591.     DEFB    'FOREST,VA 24551',0DH,0AH
  2592.     DEFB    'REVISION 4/3/82',0DH,0AH,0H
  2593. ;
  2594. ;
  2595. ; MOVE INITIAL CHECK DATA TO START OF CHECK FILE
  2596. ;
  2597.     LD    HL,CKTBL
  2598.     LD    DE,CKLOC
  2599.     LD    BC,CKSIZ
  2600.     LDIR
  2601. ;
  2602. ; INITIALIZE NAME FILE
  2603. ;
  2604.     LD    A,0
  2605.     LD    (NAMLOC),A
  2606.     LD    (NAMLOC+1),A
  2607.     LD    (NAMLOC+2),A
  2608. ;
  2609. ; CHECK IF FILE NAME FOR CHECKS IS IN THE FCB
  2610. ;
  2611.     LD    A,(FCB+1)    ;CHECK IF THERE IS A NAME
  2612.     CP    20H        ;IF SPACE THEN NO NAME
  2613.     JR    Z,ST10
  2614. ;
  2615. ; NOW THAT A NAME IS PRESENT, LOAD THE CHECK AND NAME FILES
  2616. ;
  2617.     CALL    MOVNAM        ;MOVE NAMES IN FCS
  2618.     CALL    LDCHK
  2619.     CALL    LDNAM
  2620.     JP    GETCMD
  2621. ;
  2622. ST10:    CALL    PRINT
  2623.     DEFB     'CHECK FILE IS CLEAR',0DH,0AH,0
  2624.     JP    GETCMD
  2625. ;
  2626. ; FXNFCB INITIALIZES THE NAME FILE CONTROL BLOCK
  2627. ; IT FILLS NFCB WITH 32 ZEROES AND THE FILE NAME WITH SPACES
  2628. ;
  2629. FXNFCB:    LD    HL,NFCB
  2630.     LD    A,0
  2631.     LD    B,36
  2632. FXNF1:    LD    (HL),A
  2633.     INC    HL
  2634.     DJNZ    FXNF1        ;PUT 0'S IN NFCB
  2635.     LD    HL,NFCB+1
  2636.     LD    A,20H
  2637.     LD    B,11
  2638. FXNF2:    LD    (HL),A
  2639.     INC    HL
  2640.     DJNZ    FXNF2        ;PUT SPACES IN NAME AREA
  2641.     RET
  2642. ;
  2643. ; FXFCB INITIALIZES THE CHECK FILE CONTROL BLOCK
  2644. ; IT FILLS FCB WITH 32 ZEROES AND THE FILE NAME WITH SPACES
  2645. ;
  2646. FXFCB:    LD    HL,FCB
  2647.     LD    A,0
  2648.     LD    B,36
  2649. FXFC1:    LD    (HL),A
  2650.     INC    HL
  2651.     DJNZ    FXFC1        ;PUTS 0'S IN FCB
  2652.     LD    HL,FCB+1
  2653.     LD    A,20H
  2654.     LD    B,11
  2655. FXFC2:    LD    (HL),A
  2656.     INC    HL
  2657.     DJNZ    FXFC2        ;PUT SPACES IN NAME AREA
  2658.     RET
  2659. ;
  2660. ; MOVNAM READS THE FCB AND FIXES UP THE FILE TYPES  
  2661. ; IF A FILE IS SPECIFIED FOR THE NAME FILE, IT MOVES FCB2 TO NFCB
  2662. ;
  2663. MOVNAM:    LD    A,(FCB2+1)
  2664.     CP    20H        ;WAS A NAME FILE SPECIFIED?
  2665.     JR    Z,MOVN4        ;NO NAME, COPY CHECK FILE NAME
  2666.     CALL    FXNFCB
  2667.     LD    HL,FCB2
  2668.     LD    DE,NFCB
  2669.     LD    BC,15
  2670.     LDIR            ;ELSE COPY NAME SPECIFIED
  2671.     JR    FIXTYP
  2672. MOVN4:    CALL    FXNFCB
  2673.     LD    HL,FCB        ;NAME FILE IS SAME AS CHK FILE
  2674.     LD    DE,NFCB
  2675.     LD    BC,15
  2676.     LDIR
  2677. ;
  2678. ; FIXTYP SETS THE FILE TYPES FOR THE CHECK AND NAME FILES
  2679. ;
  2680. FIXTYP:    LD    HL,NAM
  2681.     LD    DE,NFCB+9
  2682.     LD    BC,3
  2683.     LDIR            ;SET .NAM AS NAME FILE TYPE
  2684.     LD    HL,CHK
  2685.     LD    DE,FCB+9
  2686.     LD    BC,3
  2687.     LDIR            ;SET .CHK AS CHECK FILE TYPE
  2688.     RET
  2689. ;
  2690. ;FIX NAME ENTRY
  2691. ;
  2692. NAMFIX:    CALL    NAMPTR ; PTR IN MASK
  2693. NF2:    CALL    PRINT
  2694.     DEFB 0DH,0AH,'FIX MNEMONIC (Y/N)',0
  2695.     CALL    INPUT
  2696.     CP     'N'
  2697.     JR    Z,NF1
  2698.     CP     'Y'
  2699.     JR    NZ,NF2
  2700. NF5:    CALL    PRINT
  2701.     DEFB 0DH,0AH,'TYPE NEW MNEMONIC',0DH,0AH,0
  2702.     CALL    GETINP
  2703.     LD    A,(INNUM)
  2704.     CP     3
  2705.     JR    NC,NF6
  2706.     CALL    PRINT
  2707.     DEFB CLRSCR,'TYPE 3 CHAR MNEMONIC',0DH,0AH,0
  2708.     JP    NF5
  2709. NF6:    LD    HL,BUFIN
  2710.     LD    BC,0000H
  2711.     LD    A,(MASK)
  2712.     LD    C,A
  2713. NF3:    LD    A,(HL)
  2714.     CP    BLANK
  2715.     JR    NZ,NF4
  2716.     INC    HL
  2717.     JP    NF3
  2718. NF4:    LD    IX,(NB1)
  2719.     ADD    IX,BC
  2720.     LD    (IX+0),A
  2721.     INC    HL
  2722.     LD    A,(HL)
  2723.     LD    IX,(NB2)
  2724.     ADD    IX,BC
  2725.     LD    (IX+0),A
  2726.     INC    HL
  2727.     LD    A,(HL)
  2728.     LD    IX,(NB3)
  2729.     ADD    IX,BC
  2730.     LD    (IX+0),A
  2731. NF1:    CALL    PRINT
  2732.     DEFB 0DH,0AH,'FIX FULL NAME (Y/N)',0
  2733.     CALL    INPUT
  2734.     CP    'N'
  2735.     JR    Z,NFRTS
  2736.     CP    'Y'
  2737.     JR    NZ,NF1
  2738.     LD    BC,0000H
  2739.     LD    A,(MASK)
  2740.     LD    C,A
  2741.     LD    IX,(OL)
  2742.     ADD    IX,BC
  2743.     LD    A,(OFFST)
  2744.     LD    (IX+0),A
  2745.     LD    IX,(OH)
  2746.     ADD    IX,BC
  2747.     LD    A,(OFFST+1)
  2748.     LD    (IX+0),A
  2749.     CALL    NADD
  2750.     LD    A,(NIND)
  2751.     DEC    A
  2752.     LD    (NIND),A
  2753. NFRTS:    JP    GETCMD
  2754. ;
  2755. ; PRINT MONTHLY BALANCE SHEET
  2756. ;
  2757. TALPR:    CALL    GETMO
  2758.     LD    A,(PTRFLG)
  2759.     OR    A
  2760.     JR    Z,TP1
  2761.     LD    A,FORMFD
  2762.     CALL    PRTOUT
  2763. TP1:    CALL    CRLF 
  2764.     CALL    CRLF
  2765.     LD    B,25
  2766.     CALL    TABIT
  2767.     CALL    TPRINT
  2768.     DEFB 'BALANCE SHEET ',0
  2769.     CALL    CRLF
  2770.     CALL    CRLF
  2771. ;
  2772. ; COMPUTE BAL AT MONTH START
  2773. ;
  2774.     CALL    YRSTRT
  2775.     CALL    GOTOP
  2776.     CALL    END
  2777. TL1:    CALL    GETNXT
  2778.     JR    C,TDON1
  2779.     CALL    MTEST
  2780.     JR    Z,TL1
  2781.     JR    C,TL1        ;ONLY ADD UP IF < MONTH TALLIED
  2782.     LD    HL,DAY
  2783.     BIT    7,(HL)
  2784.     JR    NZ,TL2
  2785.     CALL    SUBTR
  2786.     JP    TL1
  2787. TL2:    CALL    ADD
  2788.     JP    TL1
  2789. TDON1:    CALL    TPRINT
  2790.     DEFB 'STARTING BALANCE',0
  2791.     LD    B,68
  2792.     CALL    TABIT
  2793.     CALL    TOTAL
  2794.     CALL    CRLF
  2795.     CALL    CRLF
  2796.     CALL    TPRINT
  2797.     DEFB 'DEPOSITS',0
  2798.     CALL    CRLF
  2799.     CALL    CRLF
  2800.     CALL    THEAD
  2801.     CALL    CRLF
  2802.     CALL    GOTOP
  2803.     CALL    END
  2804.     LD    A,80H
  2805.     LD    (MASK),A
  2806. TL3:    CALL    GETNXT
  2807.     JR    C,TL4
  2808.     CALL    MTEST
  2809.     JR    NZ,TL3
  2810.     LD    A,(DAY)
  2811.     AND    0C0H
  2812.     LD    B,A
  2813.     LD    A,(MASK)
  2814.     CP    B
  2815.     JR    NZ,TL3
  2816.     LD    A,0
  2817.     LD    (OUTPOS),A
  2818.     CALL    PRCHK
  2819.     LD    B,67
  2820.     CALL    TABIT
  2821.     CALL    PRVAL
  2822.     CALL    CRLF
  2823.     CALL    ADD
  2824.     JP    TL3
  2825. TL4:    CALL    CRLF
  2826.     LD    B,70
  2827.     CALL    TABIT
  2828.     CALL    TPRINT
  2829.     DEFB '----------',0
  2830.     CALL    CRLF
  2831.     CALL    TPRINT
  2832.     DEFB 'TOTAL ',0
  2833.     LD    B,68
  2834.     CALL    TABIT
  2835.     CALL    TOTAL
  2836.     CALL    SAVVAL
  2837.     CALL    ZSUM
  2838.     CALL    CRLF
  2839.     CALL    TPRINT
  2840.     DEFB 'WITHDRAWALS',0
  2841.     CALL    CRLF
  2842.     CALL    CRLF
  2843.     CALL    THEAD
  2844.     CALL    CRLF
  2845.     LD    A,040H
  2846.     LD    (MASK),A
  2847. TL7:    CALL    GOTOP
  2848. TL5:    CALL    GETNXT
  2849.     JR    C,TL6
  2850.     CALL    MTEST
  2851.     JR    NZ,TL5
  2852.     LD    A,(DAY)
  2853.     AND    0C0H
  2854.     LD    B,A
  2855.     LD    A,(MASK)
  2856.     CP    B
  2857.     JR    NZ,TL5
  2858.     CALL    PRCHK
  2859.     LD    B,60
  2860.     CALL    TABIT
  2861.     CALL    PRVAL
  2862.     CALL    CRLF
  2863.     CALL    SUBTR
  2864.     JP    TL5
  2865. TL6:    LD    A,(MASK)
  2866.     OR    A
  2867.     JR    Z,TL8
  2868.     CALL    CRLF
  2869.     CALL    TPRINT
  2870.     DEFB 'CHECKS',0
  2871.     CALL    CRLF
  2872.     CALL    CRLF
  2873.     CALL    THEAD
  2874.     CALL    CRLF
  2875.     CALL    CRLF
  2876.     LD    A,0
  2877.     LD    (MASK),A
  2878.     JP    TL7
  2879. TL8:    CALL    CRLF
  2880.     LD    B,60
  2881.     CALL    TABIT
  2882.     CALL    TPRINT
  2883.     DEFB '----------',0
  2884.     CALL    CRLF
  2885.     CALL    TPRINT
  2886.     DEFB 'TOTAL',0
  2887.     LD    B,59
  2888.     CALL    TABIT
  2889.     CALL    TOTAL
  2890.     CALL    CRLF
  2891.     CALL    CRLF
  2892.     CALL    TPRINT
  2893.     DEFB 'PERIOD ENDING BALANCE',0
  2894.     LD    B,68
  2895.     CALL    TABIT
  2896.     LD    B,3
  2897.     LD    HL,SUM
  2898.     LD    IX,CVAL
  2899.     LD    IY,STEMP
  2900. TL9:    LD    A,(HL)
  2901.     LD    (IX+0),A
  2902.     LD    A,(IY+0)
  2903.     LD    (HL),A
  2904.     INC    HL
  2905.     INC    IX
  2906.     INC    IY
  2907.     DJNZ    TL9
  2908.     CALL    SUBTR
  2909.     CALL    TOTAL
  2910.     CALL    CRLF
  2911.     LD    A,(PTRFLG)
  2912.     OR    A
  2913.     JR    Z,TP2
  2914.     LD    A,FORMFD
  2915.     CALL    PRTOUT
  2916. TP2:    LD    A,0
  2917.     LD    (PTRFLG),A
  2918.     RET
  2919. ;
  2920. ; TEST CHECK MONTH
  2921. ;
  2922. MTEST:    LD    A,(OUTMO)
  2923.     OR    A
  2924.     JR    NZ,MT1
  2925.     RET
  2926. MT1:    LD    A,(MONTH)
  2927.     AND    0FH
  2928.     LD    B,A
  2929.     LD    A,(OUTMO)
  2930.     CP    B
  2931.     RET
  2932. ;
  2933. ; TAB TO PRINTER POS AT B
  2934. ;
  2935. TABIT:    LD    A,(OUTPOS)
  2936.     CP    B
  2937.     JR    Z,TABRTS
  2938.     LD    A,BLANK
  2939.     CALL    OUTPUT
  2940.     JR    NZ,TABIT
  2941. TABRTS:    RET
  2942. OUTPOS:    DEFB 0
  2943. ;
  2944. ; GET MONTH ARG FOR PRNT
  2945. ; IF MONTH ARE PRESENT, PUT IN OUTMO
  2946. ; DEFAULT IS MONTH 0
  2947. ;
  2948. GETMO:    CALL    PRINT
  2949.     DEFB  13,10,'WHAT MONTH ?',0
  2950.     CALL    GETINP
  2951.     CALL    CRLF
  2952.     LD    B,0H
  2953.     LD    HL,BUFIN
  2954. TAL1:    LD    A,(HL)
  2955.     CP    NEWLIN
  2956.     JR    Z,TAL3
  2957.     CP    BLANK
  2958.     JR    NZ,TAL2
  2959.     INC    B
  2960.     INC    HL
  2961.     JR    NZ,TAL1
  2962. TAL2:    INC    B
  2963.     INC    HL
  2964.     LD    A,(INNUM)
  2965.     CP    B
  2966.     JR    NZ,TAL1
  2967. TAL3:    LD    A,0
  2968.     LD    (INPTR),A
  2969.     CALL    GETDEC
  2970.     CALL    DTOB
  2971.     LD    A,(BINARY)
  2972.     AND    0FH
  2973.     LD    (OUTMO),A
  2974.     RET
  2975. ;
  2976. ; PRINT CHECK ENTRY FOR TALLY
  2977. ; IF TALLY IS ON SCREEN, SLOW THE PROCESS DOWN
  2978. ; ELSE LET IT RIP.
  2979. ;
  2980. PRCHK:    CALL    KBDTST        ;ADDED REV 1.4
  2981.     CALL    SLOW
  2982.     LD    B,0
  2983.     LD    HL,BUFFER
  2984.     LD    IX,BINARY
  2985.     LD    A,0
  2986.     LD    (INPTR),A
  2987.     LD    A,(HL)
  2988.     LD    (IX+0),A
  2989.     INC    B
  2990.     INC    HL
  2991.     INC    IX
  2992.     LD    A,(HL)
  2993.     AND    03FH
  2994.     LD    (IX+0),A
  2995.     LD    A,0
  2996.     INC    B
  2997.     INC    HL
  2998.     INC    IX
  2999.     LD    (IX+0),A
  3000.     CALL    BTOD
  3001.     LD    B,4
  3002.     CALL    PUTBIN
  3003. ;
  3004. ;PRINT MONTH
  3005. ;
  3006.     LD    A,(MONTH)
  3007.     AND    0FH
  3008.     LD    (BINARY),A
  3009.     CALL    BTOD
  3010.     LD    B,4
  3011.     CALL    PUTBIN
  3012. ;
  3013. ;PRINT DAY
  3014. ;
  3015.     LD    A,(DAY)
  3016.     AND    03FH
  3017.     LD    (BINARY),A
  3018.     CALL    BTOD
  3019.     LD    B,5
  3020.     CALL    PUTBIN
  3021.     LD    A,BLANK
  3022.     CALL    OUTPUT
  3023.     CALL    OUTPUT
  3024.     CALL    UPFLG
  3025.     LD    B,22
  3026.     CALL    TABIT
  3027.     LD    BC,0000H
  3028.     LD    A,(NAME)    ;IS OFFSET TO NAME ADDRESS
  3029.     LD    C,A
  3030.     CALL    PRNAM
  3031.     RET
  3032. ; 
  3033. ; PRINT CHECK VALUE
  3034. ;
  3035. PRVAL:    LD    HL,CVAL        ;MOVE 3 BYTES FROM CVAL TO BINARY
  3036.     LD    DE,BINARY
  3037.     LD    BC,03H
  3038.     LDIR
  3039.     LD    A,(BINARY+2)
  3040.     AND    07FH
  3041.     LD    (BINARY+2),A
  3042.     CALL    BTOD
  3043.     LD    B,1
  3044.     LD    A,B
  3045.     LD    (V),A
  3046.     CALL    PUTBIN
  3047.     LD    A,0
  3048.     LD    (V),A
  3049.     RET
  3050. ;
  3051. ; SLOW DOWN OUTPUT PRINTING WHEN ON CONSOLE
  3052. ;
  3053. SLOW:    LD    A,(PTRFLG)
  3054.     OR    A
  3055.     RET    NZ
  3056.     LD    A,50         ;SET UP FOR 50 MS. DELAY
  3057. DELAY:    LD    C,249
  3058. DLY1:    DEC    C
  3059.     JR     NZ,DLY1
  3060.     DEC    A
  3061.     JR    NZ,DELAY
  3062.     RET
  3063. ;
  3064. THEAD:    CALL    TPRINT
  3065.     DEFB '    #  MO DA  FLG   NAME',0
  3066.     JP    CRLF
  3067. ;
  3068. ; MOVE 3 BYTES FROM SUM TO STEMP
  3069. ;
  3070. SAVVAL:    LD    A,(SUM)
  3071.     LD    (STEMP),A
  3072.     LD    A,(SUM+1)
  3073.     LD    (STEMP+1),A
  3074.     LD    A,(SUM+2)
  3075.     LD    (STEMP+2),A
  3076.     RET
  3077. ;
  3078. ; GET FILE NAME
  3079. ;
  3080. FILNAM:    RET        ;FOR NOW
  3081. ;
  3082. STEMP:    DEFS    3
  3083.  
  3084.  
  3085.  
  3086.  
  3087.  
  3088. ;
  3089. ; GENERAL PURPOSE SUBROUTINES
  3090. ;
  3091. SYSIN:    PUSH    BC
  3092.     PUSH    DE
  3093.     PUSH    HL
  3094.     LD    C,1
  3095.     CALL    BDOS
  3096.     POP    HL
  3097.     POP    DE
  3098.     POP    BC
  3099.     RET
  3100. ;
  3101. ; MAP LOWER CASE TO UPPER CASE
  3102. ;    
  3103. CASE:    CP    60H
  3104.     JR    C,CAS10
  3105.     AND    07FH
  3106.     SUB    020H
  3107. CAS10:    RET
  3108. ;
  3109. ; GET AN INPUT WITHOUT ECHO
  3110. ;
  3111. SYSINP:    PUSH    BC
  3112.     PUSH    DE
  3113.     PUSH    HL
  3114. INPADR:    CALL    CONIN        ;BIOS CONSOLE INPUT ADDRESS
  3115. ;                ;COMPUTED DURING START
  3116.     POP    HL
  3117.     POP    DE
  3118.     POP    BC
  3119.     RET
  3120. CONIN    EQU    INPADR+1    ;DUMMY ADDRESS
  3121. ;
  3122. ; VARIABLES
  3123. ;
  3124. CTRLC    EQU    3
  3125. NEWLIN    EQU    13
  3126. LINEFD    EQU    10
  3127. BLANK    EQU    32
  3128. EOL     EQU    0FFH
  3129. CPTR:    DEFS    2 ; CHECK FILE POINTER
  3130. SUM:    DEFS    3 
  3131. ADDER:    DEFS    3
  3132. X0:    DEFS    2 ; X TEMP
  3133. BUFFER:    DEFS    8 ; CHECK BUFFER
  3134. CNUM    EQU    BUFFER
  3135. MONTH    EQU    CNUM+5
  3136. DAY    EQU    CNUM+6
  3137. CVAL    EQU    CNUM+2
  3138. NAME    EQU    CNUM+7
  3139. CREV:    DEFB    0
  3140. CATMOD:    DEFB    00H
  3141. NAM3:    DEFB    'NAM'
  3142. NREV:    DEFB    0
  3143. CMODE:    DEFB    0
  3144. CMNEM:    DEFS    3 ; CHECK MNEMONIC
  3145. TPTR:    DEFS    2 ; TEMPORARY POINTER
  3146. REMAIN:    DEFS    3
  3147. BINARY:    DEFS    3
  3148. BUFIN:    DEFS    32
  3149. BUFSIZ    EQU    $-BUFIN
  3150. INNUM:    DEFS    1
  3151. INPTR:    DEFS    1
  3152. XIND:    DEFS    1
  3153. CMD:    DEFS    1
  3154. WIFE:    DEFS    1
  3155. V:    DEFB    0
  3156. CKSTRT:    DEFW    CK
  3157. BUFEND:    DEFS    2
  3158. MASK:    DEFS    1
  3159. NOFFST:    DEFW    OFFST
  3160. NB1:    DEFW    MNEU1
  3161. NB2:    DEFW    MNEU2
  3162. NB3:    DEFW    MNEU3
  3163. OL:    DEFW    OFFL
  3164. OH:    DEFW    OFFH
  3165. NTABLE:    DEFW    NTABL
  3166. TABFLG:    DEFB    0     ;0    EQU    OFF FF    EQU    ON
  3167. PTRFLG:    DEFB    0
  3168. OUTMO:    DEFB    0
  3169. INPOS:    DEFS    1
  3170. NPTR:    DEFS    2
  3171. MODE:    DEFB    2
  3172. LENGTH:    DEFS    2
  3173. CHKS:    DEFW    CFILE
  3174. NAMES:    DEFW    NFILE
  3175. NTEMP:    DEFS    2
  3176. TOP:    DEFW    CCPBAS
  3177. STRING:    DEFS    16
  3178. ;
  3179. ; NEW VARIABLES AS A RESULT OF Z80 CONVERSION
  3180. ;
  3181. ;NEWVAR
  3182. ;
  3183. AUTFLG:    DEFB    0        ;AUTO CHECK NUMBER OFF
  3184. AUTOCN:    DEFS    2        ;STOREAGE FOR CHECK NUMBER
  3185. JMPADR:    DEFS    2        ;LOCATION FOR JUMP INDIRECT
  3186. OLDSP:    DEFS    2        ;OLD STACK POINTER
  3187. STACK:    DEFS    128        ;LOCAL STACK
  3188. CHKEND:    DEFS    2        ;END ADR. OF CHECK FILE
  3189. NAMEND:    DEFS    2        ;END ADR. OF NAME FILE
  3190. BAK:    DEFB    'BAK'        ;BAK FILE TYPE
  3191. NAM:    DEFB    'NAM'        ;NAME FILE TYPE
  3192. CHK:    DEFB    'CHK'        ;CHECK FILE TYPE
  3193. NFCB:    DEFS    36        ;NAME FILE CONTROL BLOCK
  3194. CKTBL    EQU    $
  3195.     .PHASE CKLOC
  3196. BEGYR:    DEFB    0,0,0 ; BAL AT YR START
  3197. WITHNO:    DEFB    1; WITHDRAWAL #
  3198. DEPNO:    DEFB    1 ; DEPOSIT #
  3199. BAL:    DEFB    0,0,0 ; PRESENT BAL
  3200. FILSIZ:    DEFB    0,0 ; SIZE OF CFILE IN BYTES
  3201. CK    EQU    $ ; START OF CHECKS
  3202. CKSIZ    EQU    $-BEGYR     ;SIZE OF INITIAL CHECK DATA
  3203.     .DEPHASE
  3204.     .PHASE NAMLOC
  3205. NIND:    DEFB    0
  3206. OFFST:    DEFB    0,0
  3207. MNEU1:    DEFS    256
  3208. MNEU2:    DEFS    256
  3209. MNEU3:    DEFS    256
  3210. OFFL:    DEFS    256
  3211. OFFH:    DEFS    256
  3212. NTABL    EQU    $
  3213.     .DEPHASE
  3214.     END START
  3215.