home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / modem7 / m7-scat.aqm / M7-SCAT.ASM
Encoding:
Assembly Source File  |  1985-02-10  |  26.1 KB  |  1,099 lines
  1. ; M7SCAT.ASM  Novation Smart-Cat overlay for MDM714 - 03/10/84
  2. ; NOTES: (1) This overlay will not work with MDM724. (CEH)
  3. ;     (2) The machine dependent code in this overlay is for
  4. ;         the H/Z H-89.  It might need to be changed for you use.
  5. ;
  6. ; This overlay is a modification of M7RV-1.ASM, which was written for
  7. ; the Racal-Vadic VA212PA modem.  That overlay had some problems with
  8. ; sending characters out to the modem too fast for it to accept them.
  9. ; This problem was corrected in the overlay for the VA3451.  This overlay
  10. ; was, in turn, created from it.  The delay timer routine is called TIMER5,
  11. ; and is called with a delay value in the B register.  This value is
  12. ; obtained from the value that is stored at the TDELAY equate, which
  13. ; must be selected before assembly.  TDELAY is the number of 100mS
  14. ; segments in the delay.  The default value for the Smart-Cat is 3.
  15. ;
  16. ; A DEBUG feature had been added that can be selected by setting the
  17. ; DBUG equate to YES.  This function was added mainly to permit
  18. ; debugging with full control over the DTR signal to the phone.  This
  19. ; function might be desired as a permanent feature.  It becomes one of
  20. ; the SET choices if selected, and appears in the SET menu.
  21. ;
  22. ; This overlay is configured for the Heath/Zenith H-89.  Other machines
  23. ; will require changes to the PORT addresses and functions and the
  24. ; INITMOD routine as required for a particular UART.  Also, change
  25. ; SETUPR, SETDTRH, and SETDTRL as required.  Changes might also be
  26. ; needed at the CLREOS and CLRSCRN DB values.  The SYSVER can be
  27. ; configured to any reasonable signon desired.
  28. ;
  29. ; Caution is advised in setting up names in the internal number library.
  30. ; The Smart-Cat does not have an offline command arrangement, as found
  31. ; in the Hayes SmartModem and The Vadic units.    It reserves the character
  32. ; '%' to tell the modem that a command is comming.  This character is
  33. ; not sent out to the line, and will be accepted at any time to set the
  34. ; modem into the command mode.    This character is sent out by the program
  35. ; as a preamble to sending out the phone number.  IT SHOULD NEVER be
  36. ; included in the library listing in ANY location.  The modem also recog-
  37. ; nizes several other characters that may be placed within the phone
  38. ; number string.  They are 'I' (impulse dialing - default is DTMF),
  39. ; 'P' (pause), and 'W' (wait).    Also '*' and '#' (used in PABX dialing).
  40. ; All other alpha characters are discarded by the program.
  41. ; The reserved alpabetical characters may appear in the name field of
  42. ; the library listing, BUT ONLY AS LOWER CASE CHARACTERS).  The program
  43. ; scans the entire library entry for the number; hence, NO RESERVED
  44. ; character or NO DIGIT may appear unless it is actually part of the
  45. ; number.  If Novation ever adopts the procedure of sending control
  46. ; strings only when DTR is off, then placing the modem in UNLISTEN
  47. ; mode when DTR is on, this problem can be solved.
  48. ;
  49. ; Another consequence of this arrangement is that the modem can not be
  50. ; used for XMODEM transfers unless it is placed into the UNLISTEN mode,
  51. ; either by internal switch or by terminal mode command.  After this is
  52. ; done, the power must be cycled to get it back into command mode.  It
  53. ; also defaults to 7-bit characters for ASCII operation.  It must be set
  54. ; for 8-bit characters for XMODEM transfers.
  55. ;
  56. ; This code may not be optimum by any means.  The TDELAY value of 3
  57. ; might be reduced without causing problems.  The 3.5 second delay that
  58. ; is provided at DISCONNT2 to provide plenty of time for the modem to
  59. ; recover from a disconnect might be greater than needed and slows the
  60. ; response to redialing.  The disabled code at DISCONNT that was supposed
  61. ; to help reinitialize the modem prevented the program from working,
  62. ; perhaps because there was insufficient time delay to recover from it.
  63. ; the %I initialization command was not used because the modem takes
  64. ; 5-10 seconds to cycle through its routine.  It might have been used
  65. ; to some advantage.  If the program seems slow, the user is invited to
  66. ; experiment with these values and features.
  67. ;
  68. ; The Novation Smart-Cat modem is configured as follows:
  69. ;
  70. ;    SWITCH        SETTING     RESULT
  71. ;    1        OFF        Transparent mode not forced
  72. ;    2        ON        Not quiet mode
  73. ;    3        ON        Verbose responses (required here)
  74. ;    4        ON        1200 baud default data rate
  75. ;    5        OFF        Auto-answer off
  76. ;    6        OFF        Carrier detect not required.
  77. ;
  78. ; For PABX use, # and * may be used on the phone number command line.
  79. ; (Read the manual for use of the I, P, and W commands within the number).
  80. ;
  81. ; Initialization routines need to be changed to support your I/O devices
  82. ; are INITMOD:,  SETUPR: SETDTRH: and SETDTRL: - Examples for USART
  83. ; initialization may be found in BYE2-16.LBR.  The modem is disconnected
  84. ; from on-line by dropping the DTR line, this must be implemented in the
  85. ; SETDTRL: routine in accordance with your I/O devices.  The modem is
  86. ; enabled by setting DTR high and must be implemented in your SETDTRH:
  87. ; routine.
  88. ;
  89. ;    To install the overlay make your changes for the USART
  90. ;    dependent routines.  This overlay may directly be used
  91. ;    if using a Zilog Z-80 SIO for I/O and a CTC for the baud
  92. ;    rate clock, just change ports and time constant for CTCs
  93. ;
  94. ;    A>DDT MDM7xx.COM   (Any .COM version of MDM714)
  95. ;    DDT VERS 2.2
  96. ;    NEXT   PC
  97. ;    4300  0100
  98. ;    -IM7SCAT.HEX
  99. ;    -R
  100. ;    NEXT   PC
  101. ;    4300  0000
  102. ;    -G0           (or CTRL-C)
  103. ;
  104. ;    A>SAVE 66 M7SCAT.COM
  105. ;
  106. ;***********************************************************************
  107. ;
  108. ; 03/10/84 - Configured for the Novation
  109. ;         Smart-Cat Modem and called M7SCAT.ASM - Charles Horn
  110. ; 03/03/84 - Configured for the VA3451 and
  111. ;               called M7RV3451.ASM    - Charles Horn
  112. ; 11/11/83 - Renamed to M7RV-1.ASM, no changes    - Irv Hoff
  113. ; 10/15/83 - First version for Racal-Vadic    - Fred Willink
  114. ;
  115. ;***********************************************************************
  116. ;
  117. ; Change these equates for YOUR ports
  118. ; Change the value at MODDATP if it does not match what you are using.
  119. ;
  120. MODDATP:    EQU    0D8H        ;data port for H89
  121. MODCTL1:    EQU    MODDATP+5    ;status port for H89
  122. MODRCVB:    EQU    1        ;bit to test for received data
  123. MODRCVR:    EQU    1        ;modem receive ready
  124. MODSNDB:    EQU    20H        ;bit to test for ready to send
  125. MODSNDR:    EQU    20H        ;modem send ready bit
  126. ;
  127. ;
  128. ;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  129. ;
  130. YES:        EQU    0FFH
  131. NO:        EQU    0
  132. ;
  133. DBUG:        EQU    YES        ;Set to NO for normal use (CEH)
  134. ;
  135. TDELAY:     EQU    3        ;DELAY5 value. 1=100 mS, 2=200mS,etc.
  136. ;
  137. CANCEL:        EQU    'X'-40H    ;^X = Cancel
  138. ESC:        EQU    '['-40H    ;^[ = escape
  139. BELL:        EQU    'G'-40H    ;^G = bell character
  140. LF:        EQU    'J'-40H    ;^J = linefeed
  141. CR:        EQU    'M'-40H    ;^M = carriage return
  142. PRINT:        EQU    9
  143. BDOS:        EQU    0005H
  144. ;
  145. LIBLEN:        EQU    34
  146. ;
  147. ;=======================================================================
  148. ;
  149.         ORG    0100H
  150. ;
  151. ;
  152.         JMP    START    ;skip the data area below
  153. ;
  154. PMMIMODEM:    DB    NO
  155. SMARTMODEM:    DB    YES    ; yes=Novation Smart-Cat. The main
  156.                 ; program test this byte to use the
  157.                 ; new routines
  158.         DS    1
  159. CLOCK:        DB    20    ;clock speed x10, up to 25.5 mhz.
  160.                 ;2 MHz=20, 3.68 MH=37, 4 MHz=40, etc.
  161. MSPEED:        DB    5    ;sets display time for sending a file
  162.                 ;0=110    1=300  2=450  3=600  4=710
  163.                 ;5=1200 6=2400 7=4800 8=9600 9=19200
  164. BYTDLY:     DB    0    ;Default time to send character in
  165.                 ;terminal mode file transfer (0-9)
  166. CRDLY:        DB    0    ;End of line delay after CRLF in terminal
  167.                 ;mode file transfer (0-9).
  168.                 ;0=zero delay, 1=10mS, 5=50mS, 9=90mS.
  169. NOOFCOL:    DB    5    ;number of columns in directory
  170. SETUPTST:    DB    YES    ;yes=non-PMMI setup routine
  171. SCRNTEST:    DB    YES    ;yes=home cursor and clear screen
  172.         DS    29
  173. ;
  174. ;
  175. ; Handles in/out ports for data and status
  176. ;
  177. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port
  178.         DB    0,0,0,0,0,0,0    ;spares if needed for non-PMMI
  179. OUT$MODDATP:    OUT    MODDATP    ! RET    ;out modem data port
  180.         DB    0,0,0,0,0,0,0    ;spares if needed for non=PMMI
  181. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port
  182.         DB    0,0,0,0,0,0,0    ;spares if needed for non-PMMI
  183. ANI$MODRCVB:    ANI    MODRCVB ! RET    ;bit to test for receive ready
  184. CPI$MODRCVR:    CPI    MODRCVR ! RET    ;value of receive bit when ready
  185. ANI$MODSNDB:    ANI    MODSNDB ! RET    ;bit to test for send ready
  186. CPI$MODSNDR:    CPI    MODSNDR ! RET    ;value of send bit when ready
  187. ;
  188. IN$BAUDRP:    RET    !  NOP    ! NOP     ;in baudrate port
  189. OUT$BAUDRP:    RET    !  NOP    ! NOP     ;out baudrate port
  190. OUT$MODCTL1:    OUT    MODCTL1    ! RET     ;out modem control port #1
  191. OUT$MODCTL2:    RET    !  NOP    ! NOP     ;out modem control port #2
  192. ;
  193. LOGONPTR:    DW    LOGON
  194. JMP$DIAL:    JMP    DIAL
  195. JMP$DISCONNT:    JMP    DISCONNT
  196. JMP$GOODBYE:    JMP    GOODBYE
  197. JMP$INITMOD:    JMP    INITMOD
  198. JMP$NEWBAUD:    RET
  199.         DS    2
  200. JMP$NOPARITY:    RET
  201.         DS    2
  202. JMP$PARITY:    RET
  203.         DS    2
  204. JMP$SETUPR:    JMP    SETUPR
  205. JMP$SPCLMENU:    RET
  206.         DS    2
  207. JMP$SYSVER:    JMP    SYSVER
  208. JMP$BREAK    RET
  209.         DS    2
  210. ;
  211. JMP$ILPRT:    JMP    ILPRT
  212. JMP$INBUF:    JMP    INBUF
  213. JMP$INLNCOMP:    JMP    INLNCOMP
  214. JMP$INMODEM:    JMP    INMODEM
  215. JMP$NXTSCRN:    JMP    NXTSCRN
  216. JMP$TIMER:    JMP    TIMER
  217. ;
  218. ;
  219. ; Clear sequences are for H/Z H-89.  Change to match
  220. ; your terminal.
  221. ;
  222. CLREOS:        CALL    ILPRT
  223.         DB    ESC,'J',0,0,0    ;HZ-89
  224.         RET
  225. ;.....
  226. ;
  227. ;
  228. CLRSCRN:    CALL    ILPRT
  229.         DB    ESC,'E',0,0,0    ;HZ-89
  230.         RET
  231. ;.....
  232. ;
  233. ;
  234. ;======================== SIGN-ON MESSAGE ==============================
  235. ;
  236. ; Send version number and date
  237. ;
  238. SYSVER: CALL    ILPRT
  239.     DB    'Version for the Novation SmartCat Modem',CR,LF
  240.     DB    '(Starts at 1200 Baud)',CR,LF,0
  241.     RET
  242. ;.....
  243. ;
  244. ;
  245. ;==================== LOGON MESSAGE (IF ANY) ===========================
  246. ;
  247. ; Insert your logon message here.  End with a 0 (for "CALL ILPRT").
  248. ;
  249. LOGON:    DS    59        ;UP TO 59 CHARACTERS ALLOWED
  250.     DB    0        ;TO TERMINATE THE LOGON MESSAGE
  251. ;.....
  252. ;
  253. ;
  254. ;===================== USART INITIALIZATION ============================
  255. ;
  256. ; Begining of USART dependent routines change as needed
  257. ;
  258. ;=======================================================================
  259. ;
  260. ; NOTE: The DTR line is used to control the modem
  261. ;
  262.  
  263. INITMOD:  MVI    A,5        ;default transfer speed to 1200 baud
  264.       STA    MSPEED
  265.       DI            ;turn off interrupts for init.
  266.       XRA    A
  267.       OUT    MODDATP+1    ;interrupt enable register
  268.       MVI    A,80H        ;insure out of mode to set baud rate
  269.       OUT    MODDATP+3    ;line control register
  270.       OUT    MODDATP+3    ;again
  271. ;
  272. LSPSPD:   MVI    A,60H        ;default 'LSP' speed for 1200 baud
  273.       OUT    MODDATP        ;register for 'LSP' speed if enabled
  274. ;
  275. MSPSPD:   MVI    A,00H        ;default 'MSP' speed for 1200 baud
  276.       OUT    MODDATP+1    ;register for 'MSP' speed if enabled
  277. ;
  278.       MVI    A,03H        ;8-level, 1 stop bit, no parity
  279.       OUT    MODDATP+3    ;line control register
  280.       MVI    A,01H        ;set 'DTR' for proper modem output level
  281.       OUT    MODDATP+4    ;modem control register
  282.       EI            ;restore interrupts to normal
  283.       RET
  284. ;.....
  285. ;The following routine changes the baud rate for the H89 with the SET
  286. ; command.
  287. ;
  288. ;SETUPR = SPEED CHANGE
  289. SETUPR:      LXI    D,BAUDBUF    ;point to input buffer for INLNCOMP
  290.       CALL    JMP$ILPRT
  291.     IF DBUG
  292.       DB    '(DTR ON: Type ON) (DTR OFF: Type OFF)',CR,LF
  293.     ENDIF    ;DBUG
  294.       DB    'Input Baud Rate (300, 450, 600, 1200, 9600): ',0
  295.       CALL    JMP$INBUF
  296.       LXI    D,BAUDBUF+2
  297.       CALL    JMP$INLNCOMP    ;compare BAUDBUF+2 with characters below
  298.       DB    '300',0
  299.       JNC    OK300        ;go if got match
  300.       CALL    JMP$INLNCOMP
  301.       DB    '450',0
  302.       JNC    OK450
  303.       CALL    JMP$INLNCOMP
  304.       DB    '600',0
  305.       JNC    OK600
  306.       CALL    JMP$INLNCOMP
  307.       DB    '1200',0
  308.       JNC    OK1200
  309.       CALL    JMP$INLNCOMP
  310.       DB    '9600',0
  311.       JNC    OK9600
  312. ;
  313.     IF DBUG         ;not normally needed
  314.       CALL    JMP$INLNCOMP
  315.       DB    'ON',0
  316.       JNC    SETDTRH
  317.       CALL    JMP$INLNCOMP
  318.       DB    'OFF',0
  319.       JNC    SETDTRL
  320.     ENDIF    ;DBUG
  321. ;
  322.       CALL    JMP$ILPRT    ;all matches failed - tell operator
  323.       DB    '++ Incorrect entry ++',CR,LF,BELL,0
  324.       JMP    SETUPR        ;try again
  325. ;
  326. OK300:      MVI    A,1        ;MSPEED 300 baud value
  327.       LHLD    BD300        ;get 300 baud parameters in HL
  328.       JMP    LOADBD        ;go load them
  329. ;
  330. OK450:      MVI    A,2
  331.       LHLD    BD450
  332.       JMP    LOADBD
  333.  
  334. OK600:      MVI    A,3
  335.       LHLD    BD600
  336.       JMP    LOADBD
  337. ;
  338. OK1200:      MVI    A,5
  339.       LHLD    BD1200
  340.       JMP    LOADBD
  341. ;
  342. OK9600:      MVI    A,8
  343.       LHLD    BD9600
  344. ;
  345. LOADBD:      STA    INITMOD+1    ;store speed to show transfer time 
  346.       MOV    A,L        ;get least significant baud rate byte
  347.       STA    LSPSPD+1    ;store in INITMOD
  348.       MOV    A,H        ;get most signifcant baud rate byte
  349.       STA    MSPSPD+1    ;store in INITMOD
  350.       JMP    INITMOD        ;reset H89 8250
  351. ;
  352. ;
  353. ; Table of baud rate parameters
  354. ;
  355. BD300:      DW    0180H
  356. BD450:      DW    0100H
  357. BD600:      DW    00C0H
  358. BD1200:      DW    0060H
  359. BD9600:      DW    000CH
  360. ;
  361. BAUDBUF:  DB    10,0
  362.       DS    10
  363. ;
  364. ;
  365. ;RAISE DTR TO ENABLE MODEM
  366. ;
  367. SETDTRH:  MVI    A,01H
  368.       OUT    MODDATP+4    
  369.       RET
  370. ;
  371. ;DROP DTR TO DISABLE MODEM
  372. ;
  373. SETDTRL:  MVI    A,00H
  374.       OUT    MODDATP+4
  375.       RET
  376. ; 
  377. ;            End of USART dependent routines
  378. ;=======================================================================
  379. ;
  380. ;             RACAL-VADIC DIALING ROUTINES
  381. ;
  382. ;=======================================================================
  383. ;
  384. ; Dialing routine
  385. ;
  386. DIAL:      XRA    A
  387.       STA    CRFLAG
  388.       STA    RINGBKFL
  389.       STA    RINGFLG
  390.       LXI    H,0
  391.       SHLD    DIALCT
  392.       LXI    H,CMDBUF+1
  393.       MOV    A,M
  394.       CPI    3+1
  395.       JC    DIAL1            ;if only CAL was entered
  396. ;
  397. ;
  398. ; If there were only 3 characters, then "CAL<RET>" was typed -- the user
  399. ; obviously expecting to get a phone number (or letter) from the library
  400. ; file.  If 4 or more, a number (or letter) was typed in from the menu
  401. ; command line, so move the characters down 4 to compensate.  Needed for
  402. ; auto-redialing of menu command line entries.
  403. ;
  404.       MOV    C,A
  405.       MVI    B,0
  406.       SUI    4
  407.       MOV    M,A
  408.       INX    H
  409.       XCHG
  410.       LXI    H,CMDBUF+6
  411.       CALL    MOVER
  412.       JMP    DIAL4            ;with letter or number at CMDBUF+2
  413. ;...
  414. ;
  415. ;
  416. ; Comes here if no phone number was manually entered after "CAL" and if
  417. ; no phone library letter was entered.    Displays the phone number li-
  418. ; brary, then asks for an entry.
  419. ;
  420. DIAL1:      MVI    C,13
  421.       LXI    H,NUMBLIB
  422.       LXI    D,BUFFER
  423.       CALL    NEWLINE
  424.       STAX    D
  425.       INX    D
  426. ;
  427. DIAL2:      MVI    B,LIBLEN
  428.       CALL    MOVE
  429.       CALL    SPACES
  430.       MVI    B,LIBLEN
  431.       CALL    MOVE
  432.       CALL    NEWLINE
  433.       DCR    C
  434.       JNZ    DIAL2
  435. ;
  436. DIAL3:      MVI    A,'$'
  437.       STAX    D
  438.       CALL    CLRTST        ;clear screen
  439.       MVI    C,PRINT
  440.       LXI    D,BUFFER    ;show library
  441.       CALL    BDOS
  442.       CALL    ILPRT
  443.       DB    CR,LF,'Enter library letter or phone number,',CR,LF
  444.       DB    'CTL-X quits while dialing or ringing: ',0
  445.       LXI    D,CMDBUF
  446.       CALL    INBUF        ;get input, library letter or phone #
  447. ;
  448. ;
  449. ; You now have either a library letter or a manually entered phone num-
  450. ; ber.    These either came from the menu command line or from the library
  451. ; command line.  Next we see if a letter, if so, get the corresponding
  452. ; line with phone number from the library.  If a number we ignore the
  453. ; library look-up.  (Ringback numbers must end with letter 'R'.)
  454. ;
  455. DIAL4:      LXI    H,CMDBUF+1
  456.       MOV    A,M
  457.       ORA    A
  458.       JZ    DIALEXIT    ;no entry in command line exit
  459.       PUSH    H
  460.       CALL    DISCONNT    ;hangup modem and drop DTR
  461.       POP    H
  462.       INX    H
  463.       MVI    B,'A'
  464.       MVI    E,0
  465.       MVI    C,26
  466.       MOV    A,M
  467. ;
  468. DIAL5:      CMP    B
  469.       JZ    DIAL6        ;If a letter
  470.       INR    B
  471.       INR    E
  472.       DCR    C
  473.       JZ    DIAL9        ;If a number
  474.       JMP    DIAL5
  475. ;
  476. ;
  477. ; Now have a match between the requested letter and one in the library
  478. ; E-reg. holds the decimal equivalent (1-26) of the letter (A-Z).
  479. ;
  480. DIAL6:      LXI    H,NUMBLIB    ;come here if a letter
  481.       LXI    B,LIBLEN
  482.       MOV    A,E
  483.       ORA    A
  484.       JZ    DIAL8
  485. ;
  486. DIAL7:      MOV    A,M
  487.       ORA    A
  488.       JZ    DIALBAD
  489.       DAD    B
  490.       DCR    E
  491.       JNZ    DIAL7
  492. ;
  493. ;
  494. ; Now have the line in the phone number library matching the requested
  495. ; letter so store that line starting at 'CMDBUF+1'
  496. ;
  497. DIAL8:      MVI    B,LIBLEN
  498.       LXI    D,CMDBUF+1
  499.       XCHG
  500.       MOV    M,B
  501.       XCHG
  502.       INX    D
  503.       CALL    MOVE
  504. ;
  505. ;
  506. ; Now have the full line including phone number in 'CMDBUF' area.
  507. ;
  508. DIAL9:      LDA    SMARTMODEM    ;comes here if CAL (number)
  509.       ORA    A
  510.       CNZ    SMINIT        ;turns DTR back on
  511. ;    
  512. DIAL10:      LXI    H,CMDBUF+1
  513.       MOV    E,M
  514.       INX    H
  515. ;
  516. DIAL11:      MOV    A,M
  517.       ORA    A
  518.       JZ    DIALBAD
  519. ;
  520. ;
  521. ; Dial a digit, check keyboard for abort
  522. ;
  523.       CALL    DIALA
  524.       CALL    STAT
  525.       JZ    DIAL13
  526.       CALL    KEYIN
  527.       CPI    CANCEL
  528.       JNZ    DIAL13
  529.       JMP    DIALEXIT
  530. ;
  531. DIAL13:      INX    H
  532.       DCR    E
  533.       JNZ    DIAL11
  534. ;
  535. ;
  536. ; Show the number of dial attempts
  537. ;
  538.       MVI    B,CR        ;end with cr to start dialing
  539.       CALL    TIMER5        ;preset delay (CEH)
  540.       CALL    SENDCHR
  541.       MVI    B,30        ;wait 3 sec for SmartCat to echo number
  542.       CALL    TIMER        ;...and gobble whatever
  543. ;
  544. EATIT:      CALL    JMP$INMODEM    ;gobble anything else that remains
  545.       JNC    EATIT
  546. ;
  547.       CALL    ILPRT
  548.       DB    ' - try #',0
  549.       LHLD    DIALCT
  550.       INX    H
  551.       SHLD    DIALCT
  552.       CALL    DECOUT
  553.       MVI    A,' '
  554.       CALL    TYPE
  555. ;
  556. DIAL14:   CALL    JMP$INMODEM    ;gobble some more if there
  557.       JNC    DIAL14
  558.       JMP    SMRESULT
  559. ;
  560. DIALAGN:  LDA    CRFLAG
  561.       ORA    A
  562.       JNZ    DIALAGN1
  563.       CALL    ILPRT
  564.       DB    ' Redial? '
  565.       DB    '(Y/N/C): ',BELL,0
  566.       CALL    KBDCHR
  567.       CALL    CRLF
  568.       CPI    'N'
  569.       JZ    DIALAGN2
  570.       CPI    'Y'
  571.       JZ    DIALAGN1
  572.       CPI    'C'
  573.       JNZ    DIALAGN
  574.       MVI    A,1
  575.       STA    CRFLAG
  576. ;
  577. DIALAGN1: MVI    B,35
  578.       CALL    TIMER
  579.       CALL    CRLF
  580.       LDA    RINGBKFL
  581.       ORA    A
  582.       JZ    DIAL4
  583.       STA    CMDBUF+1
  584.       JMP    DIAL4
  585. ;.....
  586. ;
  587. ;
  588. DIALAGN2: CALL    DIALBGN        ;disconnect the modem
  589.       JMP    MENU
  590. ;
  591. ;
  592. ; Connection has been made
  593. ;
  594. CONMADE:  CALL    ILPRT
  595.       DB    CR,LF,LF,'CONNECTION MADE',BELL,0
  596.       LDA    CRFLAG
  597.       ORA    A
  598.       JZ    RETURN
  599.       CALL    ILPRT
  600.       DB    ' - hit any key to stop the bell ',0
  601. ;
  602. CONMADE1: CALL    STAT
  603.       JZ    CONMADE2
  604.       CALL    KEYIN
  605.       XRA    A
  606.       JMP    RETURN
  607. ;
  608. CONMADE2: MVI    B,10
  609.       CALL    TIMER
  610.       MVI    A,BELL
  611.       CALL    TYPE
  612.       JMP    CONMADE1
  613. ;.....
  614. ;
  615. ;
  616. ; Automatic dialing routine, prints the number being dialed
  617. ;
  618. DIALA:      CALL    TYPE        ;comes here with character in A
  619.       CPI    'R'
  620.       JNZ    DIALA1
  621.       PUSH    PSW
  622.       MOV    A,E
  623.       CPI    1        ;was 'R' last character?
  624.       JZ    RINGBK
  625.       POP    PSW
  626. ;
  627. DIALA1:      MOV    B,A
  628.       CALL    DIALAD
  629.       MOV    A,B
  630.       CPI    '*'        ;* is valid dial digit, must not be in name
  631.       JZ    DIALA2
  632.       CPI    '#'        ;# is valid dial digit, must not be in name
  633.       JZ    DIALA2
  634.       CPI    'I'        ;I indicates pulse dialing is requested.
  635.       JZ    DIALA2        ;all I's, P's, and W's
  636.       CPI    'P'        ;in the library names MUST be lower case.
  637.       JZ    DIALA2
  638.       CPI    'W'
  639.       JZ    DIALA2
  640.       CPI    '0'
  641.       RC
  642.       CPI    '9'+1
  643.       RNC
  644. ;
  645. ;
  646. ; Must be a number.  Send it to the modem
  647. ;
  648. DIALA2:
  649.       MOV    C,A
  650.       CALL    TIMER5        ;preset delay (CEH)
  651.       JMP    SENDCHR     ;In main program. RETs to caller
  652. ;
  653. ;
  654. ; Print bad library number message and abort if a null is encountered.
  655. ;
  656. DIALBAD:  CALL    ILPRT
  657.       DB    CR,LF,'++ Bad library number called ++',CR,LF,0
  658. ;
  659. DIALEXIT: CALL    DISCONNT
  660. ;
  661. DIALEXT1: CALL    CRLF
  662.       XRA    A
  663.       STA    CRFLAG
  664. ;
  665. DIALEXT2: CALL    JMP$INMODEM
  666.       JNC    DIALEXT2
  667.       CALL    JMP$GOODBYE
  668.       JMP    MENU
  669. ;.....
  670. ;
  671. ;
  672. DIALBGN:  JMP    DISCONNT
  673. ;
  674. ;
  675. ; Do any alternate dialing such as 'MCI' or 'SPRINT'
  676. ;
  677. DIALAD:      MOV    A,B
  678.       CPI    '<'
  679.       JNZ    DIALAD1
  680.       PUSH    H
  681.       LXI    H,ALTDIAL1
  682.       JMP    DIALAD2
  683. ;
  684. DIALAD1:  CPI    '>'
  685.       RNZ
  686.       PUSH    H
  687.       LXI    H,ALTDIAL2
  688. ;
  689. DIALAD2:  MOV    A,M
  690.       CPI    '$'
  691.       JZ    DIALAD3
  692.       CALL    TYPE
  693.       MOV    B,A
  694.       CALL    TIMER5        ;preset delay (CEH)
  695.       CALL    SENDCHR     ;In main program
  696.       INX    H
  697.       CALL    STAT
  698.       JZ    DIALAD2
  699.       CALL    KEYIN
  700.       CPI    CANCEL
  701.       JZ    DIALEXIT
  702.       JMP    DIALAD2
  703. ;
  704. DIALAD3:  MVI    A,' '
  705.       CALL    TYPE
  706.       POP    H
  707.       RET
  708. ;.....
  709. ;
  710. ;
  711. ; Provide a preset delay between command characters to the modem (CEH)
  712. ; (See header for usege)
  713. ;
  714. TIMER5:
  715.       PUSH    H    ;Save all registers
  716.       PUSH    D
  717.       PUSH    B
  718.       PUSH    PSW
  719.       MVI    A,TDELAY    ;Get selected delay value
  720.       ANA    A        ;Zero?
  721.       JZ    TIMER5A     ;If so - no delay
  722.       MOV    B,A        ;Number of 100 mS intervals
  723.       CALL    TIMER
  724. TIMER5A:  POP    PSW    ;Restore registers
  725.       POP    B
  726.       POP    D
  727.       POP    H
  728.       RET
  729. ;.....
  730. ;
  731. ;
  732. ; Disconnect the Smartmodem from the phone line
  733. ;
  734. GOODBYE:
  735. DISCONNT: CALL    SETDTRH     ;in case it wasn't
  736. ;(disbled)LXI    H,DISC0     ;send the hangup command
  737. ;(disbled)CALL    SENDMDM
  738. ;
  739.       CALL    TIMER5        ;delay some and
  740. DISCONN2: CALL    JMP$INMODEM    ;gobble any return garbage
  741.       JNC    DISCONN2
  742.       CALL    SETDTRL     ;now drop the DTR
  743.       MVI    B,35        ;and give modem time to
  744.       CALL    TIMER        ;reinitialize
  745.       RET
  746. ;.....
  747. ;
  748. ;
  749. DISC0:      DB    '%H',CR,'$'    ;not called if disabled above but is
  750. ;.....                ;used by the HANGUP routine.
  751. ;
  752. ;
  753. ; Set Smartmodem for dialing
  754. ;
  755. SMINIT:      CALL    SETDTRH        ;enable dtr
  756.       LXI    H,SM$DAL1    ;put out the dial command
  757.       CALL    SENDMDM
  758.       RET
  759. ;
  760. SMINIT1:  RET
  761. ;.....
  762. ;
  763. ;
  764. SM$DAL1:  DB    '%D ','$'      ;send the <CM>, DIAL command, and SPACE
  765. ;
  766. ;
  767. ; Send the string pointed to by 'HL' to both the CRT and the modem.
  768. ;
  769. SENDOUT:  PUSH    H
  770.       CALL    SENDNOW
  771.       POP    H
  772.       MOV    A,M
  773.       CPI    '$'
  774.       RZ
  775.       MOV    A,M
  776.       CALL    TIMER5        ;preset delay between string char (CEH)
  777.       CALL    OUT$MODDATP    ;Call to main program
  778.       CALL    TYPE
  779.       INX    H
  780.       JMP    SENDOUT
  781. ;.....    
  782. ;
  783. ;
  784. ; Send the string pointed to by 'HL' to the modem only
  785. ;
  786. SENDMDM:  PUSH    H
  787.       CALL    SENDNOW
  788.       POP    H
  789.       MOV    A,M
  790.       CPI    '$'
  791.       RZ
  792.       CALL    TIMER5        ;preset delay between string char (CEH)
  793.       CALL    OUT$MODDATP    ;Call to main program
  794.       INX    H
  795.       JMP    SENDMDM
  796. ;......
  797. ;
  798. ;
  799. ; Checks for answer from Smartmodem
  800. ;
  801. SMRESULT: LXI    H,RESULBUF
  802.       PUSH    H
  803. ;
  804. SMRESUL2: CALL    RCVREADY    ;loop here 'till something happens
  805.       JZ    SMRESUL1
  806.       CALL    STAT
  807.       JZ    SMRESUL2
  808.       CALL    KEYIN
  809.       CPI    CANCEL
  810.       JNZ    SMRESUL2
  811.       MVI    B,CR
  812.       CALL    TIMER5        ;preset delay (CEH)
  813.       CALL    SENDCHR     ;Call to main program
  814.       POP    H
  815.       JMP    DIALEXT1
  816. ;
  817. RESULBUF: DS    16
  818. ;
  819. SMRESUL1: CALL    JMP$INMODEM
  820.       JC    SMRESUL4    ;no more characters coming
  821. ;
  822. SMRESUL6: ANI    7FH
  823.       CPI    ' '
  824.       JZ    SMRESUL1    ;throw away spaces, lf, cr, nuls
  825.       CPI    LF        ;bell, %, and * in the resulbuf
  826.       JZ    SMRESUL1
  827.       CPI    00H
  828.       JZ    SMRESUL1
  829.       CPI    '*'
  830.       JZ    SMRESUL1
  831.       CPI    CR
  832.       JZ    SMRESUL1
  833.       CPI    BELL
  834.       JZ    SMRESUL1
  835.       CPI    '%'
  836.       JZ    SMRESUL1
  837.       POP    H
  838.       MOV    M,A
  839.       INX    H
  840.       PUSH    H
  841.       JMP    SMRESUL1    ;get next char for RESULBUF
  842. ;
  843. ;
  844. ; Compare the SmartCat response
  845. ;
  846. SMRESUL4: POP    H
  847.       LXI    D,RESULBUF
  848.       CALL    INLNCOMP
  849.       DB    'OK',0            ;should never happen in dialing
  850.       JNC    DISCONNT        ;....routine
  851.       CALL    INLNCOMP
  852.       DB    'BUSY',0        ;busy response
  853.       JNC    NUM$BUSY
  854.       CALL    INLNCOMP
  855.       DB    'NO AN',0        ;no answer
  856.       JNC    FAILCAL
  857.       CALL    INLNCOMP
  858.       DB    'NO DI',0        ;no dialtone
  859.       JNC    NO$DT
  860.       CALL    INLNCOMP
  861.       DB    'RI',0             ;ringing...
  862.       JNC    RING
  863.       CALL    INLNCOMP
  864.       DB    'CONNECT',0        ;connection made...
  865.       JNC    CONMADE
  866.       CALL    INLNCOMP
  867.       DB    'CONN L',0        ;connection lost...
  868.       JNC    CARLOST
  869. ;
  870. SMDM1:      JMP    FAILCAL
  871. ;.....
  872. ;
  873. ;
  874. ; Carrier lost is a result of the remote end hanging up or a failure
  875. ; in the telephone circuit.  This is reported by the SmartCat.
  876. ;
  877. CARLOST:  CALL    CRLF
  878.       CALL    ILPRT
  879.       DB    'Connection lost....',0
  880.       JMP    DISCONNT
  881. ;.....
  882. ;
  883. ;
  884. ; Failed call is the result of no answer after 60 sec of ringing, wrong
  885. ; baud rate, or an incorrect response from the modem.
  886. ;
  887. FAILCAL:  CALL    CRLF
  888.       CALL    ILPRT
  889.       DB    'No answer... Failed call....',0
  890.       JMP    DIALAGN
  891. ;
  892. ;
  893. ; No dial tone can occur when using the alternate dialing option and a
  894. ; dial tone is not detected after the pause 'P' or within 5 sec after
  895. ; the start of the modem dialing routine
  896. ;
  897. NO$DT:      CALL    CRLF
  898.       CALL    ILPRT
  899.       DB    'No dial tone present....',0
  900.       JMP    DIALAGN
  901. ;
  902. NUM$BUSY: CALL    CRLF
  903.       CALL    ILPRT
  904.       DB    'Number busy....',0
  905.       JMP    DIALAGN
  906. ;
  907. RING:      CALL    CRLF
  908.       CALL    ILPRT
  909.       DB    'Ringing....',0
  910.       LDA    RINGFLG
  911.       ORA    A
  912.       JZ    SMRESULT
  913.       JMP    RINGBK1
  914. ;
  915. ;
  916. ; Handles the special ringback numbers.  Dials, lets it ring only once,
  917. ; hangs up and then redials.
  918. ;
  919. RINGFLG:  DB    0
  920. ;
  921. RINGBK:      POP    PSW
  922.       LDA    CMDBUF+1
  923.       STA    RINGBKFL
  924.       STA    RINGFLG
  925.       SUI    1
  926.       STA    CMDBUF+1
  927.       RET
  928. ;.....
  929. ;
  930. ;
  931. ; Hang up and redial
  932. ;
  933. RINGBK1:  CALL    CRLF
  934.       CALL    ILPRT
  935.       DB    'Ringback active - hanging up on first ring....',0
  936.       CALL    HANGUP
  937.       MVI    B,50
  938.       CALL    TIMER
  939.       CALL    CRLF
  940.       JMP    DIAL9
  941. ;.....
  942. ;
  943. ;
  944. HANGUP:   MVI    B,CR        ;abort the dialing process
  945.       CALL    SENDCHR
  946.       CALL    TIMER5        ;delay some
  947.       LXI    H,DISC0     ;send the hangup command
  948.       CALL    SENDMDM
  949.       XRA    A
  950.       STA    RINGFLG        ;clear flag for next dial
  951.       CALL    TIMER5        ;wait some
  952. ;
  953. HANGUP1:  CALL    JMP$INMODEM    ;wait for the modem to complete its
  954.       JNC    HANGUP1     ;response to the abort
  955.       JMP    DISCONNT    ;return here
  956. ;.....
  957. ;
  958. ;
  959. ; Time-out routine.  Must be called with mask in 'D' reg. for input at
  960. ; relative port 2 and number of seconds (times 10) in 'C' reg.
  961. ;
  962. WAIT:      MVI    B,2
  963.       CALL    TIMER
  964.       CALL    IN$MODCTL1
  965.       ANA    D
  966.       RZ
  967.       PUSH    B
  968.       PUSH    D
  969.       CALL    STAT
  970.       JZ    WAIT1
  971.       CALL    KEYIN
  972.       CPI    CANCEL
  973.       JZ    WAIT2
  974. ;
  975. WAIT1:      POP    D
  976.       POP    B
  977.       DCR    C
  978.       JNZ    WAIT
  979.       STC
  980.       RET
  981. ;.....
  982. ;
  983. ;
  984. WAIT2:      POP    D
  985.       POP    B
  986.       JMP    DONETCD
  987. ;.....
  988. ;
  989. ;
  990. ; Patch for SETUPENT: to prevent sending of Hayes commands to SmartCat
  991. ;
  992. ;
  993.       ORG    404BH
  994. ;
  995. ;
  996. SETUPENT: LDA    SETUPTST
  997.       ORA    A
  998.       JZ    NOTVLD
  999.       CALL    JMP$SETUPR
  1000.       JMP    XPRT
  1001. ;
  1002. NOTVLD:      EQU    39A3H
  1003. ;
  1004. ;
  1005. ; Lets fix the byebye routine it calls GOODBYE: directly  and not
  1006. ; through the jump vectors at the begining
  1007. ;
  1008. ;
  1009.       ORG    39C6H
  1010. ;
  1011. ;
  1012. BYEBYE:      LDA    PMMIMODEM
  1013.       ORA    A
  1014.       CNZ    JMP$GOODBYE
  1015.       LDA    SMARTMODEM
  1016.       ORA    A
  1017.       CNZ    JMP$GOODBYE
  1018.       CALL    ILPRT
  1019.       DB    CR,LF,'<<Exit to CP/M>>',CR,LF,0
  1020.       JMP    EXIT
  1021. ;.....
  1022. ;
  1023. ;
  1024. ; Fix for ILPRT: when exits routine the stack dose not contain the cor-
  1025. ; rect location of the next instruction.  Shouldn't make any difference
  1026. ; as points to NOP, but?
  1027. ;
  1028. ;
  1029.       ORG    262EH
  1030. ;
  1031. ;
  1032. ILPRT:      XTHL
  1033. ;
  1034. ILPRT1:      MOV    A,M
  1035.       INX    H
  1036.       ORA    A
  1037.       JZ    ILPRT2
  1038.       CALL    CTYPE
  1039.       JMP    ILPRT1
  1040. ;
  1041. CTYPE:      EQU    257BH
  1042. ILPRT2      EQU    263BH
  1043. ;
  1044. ;
  1045. ; Fix for DONETCD: the routines GOODBYE: and DISCONNT: are the same so
  1046. ; no need to call twice.
  1047. ;
  1048. ;
  1049.       ORG    2511H
  1050. ;
  1051. ;
  1052. DONETCD:  CALL    ILPRT
  1053.       DB    CR,LF,'<< DISCONNECTED >>',BELL,CR,LF,0
  1054.       CALL    JMP$GOODBYE
  1055.       JMP    MENU0
  1056. ;
  1057. MENU0:      EQU    2CB6H
  1058. ;
  1059. ;
  1060. ; M712RACL.ASM uses these routines located in the main program
  1061. ;
  1062. TIMER:      EQU    0B80H        ;timer routine
  1063. INLNCOMP: EQU    2A2BH        ;compare routine
  1064. ILPRT:      EQU    262EH        ;print string routine
  1065. CRLF:      EQU    2588H        ;print crlf
  1066. CMDBUF:      EQU    42F8H        ;cmd buffer
  1067. RINGBKFL: EQU    42F4H        ;ring back flag
  1068. KEYIN:      EQU    25A0H        ;kbd input
  1069. STAT:      EQU    2595H        ;console status
  1070. SENDCHR:  EQU    26B7H        ;send character
  1071. RCVREADY: EQU    188DH        ;reciever ready
  1072. INMODEM:  EQU    1AD2H        ;in modem
  1073. KBDCHR:      EQU    25C1H        ;wait for keyboard input
  1074. CRFLAG:      EQU    42E5H        ;cr flag
  1075. ALTDIAL1: EQU    0BD0H        ;alt dial 1
  1076. ALTDIAL2: EQU    0BE8H        ;alt dial 2
  1077. TYPE:      EQU    25B4H        ;type
  1078. MENU:      EQU    2CFDH        ;menu
  1079. NUMBLIB:  EQU    0C00H        ;number library
  1080. BUFFER:      EQU    4700H
  1081. CLRTST:      EQU    41B7H        ;clear screen test
  1082. MOVER:      EQU    2AFAH        ;move routine
  1083. MOVE:      EQU    26AEH
  1084. SPACES:      EQU    415DH
  1085. INBUF:      EQU    2951H
  1086. DECOUT:      EQU    25D4H
  1087. INBUF:      EQU    2951H
  1088. NXTSCRN:  EQU    4187H
  1089. RETURN:      EQU    14CAH
  1090. SENDNOW:  EQU    189FH
  1091. DONETCD:  EQU    2511H
  1092. DIALCT:      EQU    42DAH
  1093. NEWLINE:  EQU    4154H
  1094. START:      EQU    0F75H        ;start
  1095. EXIT:      EQU    2671H
  1096. XPRT:      EQU    382FH
  1097. ;
  1098.       END
  1099.