home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpmug / cpmug035.ark / NUMBER.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  15KB  |  448 lines
  1. ;16 MAR 79,MOSHELL: REMOVE STTACK-INIT.IN 'MOVE'.
  2. ;************************************************************************
  3. ;
  4. ; NUMBER GROUP * MOVE, COMP, COMPU, ADD, SUBT *
  5. ;   1/79       * JANE KIENINGER
  6. ;
  7. ;
  8. ;  NOTES:
  9. ;    1.  WHEN AN 8 BIT PARAMETER IS PROCESSED AGAINST A 16 BIT PARAMETER,
  10. ;        THE 8 BIT PARAMETER IS TREATED LIKE A 16 BIT PARAMETER
  11. ;        WITH 0'S IN THE HIGH ORDER 8 BITS - FLAGS AND PROCESSING
  12. ;        PROGRESS AS IF BOTH WERE 16 BITS (MOVE ROUTINE IS NOT
  13. ;        AFFECTED).
  14. ;    2.  COMPARE - USE 'COMP' TO COMPARE SIGNED INTEGERS, USE 'COMPU'
  15. ;        TO COMPARE UNSIGNED.
  16. ;    3.  ADD - TO DETECT A RESULT WHICH HAS EXCEEDED STORAGE ALLOWED:
  17. ;        A. CHECK CARRY FLAG FOR UNSIGNED INTEGERS.
  18. ;        B. CHECK OVERFLOW FLAG FOR SIGNED INTEGERS.
  19. ;    4.  SUBT - 
  20. ;        A. FOR UNSIGNED INTEGERS CHECK CARRY FLAG TO DETECT A
  21. ;            NEGATIVE RESULT.
  22. ;        B. FOR SIGNED INTEGERS CHECK OVERFLOW FLAG TO DETECT A RESULT
  23. ;            WHICH HAS EXCEEDED STORAGE ALLOWED.
  24. ;    5.  MINUS FLAG - IS SET:
  25. ;        A.  IN ADD, SUB OR MOVE ROUTINES TO INDICATE THAT THE
  26. ;            RESULLT (OR PARAMETER OF 'MOVE') IS NEGATIVE - TO
  27. ;            BE USED WITH SIGNED INTEGERS ONLY.
  28. ;        B.  IN COMP, TO INDICATE THAT THE SECOND PARAMETER IS GREATER
  29. ;            THAN THE FIRST WHEN DEALING WITH SIGNED INTEGERS.
  30. ;        C.  IN COMPU, TO INDICATE THAT THE SECOND PARAMETER IS
  31. ;            GREATER THAN THE FIRST WHEN DEALING WITH
  32. ;            UNSIGNED INTEGERS.
  33. ;
  34. ;    6.  WARNING - IF SIGNED AND UNSIGNED PARAMETERS ARE INADVERTANTLY
  35. ;        MIXED, RESULTS AND FLAGS ARE UNPREDICTABLE.
  36. ;
  37. ;;************************************************************************
  38. INPARM    EQU    5030H
  39. OUTPRM    EQU    5033H
  40. FLAGS    EQU    0114H    ;(*REGISTER #2)
  41. MFLAG    EQU    80H    ; LOCATION OF MINUS FLAG (BIT 7)
  42. OFFM    EQU    7FH    ; TO TURN OFF MINUS FLAG
  43. ZFLAG    EQU    40H    ; LOCATION OF ZERO FLAG  (BIT 6)
  44. OFFZ    EQU    0BFH    ; TO TURN OFF ZERO FLAG
  45. ZAPFLAG EQU    3FH    ; TO TURN OFF BOTH ZERO AND MINUS (BIT 6 AND 7)
  46. CFG    EQU    02H    ; TO TURN ON  CARRY FLAG (BIT 1)
  47. OFG    EQU    08H    ; TO TURN ON OVERFLOW FLAG (BIT 3)
  48. ZAPALL    EQU    35H    ; TO TURN OFF ALL FELIX FLAGS (BITS 1,3,6,7)
  49. ON    EQU    0FFH    ; USED TO TURN INTERNAL FLAG ON
  50. ZERO    EQU    00H    ;
  51.     ORG    5300H
  52. RESULT    DB    00H    ; TEMPORARY SAVE AREA FOR COMPUTATIONAL RESULTS
  53. RTSW    DB    00H    ; ROUTINE SWITCH
  54. ;*************************************************************************
  55. ;
  56. ; MOVE     * MOVE ROUTINE * J-2LANE KIENINGER
  57. ;    *     1/79     * VERSION 1.1
  58. ;
  59. ;  DESCR:   THIS ROUTINE EXAMINES THE FIRST PARAMETER AND
  60. ;    SETS MINUS AND ZERO (FELIX) FLAGS AS NECESSARY.  
  61. ;    IT TESTS THE SIGN FLAG SET BY INPARM TO DETERMINE WHETHER 8 OR
  62. ;    16 BITS SHOULD BE EXAMINED.  OUTPRM ACTUALLY MOVE THE VALUE TO A
  63. ;    NEW VARIABLE.
  64. ;  INPUT:  REGISTERS D AND E FROM INPARM.
  65. ;  OUTPUT: REGISTERS D AND E TO OUTPRM.
  66. ;  SUBROUTINES:  INPARM, OUTPRM
  67. ;  REGISTERS DESTROYED: A AND B
  68. ;
  69. ;****************************************************************************
  70. MOVE:    LDA    FLAGS    ; ZERO FLAGS
  71.     ANI    ZAPFLAG    
  72.     STA    FLAGS
  73.     MVI    B,00H    ; ZERO B USED TO INDICATE 16 BIT PARAMETER SIZE
  74.     CALL    INPARM    ; GET PARAMETER
  75.     JC    BIT16    ; IF CARRY FLAG SET, PARAMETER SIZE IS 16 BITS
  76. ;
  77. ;  SET MINUS FLAG FOR 8-BIT IF NEGATIVE
  78. ;
  79.     MOV    A,E    ; IF E IS NEGATIVE 
  80.     CPI    0H    ;     SET MINUS FLAG TEMPORARILY IN B
  81.     JP    CKZERO    
  82.     MVI    B,MFLAG
  83.     JMP    CKZERO
  84. ;
  85. ;  SET MINUS FLAG FOR 16 BIT IF NECESSARY
  86. ;
  87. BIT16:    MOV    A,D    ; IF D IS NEGATIVE SET TEMPORARY MINUS FLAG IN B
  88.     CPI    0H    ;
  89.     JP    CKZERO
  90.     MVI    B,MFLAG
  91. CKZERO: MOV     A,D    ; CHECK TO SEE IF VALUE =0
  92.     ORA    E
  93.     LDA    FLAGS    ;  UPDATE FLAGS
  94.     JNZ    MVEND
  95.     ORI    ZFLAG    ; SET ZERO FLAG
  96. MVEND:  ORA    B    ; SET MINUS FLAG FROM B
  97.     STA    FLAGS    ; RESTORE FLAGS
  98.     CALL    OUTPRM    ; CALL OUTPRM TO GET VALUE TO BE MOVED
  99.     RET
  100. ;********************************************************************
  101. ; COMP/COMPU * COMPARE SIGNED (COMP) AND COMPARE UNSIGNED (COMPU) ROUTINES *
  102. ;      * JANE KIENINGER
  103. ;      *      1/79       * VERSION 1.1
  104. ;
  105. ; DESCR:  THIS ROUTINE COMPARES THE SECOND PARAMETER VALUE FROM
  106. ;    THE FIRST.  IF THE SECOND VALUE IS GREATER THAN THE FIRST THE
  107. ;    FELIX MINUS FLAG IS SET AND IF THE RESULT IS ZERO (THE VALUES
  108. ;    ARE EQUAL) THE FELIX ZERO FLAG IS SET.  THE MINUS FLAG IS
  109. ;    SET BASED ON THE 16 BITS OF THE RESULT EXCEPT WHEN BOTH
  110. ;    PARAMETER VALUES ARE 8 BITS AS INDICATED BY THE CARRY FLAG
  111. ;    SET BY INPARM - IN THAT CASE  THE MINUS FLAG IS SET BASED
  112. ;    ON THE LOWER 8 BITS OF DE.
  113. ;      COMP SETS THE FLAGS ASSUMING BOTH PARAMETERS ARE SIGNED
  114. ;    INTEGERS WHILE COMPU SETS THE FLAGS ASSUMING THEY ARE UNSIGNED
  115. ;    INTEGERS.  THE ENTRY POINT INTO THIS ROUTINE DETERMINES WHETHER
  116. ;    IT WILL DO A SIGNED OR UNSIGNED COMPARE.  A ROUTINE FLAG IS SET
  117. ;    (RTSW) TO 00 FOR UNSIGNED AND FF FOR SINGED.
  118. ; INPUT:  REGISTERS D AND E FROM INPARM
  119. ; OUTPUT:   FELIX FLAGS ZERO (BIT 6) AND MINUS (BIT 7) SET
  120. ; SUBROUTINES:  INPARM
  121. ; REGISTERS DESTROYED: ALL
  122. ;
  123. ;***************************************************************************
  124.     ORG    5340H
  125. ;
  126. ;  UNSIGNED COMPARE ROUTINE START POINT
  127. ;
  128. CKMPU:    XRA    A    ; SET ROUTINNE SWITCH TO 0
  129.     STA    RTSW    ;
  130.     JMP    C0    ;
  131. ;
  132. ;  SIGNED COMPARE ROUTINE START POINT
  133. ;
  134.     ORG    5350H
  135. COMP:    ORI    ON    ; SET ROUTINE SWITCH TO FF TO INDICATE
  136.     STA    RTSW    ;    SIGNED NUMBERS.
  137. ; 
  138. ; BEGIN COMPARE ROUTINE
  139. ;
  140. C0:    LDA    FLAGS    ; ZERO FLAGS
  141.     ANI    ZAPFLAG 
  142.     STA    FLAGS
  143.     MVI    B,00H    ; ZERO REGISTERS
  144.     MVI    C,00H    ; 
  145. ;
  146. ;  GET PARAMETERS - SET 16 BIT FLAG IN B IF EITHER IS 16 BITS LONG
  147. ;
  148.     CALL    INPARM    ; GET FIRST PARAMETER TO BE COMPARED
  149.     JNC    C1    ; IF CARRY FLAG IS SET, SET
  150.     MVI    B,ON    ;    16 BIT FLAG IN REG B
  151. C1:    XCHG        ; MOVE VALUE OF FIRST PARM INTO HL
  152.     CALL    INPARM    ; GET SECOND PARAMETER
  153.     JNC    C2    ; IF CARRY FLAG SET, SET
  154.     MVI    B,ON    ;    16 BIT FLAG IN REG B.
  155. ;
  156. ;  8 BIT PROCESSING
  157. ;
  158. C2:     MOV    A,L    ; COMPARE L AND E
  159.     CMP    E
  160.     RAL        ; PUT CARRY BIT IN LOW ORDER BIT OF ACCUM
  161.     MOV    C,A    ;     SAVE CARRY IN C
  162.     JNZ    C3    ; IF ZERO SET ZERO FLAG AND BYPASS CARRY CHECK
  163.     LDA    FLAGS
  164.     ORI    ZFLAG
  165.     STA    FLAGS
  166.     JMP    C65
  167. C3:    CALL     CSUBR1
  168. ;
  169. ;  IF BOTH VALUES ARE 8 BITS END PROCESSING
  170. ;
  171. C65:    MOV    A,B    ; B = 16 BIT FLAG
  172.     CPI    ON    ; IF FLAG ON?
  173.     JNZ    CEND    ; IF NOT, END PROCESSING
  174. ;
  175. ;   16-BIT PROCESSING
  176. C7:    MOV    E,D    ; MOVE D TO E AND H TO L TO SET UP
  177.     MOV    L,H    ;    UP FOR SUBROUTINE CALL
  178.     MOV    A,L    ; COMPARE H & D
  179.     CMP    E
  180.     JZ    CEND    ; IF EQUAL THEN THE MINUS AND ZERO FLAGS ALREADY HAVE
  181.             ;    BEEN SET IN 8 BIT COMPARE.
  182.     RAL        ; PUT CARRY BIT IN LOW ORDER BIT OF ACCUM.
  183.     MOV    C,A    ; SAVE CARRY IN C
  184.     LDA    FLAGS    ; GET FELIX FLAGS
  185.     ANI    OFFZ    ; TURN OFF ZERO FLAG IF SET IN 8 BIT COMPARE
  186.     STA    FLAGS
  187.     CALL     CSUBR
  188. CEND:    RET
  189. ;**
  190. ;
  191. ; COMPARISON SUBROUTINE
  192. ;
  193. ;     SETS MINUS FLAG IF SECOND OPERAND GREATER THAN FIRST
  194. ;
  195. ;**
  196. CSUBR1: MOV    A,B    ; IF 16 BIT PROCESSING, SIGNED ROUTINE MUST
  197.     CPI    ON    ;    BE IGNORED DURING 8 BIT COMPARE
  198.     JZ    C4
  199. CSUBR:    LDA    RTSW    ; IF SIGNED NO. (IF ON), THEN MUST
  200.     CPI    ON    ;    CHECK SIGNS.
  201.     JNZ    C4    ;    ELSE BYPASS SECTION.
  202. ;**
  203. ;  SIGNED NUMBER SPECIAL ROUTINE
  204. ;
  205.     PUSH     B    ; SAVE REGISTERS
  206.     MOV    A,E    ; TURN OFF ALL BUT SIGN BIT IN E
  207.     ANI    80H    ;
  208.     MOV    C,A    ; SAVE IN C
  209.     MOV    A,L    ; TURN OFF ALL BUT SIGN BIT IN H
  210.     ANI    80H
  211.     CMP    C    ; COMPARE TWO SIGNS
  212.     POP    B    ; RESTORE BC
  213.     MOV    A,C    ; LOW BIT OF C CONTAINS CARRY
  214.     JZ    C4    ; IF UNEQUAL COMPLEMENT CARRY
  215.     RAR        ; PUT CARRY BACK
  216.     CMC        ; COMPLEMENT CARRY
  217.     JMP    C5    
  218. C4:    MOV    A,C    ; LOW BIT OF C CONTAINS CARRY
  219.     RAR
  220. C5:    LDA    FLAGS    ; GET FELIX FLAGS
  221.     JNC    C55    ; IF CARRY, SET MINUS FLAG
  222.     ORI    MFLAG    ; SET MINUS FELIX FLAG
  223.     JMP    C6
  224. C55:    ANI    OFFM    ; TURN OFF MINUS IF SET IN 8 BIT COMPARE
  225. C6:    STA    FLAGS    ; RETURN FELIX FLAGS
  226.     RET
  227. ;******************************************************************************
  228. ;
  229. ; ADD/SUB * ADD AND SUBTRACT ROUTINE * JANE KIENINGER
  230. ;         *         1/79             * VERSION 1.1
  231. ;
  232. ; DESCR:  THIS ROUTINE ADDS THE FIRST PARAMETER TO THE SECOND, OR
  233. ;    SUBTRACTS THE SECOND FROM THE FIRST, AND PLACES THE RESULT
  234. ;    IN THE THIRD.  THE ENTRY POINT INTO THIS ROUTINE DETERMINES
  235. ;    WHETHER IT WILL ADD OR SUBTRACT.  A ROUTINE FLAG (RTSW) IS SET TO
  236. ;    00 FOR ADD AND FF FOR SUBTRACT.  THE ROUTINE USES INPARM AND OUTPRM
  237. ;    FOR INPUT AND OUTPUT OF PARAMETERS AND SETS FELIX FLAGS.  THE
  238. ;    MINUS FLAG IS SET BASED ON THE 16 BITS OF THE RESULT EXCEPT WHEN
  239. ;    BOTH PARAMETER VALUES ARE 8 BITS (AS INDICATED BY THE CARRY FLAG
  240. ;    SET BY INPARM), WHEN THAT OCCURS THE MINUS FLAG IS SET BASED
  241. ;    ON AN 8 BIT RESULT.
  242. ; INPUT:  REGISTERS D AND E FROM INPARM
  243. ; OUPUT:  REGISTERS D AND E FOR OUTPRM AND FELIX FLAGS: ZERO (BIT 6),
  244. ;    MINUS (7), CARRY (1), OVERFLOW (3)
  245. ; SUBROUTINES:  INPARM, OUTPRM
  246. ; REGISTERS DESTROYED:  ALL
  247. ;
  248. ;******************************************************************************
  249.     ORG    53E0H
  250. ;
  251. ;  ADD ROUTINE START POINT
  252. ;
  253. ADDIT:  XRA    A    ; SET ROUTINNE SWITCH TO 0 TO INDICATE
  254.     STA    RTSW    ;    ADD ROUTINE.
  255.     JMP    A1
  256. ;
  257. ;  SUBTRACT ROUTINE START POINT
  258. ;
  259.     ORG    53F0H
  260. SUBIT:    ORI    ON    ; SET ROUTINE SWITCH TO FF TO INDICATE SUBTRACT
  261.     STA    RTSW    ;       ROUTINE.
  262. ;
  263. ;    BEGIN
  264. ;
  265. A1:    LDA    FLAGS    ; ZERO FLAGS AND REGISTERS.
  266.     ANI    ZAPALL
  267.     STA    FLAGS    ;
  268.     MVI    C,00H
  269.     MVI    B,00H
  270. ;
  271. ; GET PARAMETERS - SET 16 BIT FLAG IN REG B IF EITHER IS 16 BITS LONG
  272. ;
  273.     CALL    INPARM    ; 1ST PARAMETER PLACED IN DE
  274.     JNC    A5    ; IF CARRY FLAG SET, SET
  275.     MVI    B,ON    ;   16 BIT FLAG IN REG B
  276. A5:    XCHG        ; 1ST PARAMETER NOW IN HL
  277.     CALL    INPARM    ; 2ND PARAMETER IN DE
  278.     JNC    A10    ; IS CARRY FLAG SET, SET
  279.     MVI    B,ON    ;    16 BIT FLAG IN REG B
  280. ;
  281. ; 8-BIT PROCESSING
  282. ;
  283. A10:    LDA    RTSW    ; IS THIS ADD OR SUBTRACT ROUTINE?
  284.     CPI    ON    ; IF NOT ON THEN ADD ELSE SUBTRACT
  285.     JNZ    A15    ;
  286. *
  287. *  8 BIT SUBTRACTION
  288. *
  289.     MOV    A,L    ; SUBTRACT LOWER 8 BITS (E & L)
  290.     SUB    E    ;
  291.     STA    RESULT    ; STORE 8-BIT RESULT
  292.     PUSH    PSW    ; SAVE RESULTS AND FLAGS FOR LATER USE
  293.     MOV    A,B    ; IF 16 BIT PROCESSING, SKIP 8 BIT FLAG SETTINGS
  294.     CPI    ON
  295.     LDA    RESULT    ; ACCUMULATOR MUST CONTAIN RESULT FOR OVERFLOW
  296.                 ;     SUBROUTINE.
  297.     JZ    A31
  298.     CALL    SOVFLOW    ; SET 8 BIT OVERFLOW FLAG IN REG C IF NEC.
  299.     JMP    A20    ; BYPASS ADD ROUTINE.
  300. *
  301. *  8-BIT ADDITION
  302. *
  303. A15:    MOV    A,L    ; ADD LOWER 8 BITS (E & L)
  304.     ADD    E    ;
  305.     STA    RESULT    ; STORE 8 BIT RESULT
  306.     PUSH    PSW    ; SAVE RESULTS AND FLAGS FOR LATER USE
  307.     MOV    A,B    ; IF 16 BIT PROCESSING, SKIP 8 BIT FLAG SETTING
  308.     CPI    ON    ;
  309.     LDA    RESULT    ; ACCUMULATOR MUST CONTAIN RESULT FOR OVERFLOW
  310.             ;    SUBROUTINE.
  311.     JZ    A31    ;
  312.     CALL    OVFLOW    ; SET 8BIT OVERFLOW FLAG IN REG C
  313. A20:    POP    PSW    ; RECOVER RESULT AND FLAGS
  314.     MVI    A,ZERO    ; CLEAR ACCUMULATER (MUST USE MVI)
  315.     JNC    A25    ; SET  CARRY FLAG TEMPORARILY IN A
  316.     MVI    A,CFG    ;   IF CARRY SYSTEM FLAG SET
  317. A25:    JP    A30    ; SET FELIX MINUS FLAG TEMP WITH 8 BIT
  318.     ORI    MFLAG    ;   CARRY FLAG IN A IF RESULT WAS NEGATIVE
  319. A30:     ORA    C    ; ADD OVERFLOW FLAG TO CARRY AND MINUS
  320.     MOV    C,A    ; SAVE ALL FLAGS IN C
  321.     LDA    FLAGS    ; BRING IN FELIX FLAGS
  322.     ORA    C    ; SET 8-BIT OVERFLOW, CARRY AND MINUS PERMANNENTLY
  323.     STA    FLAGS
  324.     JMP    A60    ; SKIP TO SET ZERO FLAG
  325. ;
  326. ; 16 BIT PROCESSING
  327. ;
  328. ;
  329. A31:    LDA    RTSW    ; IF THIS ADD OR SUBTRACT ROUTINE ?
  330.     CPI    ON    ; IF NOT ON THEN ADD ELSE SUBTRACT
  331.     JNZ    A35    ;
  332. *
  333. *  16 BIT SUBTRACTION
  334. *
  335.     POP    PSW    ; RESTORE CARRY FLAG
  336. A32:    MOV    A,H    ; SUBTRACT TOP 8 BITS (H & D) WITH BORROW FROM
  337.     SBB    D    ;     LOWER 8 BITS.
  338.     MOV    E,D    ; MOVE D TO E AND H TO L TO PROPERLY USE 
  339.     MOV    L,H    ;    OVERFLOW ROUTINE.
  340.     PUSH    PSW    ; SAVE RESULT AND SYSTEM FLAGS
  341.     CALL    SOVFLOW    ; SETS OVERFLOW FLAG IN C IF ANY
  342.     JMP    A38    ; BYPASS ADD ROUTINE
  343. *
  344. *
  345. *  16 BIT ADDITION
  346. *
  347. A35:    POP    PSW    ; RESTORE CARRY FLAG
  348. A36:    MOV    A,H    ; ADD TOP 8-BITS (H & D) WITH CARRY FROM
  349.     ADC    D    ;     LOWER 8-BITS.
  350.     MOV    E,D    ; MOVE D TO E AND H TO L TO PROPERLY USE OVERFLOW
  351.     MOV    L,H    ;     ROUTINE.
  352.     PUSH    PSW    ; SAVE RESULT AND SYSTEM FLAGS.
  353.     CALL    OVFLOW  ; SETS OVERFLOW FLAG IN REG C (IF ANY)
  354. A38:    POP    PSW    ; RESTORE RESULT IN ACCUMULATOR AND ALL SYSTEM FLAGS
  355.     MOV    D,A    ; SAVE RESULT OF FUNCTION IN D
  356.     MVI    H,00H    ; CLEAR H
  357.     JNC    A40    ; SET  CARRY TEMP IN H IF SYSTEM 
  358.     MVI    H,CFG    ;    CARRY WAS SET
  359. A40:    LDA    FLAGS    ; BRING IN FELIX FLAGS
  360.     JP    A45    ; IF RESULT WAS NEGATIVE SET MINUS FLAG
  361.     ORI    MFLAG  ;      PERMANENTLY.
  362.     JMP    A50    ;
  363. A45:    ANI    OFFM    ; IF RESULT WAS POSITIVE RESET FLAG
  364. A50:     ORA    C    ; SET 16 BIT OVERFLOW FLAG PERMANENTLY
  365.     ORA    H    ; SET 16 BIT CARRY FLAG PERMANENTLY
  366.     STA    FLAGS    ; RETURN FELIX FLAGS TO MEMORY
  367. ;
  368. ; SET ZERO FLAG
  369. ;
  370. A60:    LDA    RESULT ; READ IN 8 BIT PROCESSING RESULTS
  371.     MOV    E,A    ; STORE THIS RESULT PERMANENTLY IN E
  372.     ORA    D    ; COMPARE IT WITH 16-BIT RESULTS
  373.     JNZ    A65    ; IF RESULT = 0 SET ZERO FLAGS
  374.     LDA    FLAGS    ;
  375.     ORI    ZFLAG    ;
  376.     STA    FLAGS    ; RETURN FELIX FLAGS TO MEMORY FOR LAST TIME
  377. A65:    CALL    OUTPRM
  378.     RET
  379. ;
  380. ; OVFLOW * OVERFLOW SUBROUTINE FOR ADD *
  381. ;
  382. ; DESCR: THIS SUBROUTINE SETS THE FELIX OVERFLOW FLAG IF BOTH OPERANDS ARE
  383. ;     THE SAME SIGN AND THE RESULT IS OF THE OPPOSITE SIGN. THE CODING HAS
  384. ;     THE ORDER OF THIS REVERSED FOR EFFICIENCY.  AT THE END OF THE 
  385. ;     ROUTINE REGISTER C CONTAINS AN 8 BIT OVERFLOW FLAG CONFIGURATION.
  386. ; REGISTERS: REG A - RESULT OF ADDITION (INITIALLY ONLY)
  387. ;            REG E - SECOND OPERAND
  388. ;         REG L - FIRST OPERAND
  389. ;         REG C - ALL ZEROS OR 8 BIT OVERFLOW FLAG CONFIGURATION
  390. ;                    (AT  END OF SUBROUTINE)
  391. ;;;
  392. ; 1.  COMPARE SIGN BITS OF RESULT (A) WITH OPERAND IN E.  IF = THEN
  393. ;     NO OVERFLOW.
  394. ;
  395. OVFLOW:    ANI    80H    ; TURN OFF ALL BUT SIGN BIT IN RESULT
  396.     MOV    C,A    ; SAVE THIS
  397.     MOV    A,E    ; NOW BRING IN OPERAND IN E AND TURN OFF
  398.     ANI     80H    ;     ALL BUT SIGN BIT.
  399.     CMP    C    ; COMPARE SIGN BIT OF RESULT WITH OPERAND FROM E
  400.     JZ    F15    ; IF SIGNS ARE EQUAL THEN NO OVERFLOW
  401. ;
  402. ; 2.  NOW COMPARE SIGN BIT OF OPERAND FROM E WITH THAT OF L.
  403. ;
  404.     MOV    C,A    ; SAVE E'S SIGN
  405.     MOV    A,L    ; BRING IN L AND TURN OFF ALL BUT SIGN BIT
  406.     ANI    80H    ; 
  407.     CMP    C    ; COMPPARE SIGN BIT OF E WITH L
  408.     JNZ    F15    ; IF EQUAL SET OVERFLOW FLAG TEMPORARILY
  409.     MVI    C,OFG  ;    IN C.
  410.     JMP    F20    ; BYPASS CLEARING C.
  411. F15:    MVI    C,00H    ; CLEAR C FOR FLAG USE
  412. F20:    RET
  413. ;
  414. ; SOVFLOW * OVERFLOW SUBROUTINE FOR SUBTRACT *
  415. ;
  416. ; DESCR:  THIS SUBROUTINE SETS THE FELIX OVERFLOW FLAG IF THE SIGNS
  417. ;    OF THE OPERANDS DIFFER AND THE RESULT SIGN IS THE SAME AS THE
  418. ;    SIGN OF THE SECOND OPERAND.  THE CODING HAS THE ORDER OF THIS
  419. ;    REVERSED FOR EFFICIENCY.  AT THE END OF THE ROUTINE REGISTER C 
  420. ;    CONTAINS AN 8 BIT OVERFLOW FLAG CONFIGURATION.
  421. ; REGISTERS:    REG A - RESULT OF SUBRACTION (INITIALLY ONLY)
  422. ;        REG L - FIRST OPERAND
  423. ;        REG E - SECOND OPERAND
  424. ;        REG C - ALL ZEROS OR 8 BIT OVERFLOW FLAG CONFIGURATION
  425. ;            AT END OF SUBROUTINE.
  426. ;
  427. ; 1.  COMPARE SIGN BITS OF RESULT (A) WITH OPERAND IN E.  IF UNEQUAL
  428. ;    THEN NO OVERFLOW.
  429. ;
  430. SOVFLOW:    ANI    80H    ; TURN OFF ALL BUT SIGNN BIT IN RESULT
  431.     MOV    C,A    ; SAVE THIS
  432.     MOV    A,E    ; NOW BRING IN OPERAND IN E AND TURN OFF
  433.     ANI    80H    ;    ALL BUT SIGN BIT.
  434.     CMP    C    ; COMPARE SIGN BIT OF RESULT WITH OPERAND FROM E.
  435.     JNZ    S15    ; IF SIGNS DIFFER THEN NO OVERFLOW.
  436. ;
  437. ; 2.  NOW COMPARE SIGNS OF TWO OPERANDS
  438. ;
  439.     MOV    C,A    ; SAVE E'S SIGNN
  440.     MOV    A,L    ; BRING IN L AND THRN OFF ALL BUT SIGN BIT
  441.     ANI    80H    ; 
  442.     CMP    C    ; COMPARE SIGN BIT OF E WITH L
  443.     JZ    S15    ; IF UNEQUAL SET OVERFLOW FLAG IN C
  444.     MVI    C,OFG    ;
  445.     JMP    S20    ; BY PASS CLEARING C
  446. S15:    MVI    C,00H    ; CLEAR C FOR FLAG USE
  447. S20:    RET
  448.