home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpmug / cpmug047.ark / DIAL6_23.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  22KB  |  868 lines
  1. ;
  2. ;DIAL.ASM  V2.0   BY JEFF HAMMERSLEY
  3. ;                    7738 MIDDLEPOINTE
  4. ;                    DEARBORN,MI  48126
  5. ;                    313-935-1716
  6. ;
  7. ;(WRITTEN 9/21/79)
  8. ;MODIFIED BY KEITH PETERSEN 
  9. ;  11/21/79  BASIC TIMING MODS.
  10. ;  12/04/79  EQUATE AND LABEL FOR 20PPS DIALING
  11. ;NUMBER LIST ASCII INFO. EXTENDED 12/16/79
  12. ;RINGBACK REWRITTEN 3/8/80
  13. ;      (BY COMMITTEE DECISION, THE FANCY FOOTWORK PREVIOUSLY
  14. ;    DONE TO IDENTIFY BUSY AND FAR END RINGING HAVE BEEN
  15. ;    REMOVED IN FAVOR OF A MORE RELIABLE, SIMPLE CARRIER OR TONE
  16. ;    IDENTIFICATION.)
  17. ;
  18. ;UPDATE 6/22/80
  19. ;CORRECTED ERROR IN SELECTING 'A' (REQUIRES NO OFFSET) 
  20. ;ALSO CLEANED UP PHONELIST, NOLONGER LEAVES 'GARBAGE' IN AREA.
  21. ;AND IT IS EASIER TO KEEP TRACK OF DATA AREA.....
  22. ;    HANK SZYSZKA
  23. ;    PO BOX 6
  24. ;    BEARSVILLE NEW YORK 12409
  25. ;       1-914-679-6559 (MODEM)
  26. ;
  27. ;06/23/80 CORRECTED EDITING ERRORS IN COMMENTS AND
  28. ;      SET MODEM PORT NUMBERS TO PMMI STANDARD. (KBP)
  29. ;
  30. ;CP/M - PMMI CONSOLE, STORED, AND PRESET AUTODIALING
  31. ;PROGRAM.
  32. ;
  33. ;  THIS PROGRAM CONTAINS MANY FEATURES FOUND IN WARD
  34. ;CHRISTENSEN'S MODEM PROGRAM 8/6/79 AND THE ORIGINATE-
  35. ;ANSWER DEMO. PROGRAM DISTRIBUTED BY PMMI FOR THEIR
  36. ;MM103 MODEM (4/2/79). FULL CREDIT MUST BE GIVEN TO
  37. ;THESE INDIVIDUALS FOR THEIR GROUND WORK.
  38. ;
  39. ;***********************************************************
  40. ;   EQUATES
  41. ;
  42. MCTLP     EQU    0C0H    ;PMMI VALUES
  43. MSNDB    EQU    1    ;BIT TO TEST FOR SEND
  44. MSNDR     EQU    1    ;VALUE WHEN READY
  45. MRCVB    EQU    2    ;BIT TO TEST FOR RECEIVE
  46. MRCVR     EQU    2    ;VALUE WHEN READY
  47. MDATP    EQU    0C1H    ;DATA PORT
  48. BAUDRP     EQU    0C2H    ;BAUD RATE OUTPUT
  49. MCTL2     EQU    0C3H    ;SECOND CTL PORT
  50. ;
  51. ORIGM     EQU    1DH    ;8 DATA, NO PARITY, ORIG
  52. ;
  53. NUMPPS     EQU    125    ;125=20PPS, 250=10PPS
  54. PULSE     EQU    80H    ;TIMER PULSE MASK
  55. MAKE     EQU    01H    ;TEL LINE MAKE (OFF HOOK)
  56. BRK     EQU    00H    ;TEL LINE BREAK (ON HOOK)
  57. INTER     EQU    7    ;INTERDIGIT TIME
  58. CLEAR     EQU    3FH    ;CLEAR MODEM TO IDLE
  59. DTDET     EQU    2FH    ;SWITCH ON DIAL TONE DETECT
  60. DTMSK     EQU    01H    ;DIAL TONE MASK
  61. DTR3     EQU    07FH    ;DATA TERMINAL READY (300 baud)
  62. CTSBT     EQU    04H    ;CLEAR TO SEND BIT
  63. BAUDRT     EQU    52    ;BAUD RATE = 300
  64. TRATE     EQU    255    ;TIMER RATE = 0.1 SEC/PULSE
  65. ;
  66. ;** RINGBACK TIMING EQUATES **
  67. ;(MAY REQUIRE OPTIMIZATION TO YOUR LOCAL OR LONG DISTANCE SITUATION)
  68. ;
  69. ;ROUTINE DIALING
  70. NATOUT     EQU    200    ;# OF SEC*10 TO WAIT BEFORE GIVING NO ANSWER MESSAGE
  71. ;
  72. ;RINGBACK
  73. RBLMT     EQU    70    ;# OF SEC*10 TO WAIT BEFORE GIVING NO RING HEARD MESS.
  74. RBWAIT     EQU    50    ;# OF SEC*10 DELAY BEFORE REDIALING NUMBER
  75. ;
  76. ;
  77. DISCCH     EQU    'D'-40H    ;CTL-D DISCONNECTS MODEM RTN TO CP/M
  78. RESTAR   EQU    'C'-40H    ;CTL-C ABORT TO CONSOLE PHONE # ENTRY
  79. ESCTCP   EQU    'E'-40H    ;CTL-E RTN TO CPM WITHOUT DISCONNECT
  80. LSTCHR     EQU    'P'-40H    ;CTL-P TURN ON/OFF LIST DEVICE (SPEED >300 BAUD)
  81. RBKCHA     EQU    'R'    ;RINGBACK SEQUENCE
  82. ;
  83. TIMESH     EQU    0    ;PUT 1 HERE TO PULL BIT 7 HIGH
  84. LSTDEV     EQU    1    ;PUT 1 HERE IF YOU HAVE A LIST DEVICE CAPABLE
  85.             ; OF SPEED >300 BAUD
  86. ;
  87. ;DEFINE ASCII CHARACTERS USED
  88. ;
  89. LF       EQU    10    ;LINEFEED
  90. CR     EQU    13    ;CARRIAGE RETURN
  91. BELL     EQU    07    ;BELL
  92. ; 
  93. ;*********************************************************
  94. ;
  95.     ORG    100H
  96. ;
  97. ;INIT PRIVATE STACK
  98.     LXI    H,0    ;HL=0
  99.     DAD    SP    ;HL=STACK FROM CP/M
  100.     SHLD    STACK    ;..SAVE IT
  101. ;
  102. RESTRT    LXI    SP,STACK ;SP=MY STACK
  103.     CALL    START    ;GO PRINT ID
  104.     DB    1AH,0,0,0,0,0 ;ADM-3 SCREEN CLEAR 
  105.     DB    0,0,0,0,0,0    ;NULLS FOR SCREEN CLEAR
  106.     DB    'DIAL PROGRAM as of '
  107.     DB    '6/22/80',CR,LF,CR,LF,'$'
  108. ;
  109. START    POP    D    ;GET ID MESSAGE
  110.     CALL    PRTMSG    ;PRINT IT
  111. ;
  112. ;INITIALIZE JUMPS TO CP/M CBIOS
  113. ;
  114.     CALL    INITAD
  115. ;
  116. ;CHECK FOR PRIMARY OPTIONS OF EITHER X OR #
  117.     LXI    D,FCB+1    ;GET FIRST OPTION
  118.     LDAX    D
  119.     CPI    'X'    ;IS IT 'X' ?
  120.     JZ    EXAM    ;YES, EXAMPLE PRINT
  121.     CPI    '#'    ;IS IT '#' ?
  122.     JZ    DISCON    ;YES, DISCONNECT
  123. ;
  124. ;CLEAR MODEM TO IDLE
  125.     MVI    A,CLEAR
  126.     OUT    MCTL2
  127.     MVI    A,BRK    ;GO ON HOOK IF NOT ALREADY THERE
  128.     OUT    MCTLP
  129.     MVI    B,25    ;SET UP TIMER
  130.     CALL    TIMER
  131. ;
  132. ;HELP PRINT
  133.     LXI    D,MENU    ;PRINT CTRL-CHAR. CODES
  134.     CALL    PRTMSG
  135. ;
  136. ;EVALUATE OPTION SELECTED
  137.     JMP    PRIOPT
  138. ;
  139. ;
  140. ;  GO TO ORIGINATE MODE AND IDENTIFY THE DIAL TONE
  141. ;***********************************************************
  142. ;
  143. ORIGMD:    MVI    A,MAKE    ;GO OFF HOOK IN ORGINATE MODE
  144.     OUT    MCTLP    ;
  145.     MVI    A,DTDET    ;SWITCH IN DIAL TONE DETECT FILTERS
  146.     OUT    MCTL2
  147. ; WAIT FOR DIAL TONE (TIME OUT)
  148.     MVI    D,DTMSK    ;LOAD MASK FOR DIAL TONE PRESENCE
  149.     CALL    WAT15
  150.     LXI    D,DMESS    ;DIAL TONE DETECTED MESSAGE
  151.     CALL    PRTMSG    ;PRINT ROUTINE
  152.     RET
  153. ;
  154. ;
  155. ;   EVALUATE OPTION AFTER DIAL COMMAND
  156. ;**********************************************************
  157. ;
  158. PRIOPT:    XRA    A
  159.     STA    NFLAG    ;ZERO NUMBER FLAG
  160.     LXI    D,FCB+1    ;GET 1ST OPTION CHAR.
  161.     LDAX    D    ; FOUND IN FCB
  162.     STA    OPTION    ;SAVE IT
  163.     CPI    40H    ;IS IT >= A
  164.     JNC    GTHAN    ;YES (IT MAY BE A LETTER)
  165.     JMP    CKNUM    ;NO, SEE IF A NUMBER
  166. ;
  167. GTHAN    CPI    5BH    ;IF <= Z THEN IT IS A LETTER
  168.     JC    LETTER
  169.     JMP    CKNUM    ;SEE IF IT IS ANOTHER CHAR. > Z
  170. ;
  171. LETTER    CALL    ORIGMD    ;GO OFF HOOK, IDENT. DIAL TONE
  172.     LXI    H,00    ;LOAD H-L RESET TO ZERO
  173.     LDA    OPTION    ;GET OPTION CHAR.
  174.     CPI    'A'    ;IS IT AN 'A' (NO  OFFSET REQ)
  175.     JZ    NOFFS    ;YES, THE BYPASS OFFSET.
  176.     LXI    D,30    ;SET D-E TO OFFSET VALUE
  177.     SUI    41H    ;SUBTRACT 41H FROM LETTER TO GET #
  178.             ; OF 30 BYTE BLOCKS TO SKIP
  179.     MOV    B,A    ;MOVE TO B
  180. ;
  181. LOOP    DAD    D    ;ADD OFFSET
  182.     DCR    B
  183.     JNZ    LOOP    ;ADD APPROPRIATE # UNTIL DONE
  184. ;
  185. NOFFS    LXI    D,NUMLST ;GET PHONE NUMBER LIST ORIGIN
  186.     DAD    D    ;ADD TO OFFSET IN H-L
  187.     XCHG        ;MOVE RESULT TO D-E
  188.     JMP    PROCS    ;READ AND DIAL PRESET NUMBER
  189. ;
  190. CKNUM    CALL    ORIGMD    ;GO OFF HOOK, IDENT. DIAL TONE
  191.     LXI    H,NUMBR    ;LOAD H-L WITH LOCATION OF CURRENT # BUFF
  192.     SHLD    NBP    ;SAVE IN BUFF POINTER
  193.     LDA    FCB+1    ;GET FIRST CHARACTER AGAIN
  194.     LXI    D,DBUF+2
  195. ;
  196. CKNM    CPI    'R'    ;IS IT RINGBACK?
  197.     JZ    RINGBK    ;YES
  198.     CPI    2FH    ;IF CHAR. >='0'
  199.     JNC    GT0    ;YES
  200.     CPI    ' '    ;IS IT A SPACE?
  201.     JZ    QDONE    ;YES, CK IF DONE OR CONSOLE ENTRY
  202.     ORA    A    ;IS IT BINARY 0? (END OF DBUF)
  203.     JZ    QDONE    ;YES, DONE
  204.     CPI    '-'    ;IS IT DASH?
  205.     JZ    IGN    ;IGNORE
  206.     JMP    BDCHR    ;NO, MUST BE A BAD CHAR.
  207. ;
  208. GT0    CPI    3AH    ;IS IT <= 9 ?
  209.     JC    NUM    ;YES
  210.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  211. ;
  212. NUM    CALL    TYPE    ;PRINT DIGIT
  213.     CALL    DIAL    ;DIAL THE DIGIT
  214.     MVI    A,0FFH    ; FLIP NUMBER FLAG (NOTES IF ANY # DIALED)
  215.     STA    NFLAG    ;
  216. ;
  217. IGNRE    INX    D    ;GET ANOTHER CHAR. FROM DBUF
  218.     LDAX     D    ;
  219.     JMP    CKNM    ;IF FIRST CHARACTER IS A NUMBER ASSUME THAT THE REST
  220.             ;ARE AND SO GO GET ANOTHER.
  221. IGN    CALL    TYPE    ;PRINT '-'
  222.     JMP    IGNRE
  223. ;
  224. QDONE    LDA    NFLAG    ;IS THIS THE FIRST CHAR. POSITION?
  225.     ORA    A    ; IF SO, AND IT IS A BLANK, ASSUME
  226.     JZ    CNSLE    ; THAT WE WANT CONSOLE INPUT
  227.     JMP    DIALE    ;NO, IT ISN'T- SO STORE AN EOF CHAR. IN
  228.             ; CURRENT NUMBER BUFFER
  229.             ;DIALING ENDED WAIT FOR ANSWER
  230. ;
  231. CNSLE:    LXI    D,PMESS    ;ENTER PHONE NUMBER MESSAGE
  232.     CALL    PRTMSG
  233.     MVI    D,255    ;25 SECONDS - TOTAL DIALING TIME ALLOWED
  234. ;
  235. CNSL1    CALL    STAT    ;CHAR. ENTERED?
  236.     JNZ    CNSL2    ;YES
  237. ;
  238. ;ALLOW ONLY 255 TIME ELEMENTS TO DIAL
  239.     MVI    B,1
  240.     CALL    TIMER
  241.     DCR    D
  242.     JZ    HEXIT    ;ABORT- TAKING TOO LONG TO DIAL
  243.     JMP    CNSL1
  244. ;
  245. CNSL2    CALL    KEYIN    ; GET IT
  246.     CALL    SPECL    ;ABORT?, REDIAL? etc.
  247.     CALL    TYPE    ; PRINT IT ON TERMINAL
  248.     CPI    2FH    ; >=0 ?
  249.     JNC    NM0    ;YES
  250.     CPI    ' '    ;IGNORE SPACES
  251.     JZ    CNSL1    ;
  252.     CPI    '-'    ;IGNORE DASHES
  253.     JZ    CNSL1    ;
  254.     CPI    CR    ;IF 'CR', THEN END OF NUMBER
  255.     JZ    NEND    ;
  256.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  257. ;
  258. NEND    CALL    CRLF    ;PRINT A CRLF
  259.     JMP    DIALE    ;END OF DIALING
  260. ;
  261. NM0    CPI    3AH    ; <= 9 ?
  262.     JC    CSLE    ;FOUND A NUM. 0-9
  263.     CPI    'R'    ;RINGBACK MODE
  264.     JZ    RINGBK    ;
  265.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  266. ;
  267. CSLE    CALL    DIAL    ;DIAL DIGIT
  268.     JMP    CNSL1    ;GET ANOTHER
  269. ;
  270. ;  DIAL STORED NUMBER REFERENCED BY D-E, THEN
  271. ;   PRINT TRAILING INFO.
  272. PROCS:    XRA    A    ;ZERO    ACC.
  273.     STA    PFLAG    ;ZERO PRINT FLAG
  274.     LXI    H,NUMBR    ;GET NUM BUFF START
  275.     SHLD    NBP    ;SAVE IN POINTER
  276. ;
  277. PRCS1    LDA    PFLAG    ;IS PRINT FLAG ON ?(=FFH)
  278.     CPI    0FFH
  279.     LDAX    D    ;LOAD ACC WITH 1ST CHARACTER REF. BY D-E
  280.     JZ    INCR    ;IF PFLAG ON THEN PRINT ONLY
  281.     CPI    '*'    ;EMPTY NUMBER SLOT
  282.     JZ    NONUM
  283.     CPI    ' '    ;BLANK?
  284.     JZ    INCR    ;PRINT AND ADVANCE
  285.     CPI    '-'    ;DASH?
  286.     JZ    INCR    ;PRINT AND ADVANCE
  287.     CPI    '"'    ;REST TO BE PRINT ONLY?
  288.     JZ    PSET    ;YES
  289.     CPI    2FH    ; >=0
  290.     JNC    GTH    ;YES
  291.     CPI    '$'    ;EOF ?
  292.     JZ    DIALE    ;END OF DIALING
  293.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  294. ;
  295. DIGIT    CALL    TYPE    ;PRINT DIGIT
  296.     CALL    DIAL    ;DIAL IT
  297.     JMP    INCR1
  298. ;
  299. GTH    CPI    3AH    ;<=9 ?
  300.     JC    DIGIT    ;DIAL THE NUMBER
  301.     DCX    D    ;ADJUST POINTER TO 1 LESS
  302.             ; THAN LOC. OF 'R'
  303.     CPI    'R'    ;RINGBACK?
  304.     JZ    RBPRT    ;YES
  305.     JMP    BDCHR    ;BAD CHARACTER
  306. ;
  307. RBPRT    INX    D    ;RINGBACK PRINT SEQ.
  308.     LDAX    D    ;GET CHAR.
  309.     CPI    '"'    ;NON-PRINTING
  310.     JZ    RBPRT
  311.     CPI    '$'    ;END?
  312.     JZ    RBPR1    ;YES
  313.     CALL    TYPE    ;PRINT IT
  314.     JMP    RBPRT    ;GET ANOTHER
  315. ;
  316. RBPR1    MVI    A,LF    ;
  317.     CALL    TYPE
  318.     JMP    RINGBK    ;TO RINGBACK ROUTINE
  319. ;
  320. INCR    CPI    '$'    ;EOF CHAR.?
  321.     JZ    DIALE    ;DIALEND
  322.     CALL    TYPE
  323. ;
  324. INCR1    INX    D
  325.     JMP    PRCS1
  326. ;
  327. NONUM    LXI    D,NMESS    ;NO NUMBER LISTED MESSAGE
  328.     CALL    PRTMSG
  329.     JMP    HEXIT    
  330. ;
  331. PSET    MVI    A,0FFH    ;LOAD PRINT ONLY FLAG
  332.     STA    PFLAG
  333.     JMP    INCR1    ;GET NEXT CHAR.(DON'T PRINT  ")
  334. ;
  335. ;
  336. ;
  337. ;  AUTO-DIAL ROUTINE
  338. ;*********************************************************
  339. ;
  340. DIAL    ANI    0FH    ;CONVERT TO BINARY
  341.     LHLD    NBP    ;GET BUFF POINTER
  342.     MOV    M,A    ;SAVE DIGIT IN BUFF
  343.     INX    H    ;INCRE. BUFF POINTER
  344.     SHLD    NBP    ;SAVE BUFF. POINTER
  345. ;
  346. DIALR    CPI    0    ;IF 0 CONVERT TO 10
  347.     JNZ    DIALS
  348.     MVI    A,10
  349. ;
  350. DIALS    MOV    C,A    ;LOAD C WITH #
  351.     MVI    A,NUMPPS ;SET UP TIMER PULSE RATE
  352.     OUT    BAUDRP
  353. ;
  354. DIALC    IN    BAUDRP    ;WAIT IF TIMER PULSE NOT = 0
  355.     ANI    PULSE
  356.     JNZ    DIALC
  357. ;
  358. DIALB    IN    BAUDRP    ;WAIT UNTIL TRANSITION TO 1 FOR SYNC
  359.     ANI    PULSE
  360.     JZ    DIALB
  361. ;
  362. MKPLSE    MVI    A,MAKE    ;START WITH A MAKE
  363.     OUT    MCTLP
  364. ;
  365. TIMEM    IN    BAUDRP    ;WAIT FOR MAKE INTERVAL TO END
  366.     ANI    PULSE
  367.     JNZ    TIMEM
  368.     MVI    A,BRK    ;BREAK
  369.     OUT    MCTLP
  370. ;
  371. TIMEB    IN    BAUDRP    ;WAIT FOR BREAK PULSE INTERVAL
  372.     ANI    PULSE
  373.     JZ    TIMEB
  374.     DCR    C    ;MORE PULSES FOR THIS DIGIT?
  375.     JNZ    MKPLSE    ;YES
  376. ; LAST PULSE WAIT FOR INTERDIGIT TIME
  377.     MVI    A,MAKE
  378.     OUT    MCTLP
  379.     MVI    A,NUMPPS
  380.     MVI    B,INTER    ;INTERDIGIT INTERVAL = 7 GEN.
  381.     CALL    TIMER2
  382.     RET
  383. ;
  384. ;
  385. ; SUBROUTINE- TIMER     reg B = # time periods to count
  386. ;***********************************************************
  387. ;
  388. TIMER    MVI    A,TRATE    ;RESET TO .1 SEC
  389. ;
  390. TIMER2    OUT    BAUDRP
  391. ;
  392. TIMES    IN    BAUDRP    ;CK TO SEE IF TIMER BIT IS LOW
  393.     ANI    PULSE
  394.     JNZ    TIMES
  395. ;
  396. TIMEE    IN    BAUDRP    ;CK TO SEE IF BIT IS HIGH
  397.     ANI    PULSE
  398.     JZ    TIMEE
  399.     DCR    B    ;ONE PERIOD DONE
  400.     JNZ    TIMES
  401.     RET        ;TOTAL TIME EXPIRED
  402. ;
  403. ;
  404. ;   DIALING ENDED:  CARRIER DETECT ROUTINES
  405. ;********************************************************************
  406. ;
  407. BUSY:    LXI    D,BMESS    ;PHONE BUSY MESSAGE
  408.     CALL    PRTMSG
  409.     LXI    D,NAMES2
  410.     JMP    ABORT2
  411. ;
  412. DIALE:    MVI    A,'$'    ;PUT INTO CURRENT NUMBER BUFF.
  413.     LHLD    NBP    ;GET BUFF POINTER
  414.     MOV    M,A    ;SAVE EOF CHAR.
  415. ;
  416. DTRON:    CALL    CRLF    ;PRINT A CRLF
  417.     MVI    A,DTR3    ;TURN ON DTR AT APPROPRIATE BAUD RATE
  418.     OUT    MCTL2
  419.     MVI    B,1    ;WAIT FOR MODEM TO TURN ON DTR
  420.     CALL    TIMER
  421. ;SET UP UART
  422.     MVI    A,ORIGM    ;8bits, No parity, orig 
  423.     OUT    MCTLP
  424. ;
  425. ;WAIT FOR CLEAR TO SEND OR RINGTONE
  426.     MVI    C,NATOUT ;SET FOR X SEC
  427.     MVI    D,CTSBT    ;CARRRIER MASK BIT
  428. ;
  429. DZ1    MVI    B,1    ;SET TIMER FOR 0.1 SEC
  430.     CALL    TIMER
  431.     IN    BAUDRP    ;GET STATUS
  432.     STA    MSTAT    ;SAVE STATUS
  433.     ANA    D    ;CARRIER ?
  434.     JZ    CARRIER    ;YES
  435.     CALL    STAT    ;KEYBOARD INPUT?
  436.     JZ    DZZ    ;NO
  437.     CALL    KEYIN    ;YES,GET IT
  438.     CALL    SPECL    ;ABORT CHAR.?
  439. ;
  440. DZZ    DCR    C    ;GET NEXT INTERVAL
  441.     JNZ    DZ1    ;
  442.     JMP    ABORT    ;TIME EXPIRED, NO ANSWER
  443.             ; OR BUSY
  444. ;
  445. CARRIER:
  446.     CALL    WAT15    ;ALLOW 15 SECONDS FOR CTS
  447.     IN    MDATP    ;CLEAR OUT DATA GARBAGE
  448. ;PRINT CARRIER RECEIVED MESSAGE
  449.     LXI    D,CMESS
  450.     CALL    PRTMSG
  451. ;
  452. ;SET BAUD RATE (USUALLY 300)
  453.     MVI    A,BAUDRT
  454.     OUT    BAUDRP
  455. ;
  456. ;**********************************************************
  457. ; MAIN COMMUNICATION SECTION
  458. ;**********************************************************
  459. ;
  460. TERM    CALL    LOSS    ;CK FOR CARRIER LOSS
  461.     CALL    STAT    ;LOCAL CHAR KEYED?
  462.     JZ    TERML    ;..NO, CHECK LINE
  463.     CALL    KEYIN    ;GET CHAR
  464.     CPI    ESCTCP    ;TIME TO END?
  465.     JZ    NDIS    ;YES, NO DISCON
  466.     CPI    DISCCH    ;DISCONNECT REQUEST?
  467.     JZ    DISCON    ;YES, DO IT
  468.     CPI    LSTCHR    ;PRINT ON LIST DEVICE ?
  469.     JNZ    NCHG    ;NO CHANGE, CONTINUE
  470.     LDA    LFLAG    ;YES, FLIP FLAG
  471.     CMA
  472.     STA    LFLAG    ; & SAVE IT
  473.     XRA    A    ;CLEAR ACCUM.
  474. ;
  475. NCHG:
  476.     IF    TIMESH
  477.     ORI    80H    ;FORCE BIT 7 TO HIGH
  478.     ENDIF        ;TIMESH
  479. ;
  480.     OUT    MDATP    ;SEND THE CHAR
  481. ;
  482. ;SEE IF CHAR FROM LINE
  483. ;
  484. TERML    IN    MCTLP    ;READ STATUS
  485.     ANI    MRCVB    ;ISOLATE BIT
  486.     CPI    MRCVR    ;READY?
  487.     JNZ    TERM    ;..NO, LOOP
  488.     IN    MDATP    ;READ DATA
  489.     CALL    TYPE    ;TYPE IT
  490. ;
  491.     IF    LSTDEV
  492.     CALL    LIST    ;IF LIST DEVICE PRESENT (SPEED >300 BAUD)
  493.     ENDIF
  494. ;
  495.     JMP    TERM    ;LOOP
  496. ;
  497. ;---->    DISCON: DISCONNECT THE PHONE
  498. ;
  499. DISCON    XRA    A    ;GET DISCON VALUE
  500.     OUT    MCTLP    ;RESET ORIG/ANSW
  501.     OUT    MCTL2    ;TURN OFF DTR, DO BREAK
  502.     CALL    ILPRT    ;PRINT:
  503.     DB    CR,LF,'++ DISCONNECTED ++',CR,LF,0
  504.     JMP    EXIT
  505. ;
  506. ;NO DISCONNECT, TYPE MSG AS REMINDER THAT PHONE'S
  507. ;OFF HOOK
  508. ;
  509. NDIS    CALL    ILPRT
  510.     DB    CR,LF,'++ DON''T FORGET - THE MODEM IS '
  511.     DB    'NOT DISCONNECTED ++',CR,LF
  512.     DB    'Use "DIAL #" to Disconnect',CR,LF,0
  513.     JMP    EXIT
  514. ;
  515. ;*********************************************************
  516. ;
  517. LOSS    IN    BAUDRP
  518.     ANI    CTSBT    ;MASK FOR CARRIER LOSS
  519.     RZ        ;STILL PRESENT
  520.     LXI    D,CLMES    ;TYPE CARRIER LOST MESSAGE
  521.     CALL    PRTMSG
  522.     JMP    HEXIT    ;GO TO ABORT
  523. ;
  524. HANGP:    XRA    A    ;GET DISCONNECT VALUE
  525.     OUT    MCTL2    ;TURN OFF DTR, DO BREAK
  526.     OUT    MCTLP    ;GO ON HOOK
  527.     RET
  528. ;
  529. ABORT:    LXI    D,NAMES    ;NO ANSWER MESSAGE
  530.             ; DO YOU WISH TO REDIAL?
  531. ;
  532. ABORT2    CALL    HANGP
  533.     MVI    B,25    ;LOAD TIMER
  534.     CALL    TIMER    ; WITH LONG PAUSE
  535.     CALL    PRTMSG    ;PRINT THE MSG
  536.     CALL    KEYIN    ;GET REPLY
  537.     CALL    TYPE
  538.     CPI    'D'    ;WAS A 'D' HIT?
  539.     JZ    REDIAL    ;YES
  540.     JMP    EXIT    ;NO,GO TO CP/M
  541. ;
  542. SPECL    CPI    ESCTCP    ;CTL-E JMP TO CPM
  543.     JZ    EXIT
  544.     CPI    DISCCH    ;CTL-D DISCONNECT,TO CPM
  545.     JZ    HEXIT
  546.     CPI    RESTAR    ;CTL-C ABORT,RESTAR
  547.     JZ    RESTRT
  548.     CPI    RBKCHA    ;IF R
  549.     JZ    RINGBK    ;SET UP RINGBACK SEQUENCE
  550.     CPI    LSTCHR    ;CTL-P CONCURRENT LIST (DEVICE SPEED >300 BAUD)
  551.     RNZ        ;RETURN, NO SPECIAL CHARACTER IDENTIFIED
  552.     LDA    LFLAG
  553.     CMA        ;UPDATE LIST FLAG
  554.     STA    LFLAG
  555.     RET
  556. ;
  557. RINGBK:    MVI    A,'$'    ;PUT INTO CURRENT # BUFFER
  558.     LHLD    NBP    ;GET BUFF POINTER
  559.     MOV    M,A    ;SAVE EOF CHAR.
  560.     MVI    D,DTMSK    ;LOAD IN TONE DETECT MASK
  561.     MVI    C,RBLMT    ;SET TIMER FOR RBLIMIT # OF SEC.
  562.     CALL    RBTIME    ;  ABORTS IF IT TAKES LONGER
  563.     MVI    B,25    ;WAIT 2.5 SEC
  564.     CALL    TIMER    ;
  565.     IN    BAUDRP    ;IS TONE STILL PRESENT ?
  566.     ANA    D    ;
  567.     JNZ    RNGBK1    ;
  568.     JMP    BUSY    ;YES, MUST BE BUSY
  569. ;
  570. RNGBK1    CALL    HANGP    ;HANGUP PHONE
  571.     MVI    B,RBWAIT    ;WAIT X SEC.
  572.     CALL    TIMER    ;
  573.     JMP    REDIAL    ;REDIAL NUMBER
  574. ;
  575. RBTIME:    MVI    B,1    ; 0.1SEC TIME OUT
  576.     CALL    TIMER
  577.     IN    BAUDRP    ;GET STATUS
  578.     ANA    D    ;IS TONE PRESENT ?
  579.     RZ        ;YES
  580.     DCR    C    ;GET NEXT 0.1 SEC INTERVAL
  581.     JNZ    RBTIME
  582.     LXI    D,RBMES    ;NO TONE IDENTIFIED IN TIME LIMIT
  583.     CALL    PRTMSG    ;  BUT WILL CONTINUE
  584.     POP    D    ;GET RID OF SUBROUTINE RETURN
  585.     JMP    RNGBK1    ;HANGUP, REDIAL, & LISTEN FOR CARRIER
  586. ;
  587. REDIAL:    CALL    CRLF    ;PRINT A CRLF
  588.      CALL    ORIGMD    ;LOOK FOR DIAL TONE
  589.     LXI    H,NUMBR    ;GET START OF 'LAST' NUMBER BUFF.
  590. ;
  591. RDIAL    MOV    A,M    ;GET DIGIT
  592.     CPI    '$'    ;EOF CHAR. ?
  593.     JZ    DTRON    ;DONE DIALING
  594.     ADI    '0'    ;MAKE IT PRINTABLE
  595.     CALL    TYPE
  596.     MOV    A,M    ;GET DIGIT AGAIN
  597.     CALL    DIALR    ;DIAL DIGIT
  598.     INX    H    ;NEXT ONE
  599.     JMP    RDIAL
  600. ;
  601. ;
  602. ; TIME OUT ROUTINE (CK OF BITS vs MASK IN  D )
  603. ;
  604. WAT15:    MVI    C,150    ;TIMER SET FOR 15 SEC. INTERVALS
  605. ;
  606. T15    MVI    B,1    ; .1 SEC TIMEOUT
  607.     CALL    TIMER    ;TIMER WAITS .1 SEC
  608.     IN    BAUDRP    ;TEST STATUS
  609.     ANA    D    ;MASK WITH TEST BIT IN D
  610.     RZ        ;RETURN IF OFF
  611.     CALL    STAT
  612.     JZ    TS15    ;WAIT FOR INPUT
  613.     CALL    KEYIN
  614.     CALL    SPECL    ;CK FOR ABORT
  615. ;
  616. TS15    DCR    C    ;GET NEXT .1 SEC INTERVAL
  617.     JNZ    T15
  618.     JMP    ABORT
  619. ;
  620. ;---->    INITAD: INIT'S CP/M CBIOS ADDRESSES
  621. ;
  622. ;THIS ROUTINE FILLS IN THE ADDRESSES OF VARIOUS
  623. ;JMP AND CALL INSTRUCTIONS, SO THAT CP/M BDOS
  624. ;IS BYPASSED WHILE ACCESSING THE CONSOLE.  THIS
  625. ;IS DONE TO ALLOW CHARACTERS SUCH AS CONTROL-C
  626. ;AND CONTROL-S TO BE KEYED WHILE IN TERMINAL
  627. ;MODE, WITHOUT CP/M INTERPRETING THEM.
  628. ;
  629. INITAD    LHLD    1    ;GET WARM BOOT ADDR
  630.     LXI    D,3    ;LENGTH OF A 'JMP'
  631.     DAD    D    ;TO CONSOLE STAT
  632.     SHLD    VSTAT+1    ;MODIFY CALL
  633.     DAD    D    ;TO CONSOLE IN
  634.     SHLD    VKEYIN+1 ;MODIFY CALL
  635.     DAD    D    ;TO CONSOLE OUT
  636.     SHLD    VTYPE+1    ;MODIFY CALL
  637.     IF    LSTDEV
  638.     DAD    D    ;TO LIST DEVICE
  639.     SHLD    VLIST+1    ;MODIFY    CALL
  640.     ENDIF
  641.     RET
  642. ;
  643. CRLF    MVI    A,CR
  644.     CALL    TYPE
  645.     MVI    A,LF    ;FALL INTO TYPE
  646. ;
  647. ;---->    TYPE: TYPE VIA DIRECT CBIOS ACCESS
  648. ;WE ASSUME CBIOS MAY DESTROY SOME REGISTERS,
  649. ;SO SAVE THEM ALL.
  650. ;
  651. ;THIS ROUTINE BYPASSES CP/M'S CTL-S, CTL-C
  652. ;TESTS.
  653. ;
  654. TYPE    PUSH    PSW    ;SAVE CHAR
  655.     PUSH    B    ;AND OTHER REGISTERS
  656.     PUSH    D
  657.     PUSH    H
  658.     MOV    C,A    ;FOR BIOS
  659. VTYPE    CALL    $-$    ;ADDR SET AT INIT
  660.     POP    H    ;RESTORE REGISTERS
  661.     POP    D
  662.     POP    B
  663.     POP    PSW    ;..AND CHAR
  664.     RET        ;FROM "TYPE"
  665. ;
  666. ;PRINT ON LIST DEVICE ROUTINE
  667.     IF    LSTDEV    ;IF LIST DEVICE IS PRESENT >300 BAUD
  668. LIST    MOV    C,A    ;SAVE CHAR.
  669.     LDA    LFLAG    ;GET LIST FLAG
  670.     ORA    A
  671.     RZ        ;RETURN IF OFF
  672.     PUSH    PSW    ;SAVE CHAR.
  673.     PUSH    B    ;AND OTHER REGISTERS
  674.     PUSH    D
  675.     PUSH    H
  676. VLIST    CALL    $-$    ;ADDR SET AT INIT
  677.     POP    H    ;RESTORE REGISTERS
  678.     POP    D
  679.     POP    B
  680.     POP    PSW    ;..AND CHAR
  681.     RET        ;FROM    "LIST"
  682.     ENDIF
  683. ;
  684. ;---->  STAT: KEYBOARD STATUS
  685. ;
  686. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  687. ;CBIOS CLOBBERS THEM.
  688. ;
  689. STAT    PUSH    B
  690.     PUSH    D
  691.     PUSH    H
  692. VSTAT    CALL    $-$    ;ADDR SET AT INIT
  693.     POP    H
  694.     POP    D
  695.     POP    B
  696.     ORA    A    ;0 => NOT READY
  697.     RET
  698. ;
  699. ;---->  KEYIN: KEYBOARD INPUT
  700. ;
  701. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  702. ;CBIOS CLOBBERS THEM.
  703. ;
  704. KEYIN    PUSH    B
  705.     PUSH    D
  706.     PUSH    H
  707. VKEYIN    CALL    $-$    ;ADDR SET AT INIT
  708.     POP    H
  709.     POP    D
  710.     POP    B
  711.     ANI    7FH    ;STRIP PARITY IF THERE
  712.     RET        ;FROM KEYIN
  713. ;
  714. ;---->    ILPRT: INLINE PRINT OF MSG
  715. ;
  716. ;THE CALL TO ILPRT IS FOLLOWED BY A MESSAGE,
  717. ;BINARY 0 AS THE END.  BINARY 1 MAY BE USED TO
  718. ;PAUSE (MESSAGE 'PRESS RETURN TO CONTINUE')
  719. ;
  720. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  721. ;
  722. ILPLP    MOV    A,M    ;GET CHAR
  723.     ORA    A    ;END OF MSG?
  724.     JZ    ILPRET    ;..YES, RETURN
  725.     CPI    1    ;PAUSE?
  726.     JZ    ILPAUS    ;..YES
  727.     CALL    TYPE    ;TYPE THE MSG
  728. ;
  729. ILPNEX    INX    H    ;TO NEXT CHAR
  730.     JMP    ILPLP    ;LOOP
  731. ;
  732. ;PAUSE WHILE TYPING HELP SO INFO DOESN'T
  733. ;SCROLL OFF OF VIDEO SCREENS
  734. ILPAUS    CALL    ILPRT    ;PRINT:
  735.     DB    CR,LF,'PRESS RETURN TO CONTINUE'
  736.     DB    CR,LF,0
  737.     CALL    KEYIN    ;GET ANY CHAR
  738.     CPI    'C'-40H    ;REBOOT?
  739.     JZ    EXIT    ;YES.
  740.     JMP    ILPNEX    ;LOOP
  741. ;
  742. ILPRET    XTHL        ;RESTORE HL
  743.     RET        ;PAST MSG
  744. ;
  745. ;---->    PRTMSG: PRINTS MSG POINTED TO BY (DE)
  746. ;
  747. ;A '$' IS THE ENDING DELIMITER FOR THE PRINT.
  748. ;NO REGISTERS SAVED.
  749. ;
  750. PRTMSG    MVI    C,PRINT    ;GET BDOS FNC
  751.     JMP    BDOS    ;PRINT MESSAGE, RETURN
  752. ;
  753. HEXIT    CALL    HANGP    ;DISCONNECT
  754. ;
  755. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  756.     SPHL        ;RESTORE IT
  757.     RET        ;--EXIT-- TO CP/M (WARM BOOT)
  758. ;
  759. BDCHR    CALL    TYPE    ;PRINT CHAR.
  760.     CALL    HANGP    ;DISCONNECT
  761.     CALL    ILPRT    ;PRINT EXIT MESSAGE
  762.     DB    ' :INVALID CHARACTER',CR,LF
  763.     DB    'Press Return for Help, Ctrl-c if not.',cr,lf,1,0
  764. ;
  765. EXAM    MVI    B,1    ;WAIT
  766.     CALL    TIMER
  767.     CALL    ILPRT
  768.  DB  cr,lf
  769.  DB 'Commands:',cr,lf,cr,lf
  770.  DB '   DIAL ',cr,lf
  771.  DB '        if phone number is to be input from console',cr,lf
  772.  DB '   DIAL 1-313-555-1212',cr,lf
  773.  DB '        if the trailing number is to be dialed (spaces and',cr,lf
  774.  DB '        dashes are ignored)',cr,lf
  775.  DB '   DIAL C',cr,lf
  776.  DB '        if one of 25 preset numbers is to be dialed (preset',cr,lf
  777.  DB '        at time of assembly)',cr,lf
  778.  DB '   An  R  which follows any number indicates that it is',cr,lf
  779.  DB '    to be dialed as a ringback sequence.'
  780.  DB '    (One ring then dial back)',cr,lf
  781.  DB '    (For preset numbers this must be entered before assembly)'
  782.  DB cr,lf,cr,lf,0
  783.     JMP    EXIT
  784. ;
  785. MENU:
  786.  DB '                      NOTE',cr,lf
  787.  DB '                     ======',cr,lf
  788.  DB '   ctrl- D  causes a disconnect and return to CP/M',cr,lf
  789.  DB '   ctrl- E  causes a return to CP/M without a disconnect',cr,lf
  790.  DB '   ctrl- C  aborts current dialing and restarts program',cr,lf
  791.     IF    LSTDEV
  792.  DB '   ctrl- P  turns list device on and off',cr,lf
  793.     ENDIF
  794.  DB cr,lf,cr,lf,'$'
  795. ;
  796. ;
  797. NUMLST:
  798. ;  Phone Number list (capacity 25 numbers)
  799. ;Format    '############"aaaaaaaaaaaaaaaa$'
  800. ;CAUTION:   ^----from here to here-------^
  801. ;    **MUST NOT EXCEED 30 CHARACTERS**
  802. ;    (the actual # of #'s or a's doesn't matter if <30)
  803. ;
  804. ;    where  # = a digit, space or dash
  805. ;           " = separator between number and info
  806. ;           a = ascii info
  807. ;           $ = eof
  808. ;           * = no number character
  809. ;
  810. NA    DB    '4142415406" CCCC (TOM)       $' 
  811. NB    DB    '3724901" TELENET (CHI)       $' 
  812. NC    DB    '5458086" CBBS/CACHE          $' 
  813. ND    DB    '7670202" CMMS-CHICAGO        $' 
  814. NEE    DB    '3599450" PBBS-CHICAGO        $'  ;(NE IN SOME ASM =NOT EQU)
  815. NF    DB    '*                            $' 
  816. NG    DB    '*                            $' 
  817. NH    DB    '*                            $' 
  818. NI    DB    '*                            $' 
  819. NJ    DB    '*                            $' 
  820. NK    DB    '*                            $'
  821. NL    DB    '*                            $' 
  822. NM    DB    '*                            $' 
  823. NN    DB    '*                            $' 
  824. NO    DB    '*                            $' 
  825. NP    DB    '*                            $' 
  826. NQ    DB    '*                            $' 
  827. NR    DB    '*                            $' 
  828. NS    DB    '*                            $' 
  829. NT    DB    '*                            $' 
  830. NU    DB    '*                            $' 
  831. NV    DB    '*                            $' 
  832. NW    DB    '*                            $' 
  833. NX    DB    '*                            $' 
  834. NY    DB    '*                            $' 
  835. NZ    DB    '*                            $' 
  836. ;
  837. DMESS    DB    'DIAL TONE Detected   ',cr,lf,'$'
  838. CMESS    DB    'DATA CARRIER Received',cr,lf,bell,'$'
  839. BMESS    DB    bell,cr,lf,'BUSY Signal',bell,cr,lf,'$'
  840. RBMES    DB    bell,lf,'No Ringing Tone Detected',cr,lf,'$'
  841. NAMES    DB    'NO ANSWER',cr,lf
  842. NAMES2    DB    '   If you wish to redial PRESS  D',cr,lf
  843.     DB    '$'
  844. CLMES    DB    cr,lf,'DATA CARRIER LOST',cr,lf,bell,'$'
  845. NMESS    DB    'NO NUMBER STORED',cr,lf,'$'
  846. PMESS    DB    'ENTER PHONE # (terminate with  RETURN )  ',cr,lf,'$'
  847. ;
  848. ;
  849. NUMBR    DB    '$$$$$$$$$$$$$$$$'    ;16 DIGIT BUFFER
  850. ;
  851. PFLAG    DB    0    ;PRINT FLAG
  852. NFLAG    DB    0
  853. LFLAG    DB    0    ;LIST FLAG
  854. MSTAT    DB    0    ;MODEM STATUS
  855. OPTION    DB    0
  856. NBP    DS    2    ;NUM BUFF POINTER
  857.     DS    60    ;STACK AREA
  858. STACK    DS    2    ;STACK POINTER
  859. ;
  860. ;  BDOS EQUATES
  861. ;
  862. PRINT    EQU    9    ;PRINT ROUTINE
  863. BDOS    EQU    5
  864. FCB    EQU    5CH    ;SYSTEM FCB
  865. DBUF    EQU    80H    ;CP/M DEFAULT BUFFER
  866. ;
  867.     END
  868.