home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpmug / cpmug085.ark / BYE79.ASM < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  77.7 KB  |  3,387 lines
  1. ;    TITLE    'BYE V7.9 AS OF 04/12/82'
  2. ;    PAGE    44
  3. ;
  4. ;        BYE V7.9 (revised 04/12/82)
  5. ;    REMOTE CONSOLE PROGRAM FOR CP/M AND MODEM
  6. ;
  7. ;This program allows modem callers to use your CP/M system
  8. ;just as if they were seated at the system console.  Special
  9. ;assembly-time options allow limiting the caller's access by
  10. ;password and/or access to only a message-service program.
  11. ;
  12. ;Based on an original program written by Dave Jaffe, January 1979
  13. ;Rewritten for PMMI modem by Ward Christensen, February 1979.
  14. ;This program now supports DC Hayes, PMMI, and external modems.
  15. ;CCS Card and Smartmodem code added by Paul Traina, March, 1982.
  16. ;  (Basically, added 6850 memory mapped ACIA -- Slot 2).
  17. ;The UARTS supported are the Intel 8251 and the Western Digital 8250.
  18. ;Be sure to set the equates for the modem you are using. 
  19. ;
  20. ;*************************************************************************
  21. ;DANGER: Pay close attention to the polarity of the jump instructions    *
  22. ;after any in from a uart when running under 8250/8251's,  I have tried  *
  23. ;to fix them for the most common logical setup, but your system may      *
  24. ;differ.                                 *
  25. ;*************************************************************************
  26. ;
  27. ;Thanks to Bill Precht for the "label + offset" idea allowing
  28. ;this program to relocate itself without using DDT to initially
  29. ;set it up.
  30. ;
  31. ;Modifications/fixes: (in reverse order to minimize reading time)
  32. ;
  33. ;03/25/82 Improved carrier check handling for DCHayes.
  34. ;      Fixed a bug in conditional assembly for ringback (problem in
  35. ;      Bye77 and also Bye78).
  36. ;      Changed FASTCLK conditional to a SPEED equate (for 6 & 8 Mhz CPUs)
  37. ;      Finally fixed the bug in LF parsing for OXGATE
  38. ;    ->Code added for DCHayes MM][    <- Not tested
  39. ;    +>Code added for DCHayes SModem    <- Not tested
  40. ;    ----> I won't vouch for this code, I don't have these modems,
  41. ;      `-> so please let me know if it is sick.
  42. ;                    -- Paul S Traina
  43. ;
  44. ;02/03/82 Fixed the buggy conditional jumps in/after RINGWT.
  45. ;      Now there is conditional assembly depending on if you are
  46. ;      a WD8250/IN8251 or a "standard" system.
  47. ;      Fixed a few bugs in conditional assembly.
  48. ;      Improved LF code.    -- Paul S Traina
  49. ;
  50. ;01/20/82 Add equates and routines for HEATH or IMS systems and any
  51. ;      other systems using External modems and the WD8250 UART.
  52. ;      Included assembly option for compatability with RBBS,
  53. ;      MINICBBS, and OXGATE implimentations. by Thom Quick
  54. ;
  55. ;01/09/82 Added WRTLOC flag for use with an RBBS program that sets
  56. ;      this flag during disk writes; avoids files out of synch
  57. ;      problem if caller hangs up during writes. Added MINICK
  58. ;      routines which do the same with MINICBBS. Added patch
  59. ;      to allow bye to run below the CCP with programs such as
  60. ;      TYPESQ. Separated Superb conditional assembly into Externl
  61. ;      and LOSER, this separates external modem operation from a
  62. ;      losing feature of a particular BIOS. (P. L. Kelley)
  63. ;        
  64. ;12/03/81 Implemented OxGate protocol,  fixed some bugs in conditional
  65. ;        equates.  Variables for UCLSW and NULLS moved up so that
  66. ;        programs can poke them too.    -- Paul S Traina
  67. ;
  68. ;12/02/81 Make variables for MAXDRV, MAXUSR, and TOVALUE that
  69. ;         can be found via the warm boot BIOS vector at zero,
  70. ;      so that these values can be changed while BYE is
  71. ;      running to accomodate privileged users, either through
  72. ;      action of the BYE-run .COM file or some other password
  73. ;      program run later. Move MCBOOT and the USRLOG vector
  74. ;      to just after the START vector, for easier access
  75. ;      if desired.
  76. ;
  77. ;11/04/81 Print out BYE version number in PRNLOG, to allow
  78. ;      program to be identified easily when running. Call
  79. ;      USRCHK in all cases to print out version number on
  80. ;      local ctrl-C, then ask to resume BYE instead of
  81. ;      warm boot. Convert many msgs to upper/lower case.
  82. ;                    By Steve Bogolub
  83. ;
  84. ;10/24/81 Modified NOPASS so that COM files that look for
  85. ;      a second file on the command line (such as HELP18)
  86. ;      will find a 20H at FCB+1 for default purposes.  Also
  87. ;      added RUNCOM at the end of NOPASS and changed the
  88. ;      jumps to the TPA (100h) to a CALL so that a COM file
  89. ;      will return to BYE where a clean jump to warm boot
  90. ;      can be done instead of going off to never-never land.
  91. ;                    R. L. Plouffe
  92. ;
  93. ;10/11/81 Print password on local console with DUAL$IO. Allow
  94. ;      return from PRNLOG with USRLOG. Make <CR><LF> instead
  95. ;      of <LF><CR> in USRLOG reports. Print out BYE version
  96. ;      number for easy identification. Position PRNLOG after
  97. ;      cold boot routine, and change cold boot routine to
  98. ;      jump to MBOOT, thereby defining path to PRNLOG for
  99. ;      all BYE programs and allowing one trivial program
  100. ;      that can be run to get the BYE log. Make counters
  101. ;      16 bits for greater range. By Steve Bogolub
  102. ;
  103. ;10/01/81 Added CALL CHECK to MSTAT routine to eliminate
  104. ;      possibility of system crash when carrier lost while
  105. ;      performing repeated console status checks without
  106. ;      any console output.  This problem occurs during the
  107. ;      password input of USERPW.ASM, and potentially any other
  108. ;      program that does repeated direct console input, such
  109. ;      as MBASIC, etc.  
  110. ;      By Ron Fowler and Dave Hardy
  111. ;
  112. ;05/14/81 Added CCS disk support (to turn off disks when idle)
  113. ;      Added support for Godbout SS1 Real time clock.
  114. ;      Added Phone to Lister, Punch & Reader patch. (AAJ)
  115. ;
  116. ;03/20/81 Fixed MOUTPUT so parity bit is stripped before outputting
  117. ;      character to modem.  Corrected 3/18/81 null fix.  Added
  118. ;      additional description to heading of this file.  (KBP)
  119. ;
  120. ;03/18/81 Add first-ring debounce routine, change PMMI HANGUP
  121. ;      to do break for faster disconnect, fix error in P3TODTR
  122. ;      equate for PMMI, added end-of-program error message to
  123. ;      mark ending address (see note at label DEST). By KBP.
  124. ;      Fix bug that prevented nulls at end of line if DUAL$IO
  125. ;      was true.  By Hank Szyszka.
  126. ;
  127. ;02/23/81 Conditional assembly added for Intertec SuperBrain
  128. ;      with Racal-Vadic 3451 modem. Corrected lack of RET in
  129. ;      CONIN. In MOUTPUT, replaced CZ CHECK with JNZ SILENT,
  130. ;      CALL CHECK; this eliminates chance of looping in MOUTPUT
  131. ;      if modem doesn't empty USART after carrier lost.
  132. ;      Also had to write a routine to patch BIOS so that after
  133. ;      the warm boot disk read this program repatches the BIOS.
  134. ;      Apparently the SuperBrain warm boot overwrites a portion
  135. ;      of the BIOS. By P.L. Kelley
  136. ;
  137. ;02/17/81 Added check for extraneous control characters in
  138. ;      hardcopy log.  (Formfeed seems to be a common "hit").
  139. ;      Changed local startup test to directly test for carrier
  140. ;      instead of calling CARCK, to avoid 15 second delay.
  141. ;      <BRR>
  142. ;
  143. ;02/15/81 Removed dependance on DC Hayes hardware timer so that
  144. ;         DCHAYES conditional assembly is compatible with both
  145. ;         old-style 80-103A and new-style MM100 boards.
  146. ;         Rearranged patch list to "most recent first" order.
  147. ;      Added message for invalid-drive test.
  148. ;         Added ANI 7Fh to upper case conversion test so that
  149. ;         it's not fooled by bit 7 being set.
  150. ;         Added WELUSR equate for user # containing WELCOME file.
  151. ;         Removed PTRPORT equate and changed hardcopy logic to
  152. ;         work through the BIOS printer driver. <BRR>
  153. ;
  154. ;01/22/81 Changed carrier detect routine for DC Hayes to wait for
  155. ;      15 seconds after loss of carrier to return. <DAVID KOZINN>
  156. ;
  157. ;01/17/81 Changed timing loops to use DC Hayes hardware timer
  158. ;      if present.   <DAVID KOZINN>
  159. ;
  160. ;01/16/81 Added equates and code for the DC Hayes 
  161. ;      Micromodem 100.  <DAVID KOZINN>
  162. ;
  163. ;09/23/80 Fixed bugs that prevented "bye /a" and "bye /c" from
  164. ;      working properly.  Also repaired several errors in
  165. ;      conditional assembly nesting.  By Ron Fowler
  166. ;
  167. ;09/20/80 Modified status checking during ring-wait routine to
  168. ;      use cp/m BDOS call, as suggested by Keith Petersen.
  169. ;      This should make the program more portable.  Also
  170. ;      added Bruce Ratoff's update to DCHBYE program (5.5),
  171. ;      that allows the use of bye from non-zero user areas.
  172. ;      By Ron Fowler
  173. ;
  174. ;09/19/80 Modified COM file load routine to prevent BDOS
  175. ;      overwrite if the COM file won't fit in the TPA
  176. ;      By Ron Fowler
  177. ;
  178. ;09/19/80 Added new '/' option C, which has the same affect as
  179. ;      /A, except that /C loads the com file after answering
  180. ;      the phone, while /A boots CP/M.  By Ron Fowler
  181. ;
  182. ;09/19/80 Added conditional assembly to give the operator a
  183. ;      'twit' logout key. Added conditionals for 'message
  184. ;      from operator' and 'system down in 5 minutes' keys.
  185. ;      Added front-panel selection of hard-copy log, remote
  186. ;      'black-out', and password option.  Also, if cpm/2 is
  187. ;      used, a message is printed when an unsupported user
  188. ;      area is entered.  By Ron Fowler and Dave Hardy
  189. ;
  190. ;09/19/80 Modified to prevent re-load of the com file when
  191. ;      a voice call comes in.  Reset the DMA address back
  192. ;      to 80h after the com file is loaded.  By Ron Fowler
  193. ;
  194. ;09/16/80 Added conditional assembly to allow automatic
  195. ;      loading of a com file instead of cp/m boot. Also
  196. ;      added decimal usrlog counters as conditional
  197. ;      assembly.  By Ron Fowler
  198. ;
  199. ;09/15/80 Added conditional assembly for automatic timed
  200. ;      log-out, drive and user number masking, lower
  201. ;      case query at login, and cp/m 2.x.  Thanks to
  202. ;      Bruce Ratoff for the routines (lifted from his
  203. ;      'DCHBYE54.ASM') used to implement these functions
  204. ;      NOTE: in order to implement the timed log-out, it
  205. ;      was necessary to do timing in software loops.
  206. ;      Therefore, a new equate, FASTCLK, has been added
  207. ;      to allow for 4mhz clock speeds. Also added Bruce
  208. ;      Ratoff's overrun/framing error checking when read-
  209. ;      ing the modem port.  By Ron Fowler
  210. ;
  211. ;07/16/80 Added "/R" command option to allow USRLOG
  212. ;      counters to be reset upon entry.  By Dave Hardy
  213. ;
  214. ;07/11/80 Added conditional assembly for password and
  215. ;      user log routines, and routines to print USRLOG
  216. ;      information on console after program exit.
  217. ;      By Dave Hardy
  218. ;
  219. ;07/10/80 Added code to allow auto-answer after first
  220. ;      or second ring for more reliable auto-answer
  221. ;      when using "ringback" option.  By Dave Hardy
  222. ;
  223. ;06/29/80 Added USRLOG routines to keep track of number
  224. ;      of callers, and display on front panel
  225. ;      of IMSAI (i.e. output number to port FFH).
  226. ;      By Dave Hardy
  227. ;
  228. ;06/11/80 Added routines to allow conditional assembly for
  229. ;      Morrow's Discus 2D board (all Rev's) with memory
  230. ;      mapped I/O.  Added 710 Baud rate selection option
  231. ;      at sign-on.  By Dave Hardy and Bruce Levison.
  232. ;
  233. ;01/24/80 Added routines to preserve registers when calling
  234. ;      the user's CBIOS.  Added conditional assembly for
  235. ;      callback feature.  Increased stack space to 60.
  236. ;      By Keith Petersen.
  237. ;
  238. ;09/24/79 Added routines to allow automatic multiple baud
  239. ;      rate selection, exit to CP/M from local console,
  240. ;      echo nr. of nulls selected. By Keith Petersen,
  241. ;      with thanks to Bob Mathias for suggestions.
  242. ;
  243. ;05/06/79 Added routine to allow "callback" operation so modem
  244. ;      does not answer normal voice calls.  By Robbin Hough
  245. ;      and Keith Petersen, W8SDZ.
  246. ;
  247. ;------------------------------------------------
  248. ;
  249. ;This program runs up in high RAM.  It gets there
  250. ;by being moved there when 'BYE' is typed.
  251. ;
  252. ;The program in high RAM does the following:
  253. ;
  254. ;    1.    Hangs up the phone
  255. ;    2.    Awaits ring detect, allows exit
  256. ;        to CP/M if local KBD types CTL-C
  257. ;    3.    Outputs carrier (see callback routines)
  258. ;    4.    Awaits incoming carrier going to step 1
  259. ;        if none found in 15 seconds
  260. ;    5.    Asks number of nulls (0-9)
  261. ;    6.    Types the file "WELCOME" from
  262. ;        disk, allowing CTL-C to skip it
  263. ;    7.    Asks for a password, allowing
  264. ;        5 tries to get it right.
  265. ;    8.    When password entered, if used,
  266. ;        drops into CP/M.
  267. ;    9.    Caller can leave by hanging up,
  268. ;        (any time carrier is lost, it
  269. ;        waits 15 seconds, then goes
  270. ;        back to step 1), or the caller
  271. ;        may type the program name (BYE)
  272. ;
  273. ;------------------------------------------------
  274. ;
  275. ;System equates
  276. ;
  277. FALSE    EQU    0
  278. TRUE    EQU    NOT FALSE
  279. ;
  280. CR    EQU    0DH
  281. LF    EQU    0AH
  282. MINUTES    EQU    20*60    ;CONSTANT FOR 1 MIN TIME DELAY
  283. ;
  284. ;Change the following equate to an area in your
  285. ;high memory where this program may patch itself in.
  286. ;Approximate memory requirements: 2k bytes or more,
  287. ;depending upon the options selected.  A marker has
  288. ;been placed at the end to deliberately print an error
  289. ;message during assembly in order to determine the actual
  290. ;ending address of the program.  The error message will
  291. ;not affect the assembly.  Make sure you have memory
  292. ;available up to the address shown.
  293. ;
  294. DEST0    EQU    0F800H    ;RUNNING LOCATION OF CODE
  295. ;
  296. ;Change the following to specify either DCHAYES, PMMI or systems
  297. ;with EXTERNAL  modems. Be sure to change either TPORT for PMMI or
  298. ;DATA for DCHAYES if they are not at the standard locations.
  299. ;
  300. DCHAYES    EQU    TRUE    ;TRUE FOR DC HAYES MODEM
  301. PMMI    EQU    FALSE     ;TRUE FOR PMMI MODEM
  302. MMII    EQU    FALSE    ;APPLE MICROMODEM II
  303. SMODEM    EQU    FALSE    ;DCHAYES SMARTMODEM
  304. IN8251    EQU    FALSE    ;TRUE FOR EXTERNAL AND INTEL 8251
  305. WD8250  EQU    FALSE    ;TRUE FOR EXTERNAL AND WESTERN DIGITAL 8250 
  306. PORTED    EQU    TRUE     ;TRUE USE PORTS, FALSE USE MEMORY MAP (APPLE=FALSE)
  307. ;
  308. ;If using a SmartModem then NORING should be set TRUE
  309. ;
  310. ;
  311. ;Change the following if you have a DC Hayes modem that is
  312. ;not based at 80H. All other port equates are based on this.
  313. ;
  314.     IF    DCHAYES
  315. DATA    EQU    80H    ;DC HAYES DATA PORT
  316.     ENDIF        ;DCHAYES
  317. ;
  318. ;Change the following if you have a DC Hayes Micromodem II that
  319. ;is not in slot 2.  All other port equates are based on this.
  320. ;
  321.     IF    MMII
  322. TPORT    EQU    0E0A6H    ;MMII Control port
  323.     ENDIF        ;MMII
  324. ;
  325. ;Change the following if you have a DCHayes SmartModem that
  326. ;is not in slot ???.  All other port equates are based on this.
  327. ;
  328.     IF    SMODEM AND NOT PORTED
  329. DPORT    EQU    0E0A0H    ;? What should this be? (data)
  330.     ENDIF
  331. ;
  332. ;Change the following if you have a DCHayes SmartModem that
  333. ;is not hooked up to a CompuPro serial port located at 02H
  334. ;
  335.     IF    SMODEM AND PORTED
  336. DPORT    EQU    02H    ;Base port (data)
  337.     ENDIF
  338. ;
  339. ;Change the following if you have a PMMI modem that is not
  340. ;based at 0C0H.  All other port equates are based on this.
  341. ;
  342.     IF    PMMI
  343. TPORT    EQU    0C0H    ;UART CONTROL/STATUS PORT
  344.     ENDIF
  345. ;
  346.     IF    WD8250 
  347. BASE$PORT  EQU  20H
  348.     ENDIF
  349. ;
  350. ;You will likely also want to change the password,
  351. ;located below at label 'PASSWD', and the messages
  352. ;printed at label 'WELCOME' and just above label
  353. ;'HANGUP'. The names of the welcome and com files
  354. ;are at lables 'WELFIN' and 'COMFCB' respectively. 
  355. ;
  356. ;****************************************************
  357. ;*        Option configuration section        *
  358. ;****************************************************
  359. ;
  360. ;-----------------General Options------------------
  361. ;
  362. OXGATE    EQU    TRUE     ;WANT TO RUN AN OXGATE NODE?
  363. PRINTER EQU    TRUE     ;WANT TO RETAIN LIST DEVICE?
  364. DUAL$IO EQU    TRUE     ;WANT CONSOLE & MODEM?
  365. CALLBAK EQU    FALSE    ;WANT CALLBACK FEATURE?
  366. PWRQD    EQU    FALSE     ;WANT TO USE PASSWORD?
  367. BOOTMSG    EQU    FALSE    ;TRUE IF BOOT MESSAGE
  368. FKEYS    EQU    TRUE    ;WANT SPECIAL FUNCTION KEYS
  369. USRLOG    EQU    FALSE    ;WANT TO COUNT NUMBER OF USERS?
  370. HARDLOG EQU    TRUE     ;WANT TO ECHO REMOTE KBD TO PRINTER?
  371. TIMEOUT EQU    TRUE    ;WANT AUTO LOG-OFF FOR SLEEPY CALLERS?
  372. TOVALUE EQU    5    ;MINUTES TO AUTO LOGOFF
  373. COMFILE EQU    TRUE    ;WANT TO AUTOBOOT A COM FILE?
  374. DECIMAL EQU    TRUE    ;WANT DECIMAL VALUES FOR LOGS?
  375. TRAPLC    EQU    TRUE     ;WANT TO TRAP LOWER CASE?
  376. ALLDEV    EQU    FALSE    ;RETAIN PUNCH, READER, LISTER
  377. MINICK    EQU    FALSE    ;TRUE IF MINICBBS
  378. RBBSCK    EQU    FALSE    ;TRUE IF RBBS SETS/RESETS FLAG AT 'WRTLOC'
  379. IOBYTE    EQU    0003    ;LOCATION OF INTEL IOBYTE
  380. IOVAL    EQU    0    ;INITIAL VALUE TO STORE IN IOBYTE
  381. ; 
  382. ;----------System and hardware dependent options--------------
  383. ;
  384. ZCPRT    EQU    TRUE     ;TRUE IF RUNNING NewZCPR (IN SECURE MODE)
  385. WHEEL    EQU    003EH    ;LOCATION OF NZCPR'S WHEEL FLAG
  386. BYELOW    EQU    FALSE    ;TRUE IF BYE BELOW CCP
  387. LOSER    EQU    FALSE    ;TRUE IF WARM BOOT OVERWRITE PART OF THE BIOS
  388. NORING    EQU    FALSE    ;UART RING INDICATOR NOT AVAILABLE
  389. CPM2    EQU    TRUE    ;USING CP/M 2.X?
  390. MAXUSR    EQU    15    ;SET TO 0 FOR CP/M 1.4
  391. WELUSR    EQU    14    ;USER # OF WELCOME FILE, CPM2 TRUE
  392. COMUSR    EQU     14    ;USER # OF COM FILE, CPM2 TRUE
  393. SPEED    EQU     4    ;PROCESSOR SPEED IN MHZ
  394. MAXDRV    EQU    3    ;HIGHEST DRIVE SUPPORTED
  395. IMSAI    EQU    FALSE    ;ADDS VARIOUS OPTIONS W/SENSE SW'S
  396. TWITKEY EQU    'N'-40H ;KEYCODE TO LOG-OUT A CREEP
  397. MSGKEY    EQU    'Q'-40H ;KEYCODE TO PRINT 'MESG FROM OPER:'
  398. SYSDKEY EQU    'O'-40H ;KEYCODE TO PRINT SYS DOWN MSG
  399. SENSE    EQU    0FFH    ;SENSE SWITCH PORT NUMBER IMSAI TRUE
  400. BLKOUT    EQU    FALSE    ;SWITCH TO TURN OFF REMOTE SEND IMSAI TRUE
  401. SELPASS EQU    FALSE     ;SWITCH TO REQUIRE A PASSWORD IMSAI TRUE
  402. CCSDISK    EQU    FALSE     ;SET TRUE IF CCS DISK CONTROLLER   
  403. RTC    EQU    FALSE     ;SET TRUE IF GODBOUT SS1 BOARD
  404. ;
  405.     IF CCSDISK
  406. ;
  407. DISKON    EQU    071H    ;MOTORS ON, SELECT DISK A
  408. DISK    EQU    34H    ;DISK CONTROL PORT
  409. DISKOFF    EQU    051H    ;MOTORS OFF, SELECT DISK A;
  410.     ENDIF        ;CCSDISK
  411. ;
  412. ;Assignment of front-panel options to switches:
  413. ;
  414. LOGSW    EQU    01H    ;TURN ON FOR HARDCOPY
  415. PWDSW    EQU    02H    ;TURN ON FOR 'PASSWORD' MODE
  416. BLACKSW EQU    04H    ;TURN ON TO BLACK OUT REMOTE END
  417. ENABLF    EQU    08H    ;TURN ON TO ENABLE SPL FUNC KEYS
  418. ;
  419.     IF BYELOW
  420. DEST    EQU    DEST0+3    ;KEEP ON TARGET
  421. ;
  422. ;****WARNING *** WMLOC AND OLDBD ARE SYSTEM DEPENDENT****
  423. ;WMLOC can be found in the BIOS by tracing through the
  424. ;warm boot routine with DDT until you find:
  425. ;    LXI    H,OLDBD
  426. ;    SHLD    0006
  427. ;WMLOC is the address containing the LSB of OLDBD
  428. ;
  429. WMLOC    EQU    0E04DH
  430. OLDBD    EQU    0D006H
  431. ;
  432.     ENDIF        ;BYELOW 
  433. ;
  434.     IF    NOT BYELOW
  435. DEST    EQU    DEST0
  436.     ENDIF        ;NOT BYELOW
  437. ;
  438. ;There are some cases where warm boot overwrites the
  439. ;initial bios jump table. This problem was solved for
  440. ;the Superbrain 3.0 bios by finding a warmboot call
  441. ;to high in the bios. This call is then patched by
  442. ;BYE.  The form of the call is:
  443. ;    WBCALL  CALL    WMSTRT
  444. ;
  445.     IF    LOSER
  446. ;
  447. WBCALL    EQU    0DE48H    ;CHECK THIS IN YOUR BIOS     
  448. ;
  449. ;The following location is called
  450. ;
  451. WMSTRT    EQU    0EE48H    ;CHECK THIS IN YOUR BIOS
  452. ;
  453.     ENDIF        ;LOSER
  454. ;            
  455. ;****************************************************
  456. ;*     End of option configuration section        *
  457. ;****************************************************
  458. ;
  459. ;All modem I/O and control are here
  460. ;
  461. ;
  462. ;************ D.C. Hayes modem I/O area ************
  463. ;
  464.     IF    DCHAYES
  465. ;
  466. ;The DCHayes has an annoying tendancy to think that the phone company's
  467. ;off-hook tone sets off the modem, so we have to hack up special timeout
  468. ;equates.
  469. CWAIT    EQU    8     ;SECONDS TO WAIT FOR INITIAL CARRIER
  470. CLOSS    EQU    5    ;SECONDS TO WAIT IF WE LOOSE CARRIER
  471. ;
  472. ;Port equates
  473. ;
  474. DPORT    EQU    DATA    ;DATA PORT
  475. STATUS    EQU    DATA+1
  476. RPORT    EQU    STATUS    ;MODEM STATUS PORT
  477. CR1    EQU    DATA+1
  478. CR2    EQU    DATA+2
  479. CR3    EQU    DATA+3
  480. ;
  481. ;Bit functions
  482. ;
  483. ;    Status register
  484. ;
  485. RRF    EQU    1    ;RECEIVE REGISTER FULL
  486. TRE    EQU    2    ;TRANSMITTER HOLDING REGISTER EMPTY
  487. PE    EQU    4    ;PARITY ERROR
  488. FE    EQU    8    ;FRAMING ERROR
  489. OE    EQU    10H    ;OVERRUN ERROR
  490. TMR    EQU    20H    ;TIMER STATUS (MM100 ONLY)
  491. CD    EQU    40H    ;CARRIER PRESENT
  492. RI    EQU    80H    ;NOT RING INDICATOR (LOW TRUE)
  493. P2RDET    EQU    RI    ;SAME AS ABOVE
  494. ;
  495. ;    Control register 1 (CR1)
  496. ;
  497. EPE    EQU    1    ;EVEN PARITY ENABLE
  498. LS1    EQU    2    ;WORD LENGTH SELECT BIT 1
  499. LS2    EQU    4    ;WORD LENGTH SELECT BIT 2
  500. SBS    EQU    8    ;STOP BITS
  501. PI    EQU    10H    ;PARITY INHIBIT
  502. TMIE    EQU    20H    ;TIMER INTERRUPTS ENABLE (MM100 ONLY)
  503. ;
  504. ;    Control register 2 (CR2)
  505. ;
  506. BRS    EQU    1    ;BAUD RATE CONTROL
  507. TXE    EQU    2    ;TRANSMIT CARRIER ENABLE
  508. MS    EQU    4    ;MODE (0=ANSWER 1=ORIGINATE)
  509. BRK    EQU    8    ;SEND BREAK
  510. ST    EQU    10H    ;SELF TEST
  511. TIE    EQU    20H    ;TRANSMITTER INTERRUPT ENABLE
  512. RIE    EQU    40H    ;RECEIVER INTERRUPT ENABLE (MM100 ONLY)
  513. OH    EQU    80H    ;OFF-HOOK
  514. ;
  515.     ENDIF        ;DCHAYES
  516. ;
  517. ;************ DCHayes MM ][ Code **************
  518. ;
  519.     IF    MMII
  520. ;
  521. ;MMII Modem address equates
  522. ;
  523. TPORT    EQU    TPORT    ;CONTROL/STATUS PORT
  524. DPORT    EQU    TPORT+1    ;DATA PORT
  525. RPORT    EQU    TPORT-1    ;BAUD RATE/MODEM STATUS PORT
  526. CPORT    EQU    TPORT-1    ;MODEM CONTROL
  527. RPORT1    EQU    TPORT    ;STATUS
  528. ;
  529. ;Switch hook and modem commands, output to TPORT
  530. ;
  531. P0BYE    EQU    0    ;ON HOOK OR DIALING BREAK
  532. P0ORIG    EQU    8EH    ;OFF HOOK ORIGINATE
  533. P0ANSW    EQU    8AH    ;ANSWER PHONE
  534. P0TSB    EQU    8    ;2 STOP BITS
  535. P0EI    EQU    20H    ;ENABLE INTERRUPTS
  536. P0NORM    EQU    15H    ;8 BITS, NO PARITY
  537. P0110    EQU    11H    ;SAME W/2 STOP BITS
  538. ;
  539. ;Modem status input from RPORT
  540. ;
  541. P2RDET    EQU    80H    ;RING DETECT
  542. P2CTS    EQU    4    ;CLEAR TO SEND
  543. ;
  544. ;MMII Modem status masks
  545. ;
  546. P0TBMT    EQU    2    ;XMIT BUFFER EMPTY
  547. P0DAV    EQU    1    ;DATA AVAILABLE
  548. P0RPE    EQU    40H    ;PARITY ERROR
  549. P0ORUN    EQU    20H    ;OVERRUN
  550. P0FERR    EQU    10H    ;FRAMING ERROR
  551. ;
  552. ;Baud rate divisors
  553. ;
  554. B110    EQU    0    ;110 BAUD
  555. B300    EQU    1    ;300 BAUD
  556. ;
  557.     ENDIF        ;MMII
  558. ;
  559. ;
  560. ;DCHayes Smartmodem data area
  561. ;
  562.     IF    SMODEM
  563. MSPORT    EQU    DPORT+1        ;Modem Status port
  564. ;
  565. P2CTS    EQU    08H        ;Clear to send bit
  566. P0TBMT    EQU    01H        ;Transmit buffer empty
  567. P0DAV    EQU    02H        ;Character available
  568.     ENDIF
  569. ;
  570. ;
  571. ;************ PMMI modem I/O area ************
  572. ;
  573.     IF    PMMI
  574. ;
  575. ;PMMI modem port equates (TPORT previously done)
  576. ;
  577. DPORT    EQU    TPORT+1 ;DATA PORT
  578. RPORT    EQU    TPORT+2 ;RATE GEN/MODEM STATUS
  579. CPORT    EQU    TPORT+3 ;MODEM CONTROL
  580. ;
  581. ;Switch hook and modem commands, output to TPORT (port 0)
  582. ;
  583. P0BYE    EQU    0    ;ON HOOK, OR DIALING BREAK
  584. P0ORIG    EQU    1    ;OFF HOOK, ORIG.
  585. P0ANSW    EQU    2    ;ANSWER PHONE
  586. P08BIT    EQU    0CH    ;8 DATA BITS
  587. P0NOPY    EQU    10H    ;NO PARITY
  588. P0EPS    EQU    20H    ;EVEN PARITY SELECT
  589. P0TSB    EQU    40H    ;2 STOP BITS
  590. P0EI    EQU    80H    ;ENABLE INTERRUPTS
  591. P0NORM    EQU    P08BIT+P0NOPY        ;NORMAL 8 BITS, NO PARITY
  592. P0110    EQU    P08BIT+P0NOPY+P0TSB ;SAME W/2 STOP BITS
  593. ;
  594. ;Modem status, input on RPORT (port 3)
  595. ;
  596. P2DTD    EQU    1    ;DIAL TONE DETECT
  597. P2RDET    EQU    2    ;RING DETECT
  598. P2CTS    EQU    4    ;CTS (CARRIER DETECT)
  599. P2RXBRK EQU    8    ;RECEIVE BREAK
  600. P2CONN    EQU    10H    ;CONNECTED? (0=YES, 1=MODEM CHIP HUNG UP)
  601. P2TMPUL EQU    80H    ;TIMER PULSES (40% UP CYCLE)
  602. ;
  603. ;Timer rate selection
  604. ;
  605. TRATE    EQU    250    ;VALUE FOR .1 SEC
  606. ;
  607. ;PMMI modem status masks
  608. ;
  609. P0TBMT    EQU    1    ;XMIT BUFF EMPTY
  610. P0DAV    EQU    2    ;DATA AVAILABLE
  611. P0TEOC    EQU    4    ;TEST END OF CHAR
  612. P0RPE    EQU    8    ;REC'D PARITY ERR
  613. P0ORUN    EQU    10H    ;OVERRUN
  614. P0FERR    EQU    20H    ;FRAMING ERROR
  615. ;
  616. ;Baud rate divisors
  617. ;
  618. B110    EQU    142    ;110 BAUD
  619. B300    EQU    52    ;300 BAUD
  620. B450    EQU    35    ;450 BAUD
  621. B600    EQU    26    ;600 BAUD
  622. B710    EQU    22    ;710 BAUD
  623. ;
  624.     ENDIF        ;PMMI
  625. ;
  626. ;************ EXTERNAL MODEM I/O AREA ************
  627. ;
  628.     IF    IN8251
  629. ;
  630. ;True if uart is Intel 8251 or equivalent
  631. ;
  632. DPORT    EQU    58H    ;DATA PORT
  633. CPORT    EQU    59H    ;CONTROL PORT
  634. SPORT    EQU    CPORT    ;STATUS PORT
  635. BPORT    EQU    60H    ;BAUD RATE PORT
  636. RPORT    EQU    69H    ;RING INDICATOR PORT
  637. ;
  638. ;The following are CPORT commands
  639. ;
  640. RSTINS    EQU    42H    ;RESET USART AND SEND DTR
  641. MODINS1    EQU    4EH    ;8 BITS, NO PARITY, 1 STOP BIT, 16X BAUD RATE
  642. MODINS2    EQU    0CEH    ;8 BITS, NO PARITY, 2 STOP BITS, 16X BAUD RATE
  643. ONINS    EQU    17H    ;RESET ERROR FLAGS, SEND DTR, ENABLE RECEIVE
  644.             ;AND TRANSMIT
  645. OFFINS    EQU    10H    ;DROP DTR, DISABLE RECEIVE AND TRANSMIT
  646. ;
  647. ;The following are SPORT status masks
  648. ;
  649. TRNRDY    EQU    01H    ;TRANSMITER EMPTY
  650. RCVRDY    EQU    02H    ;DATA AVAILABLE
  651. PERR    EQU    08H    ;PARITY ERROR
  652. ORERR    EQU    10H    ;OVERRUN ERROR
  653. FRERR    EQU    20H    ;FRAMING ERROR
  654. TOERR    EQU    ORERR + FRERR    ;OVERRUN PLUS FRAMING ERROR
  655. DSR    EQU    80H    ;DATA SET READY
  656. ;
  657. ;The following are baud rates for BPORT. The upper 4 bits are
  658. ;for the modem port while the lower four are for the auxiliary
  659. ;port.
  660. ;
  661. BD110    EQU    27H    ;110 BAUD
  662. BD300    EQU    57H    ;300 BAUD
  663. BD1200    EQU    77H    ;1200 BAUD
  664. ;
  665. ;Ring indicator port mask
  666. ;
  667. RI    EQU    40H    ;NOT RING INDICATOR (LOW TRUE)
  668. P2RDET    EQU    RI
  669. ;
  670.     ENDIF        ;IN8251
  671. ;
  672. ;****************WD8250  I/O AREAS*************************
  673. ;True if usar is Western Digital 8250 or equivilent.
  674. ;
  675.     IF    WD8250
  676. ; 
  677. DPORT    EQU    BASE$PORT    ;DATA PORT
  678. LPORT    EQU    BASE$PORT+3    ;LINE CONTROL
  679. CPORT    EQU    BASE$PORT+4    ;MODEM CONTROL
  680. SPORT    EQU    BASE$PORT+5    ;LINE STATUS PORT
  681. MSPORT    EQU    BASE$PORT+6    ;MODEM STATUS PORT
  682. RPORT    EQU    BASE$PORT+6    ;RING INDICATOR PORT
  683. ;
  684. *****************LINE STATUS MASKS************************
  685. ;
  686. P0TBMT    EQU    20H    ;XMIT BUFFER EMPTY
  687. P0DAV    EQU    01H    ;DATA AVAILABLE
  688. P0RPE    EQU    04H    ;PARITY ERROR
  689. P0ORUN    EQU    02H    ;OVERRUN ERROR
  690. P0FERR    EQU    08H    ;FRAMING ERROR
  691. P0BRK    EQU    10H    ;BREAK DETECT
  692. ;
  693. ;****************MODEM STATUS MASKS***********************
  694. ;
  695. P2DSR    EQU    20H    ;DATA SET READY
  696. P2CTS    EQU    080H    ;CARRIER DETECT
  697. P2RDET    EQU    040H    ;RING DETECT
  698. ;
  699. ;******************BAUD RATE DIVISORS*********************
  700. ;
  701. BR300LS    EQU    000H    ;300 BAUD
  702. BR300MS    EQU    001H    
  703. BR450LS    EQU    0ABH    ;450 BAUD
  704. BR450MS    EQU    000H    
  705. BR600LS    EQU    080H    ;600 BAUD
  706. BR600MS    EQU    000H    
  707. BR120LS    EQU    040H    ;1200 BAUD
  708. BR120MS    EQU    000H
  709. ;
  710. ;*******************MODEM CONTROL****************************
  711. ;
  712. MCDTR    EQU    01H    ;
  713. MCRTS    EQU    02H
  714. MCOUT1    EQU    04H
  715. MCOUT2    EQU    08H
  716. ;
  717. ;*********************LINE CONTROL****************************
  718. ;
  719. LCWLS0    EQU    01H
  720. LCWLS1    EQU    02H
  721. LCSTB    EQU    04H
  722. LCPEN    EQU    08H
  723. LCPES    EQU    10H
  724. LCSPS    EQU    20H
  725. LCBRK    EQU    40H
  726. LCDLAB    EQU    80H
  727.     ENDIF        ;WD8250
  728. ;
  729. ;---------------------------------------------------------
  730. ;
  731.     ORG    100H
  732. ;
  733.     IF     BYELOW    
  734. ;This code allow running below ccp and using programs such as
  735. ;Mbasic or Typesq ect....
  736. ;
  737.     LXI    H,OLDBD    ;OLD LOCATION STORED IN 6 AND 7 FOR
  738.             ;JUMP FROM BDOS CALL
  739.     SHLD    DEST-2    ;STORE IT JUST ABOVE BYE
  740.     LXI    H,DEST-3 ;POINT TO THREE BYTE ABOVE 
  741.              ;NORMAL BYE
  742.     MVI    M,0C3H    ;PUT A JUMP THERE
  743.     SHLD    0006H    ;STORE DEST-3 FOR BDOS JUMP
  744.     SHLD    WMLOC    ;STORE DEST-3 IN YOUR BIOS
  745. ;
  746.     ENDIF        ;BYELOW
  747. ;
  748. ;Move modem interface program up to high RAM and jump to it
  749. ;
  750. MOVEUP    LXI    B,PEND-START+1        ;NUMBER OF BYTES TO MOVE
  751.     LXI    H,DEST+PEND-START+1 ;END OF MOVED CODE
  752.     LXI    D,SOURCE+PEND-START ;END OF SOURCE CODE
  753. ;
  754. MVLP    LDAX    D    ;GET BYTE
  755.     DCX    H    ;BUMP POINTERS
  756.     MOV    M,A    ;NEW HOME
  757.     DCX    D
  758.     DCX    B    ;BUMP BYTE COUNT
  759.     MOV    A,B    ;CHECK IF ZERO
  760.     ORA    C
  761.     JNZ    MVLP    ;IF NOT, DO SOME MORE
  762. ;
  763.     PUSH    H    ;SAVE FOR LATER JUMP
  764.     MVI    A,0C3H    ;CLEAR ANY TRAPS SO SYSOP..
  765.     STA    0    ;CAN USER "BYE /A"
  766.     XRA    A    ;NEXT WARMBOOT TO USR0/DRV A
  767.     STA    4
  768.     MVI    C,14    ;MAKE DRIVE A DEFAULT
  769.     MOV    E,A    ;LOG-IN DRIVE CP/M FUNCTION
  770.            CALL    BDOS                                     
  771. ;
  772.     IF    CPM2    ;SET USER 0
  773.     MVI    C,32    ;GET/SET USR CP/M FUNCTION
  774.     MVI    E,WELUSR
  775.     CALL    BDOS
  776.     ENDIF        ;CPM2
  777. ;
  778.     RET        ;TO ADRS PUSHED ABOVE
  779. ;
  780. ;
  781. SOURCE    EQU    $    ;BOUNDARY MEMORY MARKER
  782. ;
  783. OFFSET    EQU    DEST-SOURCE ;RELOC AMOUNT
  784. ;
  785. ;-----------------------------------------------;
  786. ;    The following code gets moved        ;
  787. ;    to high RAM located at "DEST",        ;
  788. ;        where it is executed.        ;
  789. ;-----------------------------------------------;
  790. ;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  791. ;XX   C A U T I O N :  If modifying anything    XX
  792. ;XX    in this program from here on:        XX
  793. ;XX    A-L-L  labels must be of the form:    XX
  794. ;XX    LABEL    EQU    $+OFFSET        XX
  795. ;XX    in order that the relocation to high      XX
  796. ;XX    RAM work successfully.  Forgetting to    XX
  797. ;XX    specify '$+OFFSET' will cause the pro-    XX
  798. ;XX    gram to JMP into whatever is currently    XX
  799. ;XX    in low memory, with unpredictable    XX
  800. ;XX    results.  Be careful....        XX
  801. ;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  802. ;
  803. START    EQU    $+OFFSET
  804.     JMP    START0    ;HOP OVER FIXED VECTORS
  805. ;
  806. ;Cold boot vector ends up here. Our cold boot routine
  807. ;consists of a jump to the warm boot routine. We are
  808. ;defined to consist of only this jump, with a jump
  809. ;to PRNLOG immediately after this jump, and other
  810. ;modifiable variables after that. By doing this,
  811. ;a trivial program can be written that calculates
  812. ;where PRNLOG is thru the warm boot vector at 0001H,
  813. ;then calls PRNLOG, allowing remote users to get the
  814. ;BYE log printed. Such a program, easily entered
  815. ;with DDT, is as follows:
  816. ;
  817. ;    LHLD    0001H    ;PT TO COLD BOOT VECTOR + 3
  818. ;    DCX    H    ;PT TO VECTOR HIGH BYTE
  819. ;    MOV    D,M    ;GET THAT IN D
  820. ;    DCX    H    ;PT TO VECTOR LOW BYTE
  821. ;    MOV    E,M    ;GET THAT IN E
  822. ;    LXI    H,3    ;CALC PRNLOG ADDRESS
  823. ;    DAD    D    ; BY ADDING TO COLD BOOT ADDRESS
  824. ;    PCHL        ;GO PRINT LOG INFO, THEN
  825. ;            ; RETURN TO CCP
  826. ;
  827. ;A similar calculation can be used to determine
  828. ;the locations of the MXUSR, MXDRV, and TOVAL
  829. ;variables to change them on the fly for special
  830. ;users. Since this will often be done by a
  831. ;BASIC signon program, the following sequence
  832. ;of code is recommended:
  833. ;
  834. ;  10 A=PEEK(2)*256+PEEK(1)-2 'Pt to cold boot address
  835. ;  20 A=PEEK(A+1)*256+PEEK(A)+6 'Get address of MXUSR
  836. ;  30 POKE A,8  'Set MXUSR to 8, allows 0-8
  837. ;  40 POKE A+1,4 'Set MXDRV to 4, allows A-D
  838. ;  50 POKE A+2,5 'Set TOVAL to 5, allows 5 min of inactivity
  839. ;
  840. ;The values POKE'ed will be reset to the assembly
  841. ;values of MAXUSR, MAXDRV and TOVALUE respectively
  842. ;the next time BYE answers the phone.
  843. ;
  844. ;The following will test whether bye is active and then set
  845. ;the flag at WRTLOC.
  846. ;
  847. ;  10 A=PEEK(2)*256+PEEK(1)-2
  848. ;  20 A=PEEK(A+1)*256+PEEK(A)+9 'Get Address of WRTLOC
  849. ;  30 IF CHR$(PEEK(A+1))+SHR$(PEEK(A+2))+CHR$(PEEK(A+3))<>"BYE" THEN
  850. ;  40 POKE A,&HFF 'SET FLAG FOR WRITE IN PROGRESS
  851. ;
  852. ;The routine on line 30 should be used in RBBS so that when RBBS is 
  853. ;running locally nothing will be poked into the bios.
  854. ;   
  855. MCBOOT    EQU    $+OFFSET
  856.     JMP    MBOOT    ;OFF TO WARM BOOT
  857.     JMP    PRNLOG    ;GO PRINT OUT ITEMS OF INTEREST
  858. ;
  859. ;Variables follow in a predefined order that can
  860. ;be manipulated by a passworded or other program
  861. ;to give special users different capabilities.
  862. ;
  863. MXUSR    EQU    $+OFFSET
  864.     DB    MAXUSR    ;RUNTIME MAX USER # (UNUSED
  865.             ; UNDER CP/M 1.4)
  866. ;
  867. MXDRV    EQU    $+OFFSET
  868.     DB    MAXDRV    ;RUNTIME # DRIVES ACCESSABLE
  869. ;
  870. TOVAL    EQU    $+OFFSET
  871.     DB    TOVALUE    ;RUNTIME # INACTIVE MINUTES
  872.             ; BEFORE AUTO LOGOFF
  873. NULLS    EQU    $+OFFSET
  874.     DB    5    ;INITIAL NUMBER OF NULLS
  875. ;
  876. ULCSW    EQU    $+OFFSET
  877.     DB    0    ;UPPER CASE ONLY SWITCH
  878. ;
  879. LFEEDS    EQU    $+OFFSET
  880.     DB    0    ;LINE FEED SWITCH
  881. ;    
  882. WRTLOC    EQU    $+OFFSET
  883.     DB    0    ;LOCATION OF FLAG FOR RBBS TO 
  884.             ;SET WHILE DOING DISK WRITES
  885. ;
  886. HARDON    EQU    $+OFFSET
  887.     DB    1    ;DEFAULT HARDLOG ON (IF EQUATE IS TRUE, OTHERWISE
  888.             ;THIS IS JUST A DUMMY BIT TO HOLD SPACE SO SMART
  889.             ;PROGRAMS WON'T SCREW UP WHEN THEY POKE UP THESE
  890.             ;FLAGS
  891. ;
  892. ;Program version number message.
  893. ;
  894. VMSG    EQU    $+OFFSET
  895.     DB    'BYE version 7.9 as of 04/12/82',CR,LF
  896.     IF    SMODEM
  897.     DB    'Make sure switch 1 is down and switch 6 is up.',CR,LF
  898.     ENDIF    ;SMODEM
  899.     DB    '$'
  900.  
  901.  
  902. ;
  903. ;----------------------------------------------
  904. ;This is the official start of the BYE program.
  905. ;----------------------------------------------
  906. ;
  907. ;If carrier lost, hang up, await ring.
  908. ;Otherwise, say goodbye, and hang up
  909. ;
  910. START0    EQU    $+OFFSET
  911. ;
  912.     XRA    A    ;GET 0
  913.     STA    LOSTFLG ;SHOW NO CARR. LOST
  914. ;
  915.     IF    MINICK
  916. ;
  917. ;Set MINICK to true if you use MINICBBS and want to take
  918. ;advantage of its feature which can prevent the modem
  919. ;from hanging up if the caller should happen to discon-
  920. ;nect during a file update. MINICBBS sets the high-order 
  921. ;bit of IOBYTE to (address 0003) to indicate a file update
  922. ;is in progress.
  923. ;
  924.     MVI    A,IOVAL
  925.     STA    IOBYTE
  926. ;
  927.     ENDIF        ;MINICK
  928. ;
  929. ;Don't allow a remote user to do 'BYE /A'
  930. ;
  931.     IF    DCHAYES
  932.     IN    STATUS
  933.     ANI    CD    ;CHECK CARRIER DETECT
  934.     JNZ    GOODBY    ;SAY GOODBYE IF REMOTE
  935.     ENDIF        ;DCHAYES
  936. ;
  937.     IF    MMII
  938.     LDA    RPORT1    ;AS ABOVE, FOR MMII
  939.     ANI    P2CTS
  940.     JZ    GOODBY
  941.     ENDIF    ;MMII
  942. ;
  943.     IF    SMODEM AND PORTED
  944.     IN    MSPORT    ;GET STATUS
  945.     ENDIF
  946. ;
  947.     IF    SMODEM AND NOT PORTED
  948.     LDA    MSPORT    ;GET STATUS
  949.     ENDIF
  950. ;
  951.     IF    SMODEM
  952.     ANI    P2CTS    ;Clear to send?
  953.     JZ    GOODBY
  954.     ENDIF    ;SMODEM
  955. ;
  956.     IF    PMMI
  957.     IN    RPORT    ;AS ABOVE, FOR PMMI MODEM
  958.     ANI    P2CTS    ;CD DEDUCED FROM CTS
  959.     JZ    GOODBY
  960.     ENDIF        ;PMMI
  961. ;
  962.     IF    IN8251
  963.     IN    SPORT
  964.     ANI    DSR    ;CHECK CARRIER DETECT
  965.     JNZ    GOODBY    ;GOODBYE IF REMOTE
  966.     ENDIF        ;IN8251
  967. ;
  968.     IF    WD8250 
  969.     IN    MSPORT
  970.     ANI    P2CTS
  971.     JNZ    GOODBY
  972.     ENDIF        ;WD8250
  973. ;
  974. ;Identify version of program
  975. ;
  976.     MVI    C,PRINTF
  977.     LXI    D,VMSG
  978.     CALL    BDOS
  979. ;
  980. ;Check for /A option on command - request to
  981. ;go immediately into answer mode
  982.     LXI    H,FCB+1 ;TO OPTION
  983.     MOV    A,M
  984.     CPI    '/'    ;OPTION?
  985.     JNZ    HANGUP
  986. ;Got an option - validate it
  987.     INX    H    ;TO OPTION BYTE
  988.     MOV    A,M    ;GET IT
  989.     STA    OPTION    ;MIGHT NEED LATER
  990.     CPI    'A'    ;ANSWER?
  991.     JZ    ANSWER
  992. ;
  993.     IF    COMFILE
  994.     CPI    'C'
  995.     JZ    ANSWER
  996.     ENDIF        ;COMFILE
  997. ;
  998.     IF    USRLOG    ;CHECK FOR RESET OF COUNTERS
  999.     CPI    'R'
  1000.     CZ    RESET
  1001.     ENDIF        ;USRLOG
  1002. ;
  1003.     JMP    HANGUP    ;WE KNOW IT'S LOCAL, SO SKIP CALL TO CARCK
  1004. ;
  1005. ;No option, or invalid one
  1006. ;
  1007. NOSLASH EQU    $+OFFSET
  1008.     CALL    CARCK    ;SIGNED OFF W/THIS PROG?
  1009.     JC    HANGUP    ;NOBODY THERE
  1010. ;
  1011. GOODBY    EQU    $+OFFSET
  1012.     CALL    ILPRT    ;PRINT THIS MSG:
  1013.     DB    CR,LF,'Good-bye, call again...'
  1014.     IF     RTC
  1015.     DB    CR,LF,CR,LF,'Off at ',0
  1016.     CALL    TIME
  1017.     CALL    ILPRT
  1018.     ENDIF        ;RTC
  1019. ;
  1020.     DB    CR,LF,CR,LF,0
  1021.     CALL    UNPATCH ;UNDO BIOS PATCHES
  1022. ;
  1023. ;Nobody there, or we are done, so hang up
  1024. ;
  1025. HANGUP    EQU    $+OFFSET
  1026.     LXI    SP,STACK ;SET UP LOCAL STACK
  1027.     XRA    A     ;FORCE NEXT WARMBOOT TO USER 0
  1028.     STA    4     ;AND DRIVE A
  1029. ;
  1030.     IF CCSDISK
  1031. ;
  1032.     CALL DSKOFF    ;SHUT DOWN THE DRIVES
  1033. ;
  1034.     ENDIF    ;CCSDISK
  1035. ;
  1036.     MVI    C,14     ;MAKE DRIVE A DEFAULT
  1037.     MOV    E,A
  1038.     CALL    BDOS
  1039.     MVI    A,' '     ;DON'T ALLOW OPTIONS..
  1040.     STA    OPTION     ;..AFTER 1 "BYE / <ANYTHING>"
  1041. ;
  1042.     IF    CPM2 AND COMFILE
  1043.     MVI    C,32     ;GET/SET USER CODE
  1044.     MVI    E,COMUSR ;LOCATION OF OUR COMFILE
  1045.     CALL    BDOS
  1046.     ENDIF         ;CPM2 AND COMFILE
  1047. ;
  1048.     IF    COMFILE
  1049.     CALL    LODCOM    ;LOAD THE COM FILE
  1050.     ENDIF        ;COMFILE
  1051. ;
  1052. ;
  1053. HANGUP2 EQU    $+OFFSET
  1054. ;
  1055. ;Clear DTR causing phone to hang up
  1056. ;
  1057.     IF    DCHAYES
  1058.     XRA    A    ;GET A ZERO
  1059.     OUT    CR2    ;WRITE TO CR2, CAUSING HANGUP
  1060.     ENDIF        ;DCHAYES
  1061. ;
  1062.     IF    MMII
  1063.     XRA    A    ;CLEAR A
  1064.     STA    TPORT    ;RESET ORIG/ANSW
  1065.     STA    CPORT    ;HANG UP FERN
  1066.     ENDIF    ;MMII
  1067. ;
  1068.     IF    SMODEM
  1069.     CALL    SMINIT    ;WAIT 1 SECOND, SEND "+++", WAIT ONE SECOND
  1070.     CALL    SMSEND    ;SEND THE HANGUP CODES AND NORMALIZE MODEM
  1071.     DB    'AT H0 Z',CR,0
  1072. ;
  1073.     CALL    SMINIT    ;WAIT 1 SECOND, SEND "+++", WAIT ONE SECOND
  1074.     CALL    SMSEND    ;SEND THE PROPER CODES SO WE CAN RUN REMOTE
  1075.     DB    'AT E0 F0 M0 Q1 V1 S0=1',CR,0
  1076.     ENDIF    ;SMODEM
  1077. ;
  1078.     IF    PMMI
  1079.     XRA    A    ;GET DISCONNECT VALUE
  1080.     OUT    TPORT    ;RESET ORIG/ANSW
  1081.     OUT    CPORT    ;TURN OFF DTR, DO BREAK
  1082.     ENDIF        ;PMMI
  1083. ;
  1084.     IF    IN8251
  1085.     MVI    A,OFFINS    ;CLEAR DTR
  1086.     OUT    CPORT    ;CAUSING HANGUP
  1087.     PUSH    B    ;PRESERVE IN CASE WE NEED IT
  1088.     MVI    B,150    ;15 SECOND DELAY
  1089. ;
  1090. OFFTI    EQU    $+OFFSET
  1091.     CALL    DELAY    ;0.1 SECOND DELAY
  1092.     DCR    B
  1093.     JNZ    OFFTI    ;KEEP LOOPING UNTIL FINISHED
  1094.     POP    B    ;RESTORE B
  1095.     MVI    A,ONINS    ;TURN DTR ON ALLOWING MODEM TO ANSWER PHONE
  1096.     OUT    CPORT
  1097.     ENDIF        ;IN8251
  1098. ;
  1099.     IF    WD8250 
  1100.     XRA    A    ;SHUT OFF DTR & RTS
  1101.     OUT    CPORT    ;SHUT OFF MODEM
  1102.     ENDIF        ;WD8250
  1103. ;
  1104.     IF    WD8250 AND NORING
  1105. ;
  1106.     PUSH    B    ;PRESERVE IT IF WE NEED IT
  1107.     MVI    B,150    ;15 SEC DELAY
  1108.  
  1109. OFFTI    EQU    $+OFFSET
  1110.     CALL    DELAY    ;0.1 SEC DELAY
  1111.     DCR    B    
  1112.     JNZ    OFFTI    ;KEEP LOOPING UNTIL DONE
  1113.     POP    B    ;RESTORE B
  1114.     MVI    A,MCDTR+MCRTS    ;TURN ON DTR/RTS 
  1115.     OUT    CPORT
  1116.     ENDIF        ;WD8250 
  1117. ;
  1118.     MVI    A,0C3H    ;CLEAR ANY TRAPS..
  1119.     STA    0    ;..LEFT FROM COM FILE
  1120. ;
  1121. ;Await ringing
  1122. ;
  1123. RINGWT    EQU    $+OFFSET
  1124. ;
  1125. ;Check local keyboard for CTL-C exit request.
  1126. ;NOTE: Must do input via BDOS because CBIOS patches
  1127. ;are not done until call comes in.
  1128. ;
  1129.     CALL    UCSTS
  1130.     ANI    7FH    ;STRIP PARITY BIT
  1131.     CPI    'C'-40H ;CONTROL C?
  1132.     CZ    USRCHK    ;Check for exit if so
  1133. ;
  1134.     IF    NORING
  1135.     IN    MSPORT
  1136.     ANI    P2CTS    ;GOT CARRIER
  1137.     JNZ    ANSWER
  1138.     JMP    RINGWT    ;KEEP CHECKING
  1139.     ENDIF        ;NORING
  1140. ;
  1141. RINGW2    EQU    $+OFFSET
  1142. ;
  1143.     IF    NOT PORTED
  1144.     LDA    RPORT    ;GET STATUS
  1145.     ENDIF
  1146. ;
  1147.     IF    PORTED
  1148.     IN    RPORT    ;GET THE STATUS
  1149.     ENDIF
  1150. ;
  1151.     ANI    P2RDET    ;RINGING?
  1152. ;
  1153.     IF    WD8250 OR IN8251
  1154.     JZ    RINGWT    ;NO, WAIT
  1155.     ENDIF    ;WD8250 OR IN8251
  1156. ;
  1157.     IF    NOT (WD8250 OR IN8251)
  1158.     JNZ    RINGWT    ;NO, WAIT
  1159.     ENDIF    ;NOT (WD8250 OR IN8251)
  1160. ;
  1161. ;The phone may be ringing.  Wait .1 sec and look
  1162. ;again to make sure it isn't just relay bounce
  1163.     CALL    DELAY    ;.1 SEC DELAY FOR DEBOUNCE
  1164. ;
  1165.     IF    NOT PORTED
  1166.     LDA    RPORT    ;GET STATUS
  1167.     ENDIF
  1168. ;
  1169.     IF    PORTED
  1170.     IN    RPORT    ;GET STATUS
  1171.     ENDIF
  1172. ;
  1173.     ANI    P2RDET    ;STILL RINGING?
  1174. ;
  1175.     IF    WD8250 OR IN8251
  1176.     JZ    RINGWT    ;NO, IT WAS RELAY BOUNCE
  1177.     ENDIF    ;WD8250 OR IN8251
  1178. ;
  1179.     IF    NOT (WD8250 OR IN8251)
  1180.     JNZ    RINGWT    ;NO, IT WAS A RELAY BOUNCE
  1181.     ENDIF    ;NOT (WD8250 OR IN8251)
  1182. ;
  1183. ;The phone is definitely ringing, now wait until ring is finished
  1184. ;
  1185. ENDRING EQU    $+OFFSET
  1186.     CALL    DELAY    ;.1 SEC DELAY FOR DEBOUNCE
  1187. ;
  1188.     IF    NOT PORTED
  1189.     LDA    RPORT    ;GET STATUS
  1190.     ENDIF
  1191. ;
  1192.     IF    PORTED
  1193.     IN    RPORT    ;GET STATUS
  1194.     ENDIF
  1195. ;
  1196.     ANI    P2RDET    ;STILL RINGING?
  1197. ;
  1198.     IF    WD8250 OR IN8251
  1199.     JNZ    ENDRING ;WAIT UNTIL RING FINISHED
  1200.     ENDIF    ;WD8250 OR IN8251
  1201. ;
  1202.     IF    NOT (WD8250 OR IN8251)
  1203.     JZ    ENDRING    ;WAIT UNTIL RING FINISHED
  1204.     ENDIF    ;NOT (WD8250 OR IN8251)
  1205. ;
  1206.     IF    CALLBAK ;NEXT ROUTINES IMPLEMENT CALLBAK
  1207. ;
  1208. ;This routine minimizes the computer's interference
  1209. ;with normal household phone use by having computer
  1210. ;folk dial, let the phone ring once, hang up and 
  1211. ;then dial again.  When the phone rings only once it
  1212. ;alerts the computer which then waits for and answers
  1213. ;any ring which occurs within the next 40 seconds.
  1214. ;
  1215.     MVI    L,45    ;DELAY 4.5 SECONDS FOR NEXT RING
  1216. ;
  1217. WAITNX    EQU    $+OFFSET
  1218.     CALL    DELAY    ;WAIT .1 SECONDS
  1219.     DCR    L    ;MORE TO GO?
  1220.     JNZ    WAITNX    ;YES, LOOP
  1221.     ENDIF    ;CALLBAK
  1222. ;
  1223.     IF    CALLBAK    AND NOT PORTED
  1224.     LDA    RPORT
  1225.     ENDIF    ;CALLBAK AND MMII
  1226. ;
  1227.     IF    CALLBAK AND PORTED
  1228.     IN    RPORT    ;GET THE STATUS
  1229.     ENDIF    ;CALLBAK AND NOT MMII
  1230. ;
  1231.     IF    CALLBAK AND (WD8250 OR IN8251)
  1232.     ANI    P2RDET
  1233.     JZ    EXPECT    ;NO?...ITS FOR ME!
  1234.     ENDIF
  1235. ;
  1236.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1237.     ANI    P2RDET
  1238.     JNZ    EXPECT    ;NO?...ITS FOR ME!
  1239.     ENDIF
  1240. ;
  1241.     IF    CALLBAK
  1242. ;
  1243. ;If second ring, then check for third ring, in case
  1244. ;caller's phone exchange not synch'ed with computer's
  1245. ;
  1246. ENDRNG2 EQU    $+OFFSET
  1247.     ENDIF    ;CALLBAK
  1248. ;
  1249.     IF    CALLBAK AND NOT PORTED
  1250.     LDA    RPORT    ;GET THE STATUS
  1251.     ENDIF
  1252. ;
  1253.     IF    CALLBAK    AND PORTED
  1254.     IN    RPORT    ;GET THE STATUS
  1255.     ENDIF
  1256. ;
  1257.     IF    CALLBAK AND (WD8250 OR IN8251)
  1258.     ANI    P2RDET    ;STILL RINGING?
  1259.     JNZ    ENDRNG2 ;WAIT UNTIL RING FINISHED
  1260.     ENDIF
  1261. ;
  1262.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1263.     ANI    P2RDET    ;STILL RINGING?
  1264.     JZ    ENDRNG2    ;WAIT UNTIL RING FINISHED
  1265.     ENDIF
  1266. ;
  1267.     IF    CALLBAK
  1268.     MVI    L,45    ;DELAY 4.5 SECONDS FOR NEXT RING
  1269. ;
  1270. WAITNX2 EQU    $+OFFSET
  1271.     CALL    DELAY    ;WAIT .1 SECONDS
  1272.     DCR    L    ;MOE TO GO?
  1273.     JNZ    WAITNX2    ;YES, LOOP
  1274.     ENDIF    ;CALLBAK
  1275. ;
  1276.     IF    CALLBAK    AND NOT PORTED
  1277.     LDA    RPORT    ;GET THE STATUS
  1278.     ENDIF    ;CALLBAK AND NOT PORTED
  1279. ;
  1280.     IF    CALLBAK    AND PORTED
  1281.     IN    RPORT    ;GET THE STATUS
  1282.     ENDIF    ;CALLBAK AND PORTED
  1283. ;
  1284.     IF    CALLBAK AND (WD8250 OR IN8251)
  1285.     ANI    P2RDET    ;RINGING AGAIN
  1286.     JZ    EXPECT    ;NO?...ITS FOR ME!
  1287.     ENDIF
  1288. ;
  1289.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1290.     ANI    P2RDET    ;RINGIN AGAIN
  1291.     JNZ    EXPECT    ;NO?...ITS FOR ME!
  1292.     ENDIF
  1293. ;
  1294.     IF    CALLBAK
  1295. ;
  1296. ;Call not for computer - wait until ringing done, then reset
  1297. ;
  1298. WAITNR    EQU    $+OFFSET
  1299.     MVI    L,100    ;WAIT FOR 10 SECS NO RINGING
  1300. ;
  1301. WAITNRL EQU    $+OFFSET
  1302.     CALL    DELAY    ;DELAY .1 SECONDS
  1303.     ENDIF    ;CALLBAK
  1304. ;
  1305.     IF    CALLBAK AND NOT PORTED
  1306.     LDA    RPORT    ;GET THE STATUS
  1307.     ENDIF    ;CALLBAK AND NOT PORTED
  1308. ;
  1309.     IF    CALLBAK AND PORTED
  1310.     IN    RPORT    ;GET THE STATUS
  1311.     ENDIF    ;CALLBAK AND PORTED
  1312. ;
  1313.     IF    CALLBAK AND (WD8250 OR IN8251)
  1314.     ANI    P2RDET    ;STILL RINGING?
  1315.     JNZ    WAITNR    ;YES, WAIT 10 MORE SECONDS
  1316.     ENDIF
  1317. ;
  1318.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1319.     ANI    P2RDET    ;IS THIS MOTHER STILL RINGING?
  1320.     JZ    WAITNR    ;YES, WAIT 10 MORE SECONDS
  1321.     ENDIF
  1322. ;
  1323.     IF    CALLBAK
  1324.     DCR    L    ;NO RING, MAYBE WE'RE DONE
  1325.     JNZ    WAITNRL ;NO, LOOP SOME MORE
  1326.     ENDIF
  1327. ;
  1328.     IF    CALLBAK AND USRLOG
  1329.     LXI    H,NONUSR ;RECORD AS VOICE CALL
  1330.     CALL    BOPLOG    ;CALL ROUTINE TO ADD ONE
  1331.     ENDIF        ;CALLBAK AND USRLOG
  1332. ;
  1333.     IF    CALLBAK ;CONTINUE WITH CALLBAK ROUTINES
  1334.     JMP    HANGUP2    ;GO WAIT FOR NEXT CALL
  1335. ;
  1336. EXPECT    EQU    $+OFFSET
  1337.     LXI    H,400    ;40 SECONDS TO WAIT FOR SECOND CALL
  1338. ;
  1339. RELOOK    EQU    $+OFFSET
  1340.     ENDIF    ;CALLBAK
  1341. ;
  1342.     IF    CALLBAK AND NOT PORTED
  1343.     LDA    RPORT
  1344.     ENDIF
  1345. ;
  1346.     IF    CALLBAK AND PORTED
  1347.     IN    RPORT    ;GET THE STATUS
  1348.     ENDIF
  1349. ;
  1350.     IF    CALLBAK AND (WD8250 OR IN8251)
  1351.     ANI    P2RDET
  1352.     JNZ    ANSWER    ;YES, GO ANSWER IT
  1353.     ENDIF
  1354. ;
  1355.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1356.     ANI    P2RDET
  1357.     JZ    ANSWER    ;YES, GO ANSWER IT
  1358.     ENDIF
  1359. ;
  1360.     IF    CALLBAK
  1361.     CALL    DELAY    ;WAIT .1 SECOND
  1362.     DCX    H    ;ONE LESS COUNT
  1363.     MOV    A,H
  1364.     ORA    L    ;IS COUNT ZERO?
  1365.     JNZ    RELOOK    ;NO, LOOK SOME MORE
  1366.     JMP    HANGUP2    ;COUNT DONE, WAIT FOR NEW CALL
  1367. ;
  1368.     ENDIF        ;END OF CALLBAK ROUTINES
  1369. ;
  1370. ;Setup modem
  1371. ;
  1372. ANSWER    EQU    $+OFFSET
  1373. ;
  1374.     IF    ZCPRT        ;RESET WHEEL STATUS
  1375.     XRA    A        ;WHEN RUNNING ZCPR-T## FOR YOUR CCP.
  1376.     STA    WHEEL
  1377.     ENDIF    ;ZCPRT
  1378. ;
  1379.     IF    USRLOG AND PWRQD ;COUNT # OF LOGON ATTEMPTS
  1380.     LXI    H,OLDUSR    ;GET # OF ATTEMPTS
  1381.     CALL    BOPLOG        CALL ROUTINE TO ADD ONE
  1382.     ENDIF    ;USRLOG AND PWRQD
  1383. ;
  1384.     IF    DCHAYES
  1385.     MVI    A,LS1+LS2+PI+SBS ;8 DATA BITS, NO PARITY, 2 STOP BITS
  1386.     OUT    CR1
  1387.     MVI    A,TXE+OH ;TURN ON CARRIER AND ANSWER PHONE
  1388.     OUT    CR2
  1389.     IN    DATA    ;CLEAR DATA INPUT PORT
  1390.     IN    DATA    ;MAKE SURE IT'S CLEAR
  1391.     CALL    FRSTCAR    ;LOOK FOR CARRIER
  1392.     JC    HANGUP2    ;AWAIT ANOTHER CALLER
  1393. ;
  1394. ;Now test input for baud rate
  1395.     CALL    PATCH    ;PATCH JUMP TABLE
  1396.     CALL    TSTBAUD    ;SEE IF BAUD = 110
  1397.     JZ    WELCOME    ;YES, EXIT
  1398. ;
  1399.     MVI    A,LS1+LS2+PI    ;SET FOR 1 STOP BIT, 8 DATA, NO PARITY
  1400.     OUT    CR1
  1401.     MVI    A,TXE+OH+BRS    ;SET FOR 300 BAUD
  1402.     OUT    CR2
  1403.     CALL    TSTBAUD        ;SEE IF BAUD = 300
  1404.     JZ    WELCOME        ;YES,EXIT
  1405.     ENDIF            ;DCHAYES
  1406. ;
  1407.     IF    MMII
  1408.     MVI    A,P0ANSW    ;ANSWER MODEM
  1409.     STA    CPORT
  1410.     MVI    A,P0110        ;110 BAUD
  1411.     STA    TPORT
  1412.     LDA    DPORT        ;FILTER OUT CRAP
  1413.     LDA    DPORT
  1414.     CALL    CARCK
  1415.     JC    HANGUP2    ;AWAIT ANOTHER CALLER
  1416. ;
  1417. ;Now test input for baud rate
  1418.     CALL    PATCH    ;PATCH JUMP TABLE
  1419.     CALL    TSTBAUD    ;SEE IF BAUD = 110
  1420.     JZ    WELCOME    ;YES, EXIT
  1421. ;
  1422.     MVI    A,P0NORM    ;SET FOR 1 STOP BIT, 8 DATA, NO PARITY
  1423.     STA    TPORT
  1424.     MVI    A,B300+P0ANSW    ;SET FOR 300 BAUD
  1425.     STA    CPORT
  1426.     CALL    TSTBAUD        ;SEE IF BAUD = 300
  1427.     JZ    WELCOME        ;YES,EXIT
  1428.     ENDIF            ;MMII
  1429. ;
  1430. ;
  1431.     IF    SMODEM
  1432. ;
  1433. ;The SmartModem already answered the phone, so...
  1434. ;We DON'T do any modem stuff, because the baudrate is already
  1435. ;set...
  1436. ;
  1437.     CALL    PATCH    ;PATCH IN JUMP TABLE
  1438.     JMP    WELCOME    ;Goto welcome
  1439.     ENDIF    ;SMODEM
  1440. ;
  1441.     IF    PMMI
  1442.     MVI    A,7FH    ;TURN ON DTR
  1443.     OUT    CPORT    ;.. AND SET FILTER VALUE FOR 300 BAUD
  1444.     CALL    DELAY    ;GIVE TIME TO TURN ON
  1445.     MVI    A,P0110+P0ANSW
  1446.     OUT    TPORT    ;ANSWER PHONE
  1447.     CALL    DELAY    ;GIVE TIME FOR ANSWER
  1448.     CALL    UCSTS
  1449.     IN    DPORT    ;CLEAR MODEM PORT
  1450.     IN    DPORT    ;MAKE SURE ITS CLEAR
  1451.     MVI    A,B110    ;SET DIVISOR
  1452.     OUT    RPORT    ;.. TO 110 BAUD RATE
  1453. ;Output value allowing modem to hang up on loss of carrier
  1454.     MVI    A,P0110 ;NORMAL MODE FOR 110 BAUD
  1455.     OUT    TPORT
  1456.     CALL    CARCK    ;LOOK FOR CARRIER
  1457.     JC    HANGUP2 ;AWAIT ANOTHER CALLER
  1458. ;Now test input for baud rate
  1459.     CALL    PATCH     ;PATCH JMP TABLE
  1460.     CALL    TSTBAUD  ;SEE IF BAUD = 110
  1461.     JZ    WELCOME  ;YES, EXIT
  1462. ;
  1463.     MVI    A,P0NORM ;SET FOR 1 STOP BIT, ETC.
  1464.     OUT    TPORT
  1465.     MVI    A,B300     ;SET DIVISOR
  1466.     OUT    RPORT     ;.. TO 300 RATE
  1467.     CALL    TSTBAUD  ;SEE IF BAUD = 300
  1468.     JZ    WELCOME  ;YES, EXIT
  1469. ;
  1470.     MVI    A,B450     ;SET DIVISOR
  1471.     OUT    RPORT     ;.. TO 450 RATE
  1472.     MVI    A,5FH     ;SET FILTER VALUE
  1473.     OUT    CPORT     ;.. FOR > 300
  1474.     CALL    TSTBAUD  ;SEE IF BAUD = 450
  1475.     JZ    WELCOME  ;YES, EXIT
  1476. ;
  1477.     MVI    A,B600     ;SET DIVISOR
  1478.     OUT    RPORT     ;.. TO 600 RATE
  1479.     CALL    TSTBAUD  ;SEE IF BAUD = 600
  1480.     JZ    WELCOME  ;YES, EXIT
  1481. ;
  1482.     MVI    A,B710     ;SET DIVISOR
  1483.     OUT    RPORT     ;.. TO 710 RATE
  1484.     CALL    TSTBAUD  ;SEE IF BAUD = 710
  1485.     JZ    WELCOME  ;YES, EXIT
  1486.     ENDIF         ;PMMI
  1487. ;
  1488.     IF    IN8251
  1489.     MVI    A,BD300     ;LOAD 300 BAUD
  1490.     OUT    BPORT
  1491.     IN    DPORT     ;CLEAR
  1492.     IN    DPORT     ;DATA PORT
  1493.     MVI    A,RSTINS ;RESET USART
  1494.     OUT    CPORT
  1495.     CALL    UDELAY     ;USART DELAY
  1496.     MVI    A,MODINS1 ;1 STOP BIT, ETC.
  1497.     OUT    CPORT
  1498.     CALL    UDELAY     ;USART DELAY
  1499.     MVI    A,ONINS     ;DSR, ETC.
  1500.     OUT    CPORT
  1501.     CALL    CARCK     ;SEE IF CARRIER IS PRESENT
  1502.     JC    HANGUP2
  1503. ;Test input for baud rate
  1504.     CALL    PATCH     ;PATCH JUMP TABLE
  1505.     CALL    TSTBAUD     ;SEE IF 300 BAUD
  1506.     JZ    WELCOME     ;YES, EXIT
  1507. ;
  1508.     MVI    A,BD1200 ;LOAD 1200 BAUD
  1509.     OUT    BPORT
  1510.     CALL    TSTBAUD     ;SEE IF 1200 BAUD
  1511.     JZ    WELCOME     ;YES,EXIT
  1512. ;
  1513.     MVI    A,RSTINS ;RESET USART
  1514.     OUT    CPORT
  1515.     CALL    UDELAY     ;DELAY FOR USART
  1516.     MVI    A,MODINS2 ;2 STOP BITS, ETC.
  1517.     OUT    CPORT
  1518.     CALL    UDELAY     ;DELAY FOR USART
  1519.     MVI    A,ONINS     ;DTR, ETC.
  1520.     OUT    CPORT
  1521.     MVI    A,BD110     ;LOAD 110 BAUD
  1522.     OUT    BPORT
  1523.     CALL    TSTBAUD     ;TEST FOR 110 BAUD
  1524.     JZ    WELCOME
  1525.     ENDIF         ;IN8251
  1526. ;
  1527.     IF    WD8250 AND NOT NORING
  1528. ;
  1529.     MVI    A,MCDTR+MCRTS    ;TURN ON DATA SET, ANSWER PHONE; 
  1530.     OUT    CPORT
  1531.     ENDIF          ;WD8250 AND NOT NORING
  1532. ;
  1533.     IF    WD8250 
  1534.     MVI    A,(LCWLS0+LCWLS1) AND 0FFH ;8 BIT DATA 1 STOP BIT NO PAR
  1535.     OUT    LPORT
  1536.     CALL    PATCH    ;PATCH DRIVERS
  1537. ;
  1538. ;    BAUD RATE SELECTOR
  1539. ;
  1540. TST300:    EQU    $+OFFSET
  1541.     PUSH    D    ;SAVE D/E
  1542.     MVI    D,BR300MS
  1543.     MVI    E,BR300LS
  1544.     CALL    SETBAUD
  1545.     POP    D
  1546.     CALL    TSTBAUD
  1547.     JNZ    TST450
  1548.     CALL    TSTBAUD
  1549.     JZ    WELCOME
  1550. TST450:    EQU    $+OFFSET
  1551.     PUSH    D
  1552.     MVI    D,BR450MS
  1553.     MVI    E,BR450LS
  1554.     CALL    SETBAUD
  1555.     POP    D
  1556.     CALL    TSTBAUD
  1557.     JNZ    TST600
  1558.     CALL    TSTBAUD
  1559.     JZ    WELCOME
  1560. TST600:    EQU    $+OFFSET
  1561.     PUSH    D
  1562.     MVI    D,BR600MS
  1563.     MVI    E,BR600LS
  1564.     CALL    SETBAUD
  1565.     POP    D
  1566.     CALL    TSTBAUD
  1567.     JNZ    TST120
  1568.     CALL    TSTBAUD
  1569.     JZ    WELCOME
  1570. TST120:    EQU    $+OFFSET
  1571.     PUSH    D
  1572.     MVI    D,BR120MS
  1573.     MVI    E,BR120LS
  1574.     CALL    SETBAUD
  1575.     POP     D
  1576.     CALL    TSTBAUD
  1577.     JNZ    BADDO
  1578.     CALL    TSTBAUD
  1579.     JZ    WELCOME
  1580.     ENDIF        ;WD8250 
  1581. ;
  1582. BADDO    EQU     $+OFFSET
  1583.     CALL    UNPATCH  ;RESTORE ORIG BIOS JMP TBL
  1584.     JMP    ANSWER     ;TEST MORE - INVALID BAUD RATE
  1585. ;
  1586.     IF    IN8251
  1587. UDELAY    EQU    $+OFFSET
  1588.     NOP ! NOP ! NOP !
  1589.     RET
  1590.     ENDIF        ;IN8251
  1591. ;
  1592. ;Get the console status when unpatched
  1593. ;
  1594. UCSTS    EQU    $+OFFSET
  1595. ;
  1596.     IF    CPM2
  1597.     MVI    C,DRECTIO ;DIRECT I/O CALL
  1598.     MVI    E,0FFH      ;ASK FOR INPUT
  1599.     CALL    BDOS      ;A=0 IF NO CHAR WAITING
  1600.     RET
  1601.     ENDIF          ;CPM2
  1602. ;
  1603.     IF    NOT CPM2
  1604.     MVI    C,CSTS      ;IN CPM 1.4, WE HAVE TO GET..
  1605.     CALL    BDOS      ;..THE STATUS FIRST
  1606.     ORA    A
  1607.     RZ
  1608.     MVI    C,CI      ;AND THEN THE CHARACTER
  1609.     CALL    BDOS
  1610.     RET
  1611.     ENDIF          ;NOT CPM2
  1612. ;
  1613. ;Following are the USRLOG routines
  1614. ;
  1615.     IF    USRLOG     ;INCLUDE RESET FUNCTIONS
  1616. RESET    EQU    $+OFFSET ;RESET ALL LOGON COUNTERS
  1617.     LXI    H,0    ;ZEROING 16 BIT COUNTERS
  1618.     ENDIF         ;USRLOG
  1619. ;
  1620.     IF    USRLOG AND PWRQD
  1621.     SHLD    OLDUSR    ;RESET ATTEMPT COUNTER
  1622.     ENDIF        ;USRLOG AND PWRQD
  1623. ;
  1624.     IF    USRLOG
  1625.     SHLD    NEWUSR    ;RESET LOGON COUNTER
  1626.     ENDIF        ;USRLOG
  1627. ;
  1628.     IF    USRLOG AND CALLBAK
  1629.     SHLD    NONUSR    ;RESET VOICE COUNTER
  1630.     ENDIF        ;USRLOG AND CALLBAK
  1631. ;
  1632.     IF    USRLOG AND IMSAI
  1633.     MVI    A,0FFH
  1634.     OUT    SENSE    ;RESET IMSAI PANEL DISPLAY
  1635.     ENDIF        ;USRLOG AND IMSAI
  1636. ;
  1637.     IF    USRLOG
  1638.     RET
  1639.     ENDIF        ;USRLOG
  1640. ;
  1641. ;  PRNLOG is called to print out the BYE version
  1642. ; # and USRLOG info. It can be called from
  1643. ; outside the program, using the vector after
  1644. ; MCBOOT.
  1645. ;
  1646. PRNLOG    EQU    $+OFFSET
  1647. ;
  1648.     MVI    C,PRINTF ;PRINT OUT PROG VERSION #
  1649.     LXI    D,VMSG
  1650.     CALL    BDOS
  1651. ;
  1652.     IF    USRLOG AND PWRQD ;PRINT # OF LOGON ATTEMPTS
  1653.     MVI    C,PRINTF
  1654.     LXI    D,ATMSG
  1655.     CALL    BDOS
  1656.     LXI    H,OLDUSR+1 ;PT TO HIGH BYTE
  1657.     CALL    HXOUT
  1658.     ENDIF        ;USRLOG AND PWRQD
  1659. ;
  1660.     IF    USRLOG    ;PRINT # OF LOGONS
  1661.     MVI    C,PRINTF
  1662.     LXI    D,SUMSG
  1663.     CALL    BDOS
  1664.     LXI    H,NEWUSR+1
  1665.     CALL    HXOUT
  1666.     ENDIF        ;USRLOG
  1667. ;
  1668.     IF    USRLOG AND CALLBAK    ;# OF VOICE CALLS
  1669.     MVI    C,PRINTF
  1670.     LXI    D,VCMSG
  1671.     CALL    BDOS
  1672.     LXI    H,NONUSR+1
  1673.     CALL    HXOUT
  1674.     ENDIF        ;USRLOG AND CALLBAK
  1675. ;
  1676.     RET        ;IF NO LOG, NULL PRNLOG ROUTINE
  1677. ;
  1678. USRCHK    EQU    $+OFFSET
  1679.     IF    SMODEM
  1680.     CALL    SMINIT
  1681.     CALL    SMSEND
  1682.     DB    'AT Z',CR,0
  1683.     ENDIF    ;SMODEM
  1684.  
  1685.     CALL    PRNLOG    ;GIVE INFO
  1686.     MVI    C,PRINTF
  1687.     LXI    D,RS1MSG
  1688.     CALL    BDOS    ;PROMPT FOR RESUME BYE
  1689. ;
  1690. PRNREL    EQU    $+OFFSET
  1691.     CALL    UCSTS    ;GET REPLY
  1692.     ORA    A
  1693.     JZ    PRNREL    ;WAIT UNTIL ANSWERED
  1694.     CPI    'R'    ;IS ANSWER "R", FOR RESUME?
  1695.     JZ    PRNRES    ;GO DO IT IF SO
  1696.     CPI    'R'+20H    ;TAKE LOWER CASE ALSO
  1697.     JNZ    EXCPM    ;IF NOT "R", WARM BOOT CP/M
  1698. ;
  1699. PRNRES    EQU    $+OFFSET
  1700.     MVI    C,PRINTF
  1701.     LXI    D,RS2MSG
  1702.     JMP    BDOS    ;RESUME VIA BDOS AFTER MSG
  1703. ;
  1704. RS1MSG    EQU    $+OFFSET
  1705.     DB    CR,LF,CR,LF,'Type "R" to resume,'
  1706.     DB    ' anything else to warm boot: $'
  1707. RS2MSG    EQU    $+OFFSET
  1708.     DB    'Resuming...',CR,LF,'$'
  1709. ;
  1710. ;  Here to exit to CP/M
  1711. ;
  1712. EXCPM    EQU    $+OFFSET
  1713. ;
  1714.     IF CCSDISK
  1715. ;
  1716.     CALL    DSKON    ;TURN ON THE DRIVES
  1717. ;
  1718.     ENDIF    ;CCSDISK
  1719. ;
  1720.     IF BYELOW
  1721. ;
  1722.     LXI    H,OLDBD    ;RESET THE OLD BDOS JUMP IN
  1723.     SHLD    WMLOC    ;THE BIOS WARM BOOT ROUTINE
  1724. ;
  1725.     ENDIF        ;BYELOW
  1726. ;    
  1727.     JMP    0000H    ;Warm boot CP/M
  1728. ;
  1729.     IF    USRLOG
  1730. ;
  1731. ;  BOPLOG INCREMENTS THE 16 BIT COUNTER PT'ED AT BY
  1732. ; HL. IF DECIMAL SWITCH IN USE, NUMBER IS KEPT AS
  1733. ; 4 BCD DIGITS.
  1734. ;
  1735. BOPLOG    EQU    $+OFFSET
  1736.     MOV    A,M    ;GET LOW BYTE
  1737.     INR    A    ;INCREMENT
  1738.     ENDIF        ;USRLOG
  1739. ;
  1740.     IF    USRLOG AND DECIMAL
  1741.     DAA        ;DECIMAL ADJUST
  1742.     ENDIF        ;USRLOG AND DECIMAL
  1743. ;
  1744.     IF    USRLOG
  1745.     MOV    M,A    ;REPLACE LOW ORDER
  1746.     RNC        ;IF NO CARRY, BOP DONE
  1747.     INX    H    ; ELSE CARRY TO HIGH ORDER
  1748.     MOV    A,M    ;GET HIGH ORDER
  1749.     INR    A    ; AND BOP IT
  1750.     ENDIF
  1751. ;
  1752.     IF    USRLOG AND DECIMAL
  1753.     DAA        ;DECIMAL ADJUST
  1754.     ENDIF        ;USRLOG AND DECIMAL
  1755. ;
  1756.     IF    USRLOG
  1757.     MOV    M,A    ;REPLACE HIGH ORDER
  1758.     RET        ;CARRY OUT OF HIGH DROPPED
  1759.     ENDIF        ;USRLOG
  1760. ;
  1761.     IF    USRLOG AND PWRQD
  1762. ATMSG    EQU    $+OFFSET
  1763.     DB    CR,LF,'Number of logon attempts: $'
  1764.     ENDIF        ;USRLOG AND PWRQD
  1765. ;
  1766.     IF    USRLOG
  1767. SUMSG    EQU    $+OFFSET
  1768.     DB    CR,LF,'Number of logons: $'
  1769.     ENDIF        ;USRLOG
  1770. ;
  1771.     IF    USRLOG AND CALLBAK
  1772. VCMSG    EQU    $+OFFSET
  1773.     DB    CR,LF,'Number of voice calls: $'
  1774.     ENDIF        ;USRLOG AND CALLBAK
  1775. ;
  1776.     IF    USRLOG
  1777. HXOUT    EQU    $+OFFSET
  1778.     PUSH    H    ;SAVE PTR
  1779.     CALL    HXHAF    ;DO HIGH ORDER HALF OF #
  1780.     POP    H    ;RESTORE PTR
  1781.     DCX    H    ;PT TO LOW, THEN DROP
  1782.             ; IN TO DO LOW HALF
  1783. ;
  1784. HXHAF    EQU    $+OFFSET
  1785.     MOV    A,M    ;GET HALF # IN ACC
  1786.     MOV    B,A    ;SAVE NUMBER
  1787.     RAR        ;ROTATE RIGHT 4 BITS
  1788.     RAR        ;TO MAKE AN ASCII DIGIT
  1789.     RAR
  1790.     RAR
  1791.     CALL    ONEOUT    ;OUTPUT MSH TO CONSOLE
  1792.     MOV    A,B    ;GET NUMBER BACK
  1793. ;
  1794. ONEOUT    EQU    $+OFFSET
  1795.     ANI    0FH    ;GET LSH FOR OUTPUT
  1796.     ADI    90H    ;CVT TO DECIMAL ASCII
  1797.     DAA
  1798.     ACI    40H
  1799.     DAA
  1800.     PUSH    B
  1801.     MVI    C,02H
  1802.     MOV    E,A    ;OUTPUT THE NUMBER
  1803.     CALL    BDOS
  1804.     POP    B
  1805.     RET
  1806.     ENDIF        ;USRLOG
  1807. ;
  1808. ;Welcome to the system
  1809. ;
  1810. WELCOME EQU    $+OFFSET
  1811. ;
  1812.     IF CCSDISK
  1813. ;
  1814.     CALL DSKON    ;TURN ON THE DRIVES
  1815. ;
  1816.     ENDIF    ;CCSDISK
  1817. ;
  1818.     IF    CPM2
  1819.     MVI    A,MAXUSR    ;RESET MAX USER #
  1820.     STA    MXUSR
  1821.     ENDIF    ;CPM2
  1822. ;
  1823.     MVI    A,MAXDRV    ;RESET MAX DRIVE #
  1824.     STA    MXDRV
  1825. ;
  1826.     IF    TIMEOUT
  1827.     MVI    A,TOVALUE    ;RESET TIMEOUT COUNT
  1828.     STA    TOVAL
  1829.     ENDIF    ;TIMEOUT
  1830. ;
  1831.     MVI    A,5    ;Assume this many nulls
  1832.     STA    NULLS    ; in case error
  1833. ;
  1834.     IF     NOT OXGATE
  1835. ;
  1836. GETNULL EQU    $+OFFSET
  1837. ;
  1838.     CALL    ILPRT    ;PRINT THIS MSG:
  1839.     DB    CR,LF
  1840.     DB    'HOW MANY NULLS (0-9) DO YOU NEED? ',0
  1841.     CALL    MINPUT    ;GET VALUE
  1842.     MOV    C,A    ;TO C FOR MOUTPUT
  1843.     CALL    MOUTPUT ;ECHO CHAR
  1844.     MOV    A,C    ;RESTORE VALUE
  1845.     CPI    '0'
  1846.     JC    GETNULL ;BAD, RETRY
  1847.     CPI    '9'+1
  1848.     JNC    GETNULL ;BAD
  1849.     SUI    '0'    ;MAKE BINARY
  1850.     STA    NULLS    ;SAVE COUNT
  1851. ;
  1852.     ENDIF        ;NOT OXGATE
  1853. ;
  1854.     IF    TRAPLC AND NOT OXGATE
  1855. GETULC    EQU    $+OFFSET
  1856.     CALL    ILPRT    ;PRINT THIS MSG:
  1857.     DB    CR,LF
  1858.     DB    'CAN YOUR TERMINAL DISPLAY LOWER CASE? ',0
  1859.     MVI    A,20H    ;FORCE CASE CONVERSION FOR NOW
  1860.     STA    ULCSW
  1861.     CALL    MINPUT    ;GET Y OR NO
  1862.     MOV    C,A
  1863.     CALL    MOUTPUT ;ECHO
  1864.     MOV    A,C
  1865.     CPI    'N'
  1866.     JZ    DONEOPT ;WE'RE ALREADY SET UP FOR NO LWR CASE
  1867.     CPI    'Y'
  1868.     JNZ    GETULC    ;WASN'T Y OR N...GO ASK AGAIN
  1869.     XRA    A
  1870.     STA    ULCSW    ;SET FLAG FOR NO CONVERSION
  1871. ;
  1872. DONEOPT EQU    $+OFFSET
  1873.     ENDIF        ;TRAPLC AND NOT OXGATE
  1874. ;
  1875.     CALL    ILPRT
  1876.     DB    CR,LF,0
  1877. ;Print the welcome file
  1878.     LXI    H,WELFILN ;SOURCE
  1879.     LXI    D,FCB    ;DESTINATION
  1880.     MVI    B,13    ;LENGTH
  1881.     CALL    MOVE    ;MOVE THE NAME
  1882. ;Set DMA address to 80h
  1883.     LXI    D,80H
  1884.     MVI    C,STDMA
  1885.     CALL    BDOS
  1886. ;
  1887.     IF    CPM2
  1888. ;Set user number for welcome file
  1889.     MVI    C,32
  1890.     MVI    E,WELUSR
  1891.     CALL    BDOS
  1892.     ENDIF        ;CPM2
  1893. ;
  1894. ;Open the welcome file
  1895.     LXI    D,FCB
  1896.     MVI    C,OPEN
  1897.     CALL    BDOS
  1898. ;Did it exist?
  1899.     INR    A    ;A=> 0 MEANS "NO"
  1900.     JZ    PASSINT ;NO WELCOME FILE
  1901. ;Got a file, type it
  1902.     XRA    A    ;GET 0
  1903.     STA    FCBRNO    ;ZERO RECORD #
  1904.     LXI    H,100H    ;GET INITIAL BUFF POINTER
  1905. ;
  1906. ;Type the welcome file
  1907. WELTYLP EQU    $+OFFSET
  1908.     CALL    RDBYTE    ;GET A BYTE
  1909.     CPI    1AH    ;EOF?
  1910.     JZ    PASSINT ;YES, DONE
  1911.     MOV    C,A    ;SETUP FOR TYPE
  1912.     CALL    MOUTPUT ;TYPE THE CHAR
  1913.     CALL    MSTAT    ;CHECK FOR..
  1914.     ORA    A    ;CHAR TYPED?
  1915.     JZ    WELTYLP ;..NO, LOOP
  1916.     CALL    MINPUT    ;..YES, GET CHAR
  1917.     CPI    'C'-40H ;CTL-C?
  1918.     JNZ    WELTYLP ;..NO, LOOP UNTIL EOF
  1919. ;
  1920. ;Get the password
  1921. ;
  1922. PASSINT EQU    $+OFFSET
  1923. ;
  1924.     IF    PWRQD AND IMSAI AND SELPASS 
  1925.     IN    SENSE    ;TURN THE SWITCH UP..
  1926.     ANI    PWDSW    ;..TO REQUIRE THE PASSWORD
  1927.     JZ    NOPASS
  1928.     ENDIF        ;PWRQD AND IMSAI AND SELPASS
  1929. ;
  1930.     IF    PWRQD
  1931.     MVI    D,5    ;5 TRIES AT PASSWORD
  1932. ;
  1933. PASSINP EQU    $+OFFSET
  1934.     CALL    ILPRT
  1935.     DB    CR,LF,'Enter password: ',0
  1936.     LXI    H,PASSWD ;POINT TO PASSWORD
  1937.     MVI    E,0    ;NO MISSED LETTERS
  1938.     IN    DPORT    ;CLEAR OUT GARBAGE
  1939. ;
  1940. PWMLP    EQU    $+OFFSET
  1941.     CALL    MINPUT    ;GET A CHAR
  1942.     CPI    60H    ;LOWER CASE?
  1943.     JC    NOTLC    ;NO,
  1944.     ANI    5FH    ;MAKE UPPER CASE ALPHA
  1945. ;
  1946. NOTLC    EQU    $+OFFSET
  1947.     ENDIF        ;PWRQD
  1948.  
  1949.     IF    DUAL$IO AND PWRQD
  1950.     PUSH    PSW    ;SAVE CHAR INPUT
  1951.     CPI    20H    ;IS CHAR CONTROL?
  1952.     JNC    PWDIS    ;PASS IF DISPLAYABLE
  1953.     MVI    C,'^'    ;IF CONTROL,
  1954.     CALL    CONOUT    ; MAP TO UP-ARROW,
  1955.     POP    PSW    ; THEN DISPLAYABLE
  1956.     PUSH    PSW
  1957.     ADI    40H
  1958. PWDIS    EQU    $+OFFSET
  1959.     MOV    C,A
  1960.     CALL    CONOUT    ;OUTPUT CHAR LOCALLY
  1961.     POP    PSW    ;RESTORE TO ACC
  1962.     ENDIF        ;DUAL$IO AND PWRQD
  1963.  
  1964.     IF    PWRQD
  1965.     CPI    'U'-40H ;CTL-U?
  1966.     JZ    PASSINP ;YES, RE-GET IT
  1967.     CMP    M    ;MATCH PASSWORD?
  1968.     JZ    PWMAT    ;..YES
  1969.     MVI    E,1    ;..NO, SHOW MISS
  1970.     CPI    CR    ;C/R?
  1971.     JNZ    PWMLP    ;..NO, WAIT FOR C/R
  1972. ;
  1973. ;Password didn't match
  1974. ;
  1975. PWNMAT    EQU    $+OFFSET
  1976.     CALL    ILPRT
  1977.     DB    'Incorrect',CR,LF,0
  1978.     DCR    D    ;MORE TRIES?
  1979.     JNZ    PASSINP ;YES
  1980.     JMP    BADPASS ;NO, GO HANG UP
  1981. ;
  1982. ;Character matched in password
  1983. ;
  1984. PWMAT    EQU    $+OFFSET
  1985.     INX    H    ;TO NEXT CHAR
  1986.     CPI    CR    ;END?
  1987.     JNZ    PWMLP    ;..NO, LOOP
  1988. ;End of password.  Any missed chars?
  1989.     MOV    A,E    ;GET FLAG
  1990.     ORA    A
  1991.     JNZ    PWNMAT    ;NOT RIGHT
  1992. ;Password correct
  1993.     ENDIF        ;PWRQD
  1994. ;
  1995. NOPASS    EQU    $+OFFSET
  1996. ;
  1997.     IF     RTC
  1998.     CALL    ILPRT
  1999.     DB    CR,LF,CR,LF,'On at ',0
  2000.     CALL    TIME
  2001.     CALL    ILPRT
  2002.     DB    CR,LF,0
  2003.     ENDIF        ;RTC
  2004. ;
  2005. ;
  2006.     IF    USRLOG    ;COUNT # OF SUCCESSFUL LOGONS
  2007.     LXI    H,NEWUSR ;GET LAST VALUE
  2008.     CALL    BOPLOG    ;CALL ROUTINE TO ADD ONE
  2009.     ENDIF        ;USRLOG
  2010. ;
  2011.     IF    IMSAI AND USRLOG
  2012.     LDA    NEWUSR    ;RE-GET LOW ORDER VALUE
  2013.     CMA        ;INVERT FOR LIGHTS
  2014.     OUT    SENSE    ;DISPLAY ON IMSAI FRONT PANEL
  2015.     ENDIF        ;IMSAI AND USRLOG
  2016. ;
  2017.     IF    BOOTMSG
  2018. ;
  2019.     CALL    ILPRT
  2020.     DB    CR,LF
  2021.     DB    'Please Wait... ' ;BOOT MSG HERE
  2022.     DB    0
  2023.     ENDIF        ;BOOTMSG
  2024. ;
  2025.     IF    COMFILE AND CPM2
  2026.     MVI    C,32
  2027.     MVI    E,COMUSR    ;SWITCH TO COM FILE USER #
  2028.     CALL    BDOS
  2029.     ENDIF        ;COMFILE AND CPM2
  2030. ;
  2031. ;
  2032.     IF    COMFILE
  2033.     MVI    A,20H    ;FOOL THE SYSTEM
  2034.     STA    FCB+1    ;SO THAT COM FILE WILL SEE
  2035.             ;20H AT FCB+1 FOR DEFAULT PURPOSES.
  2036.     LDA    OPTION
  2037.     CPI    'A'    ;SYSOP CAN BYPASS COM FILE BY..
  2038.     JZ    0    ;..TYPING "BYE /A"
  2039.     CPI    'C'    ;OPER CAN ALSO GO TO COM..
  2040.     JNZ    RUNCOM    ;..FILE LOAD WITH "BYE /C"
  2041.     CALL    ILPRT    ;PRINT THIS MESSAGE:'
  2042.     DB    'Loading system...',CR,LF,0
  2043.     CALL    LODCOM
  2044. RUNCOM    EQU    $+OFFSET ;EVERYONE ELSE GETS COM FILE
  2045.     CALL    100H
  2046.     ENDIF        ;COMFILE
  2047. ;
  2048.     JMP    0    ;WARM BOOT NOW FOR "NORMAL" CP/M USE
  2049. ;
  2050. ;TSTBAUD attempts to read a LF or CR, returns with
  2051. ;zero flag if the character read is one of these two.
  2052. ;
  2053. TSTBAUD EQU    $+OFFSET
  2054.     CALL    MINPUT    ;GET CHARACTER FROM MODEM
  2055.     CPI    CR    ;IF A CARRIAGE RETURN...
  2056.     RZ        ;.. RETURN
  2057.     CPI    LF    ;IF A LINEFEED...
  2058.     RZ
  2059.     CPI    'C'-40H    ;IF A CONTROL C
  2060.     RET        ;RET ZERO FLAG, ELSE NOT ZERO
  2061. ;
  2062. ;**************SET WD8250  BAUD RATE************************
  2063. ;
  2064.     IF    WD8250
  2065. ;
  2066. SETBAUD: EQU    $+OFFSET
  2067.     MVI    A,83H    ;SET DLAB
  2068.     OUT    LPORT
  2069.     MOV    A,E    ;GET LSB
  2070.     OUT    DPORT
  2071.     MOV    A,D    ;GET MSB
  2072.     OUT    DPORT+1
  2073.     CPI    04H    ;110?
  2074.     JNZ    ONESTOP    
  2075.     MVI    A,LCWLS0+LCWLS1+LCSTB    ;8 DATA 2 STOP BITS
  2076.     OUT     LPORT
  2077.     JMP    DLOOP
  2078. ONESTOP: EQU    $+OFFSET
  2079.     MVI    A,LCWLS0+LCWLS1
  2080.     OUT     LPORT
  2081. DLOOP:    EQU    $+OFFSET
  2082.     XCHG        ;PUT DIVISOR IN HL
  2083.     DAD H!DAD H!DAD H!DAD H    ;MULTIPLY BY 16
  2084.                 ;SO WE DELAY APPROX 2 CHARS TIMES
  2085. DLOOP1:    EQU    $+OFFSET
  2086.     DCX    H
  2087.     MOV    A,L
  2088.     ORA    H
  2089.     JNZ    DLOOP1
  2090.     XCHG
  2091.     IN    DPORT
  2092.     IN    DPORT
  2093.     RET
  2094. ;
  2095.     ENDIF        ;WD8250
  2096. ;
  2097. ;Loss of connection test
  2098. ;
  2099.     IF    DCHAYES
  2100. ;This is the test for the first wait for a carrier.
  2101. ;It is only used in the DCHayes.
  2102. FRSTCAR    EQU    $+OFFSET
  2103.     IN    STATUS    ;GET MODEM STATUS
  2104.     ANI    CD    ;GET A CARRIER?
  2105.     JNZ    CARCK2    ;YES, GO ON WITH THE TESTS
  2106.     PUSH    B    ;PRESERVE B SO WE CAN USE IT
  2107.     MVI    B,CWAIT*10    ;WAIT CWAIT SECONDS
  2108.     JMP    CARLP        ;JUMP TO THE TESTING LOOP
  2109.     ENDIF    ;DCHAYES
  2110. ;
  2111. CARCK    EQU    $+OFFSET
  2112.     IF    DCHAYES
  2113. ;
  2114. ;The DC Hayes has a hardware hangup feature, but we won't use it.
  2115. ;Instead, if we detect that there is no carrier upon entry to
  2116. ;this routine, we'll keep checking for CWAIT or CLOSS seconds to see if the
  2117. ;carrier returns. If so, we'll just continue on. If not, we'll
  2118. ;signal this by setting the carry flag.
  2119. ;
  2120.     IN    STATUS    ;GET MODEM STATUS
  2121.     ANI    CD    ;GOT A CARRIER?
  2122.     JNZ    CARCK2    ;YES, GO ON WITH TESTS
  2123.     PUSH    B    ;PRESERVE SO WE CAN USE IT
  2124.     MVI    B,CLOSS*10    ;SET FOR CLOSS  SECONDS
  2125. ;
  2126. CARLP    EQU    $+OFFSET
  2127.     CALL    DELAY    ;WAIT .1 SECONDS
  2128.     IN    STATUS    ;GET MODEM STATUS
  2129.     ANI    CD    ;HAS CARRIER RETURNED?
  2130.     MOV    A,B    ;PRESERVE COUNTDOWN VALUE
  2131.     POP    B    ;FIX STACK IN CASE ALL IS OK
  2132.     JNZ    CARCK2    ;GOT CARRIER, CONTINUE ON
  2133.     DCR    A    ;COUNT TIME DOWN
  2134.     STC        ;IN CASE THIS IS THE END OF TIME
  2135.     RZ        ;RETURN IF TIMED OUT
  2136.     PUSH    B    ;PRESERVE B
  2137.     MOV    B,A    ;GET COUNTER VALUE IN B
  2138.     JMP    CARLP    ;KEEP CHECKING
  2139.     ENDIF        ;DCHAYES
  2140. ;
  2141. ;    Carrier check for MMII
  2142. ;
  2143.     IF    MMII
  2144.     LDA    RPORT1    ;GET MODEM STATUS
  2145.     ANI    P2CTS    ;GOT A CARRIER?
  2146.     JZ    CARCK2    ;YES, GO ON WITH TESTS
  2147.     PUSH    B    ;PRESERVE SO WE CAN USE IT
  2148.     MVI    B,150    ;SET FOR CLOSS  SECONDS
  2149. ;
  2150. CARLP    EQU    $+OFFSET
  2151.     CALL    DELAY    ;WAIT .1 SECONDS
  2152.     LDA    RPORT1    ;GET MODEM STATUS
  2153.     ANI    P2CTS    ;HAS CARRIER RETURNED?
  2154.     MOV    A,B    ;PRESERVE COUNTDOWN VALUE
  2155.     POP    B    ;FIX STACK IN CASE ALL IS OK
  2156.     JZ    CARCK2    ;GOT CARRIER, CONTINUE ON
  2157.     DCR    A    ;COUNT TIME DOWN
  2158.     STC        ;IN CASE THIS IS THE END OF TIME
  2159.     RZ        ;RETURN IF TIMED OUT
  2160.     PUSH    B    ;PRESERVE B
  2161.     MOV    B,A    ;GET COUNTER VALUE IN B
  2162.     JMP    CARLP    ;KEEP CHECKING
  2163.     ENDIF        ;MMII
  2164. ;
  2165. ;
  2166. ;The SmartModem hangs up immediately, we just have to tell the
  2167. ;computer it is ok.
  2168. ;
  2169.     IF    SMODEM AND PORTED
  2170.     IN    MSPORT        ;INPUT MODEM STATUS
  2171.     ENDIF
  2172. ;
  2173.     IF    SMODEM AND NOT PORTED
  2174.     LDA    MSPORT        ;INPUT MODEM STATUS
  2175.     ENDIF
  2176. ;
  2177.     IF    SMODEM
  2178.     ANI    P2CTS        ;CARRIER?
  2179.     JNZ    CARCK2        ;YES, DO OTHER CHECKS
  2180.     STC            ;NO, SET CARRY AND RETURN
  2181.     RET
  2182.     ENDIF    ;SMODEM
  2183. ;
  2184.     IF    PMMI
  2185. ;
  2186. ;The PMMI modem automatically hangs up the phone after
  2187. ;15 seconds of loss of carrier, providing you output to
  2188. ;port 0 to allow it (which this program does).
  2189. ;
  2190. ;..so, this routine first checks if the modem has hung up,
  2191. ;and if so, returns with carry set.  If not, it checks for
  2192. ;carrier and returns if carrier is on; otherwise waits for
  2193. ;carrier while still testing for disconnect.
  2194. ;
  2195. ;It tests the PMMI "CTS" (clear to send) bit
  2196. ;which is 0 when there is carrier
  2197. ;
  2198.     IN    RPORT    ;GET STATUS
  2199.     ANI    P2CONN    ;CONNECTED?
  2200.     STC        ;(IN CASE NOT)
  2201.     RNZ        ;HUNG UP.
  2202. ;Still connected, check for carrier
  2203.     IN    RPORT    ;LOOK AT STATUS
  2204.     ANI    P2CTS    ;GET CARRIER DETECT BIT
  2205.     JZ    CARCK2    ;CONTINUE W/TESTS
  2206. ;Loop until either connection lost, or carrier returns
  2207.     JMP    CARCK
  2208.     ENDIF        ;PMMI
  2209. ;
  2210.     IF    IN8251
  2211. ;
  2212. ;Racal-Vadic modem automatically hangs up phone 1 second
  2213. ;after carrier loss.
  2214. ;
  2215.     IN    SPORT    ;GET STATUS
  2216.     ANI    DSR    ;CHECK IF CARRIER ON
  2217.     JNZ    CARCK2    ;YES, CONTINUE ON
  2218.     STC        ;SET CARRY BIT FOR NO CARRIER
  2219.     RET
  2220.     ENDIF        ;IN8251
  2221. ;
  2222.     IF     WD8250
  2223. ;THE WD8250 HAS HARDWARE HANGUP. BUT WE WILL USE CARRIER DETECT
  2224. ;ROUTINE TO DETERMINE CARRIER LOSS AFTER 15 SECONDS.......
  2225. ; 
  2226.     IN    MSPORT    ;GET MODEM STATUS
  2227.     ANI    P2CTS    ;GOT A CARRIER
  2228.     JNZ    CARCK2    ;YES, GO ON WITH TESTS
  2229.     PUSH    B    ;PRESERVE SO WE CAN USE IT
  2230.     MVI    B,150    ;SET FOR 15 SECONDS
  2231. ;
  2232. CARLP    EQU    $+OFFSET
  2233. ;
  2234.     CALL    DELAY    ;WAIT .1 SECOND
  2235.     IN    MSPORT    ;GET MODEM STATUS
  2236.     ANI    P2CTS    ;HAS CARRIER RETURNED ?
  2237.     MOV    A,B    ;PRESERVE COUNT DOWN VALUE
  2238.     POP    B    ;FIX STACK IF ALL IS OK
  2239.     JNZ    CARCK2    ;HAVE CARRIER - CONTINUE
  2240.     DCR    A    ;COUNT DOWN TIME
  2241.     STC        ;IN CASE THIS IS THE END OF TIME
  2242.     RZ        ;RETURN IF TIMED OUT
  2243.     PUSH    B    ;PRESERVE B
  2244.     MOV    B,A    ;GET COUNTER VALUE IN B
  2245.     JMP    CARLP    ;CONTINUE - KEEP CHECKING
  2246.     ENDIF        ;WD8250
  2247.  
  2248. ;Now test drive #'s and (if CP/M 2.x) user #'s to
  2249. ;insure that maximums are not exceeded.
  2250. ;
  2251. CARCK2    EQU    $+OFFSET
  2252.     LDA    4    ;CHECK DISK/USER #
  2253.     ANI    0FH    ;ISOLATE DRIVE
  2254.     PUSH    H    ;SAVE HL
  2255.     LXI    H,MXDRV    ;PT TO ALLOWED # DRIVES
  2256.     CMP    M    ;VALID DRIVE?
  2257.     JC    CARCK3    ;YES, SKIP THIS JUNK
  2258.     LDA    4    ;GET WHOLE LOGIN BYTE
  2259.     ANI    0F0H    ;RETAIN USER # & FORCE DRIVE TO A
  2260.     STA    4    ;UPDATE LOGIN BYTE
  2261.     CALL    ILPRT    ;TELL USER WHAT HE DID
  2262.     DB    '[Invalid drive, returning to A:]',0
  2263.     JMP    0    ;WARM BOOT
  2264. ;
  2265. CARCK3    EQU    $+OFFSET
  2266. ;
  2267.     IF    CPM2
  2268.     LDA    4    ;GET LOGIN BYTE
  2269.     ANI    0F0H    ;ISOLATE USER #
  2270.     RRC        ;MOVE TO LOW BITS
  2271.     RRC
  2272.     RRC
  2273.     RRC
  2274.     LXI    H,MXUSR    ;PT TO MAX USER #
  2275.     CMP    M    ;VALID USER #?
  2276.     JC    CARCK4    ;YES, DON'T CHANGE
  2277.     JZ    CARCK4
  2278.     LDA    4    ;GET LOGIN BYTE AGAIN
  2279.     ANI    0FH    ;KEEP DRIVE, ZERO USER
  2280.     STA    4    ;UPDATE LOGIN BYTE
  2281.     CALL    ILPRT    ;TELL HIM WHAT HAPPENED
  2282.     DB    '> [Invalid user number, returning to 0]',0
  2283.     JMP    0    ;WARM BOOT
  2284.     ENDIF        ;CPM2
  2285. ;
  2286. CARCK4    EQU    $+OFFSET
  2287.     POP    H    ;RESTORE HL
  2288.     ORA    A
  2289.     RET
  2290. ;
  2291. ;.1 sec delay routine
  2292. ;
  2293. DELAY    EQU    $+OFFSET
  2294.     PUSH    B
  2295. ;
  2296.     LXI    B,4167*SPEED    ;TIMING CONSTANT x CLOCK MHZ
  2297. ;
  2298. DELAY1    EQU    $+OFFSET
  2299.     DCX    B
  2300.     MOV    A,B
  2301.     ORA    C
  2302.     JNZ    DELAY1
  2303.     POP    B
  2304.     RET
  2305. ;
  2306. ;50 ms delay routine
  2307. ;
  2308. KDELAY    EQU    $+OFFSET
  2309.     PUSH    B
  2310. ;
  2311.     LXI    B,2083*SPEED
  2312.     JMP    DELAY1
  2313. ;
  2314. ;Patch in the new JMP table (saving the old)
  2315. ;
  2316. PATCH    EQU    $+OFFSET
  2317.     CALL    TBLADDR        ;CALC HL= CP/M JMP TABLE
  2318.     LXI    D,VCOLDBT    ;POINT TO SAVE LOCATION
  2319.     MVI    B,24        ;SAVE ALL VECTORS
  2320.     CALL    MOVE        ;MOVE IT
  2321. ;Now move new JMP table to CP/M
  2322.     CALL    TBLADDR        ;CALC HL=CP/M'S JMP TABLE
  2323.     XCHG            ;MOVE TO DE
  2324.     LXI    H,NEWJTBL    ;POINT TO NEW
  2325.     CALL    MOVE        ;MOVE IT
  2326. ;
  2327.     IF    IN8251
  2328.     LXI    H,NWBCALL    ;POINT TO NEW CALL
  2329.     SHLD    WBCALL+1    ;MODIFY CALL IN BIOS
  2330.     ENDIF            ;IN8251
  2331. ;
  2332.     RET
  2333. ;
  2334. UNPATCH EQU    $+OFFSET
  2335.     CALL    TBLADDR        ;HL=CP/M'S JMP TABLE
  2336.     XCHG            ;MOVE TO DE
  2337.     LXI    H,VCOLDBT    ;GET SAVED TABLE
  2338.     CALL    MOVE        ;MOVE ORIG BACK
  2339. ;
  2340.     IF    LOSER
  2341.     LXI    H,WMSTRT    ;LOAD OLD CALL LOCATION
  2342.     SHLD    WBCALL+1    ;RESTORE OLD CALL
  2343.     ENDIF            ;LOSER
  2344. ;
  2345.     RET            
  2346. ;
  2347. ;Calculate HL=CP/M's jump table, B=length
  2348. ;
  2349. TBLADDR EQU    $+OFFSET
  2350.     LHLD    1    ;GET BIOS POINTER
  2351.     DCX    H    ;..SKIP
  2352.     DCX    H    ;..TO
  2353.     DCX    H    ;..COLD BOOT
  2354. ;
  2355.     IF    (NOT PRINTER) and (NOT ALLDEV)
  2356.     MVI    B,18    ;BYTES TO MOVE
  2357.     ENDIF        ;NOT PRINTER AND NOT ALLDEV
  2358. ;
  2359.     IF    PRINTER ;RETAIN LIST DEVICE?
  2360.     MVI    B,15    ;DON'T MOVE LISTER JUMP
  2361.     ENDIF        ;PRINTER
  2362. ;
  2363.     IF    ALLDEV    ;THIS PATCHES ALL DEVICES TO PHONE
  2364.     MVI    B,24    ;MOVE ALL JUMPS
  2365.     ENDIF        ;ALLDEV
  2366.  
  2367.     RET
  2368. ;
  2369. ;Move (HL) to (DE), length in (B)
  2370. ;
  2371. MOVE    EQU    $+OFFSET
  2372.     MOV    A,M    ;GET A BYTE
  2373.     STAX    D    ;PUT AT NEW HOME
  2374.     INX    D    ;BUMP POINTERS
  2375.     INX    H
  2376.     DCR    B    ;DEC BYTE COUNT
  2377.     JNZ    MOVE    ;IF MORE, DO IT
  2378.     RET        ;IF NOT,RETURN
  2379. ;
  2380.     IF    LOSER
  2381. NWBCALL    EQU    $+OFFSET
  2382.     CALL    WMSTRT    ;WARM BOOT DISK READ
  2383.     CALL    PATCH    ;FIX BIOS AGAIN AFTER WMSTRT
  2384.     RET
  2385.     ENDIF        ;LOSER
  2386. ;
  2387. ;Common routine to check for carrier lost, called from console out
  2388. ;
  2389. CHECK    EQU    $+OFFSET
  2390. ;
  2391.     IF    MINICK
  2392. ;
  2393.     LDA    IOBYTE    ;GET IOBYTE
  2394.     ANI    80H    ;TEST FOR DISK UPDATE
  2395.     RTN        ;BUSY WAIT UNTIL DONE
  2396. ;
  2397.     ENDIF        ;MINICK
  2398. ;
  2399.     IF    RBBSCK
  2400. ;
  2401.     LDA    WRTLOC    ;GET WRITE IN PROGRESS FLAG
  2402.     ORA    A
  2403.     RNZ        ;BUSY WAIT UNTIL DONE
  2404. ;
  2405.     ENDIF        ;RBBSCK
  2406. ;
  2407.     CALL    CARCK    ;SEE IF CARRIER STILL ON
  2408.     RNC        ;ALL OK
  2409. ;
  2410. ;Carrier is lost.  Type message so local console shows the reason
  2411. ;
  2412. BADPASS EQU    $+OFFSET ;COME HERE ON BAD PASSWORD
  2413.     MVI    A,1    ;SHOW CARRIER LOST SO
  2414.     STA    LOSTFLG ;..WE WON'T CK AGAIN
  2415.     LXI    SP,STACK ;ENSURE VALID STACK
  2416.     CALL    ILPRT
  2417.     DB    CR,LF
  2418.     DB    '[Carrier Lost]'
  2419.     DB    CR,LF,'   ',0
  2420. DROPCAR    EQU    $+OFFSET
  2421.     CALL    UNPATCH ;RESTORE ORIG BIOS JMP TBL
  2422.     XRA    A    ;CLEAR OUT CARRIER..
  2423.     STA    LOSTFLG ;..LOST FLAG
  2424.     JMP    HANGUP
  2425. ;
  2426. ;Readbyte routine - used to read the welcome file
  2427. ;
  2428. RDBYTE    EQU    $+OFFSET
  2429.     MOV    A,H    ;TIME TO READ?
  2430.     ORA    A    ;..IF AT 100H
  2431.     JZ    NORD    ;NO READ REQ'D
  2432. ;Have to read a sector
  2433.     LXI    D,FCB
  2434.     MVI    C,READ
  2435.     CALL    BDOS
  2436.     ORA    A    ;OK?
  2437.     MVI    A,1AH    ;FAKE UP EOF
  2438.     RNZ        ;RET EOF IF BAD
  2439.     LXI    H,80H
  2440. ;
  2441. NORD    EQU    $+OFFSET
  2442.     MOV    A,M    ;GET CHAR
  2443.     INX    H    ;TO NEXT
  2444.     RET
  2445. ;
  2446. ;Keyboard/modem status test routine
  2447. ;
  2448. MSTAT    EQU    $+OFFSET
  2449. ;
  2450.     CALL    CHECK    ;CHECK FOR CARRIER LOST
  2451. ;
  2452.     IF    DUAL$IO ;WANT LOCAL CONSOLE?
  2453.     CALL    CONSTAT ;GET LOCAL STATUS
  2454.     ORA    A
  2455.     RNZ        ;RET IF LOCAL CHAR
  2456.     ENDIF        ;DUAL$IO
  2457. ;
  2458.     IF    DCHAYES
  2459.     IN    STATUS    ;GET MODEM STATUS
  2460.     ANI    RRF    ;GOT A CHARACTER?
  2461.     RZ        ;RETURN IF NOT
  2462.     IN    STATUS    ;GET MODEM STATUS
  2463.     ANI    FE+OE    ;CHECK FOR FRAMING AND OVERRUN ERROR
  2464.     JZ    MSTAT1    ;NO ERROR, CHARACTER IS VALID
  2465.     IN    DATA    ;SWALLOW CHARACTER (ALSO CLEAR OE & FE)
  2466.     XRA    A    ;RETURN FALSE
  2467.     RET
  2468.     ENDIF        ;DCHAYES
  2469. ;
  2470.     IF    MMII
  2471.     LDA    TPORT    ;GET STATUS
  2472.     ANI    P0DAV    ;DATA AVAILABLE?
  2473.     RZ        ;NOPE
  2474.     LDA    TPORT    ;CHECK AGAIN
  2475.     ANI    30H    ;CHECK FRAMING AND OVERRUN
  2476.     JZ    MSTAT1    ;NO ERRORS
  2477.     LDA    DPORT    ;SWALLOW CHARACTER
  2478.     XRA    A    ;RETURN FALSE
  2479.     RET
  2480.     ENDIF        ;MMII
  2481. ;
  2482.     IF    SMODEM AND PORTED
  2483.     IN    MSPORT    ;GET STATUS
  2484.     ENDIF
  2485. ;
  2486.     IF    SMODEM AND NOT PORTED
  2487.     LDA    MSPORT    ;GET STATUS
  2488.     ENDIF
  2489. ;
  2490.     IF    SMODEM
  2491.     ANI    P0DAV    ;DATA AVAILABLE?
  2492.     RZ        ;RETURN IF NOT READY
  2493.     JMP    MSTAT1    ;CONTINUE
  2494.     ENDIF    ;SMODEM
  2495. ;
  2496.     IF    PMMI
  2497.     IN    TPORT    ;GET STATUS
  2498.     ANI    P0DAV    ;DATA AVAILABLE?
  2499.     RZ        ;RETURN IF NOT READY
  2500.     IN    TPORT    ;GET STATUS
  2501.     ANI    30H    ;CHECK FRAMING AND OVERRUN BITS
  2502.     JZ    MSTAT1    ;NO ERRORS...LEGIT CHARACTER
  2503.     IN    DPORT    ;SWALLOW CHARACTER (CLEARS PODAV)
  2504.     XRA    A    ;RETURN FALSE
  2505.     RET
  2506.     ENDIF        ;PMMI
  2507. ;
  2508.     IF    IN8251
  2509.     IN    SPORT    ;GET STATUS
  2510.     ANI    RCVRDY    ;GOT A CHARACTER
  2511.     RZ        ;RETURN IF NOT
  2512.     IN    SPORT    ;GET STATUS
  2513.     ANI    TOERR    ;CHECK FOR PARITY, FRAMING AND OVERRUN ERRORS
  2514.     JZ    MSTAT1    ;NO ERRORS
  2515.     MVI    A,ONINS    ;RESET ERROR FLAGS
  2516.     OUT    CPORT
  2517.     XRA    A    ;RETURN    FALSE
  2518.     RET
  2519.     ENDIF        ;IN8251
  2520. ;
  2521.     IF    WD8250 
  2522.     IN    SPORT    ;GET STATUS
  2523.     ANI    P0DAV    ;DATA AVAILABLE
  2524.     RZ        ;RTN IF NOT RDY
  2525.     IN    SPORT    ;GET STATUS
  2526.     ANI    0EH    ;CHECK PAR, FRAM ERR AND OVRN BITS
  2527.     JZ    MSTAT1
  2528.     IN    DPORT
  2529.     XRA    A    ;RTN FALSE
  2530.     RET
  2531.     ENDIF        ;WD8250 
  2532. ;
  2533. MSTAT1    EQU    $+OFFSET
  2534.     MVI    A,0FFH    ;SHOW READY
  2535.     ORA    A
  2536.     RET
  2537. ;
  2538. ;Modem input function, checks local console first
  2539. ;
  2540. MINPUT    EQU    $+OFFSET
  2541. ;
  2542.     IF    TIMEOUT
  2543.     LDA    TOVAL    ;GET # MINUTES BEFORE TIMEOUT
  2544. ;
  2545. MINPUT0    EQU    $+OFFSET
  2546.     STA    TOCNTM    ;SET MINUTES COUNTER
  2547.     PUSH    H
  2548.     LXI    H,MINUTES ;INIT ONE MINUTE TIMEOUT COUNTER
  2549.     SHLD    TOCNT
  2550.     POP    H
  2551.     ENDIF        ;TIMEOUT
  2552. ;
  2553. MINPUT1 EQU    $+OFFSET
  2554.     LDA    LOSTFLG ;KNOWN LOSS..
  2555.     ORA    A    ;..OF CARRIER?
  2556.     CZ    CHECK    ;CARRIER STILL ON?
  2557.     CALL    MSTAT    ;ANYTHING?
  2558.     ORA    A
  2559. ;
  2560.     IF    NOT TIMEOUT
  2561.     JZ    MINPUT    ;LOOP TILL CHAR RCD
  2562.     ENDIF        ;NOT TIMEOUT
  2563. ;
  2564.     IF    TIMEOUT
  2565.     JNZ    MINPUT2
  2566.     CALL    KDELAY    ;KILL 50 MS
  2567.     PUSH    H
  2568.     LHLD    TOCNT    ;KNOCK DOWN TIMEOUT COUNTER
  2569.     DCX    H
  2570.     SHLD    TOCNT
  2571.     MOV    A,H
  2572.     ORA    L
  2573.     POP    H
  2574.     JNZ    MINPUT1 ;STILL TIME LEFT..KEEP TRYING
  2575.     LDA    TOCNTM    ;COUNT OFF LAST MINUTE
  2576.     DCR    A
  2577.     JNZ    MINPUT0    ;GO BACK IF TIME LEFT
  2578.     CALL    ILPRT
  2579.     DB    '[Input timed out]',7,7,0
  2580.     JMP    NOSLASH
  2581.     ENDIF        ;TIMEOUT
  2582. ;
  2583. MINPUT2 EQU    $+OFFSET
  2584. ;
  2585.     IF    DUAL$IO ;BOTH LOCAL AND REMOTE
  2586.     CALL    CONSTAT ;CHECK LOCAL CONSOLE
  2587.     ORA    A    ;CHAR?
  2588.     JNZ    CONIN    ;..YES, READ IT, RET.
  2589.     ENDIF
  2590. ;
  2591. ;Local console wasn't ready, so read modem
  2592. ;
  2593.     IF    PORTED
  2594.     IN    DPORT    ;GET DATA BYTE
  2595.     ENDIF
  2596. ;
  2597.     IF    NOT PORTED
  2598.     LDA    DPORT
  2599.     ENDIF
  2600. ;
  2601.     ANI    7FH    ;DELETE PARITY
  2602.     JZ    MINPUT    ;IGNORE NULLS
  2603. ;
  2604.     IF    IMSAI AND HARDLOG
  2605.     PUSH    B
  2606.     MOV    B,A
  2607.     IN    SENSE
  2608.     ANI    LOGSW
  2609.     MOV    A,B
  2610.     POP    B
  2611.     JZ    NOLOG
  2612.     ENDIF        ;IMSAI AND HARDLOG
  2613. ;
  2614.     IF    HARDLOG AND (NOT IMSAI)
  2615.     PUSH    B
  2616.     MOV    B,A    ;PUT A COPY IN B
  2617.     LDA    HARDON    ;IF HARDON = 0 THEN TURN HARDLOG OFF (SO SYSOP
  2618.     ORA    A    ;        DOESN'T USE UP A LOT OF PAPER WHILE
  2619.     MOV    A,B    ;        PLAYING ZORK (FOO))
  2620.     POP    B
  2621.     JZ    NOLOG
  2622.     ENDIF
  2623. ;
  2624.     IF    HARDLOG
  2625.     CPI    20H
  2626.     JNC    MINPUT3
  2627.     CPI    CR
  2628.     JNZ    NOLOG
  2629. ;
  2630. MINPUT3    EQU    $+OFFSET
  2631.     CALL    LISTOUT ;ECHO ON PRINTER
  2632.     CPI    CR
  2633.     JNZ    NOLOG    ;CR NEEDS LINEFEED
  2634.     MVI    A,LF
  2635.     CALL    LISTOUT ;SO SEND IT
  2636.     MVI    A,CR    ;GET BACK CR
  2637.     ENDIF        ;END OF HARDLOG
  2638. ;
  2639. NOLOG    EQU    $+OFFSET
  2640. ;
  2641.     CPI    3    ;IS IT CONTROL-C?
  2642.     RNZ        ;NO, PASS IT THRU
  2643.     LDA    0    ;SEE IF WARM BOOT DISABLED
  2644.     CPI    0C3H    ;JMP MEANS WARM BOOT OK
  2645.     MVI    A,3    ;SO RETURN CONTROL-C
  2646.     RZ
  2647.     XRA    A    ;ELSE CONVERT TO NULL
  2648.     RET
  2649. ;
  2650. ;Modem output function
  2651. ;
  2652. MOUTPUT EQU    $+OFFSET
  2653. ;
  2654. ;If we already know carrier is lost, don't check
  2655. ;for it again or loop trying to output.
  2656. ;
  2657.     LDA    LOSTFLG ;KNOWN LOSS OF CARRIER?
  2658.     ORA    A
  2659.     JNZ    SILENT    ;AVOID LOOP IN CASE CARRIER LOST
  2660.     CALL    CHECK    ;CARRIER STILL ON?
  2661. ;
  2662.     IF    DCHAYES
  2663.     IN    STATUS    ;GET MODEM STATUS
  2664.     ANI    TRE    ;TRANSMIT BUFFER EMPTY?
  2665.     ENDIF        ;DCHAYES
  2666. ;
  2667.     IF    MMII
  2668.     LDA    TPORT    ;GET MODEM STATUS
  2669.     AU1P0TBMT
  2670.     ENDIF        ;MMII
  2671. ;
  2672.     IF    SMODEM AND PORTED
  2673.     IN    MSPORT
  2674.     ANI    P0TBMT
  2675.     ENDIF
  2676. ;
  2677.     IF    SMODEM AND NOT PORTED
  2678.     LDA    MSPORT
  2679.     ANI    P0TBMT
  2680.     ENDIF
  2681. ;
  2682.     IF    PMMI
  2683.     IN    TPORT    ;GET MODEM STATUS
  2684.     ANI    P0TBMT    ;TRANSMIT BUFFER EMPTY?
  2685.     ENDIF        ;PMMI
  2686. ;
  2687.     IF    IN8251
  2688.     IN    SPORT    ;GET MODEM STATUS
  2689.     ANI    TRNRDY    ;TRANSMIT BUFFER EMPTY?
  2690.     ENDIF        ;IN8251
  2691. ;
  2692.     IF    WD8250 
  2693.     IN    SPORT
  2694.     ANI    P0TBMT
  2695.     ENDIF        ;WD8250 
  2696. ;
  2697.     JZ    MOUTPUT ;LOOP IF NOT READY
  2698. ;
  2699.     IF    IMSAI AND BLKOUT AND DUAL$IO
  2700.     IN    SENSE    ;FLIP SWITCH UP...
  2701.     ANI    BLACKSW ;..TO BLIND REMOTE USER
  2702.     JNZ    SILENT
  2703.     ENDIF        ;IMSAI AND BLKOUT AND DUAL$IO
  2704. ;
  2705.     MOV    A,C    ;GET CHAR
  2706.     ANI    7FH    ;STRIP PARITY BIT
  2707. ;
  2708.     IF    TRAPLC
  2709.     CPI    60H    ;CHECK FOR LOWER CASE
  2710.     JC    MOUTP2    ;SKIP IF NOT LC
  2711.     CPI    7FH    ;CHECK FOR RUBOUT
  2712.     JZ    MOUTP2
  2713.     PUSH    H
  2714.     LXI    H,ULCSW ;SUBTRACT EITHER 20H OR 0
  2715.     SUB    M
  2716.     POP    H
  2717.     MOV    C,A    ;FORCE ON LOCAL AS WELL AS REMOTE
  2718. ;
  2719. MOUTP2    EQU    $+OFFSET
  2720.     ENDIF        ;TRAPLC
  2721. ;
  2722.     IF    OXGATE
  2723.     CPI    LF    ;WE HAVE A TOGGLE FOR LINE FEEDS
  2724.     JNZ    MOUTP3    ;NOPE, NOT A LF
  2725.     LDA    LFEEDS    ;YES, SEE IF WE CAN SEND IT...
  2726.     ORA    A    ;SET FLAGS
  2727.     MVI    A,0    ;PREPARE A WITH A NULL
  2728.     JNZ    MOUTP3    ;NOPE, DON'T (INSTEAD SEND A NULL)
  2729.     MVI    A,LF    ;YES, SEND THE LINE FEED
  2730. MOUTP3    EQU    $+OFFSET
  2731.     ENDIF        ;OXGATE
  2732. ;
  2733.     IF    NOT PORTED
  2734.     STA    DPORT    ;OUTPUT TO MODEM
  2735.     ENDIF
  2736. ;
  2737.     IF    PORTED
  2738.     OUT    DPORT    ;OUTPUT TO MODEM
  2739.     ENDIF
  2740. ;
  2741. SILENT    EQU    $+OFFSET
  2742. ;
  2743.     IF    DUAL$IO ;TO LOCAL ALSO?
  2744.     PUSH    PSW    ;SAVE CHAR
  2745.     CALL    CONOUT    ;SEND TO REGULAR BIOS
  2746.     POP    PSW    ;GET CHAR AGAIN
  2747.     ENDIF        ;DUAL$IO
  2748. ;
  2749. ;Check for nulls
  2750.     CPI    LF    ;TIME FOR NULLS?
  2751.     RNZ        ;NO, RETURN
  2752. ;Send nulls if required
  2753.     LDA    NULLS    ;GET COUNT
  2754.     ORA    A    ;ANY?
  2755.     RZ        ;..NO
  2756.     PUSH    B
  2757.     MOV    B,A    ;SAVE COUNT
  2758.     MVI    C,0    ;0 IS A NULL
  2759. ;
  2760. NULLP    EQU    $+OFFSET
  2761.     CALL    MOUTPUT ;TYPE A NULL
  2762.     DCR    B    ;MORE?
  2763.     JNZ    NULLP    ;..YES, LOOP
  2764.     POP    B
  2765.     MVI    C,LF    ;RESTORE LF
  2766.     RET
  2767. ;
  2768. ;Boot trap - becomes disconnect if JMP at 0 has been altered
  2769. ;
  2770. MBOOT    EQU    $+OFFSET
  2771.     LDA    0    ;LOOK AT OPCODE
  2772.     CPI    0C3H    ;IS IT STILL JMP?
  2773.     JZ    VWARMBT ;YES, ALLOW IT
  2774.     JMP    NOSLASH ;NO, DISCONNECT
  2775. ;
  2776. ;Inline print routine
  2777. ;
  2778. ILPRT    EQU    $+OFFSET
  2779.     XTHL        ;SAVE HL, GET MSG
  2780.     PUSH    B    ;SAVE BC REGS
  2781. ;
  2782. ILPLP    EQU    $+OFFSET
  2783.     MOV    C,M    ;GET CHAR
  2784.     CALL    MOUTPUT ;OUTPUT IT
  2785.     INX    H    ;POINT TO NEXT
  2786.     MOV    A,M    ;TEST
  2787.     ORA    A    ;..FOR END
  2788.     JNZ    ILPLP
  2789.     POP    B    ;RESTORE BC REGS
  2790.     XTHL        ;RESTORE HL, RET ADDR
  2791.     RET        ;RET PAST MSG
  2792. ;
  2793.     IF    PWRQD    ;KEEP PASSWORD HERE
  2794. ;Access password (ends in carriage return)
  2795. ;
  2796. PASSWD    EQU    $+OFFSET
  2797.     DB    'TWIT'    ;THE PASSWORD ITSELF
  2798.     DB    CR    ;END OF PASSWORD
  2799. ;Allow room for bigger password to be patched in
  2800.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2801.     ENDIF        ;PWRQD
  2802. ;
  2803. ;Routine to load the COM file
  2804. ;
  2805.     IF    COMFILE
  2806. LODCOM    EQU    $+OFFSET
  2807.     XRA    A    ;INITIALIZE FCB
  2808.     STA    COMFCB
  2809.     LXI    H,COMFCB+12
  2810.     MVI    B,21
  2811. ;
  2812. ZLOOP    EQU    $+OFFSET
  2813.     MVI    M,0
  2814.     INX    H
  2815.     DCR    B
  2816.     JNZ    ZLOOP
  2817. ;
  2818.     MVI    C,OPEN    ;NOW OPEN THE FILE
  2819.     LXI    D,COMFCB
  2820.     CALL    BDOS
  2821.     INR    A    ;SHOULD BE NON-ZERO
  2822.     JZ    ABORT    ;NO FILE, ABORT
  2823. ;
  2824. ;Now load the file
  2825.     LHLD    6    ;GET TOP OF MEMORY
  2826.     LXI    D,-80H    ;RECORD LOADS CAN'T START..
  2827.     DAD    D    ;..ABOVE (BDOS) - 80H
  2828.     PUSH    H    ;SAVE ON STACK
  2829. ;
  2830.     LXI    D,80H    ;TPA-80H
  2831.     LXI    B,0    ;KEEP A RECORD COUNTER
  2832.     PUSH    B    ;SAVE COUNTER
  2833.     PUSH    D    ;AND LOAD ADDRESS
  2834. ;
  2835. GLOOP    EQU    $+OFFSET
  2836.     POP    D    ;GET TPA ADRS
  2837.     LXI    H,80H    ;POINT TO NXT ADRS TO READ TO
  2838.     DAD    D    ;HL HAS THE ADDRESS
  2839.     POP    B    ;INCREMENT THE COUNTER
  2840. ;Check for load past top-of-memory
  2841.     POP    D    ;GET (TOP-OF-MEMORY)
  2842.     PUSH    D    ;RE-SAVE FOR NEXT TIME
  2843.     MOV    A,E    ;SUBTRACT: (TOP) - (ADRS)
  2844.     SUB    L
  2845.     MOV    A,D    ;ONLY THE CARRY NEEDED
  2846.     SBB    H
  2847.     JNC    SIZEOK    ;CY= BETTER MOVCPM
  2848.     CALL    ERRXIT    ;SO TELL THE STORY
  2849.     DB    '[Program area too small]','$'
  2850. ;
  2851. SIZEOK    EQU    $+OFFSET
  2852.     INX    B
  2853.     PUSH    B
  2854.     PUSH    H    ;SAVE TPA ADRS
  2855.     XCHG        ;ALIGN REGISTERS
  2856.     MVI    C,STDMA ;TELL BDOS WHERE TO PUT RECORD
  2857.     CALL    BDOS
  2858.     LXI    D,COMFCB ;NOW READ THE RECORD
  2859.     MVI    C,READ
  2860.     CALL    BDOS
  2861.     ORA    A
  2862.     JZ    GLOOP    ;A=0 IF MORE TO READ
  2863.     POP    B    ;UNJUNK STACK
  2864.     POP    B    ;THIS IS OUR COUNTER
  2865.     POP    H    ;MORE JUNK ON STACK
  2866.     MOV    A,B    ;CHECK FOR ZERO
  2867.     ORA    C
  2868.     JZ    ABORT    ;WE SHOULD HAVE READ SOMETHING
  2869.     LXI    D,80H    ;WE DID, RESET DMA TO 80H
  2870.     MVI    C,STDMA
  2871.     CALL    BDOS
  2872.     CALL    LOADOK    ;PRINT THIS MSG TO CONSOLE:
  2873.     DB    'COM file loaded',CR,LF,'$'
  2874. ;
  2875. LOADOK    EQU    $+OFFSET
  2876.     POP    D
  2877.     LDA    OPTION    ;SEE IF THIS WAS "BYE /C"
  2878.     CPI    'C'    ;IF IT WAS THEN..
  2879.     RZ        ;..DON'T PRINT MESSAGE
  2880.     MVI    C,PRINTF
  2881.     CALL    BDOS
  2882.     RET
  2883. ;
  2884. ABORT    EQU    $+OFFSET
  2885.     CALL    ERRXIT
  2886.     DB    CR,LF
  2887.     DB    '[Cannot find COM file]','$'
  2888. ;
  2889. ERRXIT    EQU    $+OFFSET
  2890.     POP    D
  2891.     MVI    C,PRINTF
  2892.     CALL    BDOS    ;PRINT THE ABORT MSG
  2893.     JMP    EXCPM    ;WARM BOOT
  2894.     ENDIF        ;COMFILE
  2895. ;
  2896. ;Here are two routines for the SmartModem, one will send a
  2897. ;+++ to the modem (after waiting 1 second guard time)
  2898. ;and the other one will send a string to the modem just like
  2899. ;ILPRT sends to the console.        -- pst
  2900. ;
  2901.     IF    SMODEM
  2902. SMINIT    EQU    $+OFFSET
  2903.     MVI    B,10        ;Wait one second
  2904.     CALL    DELAY
  2905.     CALL    SMSEND        ;send "+++"
  2906.     DB    '+++',0
  2907.     MVI    B,10        ;wait another second
  2908.     CALL    DELAY
  2909.     RET
  2910. ;
  2911. SMSEND    EQU    $+OFFSET
  2912.     XTHL        ;SAVE HL, GET MSG
  2913.     PUSH    B    ;SAVE BC REGS
  2914. ;
  2915. SMPLP    EQU    $+OFFSET
  2916.     ENDIF    ;SMODEM
  2917. ;
  2918.     IF    SMODEM AND PORTED
  2919.     IN    MSPORT
  2920.     ENDIF
  2921. ;
  2922.     IF    SMODEM AND NOT PORTED
  2923.     LDA    MSPORT
  2924.     ENDIF
  2925. ;
  2926.     IF    SMODEM
  2927.     ANI    P0TBMT    ;OK TO SEND?
  2928.     JZ    SMPLP
  2929.     MOV    A,M
  2930.     ENDIF    ;SMODEM
  2931. ;
  2932.     IF    SMODEM AND PORTED
  2933.     OUT    DPORT
  2934.     ENDIF
  2935. ;
  2936.     IF    SMODEM AND NOT PORTED
  2937.     STA    DPORT
  2938.     ENDIF
  2939. ;
  2940.     IF    SMODEM
  2941.     INX    H    ;POINT TO NEXT
  2942.     MOV    A,M    ;TEST
  2943.     ORA    A    ;..FOR END
  2944.     JNZ    ILPLP
  2945.     POP    B    ;RESTORE BC REGS
  2946.     XTHL        ;RESTORE HL, RET ADDR
  2947.     RET        ;RET PAST MSG
  2948.     ENDIF    ;SMODEM
  2949. ;
  2950. ;
  2951. ;This area is used for vectoring calls to the
  2952. ;user's CBIOS, but saving the registers first
  2953. ;in case they are destroyed.
  2954. ;
  2955. CONSTAT EQU    $+OFFSET
  2956.     PUSH    B
  2957.     PUSH    D
  2958.     PUSH    H
  2959.     CALL    VCONSTAT
  2960.     POP    H
  2961.     POP    D
  2962.     POP    B
  2963.     RET
  2964. ;
  2965. CONIN    EQU    $+OFFSET
  2966.     PUSH    B
  2967.     PUSH    D
  2968.     PUSH    H
  2969.     CALL    VCONIN
  2970. ;
  2971.     IF    FKEYS
  2972.     CALL    CKFUNC
  2973.     ENDIF        ;FKEYS
  2974. ;
  2975.     POP    H
  2976.     POP    D
  2977.     POP    B
  2978.     RET
  2979. ;
  2980. CKFUNC    EQU    $+OFFSET
  2981. ;
  2982.     IF    FKEYS AND IMSAI
  2983.     PUSH    B
  2984.     MOV    B,A    ;SAVE CHAR
  2985.     IN    SENSE    ;READ THE SWITCHES
  2986.     ANI    ENABLF    ;CHECK FKEY ENAB SW
  2987.     MOV    A,B    ;GET CHAR
  2988.     POP    B
  2989.     RZ        ;NO FUNCT IF SW OFF
  2990.     ENDIF        ;FKEYS AND IMSAI
  2991. ;
  2992.     IF    FKEYS
  2993.     CPI    SYSDKEY
  2994.     JZ    SYSDOWN ;TELL CALLER TO LEAVE
  2995.     CPI    TWITKEY
  2996.     JZ    DROPCAR    ;MAKE CALLER LEAVE
  2997.     CPI    MSGKEY
  2998.     RNZ
  2999.     CALL    ILPRT    ;SEND CALLER A MESSAGE
  3000.     DB    'Message from Sysop:',0
  3001.     MVI    A,' '    ;SOMETHING TO RETURN WITH
  3002.     RET
  3003. ;
  3004. SYSDOWN EQU    $+OFFSET
  3005.     CALL    ILPRT
  3006.     DB    'System going down in'
  3007.     DB    ' 5 minutes...',0
  3008.     MVI    A,' '
  3009.     RET
  3010.     ENDIF        ;FKEYS
  3011. ;
  3012. CONOUT    EQU    $+OFFSET
  3013.     PUSH    B
  3014.     PUSH    D
  3015.     PUSH    H
  3016.     CALL    VCONOUT
  3017.     POP    H
  3018.     POP    D
  3019.     POP    B
  3020.     RET
  3021. ;
  3022. LISTOUT    EQU    $+OFFSET
  3023.     PUSH    B
  3024.     PUSH    D
  3025.     PUSH    H
  3026.     PUSH    PSW
  3027.     MOV    C,A
  3028.     CALL    VLISTOUT
  3029.     POP    PSW
  3030.     POP    H
  3031.     POP    D
  3032.     POP    B
  3033.     RET
  3034. ;
  3035. ;This is the JMP table which is copied on top
  3036. ;of the one pointed to by location 1 in CP/M
  3037. ;
  3038. NEWJTBL EQU    $+OFFSET
  3039.     JMP    MCBOOT    ;COLD BOOT
  3040.     JMP    MBOOT    ;WARM BOOT
  3041.     JMP    MSTAT    ;MODEM STATUS TEST
  3042.     JMP    MINPUT    ;MODEM INPUT ROUTINE
  3043.     JMP    MOUTPUT ;MODEM OUTPUT ROUTINE
  3044.     IF    NOT ALLDEV
  3045.     RET        ;DUMMY LIST DEVICE
  3046.     NOP
  3047.     NOP
  3048.     ENDIF        ;NOT ALLDEV
  3049. ;
  3050.     IF    ALLDEV
  3051.     JMP    MOUTPUT    ;MODEM LIST DEVICE
  3052.     JMP    MOUTPUT    ;MODEM PUNCH DEVICE
  3053.     JMP    MINPUT    ;MODEM READER DEVICE
  3054.     ENDIF        ;ALLDEV
  3055. ;
  3056.     IF CCSDISK
  3057. ;
  3058. DSKON    EQU    $+OFFSET
  3059.     PUSH PSW    ;SAVE THE A AND FLAGS
  3060.     MVI A,DISKON    ;VALUE TO TURN ON MOTORS
  3061.     OUT DISK    ;TO THE DISK CONTROLLER
  3062.     PUSH H        ;THIS IS TIMER
  3063.     LXI H,0000H    ;THIS LONG
  3064. DSKLP    EQU    $+OFFSET
  3065.     XTHL
  3066.     XTHL
  3067.     DCX H        ;COUNT LOOP
  3068.     MOV A,H        ;CHECK FOR DONE
  3069.     ORA L
  3070.     JNZ DSKLP
  3071.     POP H        ;RESTORE HL
  3072.     POP PSW        ;AND A & FLAGS
  3073.     RET
  3074. ;
  3075. DSKOFF    EQU    $+OFFSET
  3076.     PUSH PSW    ;SAVE A & FLAG
  3077.     MVI A,DISKOFF    ;VALUE TO TURN MOTORS OFF
  3078.     OUT DISK
  3079.     POP PSW
  3080.     RET
  3081. ;
  3082.     ENDIF        ;CCSDISK
  3083. ;
  3084. IF     RTC
  3085. CLKBASE    EQU    50H    ;BASE OF SYSTEM SUPPORT 1 CARD
  3086. CLKCTL    EQU CLKBASE+10    ;CLOCK CONTROL PORT
  3087. CLKDATA    EQU CLKBASE+11    ;CLOCK DATA PORT
  3088. CREAD    EQU    10H+40H    ;READ COMMAND + HOLD COUNT COMMAND
  3089. ;
  3090. TIME    EQU    $+OFFSET
  3091.     PUSH H
  3092.     PUSH D
  3093.     PUSH B
  3094.     PUSH PSW
  3095.     MVI D,CREAD+5    ;POINT TO 10S OF HOURS
  3096.     MVI B,3        ;3 LOOPS
  3097.     JMP TX        ;START W/ NO SEPARATOR
  3098. ;
  3099. T1    EQU    $+OFFSET
  3100.     MVI C,':'    ;SEPARATOR
  3101.     CALL MOUTPUT    ;TO THE PRINTER
  3102. TX    EQU    $+OFFSET
  3103.     MOV A,D        ;GET THE DIGIT ADDRESS
  3104.     CALL CLOCK    ;GET THE VALUE
  3105.     MOV C,A        ;SAVE IT
  3106.     MVI A,CREAD+5    ;TEST FOR FIRST LOOP
  3107.     CMP D        ;1ST LOOP?
  3108.     MOV A,C        ;RECOVER THE VALUE
  3109.     JNZ T2        ;JUMP IF NOT 1ST LOOP
  3110.     ANI 3        ;DROP PM INDICATOR
  3111. T2    EQU    $+OFFSET
  3112.     ADI '0'        ;ADD ASCII BIAS
  3113.     MOV C,A
  3114.     CALL MOUTPUT    ;AND PRINT IT
  3115.     DCR D        ;POINT TO NEXT DIGIT
  3116.     MOV A,D        ;GET THE DIGIT ADDRESS TO A
  3117.     CALL PCLOCK    ;GET & PRINT ASCII
  3118.     DCR D        ;BUMP DIGIT COUNTER
  3119.     DCR B
  3120.     JNZ T1        ;LOOP TILL ALL PRINTED
  3121. ;
  3122. ;
  3123.     CALL ILPRT    ;PRINT THE TIME ZONE
  3124.     DB ' CST  ',0 ;CENTRAL STANDARD TIME
  3125. ;
  3126. ; WE WILL NOW PRINT THE DAY OF THE WEEK, FOLLOWED
  3127. ; BY THE MONTH, DATE AND YEAR
  3128. ;
  3129. ;
  3130.     MVI A,CREAD+6    ;THIS IS DAY OF WEEK 
  3131.     CALL CLOCK    ;GET THE DAY NUMBER
  3132. ;
  3133. DAYDONE    EQU    $+OFFSET
  3134.     ADD A        ;DOUBLE DAY COUNT
  3135.     LXI H,DAYS    ;POINT TO TABLE
  3136.     MOV E,A        ;ADD OFFSET TO DE
  3137.     MVI D,0
  3138.     DAD D        ;NEW POINTER IN HL
  3139.     MOV A,M        ;GET LO BYTE OF WORD
  3140.     INX H        ;POINT TO HI BYTE
  3141.     MOV H,M        ;TO H
  3142.     MOV L,A        ;PLUS LO BYTE POINTS TO STRING
  3143.     CALL LINOUT    ;PRINT THE DAY
  3144. ;
  3145.     MVI A,CREAD+10    ;10S OF MONTHS
  3146.     CALL CLOCK
  3147.     ORA A        ;WE GOT 10'S OF MONTHS?
  3148.     JZ NOTENS    ;JUMP IF NOT
  3149.     MVI A,10    ;ADD 10S IF WE GOT EM
  3150. NOTENS    EQU    $+OFFSET
  3151.     MOV B,A        ;SAVE 10S IN B
  3152.     MVI A,CREAD+9    ;GET THE ONES
  3153.     CALL CLOCK
  3154.     ADD B        ;ADD TO THE 10S PLACE TO GET MONTH
  3155.     DCR A        ;CORRECT FOR JAN=1
  3156.     ADD A        ;DOUBLE MONTH NUMBER
  3157.     LXI H,MONTHS    ;POINT TO DISPATCH TABLE
  3158.     MOV E,A        ;OFF SET TO DE
  3159.     MVI D,0
  3160.     DAD D        ;POINTER TO STRING AT (HL)
  3161.     MOV A,M        ;GET LO BYTE TO A
  3162.     INX H        ;POINT TO NEXT
  3163.     MOV H,M        ;HI BYTE TO H
  3164.     MOV L,A        ;LO BYTE TO L POINTS TO STRING
  3165.     CALL LINOUT    ;PRINT THE MONTH
  3166. ;
  3167.     MVI A,CREAD+8    ;10S OF DAYS
  3168.     CALL CLOCK
  3169.     ANI 3        ;DROP LEAP YEAR INDICATOR
  3170.     JZ NTENS    ;JUMP IF NO TENS PLACE
  3171.     CALL PASC    ;PRINT IT
  3172. NTENS    EQU    $+OFFSET
  3173.     MVI A,CREAD+7    ;ONES OF DAYS
  3174.     CALL PCLOCK    ;PRINT THEM
  3175.     LXI H,YEAR    ;PLUS YEAR MESSAGE
  3176.     CALL LINOUT    ;TO LISTER
  3177.     MVI A,CREAD+12    ;TENS OF YEAR
  3178.     CALL PCLOCK    ;PRINT THEM
  3179.     MVI A,CREAD+11    ;ONES OF YEAR
  3180.     CALL PCLOCK
  3181.     CALL ILPRT    ;FINISH THE LINE
  3182.     DB CR,LF,CR,LF,0
  3183.     POP PSW
  3184.     POP B
  3185.     POP D
  3186.     POP H
  3187.     RET
  3188. ;
  3189. PCLOCK    EQU    $+OFFSET
  3190.     CALL CLOCK    ;GET THE DIGIT
  3191. PASC    EQU    $+OFFSET
  3192.     ADI '0'        ;ADD ASCII BIAS
  3193.     MOV C,A
  3194.     JMP MOUTPUT    ;AND PRINT
  3195. ;
  3196. CLOCK    EQU    $+OFFSET
  3197.     OUT CLKCTL    ;TELL IT ADDRESS
  3198.     IN CLKDATA    ;GET THE DATA NYBBLE
  3199.     PUSH PSW    ;SAVE THE DATA
  3200.     XRA A        ;GET 0
  3201.     OUT CLKCTL    ;RESET HOLD BIT
  3202.     POP PSW        ;RESTORE DATA
  3203.     RET
  3204. ;
  3205. LINOUT    EQU    $+OFFSET
  3206.     MOV A,M        ;GET THE CHARACTER
  3207.     CPI '$'        ;DONE?
  3208.     RZ        ;RETURN IF DONE
  3209.     MOV C,A        ;ELSE PRINT IT
  3210.     CALL MOUTPUT
  3211.     INX H        ;POINT TO NEXT CHARACTER
  3212.     JMP LINOUT    ;THEN LOOP TILL DONE
  3213. ;
  3214. ;
  3215. SUN    EQU    $+OFFSET
  3216.     DB 'Sunday, $'
  3217. MON    EQU    $+OFFSET
  3218.     DB 'Monday, $'
  3219. TUE    EQU    $+OFFSET
  3220.     DB 'Tuesday, $'
  3221. WED    EQU    $+OFFSET
  3222.     DB 'Wednesday, $'
  3223. THU    EQU    $+OFFSET
  3224.     DB 'Thursday, $'
  3225. FRI    EQU    $+OFFSET
  3226.     DB 'Friday, $'
  3227. SAT    EQU    $+OFFSET
  3228.     DB 'Saturday, $'
  3229. ;
  3230. JAN    EQU    $+OFFSET
  3231.     DB 'January $'
  3232. FEB    EQU    $+OFFSET
  3233.     DB 'February $'
  3234. MAR    EQU    $+OFFSET
  3235.     DB 'March $'
  3236. APR    EQU    $+OFFSET
  3237.     DB 'April $'
  3238. MAY    EQU    $+OFFSET
  3239.     DB 'May $'
  3240. JUN    EQU    $+OFFSET
  3241.     DB 'June $'
  3242. JUL    EQU    $+OFFSET
  3243.     DB 'July $'
  3244. AUG    EQU    $+OFFSET
  3245.     DB 'August $'
  3246. SEP    EQU    $+OFFSET
  3247.     DB 'September $'
  3248. OCT    EQU    $+OFFSET
  3249.     DB 'October $'
  3250. NOV    EQU    $+OFFSET
  3251.     DB 'November $'
  3252. DEC    EQU    $+OFFSET
  3253.     DB 'December $'
  3254. ;
  3255. YEAR    EQU    $+OFFSET
  3256.     DB ', 19$'
  3257. ;
  3258. ;#################################################
  3259. DAYS    EQU    $+OFFSET
  3260.     DW SUN
  3261.     DW MON
  3262.     DW TUE
  3263.     DW WED
  3264.     DW THU
  3265.     DW FRI
  3266.     DW SAT
  3267.     DW SUN
  3268. ;
  3269. MONTHS    EQU    $+OFFSET
  3270.     DW JAN
  3271.     DW FEB
  3272.     DW MAR
  3273.     DW APR
  3274.     DW MAY
  3275.     DW JUN
  3276.     DW JUL
  3277.     DW AUG
  3278.     DW SEP
  3279.     DW OCT
  3280.     DW NOV
  3281.     DW DEC
  3282. ;
  3283. ;
  3284.     ENDIF        ;RTC
  3285. ;
  3286. WELFILN EQU    $+OFFSET
  3287.     DB    0,'WELCOME    ',0
  3288. ;Welcome file name ^^^^^^^^^^^ (must be 11 characters)
  3289. ;
  3290. COMFCB    EQU    $+OFFSET
  3291. ;
  3292.     IF    NOT OXGATE
  3293.     DB    0,'RBBS    COM'
  3294. ;COM file name       ^^^^^^^^^^^ (must be 11 characters)
  3295.     ENDIF        ;NOT OXGATE
  3296. ;
  3297.     IF     OXGATE
  3298.     DB    0,'OXENTR  COM'
  3299. ;COM file name     ^^^^^^^^^^^ (must be 11 characters)
  3300.     ENDIF        ;OXGATE
  3301. ;
  3302. PEND    EQU    $+OFFSET ;END OF RELOCATED CODE
  3303. ;
  3304. ;These areas are not initialized
  3305. ;
  3306.     DS    21    ;REST OF COM FCB
  3307. ;
  3308. OPTION    EQU    $+OFFSET
  3309.     DS    1
  3310. ;
  3311. TOCNTM    EQU    $+OFFSET
  3312.     DS    1
  3313. ;
  3314. TOCNT    EQU    $+OFFSET
  3315.     DS    2
  3316. ;
  3317. ;Byte to keep track of lost carrier when
  3318. ;typing "[Carrier Lost]" so we don't loop
  3319. ;
  3320. LOSTFLG EQU    $+OFFSET
  3321.     DS    1
  3322. ;
  3323. ;Save the CP/M jump table here
  3324. ;
  3325. VCOLDBT EQU    $+OFFSET
  3326.     DS    3
  3327. ;
  3328. VWARMBT EQU    $+OFFSET
  3329.     DS    3
  3330. ;
  3331. VCONSTAT EQU    $+OFFSET
  3332.      DS    3
  3333. ;
  3334. VCONIN     EQU    $+OFFSET
  3335.      DS    3
  3336. ;
  3337. VCONOUT  EQU    $+OFFSET
  3338.      DS    3
  3339. ;
  3340. VLISTOUT EQU    $+OFFSET
  3341.      DS    3
  3342. ;
  3343. VPUNCH    EQU    $+OFFSET
  3344.     DS    3
  3345. ;
  3346. VREADER    EQU    $+OFFSET
  3347.     DS    3
  3348. ;
  3349. ;
  3350. ;
  3351. ;Since these areas are not initialized,
  3352. ;the following counters will not be changed
  3353. ;by subsequent loads of this program
  3354. ;
  3355.     IF    USRLOG
  3356. OLDUSR    EQU    $+OFFSET
  3357.     DS    2
  3358. ;
  3359. NEWUSR    EQU    $+OFFSET
  3360.     DS    2
  3361. ;
  3362. NONUSR    EQU    $+OFFSET
  3363.     DS    2
  3364.     ENDIF        ;USRLOG
  3365. ;
  3366. ;
  3367.     DS    60
  3368. STACK    EQU    $+OFFSET ;LOCAL STACK
  3369. ;
  3370. ENDMARK    EQU    $+OFFSET ;! IGNORE ERROR. THIS MARKS END OF PGM
  3371. ;
  3372. ;BDOS equates
  3373. ;
  3374. CI    EQU    1
  3375. WRCON    EQU    2
  3376. DRECTIO EQU    6
  3377. PRINTF    EQU    9
  3378. CSTS    EQU    11
  3379. OPEN    EQU    15
  3380. READ    EQU    20
  3381. STDMA    EQU    26
  3382. BDOS    EQU    5
  3383. FCB    EQU    5CH 
  3384. FCBRNO    EQU    FCB+32
  3385. ;
  3386.     END
  3387.