home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol116 / listtu84.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  41.8 KB  |  1,568 lines
  1.  
  2. ; LISTT v1.3  --  File utility program for printers   --  02/22/83
  3. ;
  4. ; 03/17/83
  5. ;
  6. ;    LISTT v1.3 has been modified to provide the following capabilities:
  7. ;
  8. ;      1) Program some of the OKIDATA Microline printer's 
  9. ;         attributes on selective basis before printing each file.
  10. ;
  11. ;      2) Time/Date stamp each page of the printed output using
  12. ;         Electralogics Incorporated's MFIO Reat Time Clock.
  13. ;
  14. ;    Since I prefer to use 8 1/2 inch paper, I have chosen to set
  15. ;    all form width characteristics relative to that preference.
  16. ;    These values may be easily changed to suit your own 
  17. ;    requirements.
  18. ;
  19. ;    I have also chosen to set the default specifications for the
  20. ;    printer as:- 8 lines per inch vertically and 17 characters
  21. ;    per inch horizontally. The headers are set up to locate
  22. ;    pertinent data in the same relative locations at the top of
  23. ;    the printed page regardless of the print/line characteristics
  24. ;    selected.
  25. ;
  26. ;    One more little thing; I like to leave a left margin of 20
  27. ;    spaces at 17 characters per inch, 10 spaces at 12 characters
  28. ;    per inch and no spaces at 10 characters per inch. 
  29. ;        
  30. ;    When the program is executed, the current printer parameters
  31. ;    are displayed and you are then asked if you wish to
  32. ;    alter the printer parameters (print density, or lines per
  33. ;    inch). If you answer in the affirmative, options will be
  34. ;    offered. Don't forget to answer "d" (for done) when you have
  35. ;    completed your option selection. The answer "n" will result
  36. ;    in the selection of the default parameters discussed above.
  37. ;
  38. ;    If a particular parameter is changed, for example - 6 lines
  39. ;    per inch is selected, then the variable "TEXT" is modified
  40. ;    to allow more lines of text per page. A similar
  41. ;    modification to the code is made if a different print
  42. ;    density is selected. The column in which the page number 
  43. ;    starts to print is also changed to reflect the new density.
  44. ;
  45. ;    Changes to Irv Hoff's code have been left in lower case to
  46. ;    ease recognition of them.
  47. ;
  48. ;    The code isn't elegant but it works. My apologies to Irv Hoff
  49. ;    for the liberties that I have taken with his efforts. Also my
  50. ;    thanks are extended to him for the education that this little
  51. ;    effort has given me.
  52. ;
  53. ;    If you care to leave any comments, or pose any questions,
  54. ;    leave a message on Jud's system.
  55. ;
  56. ;
  57. ;                Bill Harnell,
  58. ;                Scarborough, Ontario
  59. ;
  60. ;    * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  61. ;
  62. ;
  63. ;                        Irvin M. Hoff
  64. ;                  Los Altos Hills, CA  94022
  65. ;
  66. ;      "LISTT" is a printer utility program that lists any re-
  67. ;      quested file on your printer.  The name was selected so
  68. ;      it would be easy to type, easy to remember, and be illus-
  69. ;      trative of its capabilities.  It works equally well on
  70. ;      printers that do/do not respond to form feed characters.
  71. ;
  72. ;      When requesting the program, include the name of the
  73. ;      file (and its extent) that is to be listed:
  74. ;
  75. ;
  76. ;                      A>LISTT HELLO.ASM
  77. ;
  78. ;
  79. ;      A menu then appears asking several questions:
  80. ;
  81. ;         1) Roll paper or fanfold (it adds tear tabs each
  82. ;               11" if using roll paper).
  83. ;         2) Ability to include 0-99 spaces at the left
  84. ;               margin for those printers without adjust-
  85. ;               able margins.
  86. ;         3) Ignore form feeds (Y/N) - By default accepts normal
  87. ;               form feeds.  (Automatically paginates with or
  88. ;               without form feeds).
  89. ;         4) Heading desired (such as current date, etc.)
  90. ;               The name of the file plus current page num-
  91. ;               ber near the right margin are both automatic.
  92. ;         5) Asks for starting page (defaults to page 1).
  93. ;         6) Asks for page to stop at (defaults to end of
  94. ;               file).
  95. ;
  96. ;      Thus you can compensate for various printers and can print
  97. ;      any portion of the file you wish.
  98. ;
  99. ;      NOTE:  There are two options which may be user-set.  They  
  100. ;             are locations 0103 and 0104.  They may be set with
  101. ;             "DDT", "SID" or by editing and reassembling:
  102. ;
  103. ;             1)  PAGCOL   --  Sets the column the Page number
  104. ;                              starts at.  Some printers have
  105. ;                              72 columns, some 80, some 132, etc.
  106. ;
  107. ;             2)  TTABN    --  Sets the space between tear tabs
  108. ;                              for fan fold.  Some printers have
  109. ;                              72 columns, some 80, some 132, etc.
  110. ;
  111. ; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  112. ;
  113. ; 02/02/83 v1.2 Fixed the heading to indent on all pages, instead of
  114. ;               only the first. (Has worked correctly if using roll
  115. ;               paper with tear tabs, but not on fanfold.)
  116. ;                                       - Irv Hoff
  117. ;
  118. ; 01/17/83 v1.1 Would only display 99 pages and start over. Now goes 
  119. ;               to 99 pages.            - Irv Hoff
  120. ;
  121. ; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  122. ;
  123. ;
  124.         ORG   100H           
  125. ;
  126. ;
  127.         JMP   BEGIN          
  128. ;
  129. ;
  130. ; SPECIAL STORAGE LOCATIONS
  131. ;
  132. datcol:    dw    head3        ;column to start date/time
  133. PAGCOL: DB      85              ;COLUMN TO START PAGE NUMBER
  134. TTABN:  DB      78              ;SPACE BETWEEN TEAR TABS FOR ROLL PAPER
  135. lspc:    db    08        ;6 std - 6 or 8 permitted
  136. chwd:    db    17        ;10 std - 10, 12 or 17 permitted
  137. stdflg:    db    00        ;standard print parameter flag
  138. ;.....
  139. ;
  140. ; 
  141. ; ASCII CONTROL CHARACTERS
  142. ;
  143. esc    equ    1bh         ;escape character
  144. BS      EQU   'H'-40H        ;CONTROL-H FOR BACKSPACE
  145. TAB     EQU   'I'-40H        ;CONTROL-I FOR TAB
  146. LF      EQU   'J'-40H        ;CONTROL-J FOR LINE FEED
  147. FFD     EQU   'L'-40H        ;CONTROL-L FOR FORM FEED
  148. CR      EQU   'M'-40H        ;CONTROL-M FOR CARRIAGE RETURN
  149. SI      EQU   'V'-40H        ;CONTROL-V FOR SYNCH IDLE
  150. EOF     EQU   'Z'-40H        ;CONTROL-Z FOR END OF FILE
  151. ;.....
  152. ;
  153. ;
  154. ; CP/M ROUTINES AND FILE MANAGEMENT
  155. ;
  156. BDOS    EQU   0005H          ;SYSTEM CALL ENTRY POINT
  157. CONIN   EQU   1              ;CONSOLE INPUT CHAR
  158. CONOUT  EQU   2              ;DISPLAY CHAR ON CONSOLE
  159. FCB     EQU   5CH            ;LOCATION OF FILE CONTROL BLOCK
  160. LIST    EQU   5              ;SEND CHAR. TO LIST DEVICE
  161. pagenm    equ   3                 ;allows up to 999 pages
  162. STATUS  EQU   11             ;CONSOLE STATUS
  163. TBUFF   EQU   80H            ;BUFFER FOR FILE CONTROL BLOCK
  164. TFCB    EQU   005CH          ;DEFAULT FILE CONTROL BLOCK
  165. ;.....
  166. ;
  167. ;
  168. ; MISC STORAGE LOCATIONS
  169. ;
  170. ;
  171. CCP:    DB    0              ;INITIAL 'CCP' PAGE
  172. COLMN:  DB    0              ;POSITION ON THE LINE
  173. FRMFD:  DB    0              ;FORM FEED CONTROL
  174. LCNT:   DB    0              ;LINE COUNT FOR HARD COPY
  175. NOTAB:    DB    0             ;CHANGES TO '1' IF USING TEAR TABS
  176. START:    DB    0              ;START PRINTING FLAG
  177. text:    db    76             ;number of lines of text per page
  178.                 ;66 lpp = 54, 88 lpp = 76
  179. ;.....
  180. ;
  181. ;
  182. ; FILE HANDLING DATA
  183. ;
  184. FILEADR:      DW    BUFFER
  185. FILELEN:      DB    0,0
  186. FILEPTR:      DB    0,0
  187. FILESIZ:      DB    0,0
  188. FCBSTR:       DB    0,0,0,0,0,0,0,0,0,0,0,0
  189.               DB    0,0,0,0,0,0,0,0,0,0,0,0
  190.               DB    0,0,0,0,0,0,0,0,0
  191. ;.....
  192. ;
  193. ;
  194. ; HEADING LINE FOR HARD COPY
  195. ;
  196. HEAD1:  DB    SI,SI,SI,SI,SI,SI,SI,SI,SI,SI,SI,SI,'  '
  197. HEAD2:  DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  198.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  199.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  200.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  201.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  202.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  203.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  204.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  205. HEAD3:  DB    '                        - Page '
  206. HEAD4:  DB    SI,SI,'1',CR,LF,LF,LF,0
  207. PAGES:  DB    SI,SI,'1   '
  208. PAGEQ:  DB    SI,SI,'    '
  209. QUIT:   DB    CR,LF,LF,LF,LF,LF,LF,LF,LF,LF,0
  210. QUITR:  DB    CR,LF,LF,LF,LF,LF,0
  211. TURNUP:    DB    CR,LF,LF,LF,LF,LF,LF,LF,LF,LF,CR,LF,0
  212. ;
  213. ;.....
  214. ;
  215. ;
  216. ; MESSAGES
  217. ;
  218. MERRN:  DB    '== No file by that name on this disk =='
  219.         DB    CR,LF,'$'
  220. MERRR:  DB    '== No file requested ==',CR,LF,LF,'$'
  221. MERRW:  DB    '== No "*" or "?" please ==',CR,LF,'$'
  222. ;
  223. MSG1:   DB    CR,LF,'        LISTT Pgm v1.3  02/22/83',CR,LF
  224.     DB    '(With Okidata Microline u84 Enhancements)',cr,lf,lf,0
  225. MSG1B:  DB    cr,lf,'Do you want tear tabs to use roll paper? (y/n):  ',0
  226. MSG1C:  DB    'Number of spaces to augment left margin (0-99):  ',0
  227. MSG1D:  DB    'Accept FF (y/n):  ',0
  228. MSG1E:  DB    'Heading is:  ',0
  229. MSG1F:  DB    'Start at page  :  ',0
  230. MSG1G:  DB    'Quit  at page  :  ',0
  231. MSG2:   DB    'HIGHEST PAGE IS:  ',0
  232. MSG3:   DB     CR,LF,0
  233. ;
  234. ;.....
  235. ;
  236. msgpc:    db    cr,lf,lf,lf
  237.     db    'Following are Microline 84 printer options',cr,lf
  238.     db    '(Parenthetical notes show current values)',cr,lf,lf,0
  239. msgpc1:    db    ' 1. Line Spacing               (  )',cr,lf
  240.     db    '    (6 or 8 lpi permitted)',cr,lf,0
  241. msgpc2:    db    ' 2. Print Density              (  )',cr,lf
  242.     db    '    (10, 12 or 17 cpi permitted)',cr,lf,0
  243. msgpc5:    db    cr,lf,'Changes Desired (y, n or (d)one) ==> ',0
  244. msgpc6:    db    cr,lf,lf,'Enter 1 or 2                  ==> ',0
  245. ;
  246. lsmsg:    db    cr,lf,'Enter Lines Per Inch (6 or 8) ==> ',0
  247. lsmsg6:    db    esc,'6',cr,0        ;6 lpi
  248. lsmsg8:    db    esc,'8',cr,0        ;8 lpi
  249. tofmsg:    db    esc,'5',cr,0        ;top of form message
  250. ;
  251. cwmsg:    db    cr,lf,'Enter Print Density (10, 12 or 17 cpi)'
  252.     db    cr,lf,'1 = 10, 2 = 12 or 3 = 17 cpi  ==> ',0
  253. cwmsg10:db    30,cr,0            ;10 cpi
  254. cwmsg12:db    29,cr,0            ;12 cpi
  255. cwmsg17:db    28,cr,0            ;17 cpi
  256. ;
  257. ;
  258. ;.....
  259. ;
  260. ;
  261. ; TO GIVE THE FINAL LISTING A LEFT-MARGIN SO THAT IT CAN BE  MORE EASILY
  262. ; USED IN A BINDER, EXTRA SPACES CAN BE INSERTED AUTOMATICALLY INTO THE
  263. ; LEFT MARGIN AREA WHEN ANSWERING THE QUESTION AT BOOT TIME.  (NONE ARE
  264. ; NEEDED IF YOUR PRINTER HAS ADJUSTABLE MARGINS.)
  265. ;
  266. FILLS:  DB    '    '         ;TELLS HOW FAR TO MOVE THE MARGIN
  267. ;
  268. MARGIN: DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  269.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  270.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  271.         DB    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  272.  
  273. ;
  274. ;
  275. ;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  276. ;                                                                      ;
  277. ;                                                                      ;
  278. ;                    PROGRAM STARTS HERE                               ;
  279. ;                                                                      ;
  280. ;                                                                      ;
  281. ;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  282. ;
  283. ;
  284. BEGIN:    POP   H              ;GET RETURN ADDRESS TO'CCP'
  285.     SHLD  EXIT+1         ;STORE FOR RETURN TO 'CCP'
  286.         LXI   SP,STACK       ;SETUP NEW STACK FOR THIS PGM
  287. ;
  288. ;
  289. ; SIGN-ON MESSAGE
  290. ;
  291.         LXI   H,MSG1
  292.         CALL  STRNGC         ;WRITE STRING TO CRT  
  293. ;
  294. ;*****************************
  295. ;
  296. ; MOVE PGM NAME INTO HEADING BUFFER
  297. ;
  298. ;*****************************
  299. ;
  300. ; SEE IF ANY FILE WAS REQUESTED
  301. ;
  302. TITL:   LXI   H,TBUFF        ;FILE CONTROL BLOCK BUFFER
  303.         MOV   A,M            ;GET FIRST CHARACTER
  304.         ORA   A
  305.         JZ    ERRORR         ;IF ZERO, NO FILE WAS REQUESTED
  306.                  ;check for printer parm. change
  307. ;
  308. ; IF YES, SEE IF A DRIVE WAS MENTIONED, DO NOT PRINT THAT
  309. ;
  310.         LXI   H,TBUFF+3      ;SEE IF THEY SPECIFIED A DRIVE
  311.         MOV   A,M
  312.         CPI   ':'
  313.         JZ    TITL1+1        ;IF YES IGNORE
  314.         LXI   H,TBUFF        ;IF NOT, RESET TO NORMAL
  315. ;       
  316. TITL1:  INX   H              ;IGNORE THE SPACE CHAR.
  317.         LXI   D,HEAD1        ;LOCATION OF HEADING BUFFER
  318. ;.....
  319. ;
  320. ; see if printer parameter changes necessary
  321. ;
  322.     push psw!push b!push d!push h
  323.     call    shpcol
  324.     pop h!pop d!pop b!pop psw
  325. ;.....
  326. ;
  327. ; MOVE THE FILE NAME AND HEADING/DATE INTO THE BUFFER
  328. ;
  329. TITL2:  INX   H              ;NEXT LOCATION
  330.         MOV   A,M            ;GET THE CHARACTER
  331.         ORA   A              ;BINARY ZERO?
  332.         JZ    TITL3          ;IF YES, FINISHED
  333.         CPI   ' '            ;A SPACE AFTER FILENAME?
  334.         JZ    TITL3          ;IF YES, ALL FINISHED
  335.         STAX  D              ;AND STORE IN BUFFER
  336.         INX   D              ;ADVANCE BUFFER LOCATION
  337.         JMP   TITL2          ;IF NOT, CONTINUE
  338. ;
  339. ;
  340. ; CHECK FOR ANY WILD CARD CHARACTERS AND IF PRESENT SHOW ERROR
  341. ;
  342. TITL3:  LXI   H,FCB          ;WHERE NAME IS
  343.         MVI   B,11           ;NUMBER OF CHARS POSSIBLE
  344. ;
  345. TITL4:  INX   H              ;NEXT LOCATION IN FILE NAME
  346.         MOV   A,M            ;GET CHARACTER
  347.         CPI   '?'            ;CHECK FOR ANY WILD CARD CHARS.
  348.         JZ    ERRORW         ;ERROR IF ONE IS FOUND
  349.         DCR   B              ;COUNT CHARACTERS TO TEST
  350.         JNZ   TITL4          ;LOOP BACK UNLESS DONE
  351. ;
  352. ;
  353. ;*****************************
  354. ;
  355. ; CALCULATE MAXIMUM AVAILABLE BUFFER SIZE
  356. ;
  357. ;*****************************
  358. ;
  359. ;
  360.         LXI   D,BUFFER
  361.         LDA   BDOS+2         ;GET BDOS ADDRESS
  362.         SUI   8              ;PROTECT 'CCP'
  363.         MOV   H,A            ;GET THE MAIN PAGE
  364.         STA   CCP            ;STORE FOR "CLEAR BUFFER"
  365.         XRA   A              ;CLEAR CARRY IF SET
  366. ;
  367. ;
  368. ; CALCULATE THE DIFFERENCE TO GET SPACE AVAILABLE
  369. ;
  370.         SUB   E
  371.         MOV   L,A
  372. ;
  373.         MOV   A,H
  374.         SBB   D
  375.         MOV   H,A
  376. ;
  377. ;
  378. ; FREE SPACE AVAILABLE NOW IN 'HL', SO STORE FOR BUFFER SIZE
  379. ;
  380.         SHLD  FILESIZ
  381. ;
  382. ;*****************************
  383. ;
  384. ; OPEN REQUESTED FILE TO READ THE DATA TO LIST
  385. ;
  386. ;*****************************
  387. ;
  388.         LXI   H,FCB          ;LOCATION OF FILE CONTROL BLOCK
  389.         LXI   D,FCBSTR
  390.         MVI   C,12           ;NORMAL FILE LENGTH
  391.         CALL  STORE
  392. ;
  393.         XRA   A
  394.         STA   FCBSTR+12      ;NULL LOCATION FOLLOWING FILE NAME
  395.         STA   FCBSTR+32
  396.         LHLD  FILESIZ
  397.         SHLD  FILELEN
  398.         SHLD  FILEPTR
  399.         MVI   C,15
  400.         LXI   D,FCBSTR       ;OPEN FILE
  401.         CALL  BDOS
  402.         INR   A
  403.         JZ    ERRORN         ;IF UNABLE, TERMINATE
  404. ;
  405. ;
  406. ;*****************************
  407. ;
  408. ; ASK ABOUT ROLL PAPER, MARGINS, STARTING PAGE, ETC.
  409. ;
  410. ;*****************************
  411. ;
  412. ;
  413.         CALL  PRHC           ;ASK QUESTIONS
  414. ;
  415. ;
  416. ;***********************************************************************
  417. ;                                                                      ;
  418. ;                     MAIN PRINT LOOP                                  ;
  419. ;                                                                      ;
  420. ;***********************************************************************
  421. ;
  422. ;
  423. ; HANDLES TOP OF NEW PAGE
  424. ;
  425. MAIN:   call  time           ;set time/date etc. into header
  426.     CALL  NEWPG          ;SET PARAMETERS FOR A NEW PAGE
  427.         CALL  SKIP           ;SKIP CR, LF, EOF OR FFD AT NEW PAGE
  428.         JMP   MAIN2          ;ALREADY HAVE FIRST GOOD CHAR.
  429. ;
  430. ;
  431. ; HANDLE ASCII CHARACTERS
  432. ;
  433. MAIN1:  CALL  GETCH          ;GET NEW CHARACTER
  434.         CPI   EOF            ;END OF FILE IN MIDDLE OF LINE?
  435.         JZ    ROLL
  436. ;
  437. MAIN2:  CPI   ' '            ;PRINTING CHAR.?
  438.         JC    MAIN4          ;IF NOT, EXIT
  439. ;
  440. MAIN3:  CALL  WRITE2         ;WRITE CHARACTER
  441.         JMP   MAIN1          ;GET THE NEXT CHAR.
  442. ;...
  443. ;
  444. ;
  445. ; HANDLE NON-PRINTING CHARS.
  446. ;
  447. MAIN4:  CPI   CR             ;CARRIAGE RETURN
  448.         JZ    MAIN5
  449.         CPI   FFD            ;FORM FEED
  450.         JZ    MAIN6
  451.         CPI   LF             ;LINE FEED
  452.         JZ    MAIN7
  453.         CPI   TAB            ;TAB CHARACTER
  454.         JZ    MAIN8
  455.         JMP   MAIN9          ;NONE OF THESE SEND SPECIAL CHAR.
  456. ;.....
  457. ;
  458. ;
  459. ; HANDLE 'CR' CHAR.
  460. ;
  461. MAIN5:  CALL  ABORT          ;WANT TO TERMINATE?
  462.         MVI   A,CR           ;RESTORE THE CHAR.
  463.         JMP   MAIN3          ;GET NEXT CHAR.
  464. ;...
  465. ;
  466. ;
  467. ; HANDLE FORM FEED CHAR.
  468. ;
  469. MAIN6:  CALL  ABORT          ;WANT TO TERMINATE?
  470.         LDA   FRMFD          ;RESPONDING TO FORM FEED?
  471.         ORA   A
  472.         JNZ   MAIN1          ;IF NOT, IGNORE
  473. ;
  474.         LDA   LCNT           ;INCREMENT LINE COUNT
  475.         INR   A
  476.         STA   LCNT
  477.         push  h
  478.     lxi   h,text
  479.     cmp   m
  480.     pop   h
  481.         JNC   MAIN71         ;IF DONE, TURN UP NEW PAGE
  482.         MVI   A,LF
  483.         CALL  WRITEP         ;PRINT NEW LINE, DO NOT DISPLAY
  484.         JMP   MAIN6          ;CHECK AGAIN
  485. ;...
  486. ;
  487. ;
  488. ; HANDLE 'LF' CHARS.
  489. ;
  490. MAIN7:  LDA   LCNT           ;INCREMENT THE TEXT LINE COUNT
  491.         INR   A
  492.         STA   LCNT
  493.         push  h
  494.     lxi   h,text
  495.     cmp   m
  496.     pop   h                 ;MAXIMUM NUMBER OF LINES NOW?
  497.         JNC   MAIN71         ;IF YES, FINISH THE PAGE
  498.     MVI   A,LF
  499.         CALL  WRITE3
  500.         CALL  INDENT         ;INDENT IF REQUESTED
  501.         JMP   MAIN1          ;HANDLE NORMALLY
  502. ;...
  503. ;
  504. ;
  505. ;    'LF' SO START A NEW PAGE
  506. ;
  507. MAIN71: CALL  ABORT          ;WANT TO TERMINATE NOW?
  508.         CALL  SKIP           ;SKIP ANY CR, LF, EOF OR FFD TOP OF PAGE
  509.         PUSH  PSW            ;OTHERWISE SAVE CHAR.
  510.         CALL  TTABS          ;CHECK FOR ROLL PAPER
  511.         CALL  NMBR           ;INCREMENT THE PAGE NUMBER
  512.         CALL  CKSP           ;READY TO STOP AS YET?
  513.         CALL  INDENT
  514. ;
  515. MAIN72:    LXI   H,HEAD1        ;SEND THE NEW PAGE HEADING
  516.         CALL  STRNGB         ;DISPLAY AND PRINT
  517.         CALL  PAGNO          ;SET IN PAGE NUMBER
  518.     CALL  NEWPG          ;SET UP PARAMETERS FOR A NEW PAGE
  519.     POP   PSW            ;GET THE CHAR. BACK WE LOOKED AT
  520.         JMP   MAIN2          ;IGNORE GETTING A NEW CHAR.
  521. ;...
  522. ;
  523. ;
  524. ; HANDLE TAB CHARACTERS
  525. ;
  526. MAIN8:  MVI   A,' '          ;SEND A SPACE IN PLACE OF TAB
  527.         CALL  WRITE2         ;DISPLAY AND PRINT
  528.         LDA   COLMN          ;FIND WHAT COLUMN
  529.         ANI   7
  530.         JNZ   MAIN8          ;IF NOT EVEN 8, DO ANOTHER SPACE
  531.         JMP   MAIN1          ;BACK TO WORK
  532. ;...
  533. ;
  534. ;
  535. ; DISPLAY CONTROL-CHARACTERS
  536. ;
  537. MAIN9:  PUSH  PSW            ;SAVE THE CHAR.
  538.         MVI   A,'^'          ;SHOW A SPECIAL "CTL-CHAR."
  539.         CALL  WRITE2         ;DISPLAY/PRINT
  540.         POP   PSW
  541.         ADI   40H            ;CONVERT TO PRINTING CHAR.
  542.         CALL  WRITE2
  543.         JMP   MAIN           ;GET NEXT CHAR.
  544. ;.....
  545. ;
  546. ;
  547. ;***********************************************************************
  548. ;                                                                      ;
  549. ;                                                                      ;
  550. ;                    ROUTINES START HERE                               ;
  551. ;                                                                      ;
  552. ;                                                                      ;
  553. ;***********************************************************************
  554. ;
  555. ;
  556. ; CLEAR KEYBOARD OF ANY OTHER CHARS.
  557. ;
  558. ABORT:  MVI   C,STATUS
  559.         CALL  BDOS
  560.         RAR    
  561.         RNC
  562. ;
  563.         MVI   C,CONIN        ;GET THE CHAR.
  564.         CALL  BDOS
  565.         CPI   'C'-40H        ;WANT TO TERMINATE?
  566.         JNZ   ABORT          ;EXIT IF NOT CTL-C
  567. ;
  568. ABORT1: LDA   NOTAB          ;USING FANFOLD PAPER?
  569.     ORA   A
  570.     JZ    EXIT           ;IF YES, LEAVE IN NORMAL POSITION
  571.     LXI   H,TURNUP       ;OTHERWISE, TERMINATE
  572.         CALL  STRNGP         ;DISPLAY AND PRINT SOME LINE FEEDS
  573.     LXI   H,QUITR-7      ;..A FEW EXTRA LINES
  574.     CALL  STRNGP
  575.     JMP   EXIT
  576. ;
  577. ABORT2: LXI   H,QUITR-3
  578.         CALL  STRNGC
  579.         JMP   EXIT           ;FINISHED NOW
  580. ;.....
  581. ;
  582. ;
  583. ; HANDLE A BACKSPACE CHAR. WHILE ENTERING A FILE NAME
  584. ;
  585. BCKSP:  MOV   A,B            ;GET POSITION ON LINE
  586.         ORA   A
  587.         JNZ   BCKSP1         ;EXIT IF AT INITIAL COLUMN
  588.         MVI   A,' '          ;DELETE THE CHAR.
  589.         JMP   BCKSP3
  590. ;
  591. BCKSP1: DCR   B              ;SHOW ONE LESS COLUMN USED
  592.         DCX   H              ;DECREASE BUFFER LOCATION
  593.         MVI   A,' '
  594.         MOV   M,A            ;REPLACE TO ORIGINAL
  595.         CALL  WRITCC         ;BACKSPACE THE CRT
  596. ;
  597. BCKSP2: MVI   A,BS           ;RESET THE CRT AGAIN
  598. ;
  599. BCKSP3: CALL  WRITCC         ;WRITE TO CRT
  600.         RET
  601. ;.....
  602. ;
  603. ;
  604. ; CHECK TO SEE IF READY TO STOP PRINTING YET
  605. ;
  606. CKSP:   PUSH  H              ;SAVE THE REGS.
  607.         PUSH  D
  608.         PUSH  B
  609.         LXI   H,PAGEQ+2      ;ADDRESS OF QUITTING PAGE ANSWER
  610. ;
  611. CKSP1:  INX   H              ;FIND THE RIGHTMOST DIGIT
  612.         MOV   A,M
  613.         CPI   ' '
  614.         JNZ   CKSP1
  615.         DCX   H
  616. ;
  617.         LXI   D,HEAD4+2      ;RIGHTMOST DIGIT FOR PAGE NUMBER
  618.         MVI   C,PAGENM         ;ALLOWS UP TO 9,999 PAGES
  619. ;
  620. CKSP2:  LDAX  D              ;COMPARE TWO STRINGS OF NUMBERS
  621.         CMP   M
  622.         JNZ   CKSP3          ;IF DIFFERENT, NOT READY YET
  623. ;
  624.         DCX   D              ;CHECK NEXT DIGIT
  625.         DCX   H
  626.         DCR   C
  627.         JNZ   CKSP2
  628. ;
  629.         JMP   ABORT1
  630. ;
  631. CKSP3:  POP   B              ;RESTORE THE REGS.
  632.         POP   D
  633.         POP   H
  634.         RET
  635. ;.....
  636. ;
  637. ;
  638. ; CHECK TO SEE IF READY TO START PRINTING YET
  639. ;
  640. CKST:   PUSH  H              ;SAVE THE REGS.
  641.         PUSH  D
  642.         PUSH  B
  643.         LXI   H,PAGES+2      ;ADDRESS OF STARTING PAGE ANSWER
  644. ;
  645. CKST1:  INX   H              ;FIND THE RIGHTMOST DIGIT
  646.         MOV   A,M
  647.         CPI   ' '
  648.         JNZ   CKST1
  649.         DCX   H
  650. ;
  651.         LXI   D,HEAD4+2      ;RIGHTMOST DIGIT FOR PAGE NUMBER
  652.         MVI   C,PAGENM
  653. ;
  654. CKST2:  LDAX  D              ;COMPARE TWO STRINGS OF NUMBERS
  655.         CMP   M
  656.         JNZ   CKST4          ;IF DIFFERENT, NOT READY YET
  657. ;
  658.         DCX   D              ;CHECK NEXT DIGIT
  659.         DCX   H
  660.         DCR   C
  661.         JNZ   CKST2
  662. ;
  663.         STA   START          ;ALLOWS HARD COPY TO COMMENCE
  664.         MVI   A,CR
  665.         CALL  WRITEP         ;POSITION PRINTER TO LEFT FOR FIRST LINE
  666.     LDA   NOTAB         ;USING TEAR TABS?
  667.     ORA   A
  668.     CNZ   TTABS         ;IF YES, START FIRST PAGE WITH TEAR TABS
  669.         CALL  INDENT         ;INDENT IF REQUESTED
  670. ;
  671. CKST3:  LXI   H,HEAD1
  672.         CALL  STRNGB
  673.         CALL  PAGNO          ;SET IN PAGE NUMBER
  674. ;
  675. CKST4:  POP   B              ;RESTORE THE REGS.
  676.         POP   D
  677.         POP   H
  678.         RET
  679. ;.....
  680. ;
  681. ;
  682. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  683. ;                                                                     ;
  684. ;              LOAD THE DISK FILE INTO MEMORY, GET A CHAR             ;
  685. ;                                                                     ;
  686. ;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  687. ;
  688. ;
  689. ; SEE IF ANYTHING ALREADY IN THE BUFFER
  690. ;
  691. DISK1:  LHLD  FILELEN
  692.         XCHG
  693.         LHLD  FILEPTR
  694.         MOV   A,L
  695.         SUB   E
  696.         MOV   A,H
  697.         SBB   D
  698.         JC    DISK5          ;IF NOT EMPTY GO GET CHAR.
  699. ;
  700. ;
  701. ; IF EMPTY, FILL BUFFER
  702. ;
  703.         LXI   H,0
  704.         SHLD  FILEPTR        ;ZERO THE FILE POINTERS
  705. ;
  706. ;
  707. ; GET NEXT DISK SECTOR, CHECK FOR END OF FILE MARKER
  708. ;
  709. DISK2:  XCHG                 ;PUT INTO 'DE'
  710.         LHLD  FILELEN        ;SET 'HL' TO MAXIMUM BUFFER LENGTH
  711.         MOV   A,E
  712.         SUB   L
  713.         MOV   A,D
  714.         SBB   H
  715.         JNC   DISK4          ;IF NOW FULL, EXIT
  716. ;
  717. ;
  718. ; OTHERWISE GET NEXT SECTOR
  719. ;    
  720.         LHLD  FILEADR        ;START OF BUFFER
  721.         DAD   D              ;ADD IN FILE POINTER VALUE
  722.         XCHG                 ;ADDRESS FOR NEXT DISK SECTOR TO GO
  723.         MVI   C,26           ;SET DMA ADDRESS
  724.         CALL  BDOS
  725.         LXI   D,FCBSTR       ;ADDRESS OF DISK FILE NAME
  726.         MVI   C,20           ;READ SEQUENTIAL INTO MEMORY BUFFER
  727.         CALL  BDOS
  728.         ORA   A              ;CHECK FOR END OF FILE
  729.         JNZ   DISK3          ;IF YES, EXIT
  730. ;
  731.         LXI   D,TBUFF        ;SECTOR SIZE IS 128 BYTES
  732.         LHLD  FILEPTR        ;NEXT LOCATION TO PUT SECTOR        
  733.         DAD   D              ;ADD THE SECTOR SIZE
  734.         SHLD  FILEPTR        ;STORE FOR NEXT SECTOR-FILL
  735.         JMP   DISK2          ;CHECK FOR FULL, IF NOT KEEP GOING
  736. ;.....
  737. ;
  738. ; RESET FOR END-OF-FILE MARKER LOCATION
  739. ;
  740. DISK3:  LHLD  FILEPTR
  741.         SHLD  FILELEN
  742. ;
  743. ; SET FOR BUFFER FULL
  744. ;
  745. DISK4:  LXI   D,TBUFF        ;POINT TO TEMPORARY BUFFER ADDRESS
  746.         MVI   C,26           ;SET DMA ADDRESS
  747.         CALL  BDOS
  748.         LXI   H,0            ;RESET FILE POINTER TO START OF BUFFER
  749.         SHLD  FILEPTR
  750. ;
  751. ;
  752. ; GET THE NEXT CHARACTER FROM THE BUFFER
  753. ;
  754. DISK5:  XCHG                 ;FILE POINTER LOCATION
  755.         LHLD  FILEADR        ;START OF MEMORY BUFFER
  756.         DAD   D              ;ADDRESS OF NEXT CHARACTER TO GET
  757.         XCHG                 ;PUT INTO 'DE'
  758.         LHLD  FILELEN        ;GET LENGTH OF FILE
  759.         MOV   A,L            ;SEE IF EMPTY NOW
  760.         ORA   H
  761.         MVI   A,EOF          ;END OF FILE MARKER (CTL-Z)
  762.         RZ                   ;DONE IF 'H' AND 'L' BOTH ZERO
  763. ;
  764.         LDAX  D              ;GET THE CHAR.
  765.         LHLD  FILEPTR        ;BUMP THE POINTERS FOR NEXT CHARACTER
  766.         INX   H
  767.         SHLD  FILEPTR
  768.         RET
  769. ;.....
  770. ;
  771. ;
  772. ; EXIT IF HAVING A PROBLEM OPENING A FILE
  773. ;
  774. ERROR:  MVI   C,9            ;PRINT STRING
  775.         CALL  BDOS
  776.     JMP   EXIT
  777. ;
  778. ERRORR: LXI   D,MERRR        ;NO FILE REQUESTED - ERROR MSG
  779.         JMP   ERROR
  780. ;
  781. ERRORN: LXI   D,MERRN        ;NO FILE BY THAT NAME - ERROR MSG
  782.         JMP   ERROR
  783. ;
  784. ERRORW: LXI   D,MERRW        ;NO WILDCARD - ERROR MSG
  785.         JMP   ERROR
  786. ;.....
  787. ;
  788. ;
  789. ;EXIT ROUTINE
  790. ;
  791. EXIT:    JMP   0000H          ;FILLED IN BY 'BEGIN' FOR RETURN TO 'CCP'
  792. ;.....
  793. ;
  794. ;
  795. ; GET A CHARACTER FROM THE BUFFER
  796. ;
  797. GETCH:  CALL  DISK1          ;PICK OFF THE CHAR.
  798.         ANI   7FH            ;STRIP OFF ANY PARITY
  799.         RET
  800. ;.....
  801. ;
  802. ;
  803. ; INDENT FOR NEW LEFT MARGIN, IF REQUESTED
  804. ;
  805. INDENT: PUSH  PSW            ;SAVE THE CHAR.
  806.         LXI   H,MARGIN
  807.         CALL  STRNGP         ;WRITE THE STRING
  808.         XRA   A
  809.         STA   COLMN          ;RESET THE COLUMN COUNT
  810.         POP   PSW            ;RESTORE THE CHAR.
  811.         RET
  812. ;.....
  813. ;
  814. ;
  815. ; GET A CHARACTER FROM THE KEYBOARD
  816. ;
  817. INPUT:  PUSH  H
  818.         PUSH  B
  819.         MVI   C,CONIN
  820.         CALL  BDOS
  821.         ANI   7FH            ;STRIP OFF ANY PARITY
  822.         POP   B
  823.         POP   H
  824.         CPI   3              ;CONTROL-C ?
  825.         JZ    ABORT2         ;IF YES, GO TERMINATE
  826.         RET
  827. ;.....
  828. ;
  829. ;
  830. ; SET PARAMETERS FOR A NEW PAGE
  831. ;
  832. NEWPG:  XRA   A
  833.         STA   LCNT           ;RESET THE TEXT COUNT
  834.         STA   COLMN          ;RESET THE COLUMN COUNT
  835.         LDA   START          ;ALREADY PRINTING?
  836.         ORA   A
  837.         CZ    CKST           ;IF NOT CHECK WHETHER READY NOW
  838.         JMP   INDENT         ;SET IN ANY LEFT MARGIN SPACES
  839. ;.....
  840. ;
  841. ;
  842. ; INCREMENT THE PAGE NUMBER FOR HARD COPY
  843. ;
  844. NMBR:   LXI   H,HEAD4+2
  845.         MVI   C,PAGENM
  846. ;       
  847. NMBR1:  MOV   A,M            ;GET THE VALUE
  848.         CPI   ' '            ;IS IT A SPACE?
  849.         JZ    NMBR2          ;EXIT IF NOT
  850.         CPI   SI             ;SYNCH CHAR.?
  851.         JNZ   NMBR3
  852. ;
  853. NMBR2:  MVI   A,'0'          ;OTHERWISE CALL IT A ZERO
  854. ;
  855. NMBR3:  INR   A
  856.         MOV   M,A
  857.         CPI   '9'+1          ;READY TO START NEXT DIGIT?
  858.         JNZ   NMBR4          ;IF NOT, FINISHED
  859. ;
  860.         MVI   M,'0'          ;OTHERWISE MAKE THIS ONE A ZERO
  861.         DCX   H              ;WORK ON NEXT COLUMN
  862.         DCR   C              ;ONE LESS TO GO
  863.         JNZ   NMBR1          ;GO DO THE NEXT ONE
  864. ;
  865. NMBR4:  RET                  ;FINISHED
  866. ;.....
  867. ;
  868. ;
  869. ; IF NO PRINT, TELL WHAT MAXIMUM PAGE WAS
  870. ;
  871. NOPNT:  LXI   H,MSG3         ;TURN UP A BLANK LINE
  872.         CALL  STRNGC
  873.         LXI   H,MSG2         ;FINAL PAGE MSG
  874.         CALL  STRNGC
  875.         LXI   H,HEAD4
  876.         CALL  STRNGC
  877.         JMP   EXIT           ;ALL DONE NOW
  878. ;.....
  879. ;
  880. ; TO START A NEW PAGE
  881. ;
  882. NUPAGE:    LXI   H,TURNUP         ;SEND A STRING OF LINE FEEDS TO
  883.     JMP   STRNGB         ;..START A NEW PAGE
  884. ;.....
  885. ;
  886. ;
  887. ; DISPLAY AND PRINT THE PAGE NUMBER
  888. ;
  889. PAGNO:     MVI   A,' '          ;SPACE CHARACTER
  890.         CALL  WRITE2         ;DISPLAY AND PRINT AND COUNT
  891.         LDA   PAGCOL         ;FIND COLUMN TO START PAGE NUMBER
  892.         MOV   B,A
  893.         LDA   COLMN          ;GET PRESENT COLUMN
  894.         ADI   1              ;COMPENSATE FOR LEFT MARGIN "0" COUNT
  895.         SUB   B              ;SEE IF ROOM LEFT FOR SPACES
  896.         JC    PAGNO          ;IF YES SEND ANOTHER SPACE
  897. ;
  898.         LXI   H,HEAD3        ;PAGE NUMBER STRING
  899.         JMP   STRNGB         ;DISPLAY AND PRINT, FINISHED
  900. ;
  901. ;.....
  902. ;
  903. ;
  904. ; ASKS VARIOUS QUESTIONS SUCH AS HEADING, PAGE NUMBERS, ETC.
  905. ;
  906. ;    TABS FOR ROLL PAPER REQUEST
  907. ;
  908. PRHC:   CALL  RPAPER         ;USING ROLL PAPER?
  909. ;
  910. ;.....
  911. ;
  912. ;    ASK FOR ANY FILL CHARS. TO AUGMENT LEFT MARGIN
  913. ;
  914.         LXI   H,MSG1C        ;WANT FILL CHARS.?
  915.         CALL  STRNGC
  916.         MVI   B,0
  917.         LXI   H,FILLS+1      ;STORAGE FOR NUMBER OF FILL CHARS.
  918. ;
  919. PRHC1:  CALL  INPUT          ;GET KEYBOARD ANSWER
  920.         CPI   CR             ;CARRIAGE RETURN TO QUIT?
  921.         JZ    PRHC4
  922.         CPI   BS             ;BACKSPACE CHAR.?
  923.         JNZ   PRHC2
  924.         CALL  BCKSP          ;BACKSPACE
  925.         JMP   PRHC1
  926. ;
  927. PRHC2:  CPI   ' '
  928.         JC    PRHC1          ;IF NON-PRINTING, IGNORE
  929.         MOV   M,A            ;STORE CHARACTER
  930.         INX   H              ;NEXT STORAGE LOCATION
  931.         INR   B              ;INCREMENT COUNT
  932.         CPI   '0'
  933.         JC    PRHC3          ;DIGITS FROM 0-9 ACCEPTABLE
  934.         CPI   '9'+1
  935.         JNC   PRHC3          ;DIGITS FROM 0-9 ACCEPTABLE
  936.         MOV   A,B
  937.         CPI   2+1            ;TWO MAXIMUM DIGITS FOR 0-99
  938.         JC    PRHC1
  939. ;
  940. PRHC3:  CALL  BCKSP2         ;WON'T ALLOW THREE DIGITS
  941.         CALL  BCKSP1         ;   (OR NON-NUMERIC CHARS.)
  942.         JMP   PRHC1          ;GET NEXT CHAR.
  943. ;...
  944. ;
  945. ;
  946. ; NOW PUT THE NUMBER OF "INDENT SPACES" INTO THE "MARGIN" BUFFER
  947. ;
  948. PRHC4:  LXI   D,MARGIN       ;LOCATION OF THE "INDENT SPACES"
  949.         LXI   H,FILLS+2      ;SEE IF 2 DIGITS THIS TIME
  950.         MOV   A,M
  951.         CPI   ' '
  952.         JNZ   UNITS          ;IF NOT, HANDLE AS A UNIT-DIGIT
  953.         DCX   H
  954.         MOV   A,M
  955.         CPI   ' '            ;THIS ONE HAVE ANYTHING?
  956.         JZ    PRHC5          ;IF NOT, NO FILLS WANTED
  957. ;
  958. UNITS:  SUI   '0'            ;CONVERT TO BINARY
  959.         JZ    TENS           ;IF ALREADY ZERO, EXIT
  960.         MOV   B,A            ;STORE
  961.         MVI   A,' '
  962. ;
  963. UNITS1: STAX  D              ;STORE A SPACE
  964.         INX   D
  965.         DCR   B
  966.         JNZ   UNITS1
  967. ;
  968. TENS:   DCX   H
  969.         MOV   A,M
  970.         CPI   '1'            ;A NUMBER FROM 1-9?
  971.         JC    PRHC5          ;IF NOT, ALL DONE
  972.         SUI   '0'            ;IF YES, CONVERT TO BINARY
  973.         MOV   B,A            ;STORE
  974. ;
  975. TENS1:  MVI   C,10           ;10 SPACES FOR EACH "TENS" NUMBER
  976.         MVI   A,' '
  977. ;
  978. TENS2:  STAX  D              ;STORE A SPACE
  979.         INX   D              ;NEXT LOCATION
  980.         DCR   C
  981.         JNZ   TENS2
  982.         DCR   B
  983.         JNZ   TENS1          ;RELOAD 'C' TO 10 IF NEEDED
  984. ;......
  985. ;
  986. ;
  987. ;    WANT NORMAL FORM FEED?
  988. ;       
  989. PRHC5:  LXI   H,MSG3         ;TURN UP A NEW LINE
  990.         CALL  STRNGC
  991.         LXI   H,MSG1D        ;FORM FEED MSG
  992.         CALL  STRNGC
  993. ;
  994.         CALL  INPUT          ;GET KEYBOARD CHAR.
  995.         ANI   5FH            ;CHANGE TO UPPER CASE IF NEEDED
  996.         CPI   'Y'            ;FINISHED IF 'RET'
  997.         JNZ   PRHC6
  998.         STA   FRMFD
  999. ;...
  1000. ;
  1001. ;
  1002. ;    ASK FOR CURRENT HEADING/DATE
  1003. ;
  1004. PRHC6:  LXI   H,MSG3         ;TURN UP A NEW LINE
  1005.     CALL  STRNGC
  1006.     LXI   H,MSG1E         ;HEADING/DATE MESSAGE
  1007.     CALL  STRNGC
  1008.         MVI   B,0
  1009.         LXI   H,HEAD2
  1010. ;
  1011. PRHC7:  CALL  INPUT          ;GET KEYBOARD CHAR.
  1012.         CPI   CR             ;FINISHED IF 'RET'
  1013.         JZ    PRHC9
  1014.         CPI   BS
  1015.         JNZ   PRHC8
  1016.         CALL  BCKSP
  1017.         JMP   PRHC7
  1018. ;
  1019. PRHC8:  MOV   M,A
  1020.         INX   H
  1021.         INR   B
  1022.         MOV   A,B
  1023.         CPI   124+1          ;ROOM FOR 124 CHARS. IN BUFFER
  1024.         JC    PRHC7
  1025.         CALL  BCKSP2
  1026.         CALL  BCKSP1         ;DO NOT ALLOW A TOO-LONG LINE
  1027.         JMP   PRHC7
  1028. ;
  1029. ;
  1030. ;    ASK FOR STARTING PAGE
  1031. ;
  1032. PRHC9:  LXI   H,MSG3         ;TURN UP A NEW LINE
  1033.         CALL  STRNGC
  1034.         LXI   H,MSG1F
  1035.         CALL  STRNGC
  1036.         MVI   B,0
  1037.         LXI   H,PAGES+2      ;STARTING PAGE STORAGE
  1038. ;
  1039. PRHC10: CALL  INPUT
  1040.         CPI   CR
  1041.         JZ    PRHC12
  1042.         CPI   BS
  1043.         JNZ   PRHC11
  1044.         CALL  BCKSP
  1045.         JMP   PRHC10
  1046. ;
  1047. PRHC11: MOV   M,A
  1048.         INX   H
  1049.         INR   B
  1050.         MOV   A,B
  1051.         CPI   3+1            ;THREE MAXIMUM PAGE NUMBERS
  1052.         JC    PRHC10
  1053.         CALL  BCKSP2
  1054.         CALL  BCKSP1         ;DO NOT ALLOW A TOO-LONG LINE
  1055.         JMP   PRHC10
  1056. ;
  1057. ;
  1058. ;    ASK FOR STOPPING PAGE
  1059. ;
  1060. PRHC12: LXI   H,MSG3         ;TURN UP A NEW LINE
  1061.         CALL  STRNGC
  1062.         LXI   H,MSG1G
  1063.         CALL  STRNGC
  1064.         MVI   B,0
  1065.         LXI   H,PAGEQ+2      ;QUITTING PAGE STORAGE
  1066. ;
  1067. PRHC13: CALL  INPUT
  1068.         CPI   CR
  1069.         JZ    PRHC15
  1070.         CPI   BS
  1071.         JNZ   PRHC14
  1072.         CALL  BCKSP
  1073.         JMP   PRHC13
  1074. ;
  1075. PRHC14: MOV   M,A
  1076.         INX   H
  1077.         INR   B
  1078.         MOV   A,B
  1079.         CPI   3+1            ;THREE MAXIMUM PAGE NUMBERS
  1080.         JC    PRHC13
  1081.         CALL  BCKSP2
  1082.         CALL  BCKSP1         ;DO NOT ALLOW A TOO-LONG LINE
  1083.         JMP   PRHC13
  1084. ;       
  1085. PRHC15: LXI   H,MSG3         ;TURN UP A NEW LINE
  1086.         CALL  STRNGC
  1087.         RET
  1088. ;.....
  1089. ;
  1090. ; show form & printer parameters - changes necessary ?
  1091. ;
  1092. shpcol:    lxi    h,msgpc        ;point to message
  1093.     call    strngc        ; and display it
  1094. ;
  1095.     lda    lspc        ;get spacing data
  1096.     mov    e,a        ; and store in E
  1097.     lxi    h,msgpc1+32    ;point to destination
  1098.     call    biasc        ; convert and fill
  1099.     lxi    h,msgpc1    ;  point to spacing message
  1100.     call    strngc        ; and show it
  1101. ;
  1102.     lda    chwd        ;get print density
  1103.     mov    e,a        ; and save in E
  1104.     lxi    h,msgpc2+32    ;point to destination
  1105.     call    biasc        ; convert and fill
  1106.     lxi    h,msgpc2    ;  point to density message
  1107.     call    strngc        ; and show it
  1108. ;
  1109. askch:    lxi    h,msgpc5    ;changes necessary?
  1110.     call    strngc        ; print it
  1111.     call    input        ;  and get answer
  1112.     ani    5fh        ;   make ucase
  1113.     cpi    'Y'
  1114.     jz    chang        ;changes needed 
  1115.     cpi    'N'        ; no changes, bail out
  1116.     jz    stdcfg        ;  and set standard printer parms
  1117.     cpi    'D'        ;changes done?
  1118.     rz            ; yes, bail out!
  1119.     jmp    askch        ;wait for valid input
  1120. ;
  1121. stdcfg:    mvi    a,1        ;get a "1"
  1122.     sta    stdflg        ; and set the flag
  1123.     call    lspac8        ;set 6 lines/in.
  1124.     call    cwid17        ; and 10 cpi
  1125.     call    tof        ;  and top-of-form
  1126.     xra    a        ;   then
  1127.     sta    stdflg        ;  clear the flag
  1128.     ret
  1129. ;
  1130. mdone:    call    stroki        ;send a string to the oki
  1131.     lda    stdflg
  1132.     ora    a        ; see if zero
  1133.     jz    shpcol        ;  if yes, then maybe done
  1134.     call    tof        ;if not, set top-of-form
  1135.     ret            ; and bail out
  1136. ;
  1137. ; set the top-of-form on the okidata u84
  1138. ;
  1139. tof:    lxi    h,tofmsg    ;point to the tof message
  1140.     call    stroki        ; and tell the printer
  1141.     ret
  1142. ;
  1143. chang:    lxi    h,msgpc6    ;ask for changes
  1144.     call    strngc
  1145.     call    input        ; get change number
  1146.     cpi    '1'        ;line spacing change
  1147.     jz    lspac
  1148.     cpi    '2'        ;chars. per inch
  1149.     jz    cwid
  1150.     jmp    chang        ;wait for valid input
  1151. ;
  1152. ;.....
  1153. ;
  1154. ; Set up line spacing parameter for Microline 84
  1155. ;
  1156. lspac:    lxi    h,lsmsg        ;ask for lpi
  1157.     call    strngc
  1158.     call    input        ;get answer
  1159.     cpi    '6'
  1160.     jz    lspac6        ;set 6 lpi
  1161.     cpi    '8'
  1162.     jz    lspac8        ;set 8 lpi
  1163.     jmp    lspac        ;wait for good value
  1164. ;
  1165. lspac6:    mvi    a,6        ;get a 6
  1166.     sta    lspc        ; store new variable
  1167.     mvi    a,54        ;lines of text/page
  1168.     sta    text        ; for 6lpi
  1169.     lxi    h,lsmsg6    ;point to message string
  1170.     jmp    mdone        ; and send to printer
  1171. ;
  1172. lspac8:    mvi    a,8        ;get an 8
  1173.     sta    lspc        ; store new variable
  1174.     mvi    a,76        ;lines of text/page
  1175.     sta    text        ; for 8 lpi
  1176.     lxi    h,lsmsg8    ;point to message string
  1177.     jmp    mdone        ; and send to printer
  1178. ;
  1179. ;.....
  1180. ;
  1181. ; set up print density (chars/inch) for Microline 84
  1182. ;
  1183. cwid:    lxi    h,cwmsg        ;ask for cwid
  1184.     call    strngc
  1185.     call    input        ;get value
  1186.     cpi    '1'
  1187.     jz    cwid10
  1188.     cpi    '2'
  1189.     jz    cwid12
  1190.     cpi    '3'
  1191.     jz    cwid17
  1192.     jmp    cwid
  1193. ;
  1194. cwid10:    mvi    a,50        ;pg# loc. for 10 cpi
  1195.     sta    pagcol        ; store it
  1196.     mvi    a,10
  1197.     sta    chwd
  1198.     lxi    h,cwmsg10    ;point to message string
  1199.     jmp    mdone        ;  and sent to printer
  1200. ;
  1201. cwid12:    mvi    a,56        ;pg# loc. for 12 cpi
  1202.     sta    pagcol        ; and store it
  1203.     mvi    a,12
  1204.     sta    chwd
  1205.     lxi    h,cwmsg12    ;point to message string
  1206.     jmp    mdone        ;  and send to printer
  1207. ;
  1208. cwid17:    mvi    a,85        ;pg# loc. for 17 cpi
  1209.     sta    pagcol        ; and store it
  1210.     mvi    a,17
  1211.     sta    chwd
  1212.     lxi    h,cwmsg17    ;point to message string
  1213.     jmp    mdone        ;  and send to printer
  1214. ;
  1215. ;.....
  1216. ;
  1217. ; binary to ascii conversion routine accepts binary
  1218. ; data in register E with HL pointing to the destination
  1219. ; of the 2 ascii bytes.
  1220. ;
  1221. biasc:    push psw! push b    ;save registers
  1222.     lxi    b,0        ; and clear BC
  1223.     mov    a,e        ;recall data byte
  1224.     mvi    c,10        ;  value to subtract
  1225. bitod:    sub    c        ;sub 10 from bin value
  1226.     inr    b        ; and tell tens accumulator
  1227.     jnc    bitod        ;  continue till A exhausted
  1228.     add    c        ;   too much, add once to C
  1229.     dcr    b        ;    and reduce count in B
  1230.     adi    '0'        ;now, make units value ascii
  1231.     mov    c,a        ; and store it in C
  1232.     mov    a,b        ;get the tens data
  1233.     adi    '0'        ; and make it ascii
  1234.     mov    m,a        ;  store it in table area
  1235.     inx    h        ;increment table pointer
  1236.     mov    m,c        ;get the units data to table area
  1237.     pop b! pop psw
  1238.     ret
  1239. ;
  1240. ;.....
  1241. ;
  1242. ; Electralogics Real Time Clock Routines
  1243. ;
  1244. ;
  1245. BLK    EQU 40H
  1246. BLKSEL    EQU 48H
  1247. ;
  1248. ;
  1249. TIME:    JMP RDCLK
  1250. ;
  1251. TEXIT:    RET
  1252. ;.....
  1253. ;
  1254. ; CONVERT CHAR IN A TO HEX AND DISPLAY
  1255. ; ------------------------------------
  1256. DYHEX:    PUSH PSW ! RAR ! RAR ! RAR ! RAR
  1257.     CALL DYNIB ! POP PSW
  1258. DYNIB:    ANI 0FH ! ADI 30H ! CPI 3AH ! JC DY
  1259.     ADI 7
  1260. ;.....
  1261. ;
  1262. ; place time character into header
  1263. ; ----------------------
  1264. DY:    PUSH H
  1265.     LHLD DATCOL ! MOV M,A
  1266.     INX H ! SHLD DATCOL 
  1267.     POP H 
  1268.     RET
  1269. ;
  1270. SPACE:    MVI B,1
  1271. SPACES:    MVI A,20H ! CALL DY
  1272.     DCR B ! JNZ SPACES
  1273.     RET
  1274. ;
  1275. ;
  1276. CLKFLD:        ;Set from clock  (Packed BCD format)
  1277.     DB 0    ;Day of week
  1278.     DB 0    ;Day of month
  1279.     DB 0    ;Month
  1280.     DB 83H    ;Year
  1281.     DB 0    ;Hour
  1282.     DB 0    ;Minutes
  1283.     DB 0    ;Seconds
  1284. ;
  1285. ;
  1286. DAYLST:
  1287.     DB 'SUNMONTUEWEDTHUFRISAT'
  1288. MONTHLST:
  1289.     DB 'JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC'
  1290. ;
  1291. ;
  1292. ;
  1293. RDCLK:    MVI A,0CH ! OUT BLKSEL        ;Select counters
  1294.     LXI H,CLKFLD
  1295.     IN BLK+5 ! MOV M,A ! INX H    ;Read day of week
  1296.     IN BLK+6 ! MOV M,A ! INX H    ;  day of month
  1297.     IN BLK+7 ! MOV M,A ! INX H    ;  month
  1298.     INX H                ;  bypass year
  1299.     IN BLK+4 ! MOV M,A ! INX H    ;  hour
  1300.     IN BLK+3 ! MOV M,A ! INX H    ;  minutes
  1301.     IN BLK+2 ! MOV M,A        ;  seconds
  1302.     MVI A,0EH ! OUT BLKSEL        ;Select clock status block
  1303.     IN BLK+4 ! ANI 1 ! JNZ RDCLK    ;Retry if time not valid
  1304.     IN BLK+0            ;Reset interrupt
  1305. ;
  1306.     LXI D,CLKFLD
  1307.     LXI H,DAYLST
  1308.     LDAX D ! INX D ! CALL DYTX    ;Day of week
  1309.     CALL SPACE
  1310.     LDAX D ! INX D ! CALL DYHEX    ;Day
  1311.     CALL SPACE
  1312.     LXI H,MONTHLST            ;Month
  1313.     LDAX D ! INX D ! CALL DYTX
  1314.     CALL SPACE
  1315.     LDAX D  ! INX D ! CALL DYHEX    ;Year
  1316.     MVI B,2 ! CALL SPACES
  1317.     LDAX D  ! INX D ! CALL DYHEX    ;Hour
  1318.     MVI A,':' ! CALL DY
  1319.     LDAX D ! INX D ! CALL DYHEX    ;Minutes
  1320.     MVI A,':' ! CALL DY
  1321.     LDAX D ! CALL DYHEX        ;Seconds
  1322.     JMP TEXIT
  1323. ;.....
  1324. ;
  1325. ; DISPLAY TABLE ENTRY
  1326. ; Accepts: HL = ptr to table, A = BCD index into table
  1327. ;
  1328. DYTX:
  1329.     CPI 10H ! JC DYTX1    ;Convert index to binary
  1330.     ANI 0FH ! ADI 10
  1331. DYTX1:    MOV C,A ! DCR C ! XRA A
  1332.     ADD C ! ADD C ! ADD C
  1333.     MOV C,A ! MVI B,0 ! DAD B
  1334.     MOV A,M ! INX H ! CALL DY
  1335.     MOV A,M ! INX H ! CALL DY
  1336.     MOV A,M ! JMP DY
  1337. ;.....
  1338. ;
  1339. ;
  1340. ; ROLL UP PAGE TO TERMINATE
  1341. ;
  1342. ROLL:   LDA   START          ;HAVE WE STARTED PRINTING AT ALL?
  1343.         ORA   A
  1344.         JZ    NOPNT          ;IF NOT, TELL WHAT MAXIMUM PAGE WAS
  1345.         MVI   A,CR
  1346.         CALL  WRITEP         ;SEND
  1347. ;
  1348. ROLL1:  LDA   LCNT
  1349.         INR   A
  1350.         STA   LCNT
  1351.         push  h
  1352.     lxi   h,text
  1353.     cmp   m
  1354.     pop   h
  1355.         JNC   ROLL2 
  1356.         MVI   A,LF
  1357.         CALL  WRITEP         ;SEND
  1358.         JMP   ROLL1          ;GO DO ANOTHER UNTIL DONE
  1359. ;
  1360. ROLL2:  CALL  TTABS          ;CHECK FOR TEAR TABS
  1361.     LDA   NOTAB          ;USING FANFOLD PAPER?
  1362.     ORA   A
  1363.     JZ    EXIT           ;IF YES, LEAVE IN NORMAL POSITION
  1364.         LXI   H,QUIT         ;FINAL LINES TO FINISH PAGE
  1365.         CALL  STRNGP
  1366.         JMP   EXIT           ;DONE
  1367. ;.....
  1368. ;
  1369. ;
  1370. ; OPTION FOR ROLL PAPER (CHANGES FANFOLD AREAS)
  1371. ;
  1372. RPAPER: LXI   H,MSG1B        ;ASK IF USING ROLL PAPER
  1373.         CALL  STRNGC
  1374.         CALL  INPUT
  1375.         ANI   5FH            ;CHANGE TO UPPER CASE IF NEEDED
  1376.         CPI   'Y'                  
  1377.         JNZ   RPAP1          ;IF NOT, EXIT
  1378. ;
  1379.         INR   A              ;INCREMENT TO '1'
  1380.         STA   NOTAB         ;SHOW WE WANT TEAR TABS
  1381. ;
  1382. RPAP1:  LXI   H,MSG3 
  1383.         CALL  STRNGC
  1384.         RET
  1385. ;.....
  1386. ;
  1387. ;
  1388. ; IGNORE CR, LF, FFD OR EOF AT TOP OF ANY NEW PAGE
  1389. ;
  1390. SKIP:   CALL  GETCH          ;GET INPUT CHAR.
  1391.         CPI   CR
  1392.         JZ    SKIP           ;IF YES, SKIP
  1393.         CPI   LF
  1394.         JZ    SKIP           ;IF YES, SKIP
  1395.         CPI   EOF
  1396.         JZ    ROLL           ;IF YES, TERMINATE
  1397.         CPI   FFD
  1398.         JZ    SKIP           ;IF YES, IGNORE
  1399.         RET
  1400. ;.....
  1401. ;
  1402. ;
  1403. ; TRANSFER A STRING OF CHARS. FROM ONE AREA TO ANOTHER
  1404. ;
  1405. STORE:  MOV   A,M
  1406.         STAX  D
  1407.         INX   H
  1408.         INX   D
  1409.         DCR   C
  1410.         JNZ   STORE
  1411.         RET
  1412. ;.....
  1413. ;
  1414. ;
  1415. ; PRINT AND DISPLAY A STRING OF CHARACTERS
  1416. ;
  1417. STRNGB: MOV   A,M
  1418.         ORA   A
  1419.         RZ                   ;DONE IF ZERO
  1420.         CALL  WRITE2         ;DISPLAY AND PRINT CHAR.
  1421.         INX   H              ;NEXT LOCATION
  1422.         JMP   STRNGB         ;DO THE NEXT ONE
  1423. ;.....
  1424. ;
  1425. ;
  1426. ; WRITE ASCII STRING TO CRT ONLY
  1427. ;
  1428. STRNGC: MOV   A,M
  1429.         ORA   A
  1430.         RZ
  1431.         CALL  WRITCC         ;DISPLAY ONLY
  1432.         INX   H
  1433.         JMP   STRNGC         ;DO NEXT CHAR.
  1434. ;.....
  1435. ;
  1436. ;
  1437. ; PRINT A STRING OF CHARACTERS
  1438. ;
  1439. STRNGP: MOV   A,M            ;GET THE CHAR.
  1440.         ORA   A
  1441.         RZ                   ;DONE IF ZERO
  1442.         CALL  WRITEP         ;PRINT CHAR.
  1443.         INX   H
  1444.         JMP   STRNGP         ;DO THE NEXT ONE
  1445. ;
  1446. ;.....
  1447. ;
  1448. ; print a string of characters to OKI u84
  1449. ;
  1450. stroki:    mov    a,m        ;get the character
  1451.     ora    a
  1452.     rz            ;done bail out
  1453.     mov    e,a        ;put character in E reg.
  1454.     call    writpr        ;print the character
  1455.     inx    h
  1456.     jmp    stroki        ;loop till done
  1457. ;.....
  1458. ;
  1459. ;
  1460. ; ADDS TEAR TABS FOR ROLL PAPER
  1461. ;
  1462. TTABS:  LDA   NOTAB         ;WANT TEAR TABS?
  1463.     ORA   A
  1464.     JZ    NUPAGE         ;IF NOT EXIT. SEND LINE FEEDS
  1465.         LXI   H,QUITR
  1466.         CALL  STRNGB         ;SEND LF TO FINISH THE PAGE
  1467.         MVI   A,'-'
  1468.         CALL  WRITE3
  1469.         LDA   TTABN          ;GET NUMBER OF SPACES BETWEEN TABS
  1470.         MOV   B,A
  1471. ;
  1472. TTABS1: MVI   A,' '
  1473.         CALL  WRITE3
  1474.         DCR   B
  1475.         JNZ   TTABS1
  1476. ;
  1477.         MVI   A,'-'
  1478.         CALL  WRITE2
  1479.         LXI   H,QUITR
  1480.         CALL  STRNGB
  1481.         XRA   A
  1482.         STA   COLMN          ;RESET THE COLUMN COUNTER
  1483.         RET
  1484. ;.....  
  1485. ;
  1486. ;
  1487. ; WRITE CHAR. TO CRT
  1488. ;
  1489. WRITE2: CPI   SI             ;SYNCH CHAR.?
  1490.         RZ                   ;IF YES, IGNORE
  1491.         CPI   CR
  1492.         JZ    WRITE3         ;DO NOT COUNT
  1493.         CPI   LF
  1494.         JZ    WRITE3         ;DO NOT COUNT
  1495.         PUSH  PSW            ;SAVE THE CHAR. VALUE
  1496.         LDA   COLMN          ;INCREMENT THE COLUMN COUNT
  1497.         INR   A
  1498.         STA   COLMN
  1499.         POP   PSW            ;RESTORE THE CHAR. VALUE
  1500. ;       
  1501. ;
  1502. WRITE3: CALL  WRITEC
  1503. ;
  1504. ;
  1505. ; WRITE CHAR. TO PRINTER
  1506. ;
  1507. WRITE1: CALL  WRITEP
  1508.         RET
  1509. ;.....
  1510. ;
  1511. ;
  1512. ; WRITE ASCII CHARACTER TO CRT
  1513. ;
  1514. WRITEC: MOV   E,A            ;STORE THE CHAR. TEMP.
  1515.         LDA   START          ;READY TO DISPLAY YET?
  1516.         ORA   A
  1517.         MOV   A,E            ;RESTORE THE CHAR.
  1518.         RZ
  1519. ;
  1520. WRITCC: PUSH  H
  1521.         PUSH  D
  1522.         PUSH  B
  1523.         PUSH  PSW
  1524.         MOV   E,A
  1525.         MVI   C,CONOUT       ;WRITE TO THE CRT CONSOLE
  1526.         CALL  BDOS
  1527.         POP   PSW
  1528.         POP   B
  1529.         POP   D
  1530.         POP   H
  1531.         RET
  1532. ;.....
  1533. ;
  1534. ;
  1535. ; WRITE ASCII CHARACTER TO PRINTER
  1536. ;
  1537. WRITEP: CPI   SI             ;SYNCH CHAR.?
  1538.         RZ                   ;IF YES, IGNORE
  1539.         MOV   E,A            ;PUT CHAR. IN 'E' REG.
  1540.         LDA   START          ;READY TO START YET?
  1541.         ORA   A
  1542.         RZ                   ;EXIT IF NOT READY YET
  1543. ;
  1544. writpr:    PUSH  H
  1545.         PUSH  B
  1546.         MVI   C,LIST         ;WRITE TO THE PRINTER
  1547.         CALL  BDOS
  1548.         POP   B
  1549.         POP   H
  1550.         RET
  1551. ;
  1552. ;.....
  1553. ;
  1554. ;
  1555.     DS    40                ;MIMIMUM STACK DEPTH
  1556. STACK:    DS    0
  1557. ;
  1558. BUFF    equ    ($+127)/128*128    ;GET ON AN EVEN PAGE
  1559. ;
  1560. ;
  1561.     ORG    BUFF
  1562. ;
  1563. BUFFER  EQU   $
  1564. ;.....
  1565. ;
  1566. ;
  1567.         END   START
  1568.