home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / sigmv018.ark / XLOOK.ASM < prev   
Encoding:
Assembly Source File  |  1984-04-29  |  12.5 KB  |  762 lines
  1. .PAGE 80,63
  2. ;DISK EXAMINE/MODIFY UTILITY.
  3. ;    This utility allows the user to examine absolute
  4. ;addresses on a disk.  Additionally he may alter, character by
  5. ;charater, the contents of any given sector.  Entire sectors
  6. ;may be moved from the bufer onto the disk.
  7. ;    All I/O is done through the BIOS for CPM.  There are
  8. ;no calls made to the BDOS.
  9. ;
  10. ;D.A. BARKER, January 1980.
  11. ; 
  12. .PABS
  13. .SALL
  14. .OPSYN    .BLKB,DS
  15. .OPSYN    .BYTE,DB
  16. .OPSYN    .WORD,DW
  17. ;
  18. .IDENT    LOOK
  19. .PROGID    EXAM,1,2
  20. ;
  21. ;
  22. ;        *****************
  23. ;        * MISC. EQUATES *
  24. ;        *****************
  25. ;
  26. TEST    =    0
  27. CR    =    0DH
  28. LF    =    0AH
  29. DMADD    =    80H
  30. QUIT    =    0    ;USE CPM ENTRY
  31. ESC    =    1BH
  32. MAXDRV    =    2
  33. NSECS    =    26
  34. MAXGP    =    243
  35. ;
  36. ;        *************************
  37. ;        * I/0 ENTRY DEFINITIONS *
  38. ;        *************************
  39. ;
  40. COUT    =    12    ;THE FOLLOWING ARE BIOS JUMP TABLE
  41. KEYIN    =    9    ; ENTRY POINTS FOR THE VARIOUS
  42. .SETDMA    =    36    ; ROUTINES
  43. .SELDSK    =    27
  44. .SETTRK    =    30
  45. .SETSEC    =    33
  46. .READ    =    39
  47. .WRITE    =    42
  48. ;
  49. ;        **********************
  50. ;        * STRING DEFINITIONS *
  51. ;        **********************
  52. ;
  53. .DEFINE    ST1    =[     -- LOOK -- VERSION 1.3 -- D. A. BARKER  OCT. 21, 1980    ]
  54. .DEFINE    ST2    =[ Drive:]
  55. .DEFINE    ST3    =[         Track:]
  56. .DEFINE ST4    =[          Sector:]
  57. .DEFINE ST4.5    =[          Group:]
  58. .DEFINE    ST5    =[ Display is from:]
  59. .DEFINE    ST6    =[                 Auto-read is:]
  60.  
  61. ;
  62. ;        *********************
  63. ;        * MACRO DEFINITIONS *
  64. ;        *********************
  65. ;
  66. ;    CURSOR ADDRESSING
  67. ;    This routine should produce the sequence of characters
  68. ;necessary to position the cursor.  The third parameter should
  69. ;not require alteration.
  70. ;
  71. .DEFINE        XY [ROW,COL,Z(0)]  =
  72.         [
  73.         DB    ROW,COL
  74.         .IFE Z, DB 0
  75.         ]
  76. ;
  77. ;    INVERTING A STRING VALUE
  78. ;    This routine sets the MSB of each character of the
  79. ;argument string.  This is used for inverse video when the
  80. ;IObyte has been altered to accept inverse video rather than
  81. ;xy-addressing
  82. ;
  83. ;    I/O FUNCTIONS
  84. ;    Setup and do a BIOS function (FUNC).
  85. ;
  86. .DEFINE        GODO [FUNC]  =
  87.         [
  88.         PUSH    H
  89.         PUSH    D
  90.         LXI    D,FUNC
  91.         CALL    IOCALL
  92.         POP    D
  93.         POP    H
  94.         ]
  95. ;
  96. .DEFINE        TYPE  =  [CALL TYPEX]
  97. ;        
  98. .DEFINE        PRINT  =  [CALL PRNTMSG]
  99. ;
  100. .DEFINE        XYPR    =  [CALL POSPR]
  101. ;
  102. ;    GETKEY will set the zero flag if an Escape is typed.
  103. ;
  104. .DEFINE        GETKEY    =  [CALL GK]
  105. ;
  106. ;  THE MAIN PROGRAM BEGINS
  107. ;
  108. .LOC    0100H    ;MAKE IT A CPM TRANSIENT
  109. ;
  110. EXAM:
  111. INIT:    LXI    B,DMADD    ;THIS WILL NEVER CHANGE
  112.     GODO .SETDMA
  113.     LXI    H,100H
  114.     SHLD    DSKTBL
  115.     LXI    D,DSKTBL+2
  116.     LXI    H,DSKTBL
  117.     LXI    B,10
  118.     LDIR        ;INITIALIZE VARIOUS POINTERS
  119. ;
  120.     LXI    H,DMADD
  121.     MVI    M,0
  122.     LXI    D,DMADD+1
  123.     LXI    B,127
  124.     LDIR        ;CLEAR THE BUFFER AREA
  125. ;
  126. CLEAR:    CALL    CLRSC
  127. ;
  128.     CALL    WHITE    ;INVERT THE VIDEO
  129.     PRINT
  130.     .ASCII    ST1        ;PRINTING THE HEADER
  131.     DB    CR,LF        ;BLOCK AND STATUS DISPLAYS
  132.     .ASCII    ST2
  133.     .ASCII    ST3
  134.     .ASCII    ST4
  135.     .ASCII    ST4.5
  136.     .ASCII    /       /
  137.     DB    CR,LF
  138.     .ASCII    ST5
  139.     .ASCII    ST6
  140.     .ASCII    /               /
  141.     DB    0
  142.     CALL    BLACK    
  143. REENT:    LXI    SP,STACK    ;ENTRY HERE WILL UPDATE ALL
  144.     XYPR            ; STATUS DISPLAYS
  145.     XY [1,@ST2]
  146.     LHLD    DRIVE
  147.     MVI    A,'A'
  148.     ADD    L
  149.     TYPE
  150.     XYPR
  151.     XY [1,@ST2+@ST3]
  152.     MVI    H,0
  153.     DAD    H
  154.     LXI    D,DSKTBL
  155.     DAD    D
  156.     MOV    A,M
  157.     CALL    HEXOUT
  158.     XYPR
  159.     XY [1,@ST2+@ST3+@ST4]
  160.     INX    H
  161.     MOV    A,M
  162.     CALL    HEXOUT
  163. ;
  164.     XYPR
  165.     XY [1,@ST2+@ST3+@ST4+@ST4.5]
  166.     PUSH    H
  167.     MOV    A,M
  168.     LXI    H,GPTBL+NSECS
  169.     LXI    B,NSECS
  170.     CCDR        ;BC NOW CONTAINS LOGICAL SECTOR #
  171.     POP    H
  172.     DCX    H
  173.     MOV    L,M
  174.     MVI    H,0
  175.     DCR    L
  176.     DCR    L    ;TRACK-2
  177.     JP    .VALID    ;JMP IF TRACK > 1
  178.     PRINT
  179.     .ASCIZ /SYS*/
  180.     JMPR    .NTV
  181. ; NOW MULTIPLY HL BY 26
  182. .VALID:    DAD    H    ;X2
  183.     PUSH    H
  184.     POP    D
  185.     DAD    H    ;X4
  186.     DAD    H    ;X8
  187.     XCHG
  188.     DAD    D
  189.     XCHG        ;DE IS NOW X10
  190.     DAD    H    ;X16
  191.     DAD    D    ;X26
  192.     DAD    B    ;HL NOW THE TOTAL SECTOR NUMBER
  193.             ;NOW DIVIDE BY 8
  194.     MOV    A,L
  195.     ANI    0F8H
  196.     ORA    H
  197.     RRC
  198.     RRC
  199.     RRC
  200.     CALL    HEXOUT
  201.     MVI    A,':'
  202.     TYPE
  203.     MOV    A,L    ;GET REMAINDER
  204.     ANI    7
  205.     ADI    '1'    ;ADD ASCII BIAS & INCREMENT
  206.     TYPE
  207. ;
  208. .NTV:    LDA    AUTONO
  209.     ORA    A    ;CHECK FOR AUTO-READ
  210.     JNZ    RDSK    ;JUMP IF AUTO-READ
  211. ;
  212.     XYPR
  213.     XY [2,@ST5,1]
  214.     .ASCIZ    / BUFFER/
  215.     JMPR    LP
  216. RDRTN:    XYPR            ;EVERY DISK READ OR WRITE WILL
  217.     XY [2,@ST5,1]        ; RETURN HERE AND UPDATE THE 
  218.     .ASCIZ    / DISK  /    ; SECOND STATUS LINE
  219. LP:    LXI    H,AUTONO
  220.     XYPR
  221.     XY [2,@ST5+@ST6]
  222.     MOV    A,M
  223.     ORA    A
  224.     JRZ    ..OFF
  225.     PRINT
  226.     .ASCIZ    / ON /
  227.     JMPR    ..ON
  228. ..OFF:    PRINT
  229.     .ASCIZ    / OFF/
  230. ..ON:    CALL    SPIT     ;SPIT THE BUFFER ONTO THE SCREEN
  231. ;
  232. ;        *********************
  233. ;        * COMMAND PROCESSOR *
  234. ;        *********************
  235. ;
  236. GETCOM:    XYPR
  237.     XY [15,0]
  238.     CALL    ERAL    ;ERASE THE PROMPT LINE
  239.     GETKEY        ;GET THE COMMAND CHARACTER
  240.     LXI    H,CMDADD-1
  241.     LXI    B,CMDADD-CMDTBL+1
  242.     CCDR        ;SCAN THE TABLE BACKWARDS
  243.     LXI    H,CMDADD
  244.     DAD    B
  245.     DAD    B    ;HL NOW POINTS TO THE ROUTINE'S ADDRESS
  246.     MOV    E,M
  247.     INX    H
  248.     MOV    D,M
  249.     PUSH    D    ;SO A 'RET' WILL GO TO THE ROUTINE
  250. SETUP:    LHLD    DRIVE
  251.     MOV    C,L
  252.     MVI    H,0
  253.     DAD    H
  254.     LXI    D,DSKTBL
  255.     DAD    D    ;HL POINT TO CURRENT DISK'S TRACK LOC.
  256.     LXI    D,0
  257.     RET        ;GO EXECUTE THE CHOSEN ROUTINE
  258. ;
  259. ;        *********************
  260. ;        * THE COMMAND TABLE *
  261. ;        *********************
  262. ;
  263. CMDTBL:    .ASCII    /DTSIO+-GNLRWAHCQM?/[3]
  264. CMDADD:    DW    INFO,SELDRV,SELTRK,SELSEC,STPIN
  265.     DW    STPOUT,NXSEC,LSTSEC,GROUP,NXGP
  266.     DW    LSTGP,READ,WRITE,ASC,HXCMD
  267.     DW    CLEAR,QUIT,MODE,INFO,QUIT
  268. ;
  269. SELDRV:    CALL    ERAL
  270.     PRINT
  271.     .ASCIZ /DRIVE NUMBER?/
  272.     MVI    E,0    ;FOR THE GHX ROUTINE
  273.     CALL    GHX
  274.     CPI    MAXDRV
  275.     JRNC    SELDRV
  276.     STA    DRIVE
  277.     JMP    REENT
  278. ;
  279. SELTRK:    CALL    ERAL
  280.     PRINT
  281.     .ASCIZ    /DESIRED TRACK?/
  282.     CALL    GETHEX
  283.     CPI    77    ;MAXIMUM TRACK NUMBER + 1
  284.     JRNC    SELTRK
  285.     MOV    M,A
  286.     JMP    REENT
  287. ;
  288. SELSEC:    CALL    ERAL
  289.     PRINT
  290.     .ASCIZ    /DESIRED SECTOR?/
  291.     CALL    GETHEX
  292.     ORA    A
  293.     JRZ    SELSEC
  294.     CPI    NSECS+1
  295.     JRNC    SELSEC
  296.     INX    H    ;POINT TO CURRENT DRIVE'S SECTOR LOC.
  297.     MOV    M,A
  298.     JMP    REENT
  299. ;
  300. NXSEC:    INX    H
  301.     MOV    A,M
  302.     INR    A
  303.     CPI    NSECS+1
  304.     JRNC    ..NXT
  305.     MOV    M,A
  306.     JMP    REENT    ;STAY ON SAME TRACK
  307. ..NXT:    MVI    A,1
  308.     MOV    M,A
  309.     DCX    H    ;POINT TO CURRENT TRACK LOCATION
  310.     JMPR    STPIN
  311. ;
  312. LSTSEC:    INX    H
  313.     MOV    A,M
  314.     DCR    A
  315.     ORA    A
  316.     JRZ    ..LST
  317.     MOV    M,A
  318.     JMP    REENT    ;STAY ON THE SAME TRACK
  319. ..LST:    ADI    26
  320.     MOV    M,A
  321.     DCX    H    ;POINT TO CURRENT TRACK LOCATION
  322.     JMPR    STPOUT
  323. ;
  324. NXGP:    INX    H    ;GET PRESENT SECTOR #
  325.     MOV    A,M    
  326.     LXI    B,NSECS
  327.     XCHG        ;PUT SECTOR TABLE POINTER IN DE
  328.     LXI    H,GPTBL+1 ;POINT TO 2ND ENTRY OF THIS TABLE
  329.     CCIR        ;SEARCH FOR THE PRESENT SECTOR
  330.     MOV    A,M    ;GET THE NEXT SECTOR
  331.     XCHG        ;POINT HL TO THE TABLE
  332.     MOV    M,A
  333.     JPE    REENT    ;ODD PARITY MEANS END OF TABLE
  334.     DCX    H
  335. STPIN:    MOV    A,M
  336.     CPI    76    ;MAXIMUM TRACK NUMBER
  337.     JNC    REENT
  338.     INR    M
  339.     JMP    REENT
  340. ;
  341. LSTGP:    INX    H
  342.     MOV    A,M
  343.     LXI    B,NSECS
  344.     XCHG
  345.     LXI    H,GPTBL+NSECS
  346.     CCDR
  347.     MOV    A,M
  348.     XCHG
  349.     MOV    M,A
  350.     JPE    REENT
  351.     DCX    H
  352. STPOUT:    MOV    A,M
  353.     ORA    A
  354.     JZ    REENT
  355.     DCR    M
  356.     JMP    REENT
  357. ;
  358. ;        *********************
  359. ;        * SECTOR SKEW TABLE *
  360. ;        *********************
  361. ;    Assuming a sector interleave of 6 sectors
  362. ;
  363. GPTBL:    DB    22,1,7,13,19,25,5,11,17
  364.     DB    23,3,9,15,21,2,8,14,20
  365.     DB    26,6,12,18,24,4,10,16,22,1
  366. ;
  367. GROUP:    CALL    ERAL
  368.     PRINT
  369.     .ASCIZ    /GROUP NUMBER?/
  370.     CALL    GETHEX
  371.     CPI    MAXGP+1
  372.     JRNC    GROUP
  373.     MVI    A,0FFH
  374.     XCHG        ;HL CONTAIN THE GROUP NUMBER
  375.     DAD    H    ;MULTIPLY # BY 8
  376.     DAD    H
  377.     DAD    H
  378.     LXI    B,-NSECS
  379. ..AGN:    INR    A    ;DIVIDE THE # BY NSECS
  380.     DAD    B
  381.     JRC    ..AGN
  382.     ADI    2    ;QUOTIENT PLUS 2 IS NEW TRACK #
  383.     STAX    D    
  384.     DSBC    B    ;HL IS THE LOGICAL SECTOR NUMBER
  385.     LXI    B,GPTBL+1
  386.     DAD    B    ;(HL) IS NOW THE PHYSICAL SECTOR #
  387.     MOV    A,M
  388.     INX    D
  389.     STAX    D
  390.     JMP    REENT
  391. ;
  392. MODE:    LDA    AUTONO    ;TOGGLE THE AUTO-READ MODE
  393.     INR    A
  394.     ANI    1
  395.     STA    AUTONO
  396.     JNZ    RDSK
  397.     JMP    RDRTN
  398. ;
  399. ASC:    CALL    ERAL
  400.     PRINT
  401.     .ASCIZ    /ASCII BYTE NUMBER?/
  402.     CALL    GETHEX
  403.     CPI    80H
  404.     JRNC    ASC
  405. ..AGN:    CALL    MCUR    ;Position the cursor on the screen.
  406.     CALL    ACUR
  407.     CALL    MCUR0
  408.     JRNC    ..AGN
  409.     MOV    M,A    ;Update the DMA buffer.
  410.     MVI    C,1    ;Ready to advance by one.
  411.     CALL    RESTO
  412.     JMPR    ..AGN
  413. ;
  414. HXCMD:    CALL    ERAL
  415.     PRINT
  416.     .ASCIZ    /HEX BYTE NUMBER?/
  417.     CALL    GETHEX
  418.     CPI    80H
  419.     JRNC    HXCMD
  420. ..AGN:    CALL    MCUR
  421.     CALL    HCUR
  422.     CALL    MCUR0
  423.     JRNC    ..AGN
  424.     CALL    HEXFIL
  425.     MVI    C,0
  426.     JRZ    ..FWD
  427.     MOV    M,A
  428.     INR    C
  429. ..FWD:    CALL    RESTO
  430.     JMPR    ..AGN
  431. ;
  432. MCUR:    MOV    E,A    ;THE CURSOR POINTER
  433.     MVI    D,0
  434.     LXI    H,DMADD
  435.     DAD    D    ;HL TO THE CP IN THE BUFFER
  436.     CALL    HCUR    ;POSITION THE HEX CURSOR
  437.     CALL    BTYPE
  438.     CALL    BTYPE
  439.     CALL    ACUR    ;THE ASCII CURSOR
  440.     JMP    BTYPE
  441. MCUR0:    GETKEY
  442.     JZ    GIT    ;LEAVE ON AN 'ESC'
  443.     MVI    C,-1
  444.     CPI    'H'-40H    ;MOVE LEFT?
  445.     RC
  446.     JRZ    RESTO
  447.     MVI    C,10H
  448.     CPI    'J'-40H
  449.     RC
  450.     JRZ    RESTO
  451.     MVI    C,1
  452.     CPI    'L'-40H
  453.     JRZ    RESTO
  454.     CMC
  455.     RC
  456.     MVI    C,-10H
  457. RESTO:    PUSH    B
  458.     CALL    RS
  459.     POP    B
  460.     MOV    A,E
  461.     ADD    C
  462.     ANI    7FH    ;INSURE IN SECTOR
  463.     RET
  464. ;
  465. RS:    CALL    HCUR
  466.     MOV    A,M
  467.     CALL    HEXOUT
  468.     CALL    ACUR
  469.     MOV    A,M
  470.     ANI    7FH
  471.     CPI    20H
  472.     JRNC    ..FW
  473.     MVI    A,'.'
  474. ..FW:    CPI    0FFH
  475.     JRNZ    ..AGN
  476.     MVI    A,'.'
  477. ..AGN:    TYPE
  478.     RET
  479. ;
  480. HCUR:    PUSH    D
  481.     MOV    A,E
  482.     RRC
  483.     RRC
  484.     RRC
  485.     RRC
  486.     ANI    0FH
  487.     ADI    5
  488.     MOV    D,A
  489.     MOV    A,E
  490.     ANI    0FH
  491.     RLC
  492.     MOV    E,A
  493.     CALL    DEXY
  494.     MOV    A,D
  495.     POP    D
  496.     MOV    D,A
  497.     RET
  498. ACUR:    PUSH    D
  499.     MOV    A,E
  500.     ANI    0FH
  501.     ADI    24H
  502.     MOV    E,A
  503.     CALL    DEXY
  504.     POP    D
  505.     RET
  506. ;
  507. GIT:    CALL    RS
  508.     LXI    H,0
  509.     SHLD    AUTONO
  510.     JMP    REENT
  511. ;
  512. HEXFIL:    CALL    HEXIT
  513.     RZ
  514.     MOV    B,A
  515. ..AGN:    GETKEY
  516.     RZ
  517.     CPI    CR
  518.     JRZ    ..XIT
  519.     CALL    HEXIT
  520.     JRC    ..AGN
  521.     RLCR    B
  522.     RLCR    B
  523.     RLCR    B
  524.     RLCR    B
  525.     ORA    B
  526.     MOV    B,A
  527.     XRA    A
  528.     INR    A    ;JUST TO CLEAR Z-FLAG
  529. ..XIT:    MOV    A,B
  530.     RET
  531. ;
  532. RDSK:    CALL    SETUP
  533. READ:    CALL    IOSET
  534.     XYPR
  535.     XY [13,0]
  536.     GODO    .READ
  537. .IFN    TEST,    [
  538.     ORA    A
  539.     JZ    RDRTN
  540.     XYPR
  541.     XY [15,0,1]
  542.     .ASCIZ / ERROR ON READ!! /
  543.     GETKEY ]
  544.     JMP    RDRTN
  545. WRITE:    CALL    IOSET
  546.     XYPR
  547.     XY [13,0]
  548.     GODO    .WRITE
  549.     JMP    RDRTN
  550.  
  551. IOSET:    GODO    .SELDSK
  552.     MOV    C,M
  553.     GODO    .SETTRK
  554.     INX    H
  555.     MOV    C,M
  556.     GODO    .SETSEC
  557.     RET
  558. ;
  559. INFO:    CALL    CLRSC        ;SPLASH THE HELP TEXT TO THE SCREEN
  560.     XYPR
  561.     XY    [0,24,1]
  562.     .ASCII    /COMMAND SUMMARY/[CR][LF]
  563.     .ASCII    /D: select Drive (0,1,2,3)       /
  564.     .ASCII    /R: Read the current sector/[CR][LF]
  565.     .ASCII    /T: select Track (0 - 4C)       /
  566.     .ASCII    /W: Write buffer to disk/[CR][LF]
  567.     .ASCII    /S: select Sector (1 - 26)       /
  568.     .ASCII    /M: toggle the auto-read Mode/[CR][LF]
  569.     .ASCII    /I: step In               /[CR][LF]
  570.     .ASCII    /O: step Out                  /
  571.     .ASCII    /A: ASCII fill the buffer/[CR][LF]
  572.     .ASCII    /                   /
  573.     .ASCII    /H: Hex fill the buffer/[CR][LF]
  574.     .ASCII    /+: next physical sector       /[CR][LF]
  575.     .ASCII    /-: last physical sector        /
  576.     .ASCII    /^H: move cursor left/[CR][LF]
  577.     .ASCII    /                   /
  578.     .ASCII    /^L: move cursor right    /[CR][LF]
  579.     .ASCII    /The following 3 commands       /
  580.     .ASCII    /^J: move cursor down    /[CR][LF]
  581.     .ASCII    /assume sector interleave of 6       /
  582.     .ASCII    /^K: move cursor up    /[CR][LF]
  583.     .ASCII    /G: Group selection           /
  584.     .ASCII    /C: re-initialize the screen    /[CR][LF]
  585.     .ASCII    /N: Next logical sector           /
  586.     .ASCII    /Q: exit to CPM/[CR][LF]
  587.     .ASCII    /L: Last logical sector           /
  588.     .ASCII    /^C:  "   "  "/[CR][LF][0]
  589.     XYPR
  590.     XY [15,17,1]
  591.     .ASCIZ    /Esc: general command Escape./
  592.     GETKEY
  593.     JMP    CLEAR
  594.  
  595. ;
  596. ;        *********************
  597. ;        * MISC. SUBROUTINES *
  598. ;        *********************
  599. ;
  600. ;
  601. IOCALL:    LHLD    1    ;PICK UP THE BASE OF THE BIOS
  602.     MVI    L,0
  603.     DAD    D
  604.     PCHL        ;GO TO THE REQUESTED ROUTINE
  605. ;
  606. BTYPE:    MVI    A,'_'
  607. TYPEX:    MOV    C,A
  608.     GODO [COUT]
  609.     RET
  610. ;
  611. POSPR:    XTHL
  612.     MOV    D,M
  613.     INX    H
  614.     MOV    E,M
  615.     CALL    DEXY
  616.     JMPR    POSPR1
  617. PRNTMSG: XTHL
  618.     MOV    A,M
  619. ZAGN:    TYPE
  620. POSPR1:    INX    H
  621.     MOV    A,M
  622.     ORA    A
  623.     JRNZ    ZAGN
  624.     INX    H
  625.     XTHL
  626.     RET
  627. ;
  628. HEXOUT:    PUSH    B    ;SAVE BC
  629.     MVI    B,1    ;ITERATION COUNT
  630.     MOV    C,A
  631.     RAR
  632.     RAR
  633.     RAR
  634.     RAR
  635. ..AGN:    ANI    0FH
  636.     PUSH    B
  637.     ADI    '0'
  638.     CPI    '9'+1
  639.     JRC    ..OUT
  640.     ADI    7
  641. ..OUT:    TYPE
  642.     POP    B
  643.     DCR    B
  644.     JRNZ    ..DUN
  645.     MOV    A,C
  646.     JMPR    ..AGN
  647. ..DUN:    POP    B
  648.     RET
  649. ;
  650. ;    READ HEX VALUES IN FROM THE KEYBOARD
  651. ;
  652. GETHEX:    GETKEY
  653.     JZ    REENT
  654.     CALL    HEXIT
  655.     JRC    GETHEX
  656.     MOV    E,A
  657.     MOV    A,C
  658.     TYPE
  659. GHX:    GETKEY
  660.     JZ    REENT
  661.     CPI    CR
  662.     JRZ    ..EX
  663.     CALL    HEXIT
  664.     JRC    GHX
  665.     RLCR    E
  666.     RLCR    E
  667.     RLCR    E
  668.     RLCR    E
  669.     ORA    E
  670.     MOV    E,A
  671.     MOV    A,C
  672.     TYPE
  673. ..EX:    MOV    A,E
  674.     RET
  675. ;
  676. ;    CONVERT THE CONTENTS OF THE ACCUMULATOR TO
  677. ;    HEXIDECIMAL. SET CARRY ON ILLEGAL CHARACTERS
  678. ;
  679. HEXIT:    MOV    C,A
  680.     SUI    30H
  681.     RC
  682.     CPI    0AH
  683.     CMC
  684.     RNC
  685.     SUI    7
  686.     CPI    0AH
  687.     RC
  688.     CPI    10H
  689.     CMC
  690.     RET 
  691. GK:    GODO    KEYIN
  692.     CPI    ESC
  693.     RET
  694. ;
  695. ;        **************************************
  696. ;        * DISPLAY THE CONTENTS OF THE BUFFER *
  697. ;        **************************************
  698. ;
  699. SPIT:    XYPR
  700.     XY    [5,0]
  701.     LXI    H,DMADD
  702.     MVI    B,8    ;FOR 8 ROWS OF INFO
  703.     PUSH    H
  704. ..BGN:    MVI    C,10H    ;FOR 16 COLUMNS OF INFO
  705.     LXI    H,..BUF
  706.     XTHL        ;HL TO BUFFER AND STACK TO ..BUF
  707. ..AGN:    MOV    A,M
  708.     CALL    HEXOUT  
  709.     MOV    A,M
  710.     ANI    7FH
  711.     CPI    7FH
  712.     JRZ    ..BD
  713.     CPI    ' '
  714.     JRNC    ..OK
  715. ..BD:    MVI    A,'.'
  716. ..OK:    XTHL        ;GET THE ..BUF POSITION.
  717.     MOV    M,A
  718.     INX    H
  719.     XTHL
  720.     INX    H    ;ADVANCE IN THE BUFFER
  721.     DCR    C    ;SEE IF THERE IS MORE ON THIS LINE
  722.     JRNZ    ..AGN
  723.     XTHL
  724.     PRINT
  725.     .ASCII    /    /
  726. ..BUF:    DS    10H
  727.     DB    CR,LF,0
  728.     DCR    B    ;MORE FROM THIS SECTOR?
  729.     JRNZ    ..BGN
  730.     POP    H
  731.     RET
  732. DSKTBL:    DS    8    ;ROOM ENOUGH FOR 4 DRIVES
  733. DRIVE:    DS    1    ;CURRENT DRIVE
  734. AUTONO:    DS    1    ;AUTO OR MANUAL READ
  735.     DS    32
  736. STACK:    DS    1
  737. CLRSC:    PRINT
  738.     .ASCIZ    [ESC]/E/[0][0]
  739.     RET
  740. BLACK:    PRINT
  741.     .ASCIZ    [ESC]/q/[0][0]
  742.     RET
  743. WHITE:    PRINT
  744.     .ASCIZ    [ESC]/p/[0][0]
  745.     RET
  746. ERAL:    PRINT
  747.     .ASCIZ    [CR][ESC]/l/[0][0]
  748.     RET
  749. DEXY:    MVI    A,ESC
  750.     TYPE
  751.     MVI    A,'Y'
  752.     TYPE
  753.     MOV    A,D    ;THE ROW NUMBER
  754.     ADI    20H
  755.     TYPE
  756.     MOV    A,E    ;THE COLUMN NUMBER
  757.     ADI    20H
  758.     TYPE
  759.     RET
  760. .END    EXAM
  761.  
  762.