home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / sigmv009.ark / SHOWGRP.ASC < prev    next >
Encoding:
Text File  |  1984-04-29  |  1.0 KB  |  42 lines
  1. 10 REM PROGRAM TO PRINT TRACK AND SECTOR ADDRESSES OF GROUPS
  2. 20 REM ON A STANDARD CPM DISK. ALL VALUES ARE DECIMAL.
  3. 30 REM
  4. 40 REM WRITTEN BY M.NICHOLS
  5. 50 REM
  6. 60 DIM A(26)
  7. 70 FOR J=1 TO 26
  8. 80 READ A(J)
  9. 90 NEXT J
  10. 100 PRINT
  11. 110 PRINT
  12. 120 PRINT "ENTER GROUP NUMBER (DECIMAL) OR 999 TO END"
  13. 130 INPUT G
  14. 140 IF G=999 THEN GOTO 410
  15. 150 REM CHECK FOR VALID GROUPS
  16. 160 IF G<0 OR G>243 THEN GOTO 340
  17. 170 REM GET TRACK NUMBER (ADD 2 BECAUSE WE START ON TRACK 2)
  18. 180 T=INT((G*8)/26+2)
  19. 190 REM GET THE SECTOR VECTOR
  20. 200 I=(G*8) MOD 26
  21. 210 REM ADD 1 TO VECTOR SO MATRIX CORRECTLY ADDRESSED
  22. 220 I=I+1
  23. 230 REM GET SECTOR # FROM MATRIX IN A CIRCULAR FASHION
  24. 240 PRINT "GROUP";G
  25. 250 FOR J=1 TO 8
  26. 260 S=A(I)
  27. 270 PRINT " ","TRACK";T;"SECTOR";S
  28. 280 I=I+1
  29. 290 IF I<=26 THEN GOTO 320
  30. 300 T=T+1
  31. 310 I=1
  32. 320 NEXT J
  33. 330 GOTO 100
  34. 340 PRINT "GROUP NUMBER IS NOT VALID"
  35. 350 GOTO 100
  36. 360 REM
  37. 370 REM STANDARD INTERLEAVE TABLE FOR CPM
  38. 380 REM
  39. 390 DATA 1,7,13,19,25,5,11,17,23,3,9,15,21
  40. 400 DATA 2,8,14,20,26,6,12,18,24,4,10,16,22
  41. 410 END
  42.