home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / asmutl / buffers.lbr / TEST2.MZC / TEST2.MAC
Encoding:
Text File  |  1987-01-15  |  3.0 KB  |  132 lines
  1. ; test buffers module. Copy file 1 to file 2
  2. ; This does a totally unnecessary double buffering, in order
  3. ; to illustrate use of the package and linking methods to
  4. ; keep a maximum memory area available.
  5. ;
  6. ;   d>TEST2 [d[u]:]filename.typ [d[u]:]outname.typ
  7. ;        copies filename.typ to outname.typ
  8. ;        (with full du addressing, across users, drives)
  9. ; 
  10. ; SEE BUFFERS.DOC for linking instructions
  11. ;
  12. boot    equ    0
  13. tfcb    equ    boot+05ch
  14. defdma    equ    boot+080h
  15. ;
  16.     extrn    .dos, b.ohead
  17.     extrn    .bfgetc, .bfputc
  18.     extrn    .bfropen, .bfwopen, .bfclose
  19.     extrn    .pfnmdu, .initfcb
  20. ;
  21. begin:    lhld    6;        set stack at top of memory
  22.     mvi    l,0
  23.     sphl
  24. ;    "    "
  25. ; apportion memory to two file buffers
  26.     lxi    d,-inbuff-128;    128 byte stack/b.ohead allowance
  27.     dad    d;        form size of memory available
  28.     mov    a,h
  29.     ora    a
  30.     rar
  31.     mov    b,a;        1/2 space to buffers size
  32.     mov    a,l;        will be rounded down
  33.     rar
  34.     mov    c,a;        1/2 space to buffer size
  35.     lxi    h,inbuff
  36.     shld    @inbuff
  37.     dad    b
  38.     lxi    d,b.ohead;    input space + 12
  39.     dad    d
  40.     shld    @outbuff;    form outbuffer pointer
  41.     push    b;        save buffer size
  42. ;    "    "
  43. ; initialize fcbs
  44.     lxi    h,fcbin
  45.     call    .initfcb
  46.     lxi    h,fcbout
  47.     call    .initfcb
  48. ;    "    "
  49. ; mark end of command line, just in case.
  50. ; Done by most CCPs, but undocumented.  CCPLUS is documented
  51.     lxi    h,defdma
  52.     mov    a,m;        line length
  53.     inx    h
  54.     add    l
  55.     mov    l,a
  56.     adc    h
  57.     sub    l
  58.     mov    h,a
  59.     mvi    m,0;        mark eol
  60. ;    "    "
  61. ; parse the file names
  62.     lxi    d,defdma+1;    set command scanning pointer
  63.     lxi    h,fcbin
  64.     call    .pfnmdu;    will parse an empty line into
  65.     lda    fcbin+1;    a blank FCB.
  66.     cpi    ' '
  67.     jz    nofile
  68.     mov    a,b;        designated user
  69.     pop    b;        get buffer size back
  70.     push    b;        re-save buffer size
  71.     push    d;        save input scan pointer
  72.     lxi    d,fcbin
  73.     lhld    @inbuff
  74.     call    .bfropen;    open buffered file for read
  75.     jc    error;        can't find it, abort
  76.     pop    d;        restore input scan pointer
  77.     push    b;        save size again
  78.     lxi    h,fcbout
  79.     call    .pfnmdu
  80.     lda    fcbout+1
  81.     cpi    ' '
  82.     jz    noutfile
  83.     mov    a,b;        designated user
  84.     pop    b
  85.     lxi    d,fcbout
  86.     lhld    @outbuff
  87.     call    .bfwopen;    open buffered file for write
  88.     jc    createrr;    can't create file
  89. ;    "    "
  90. ; All files open, and buffers assigned.
  91. ; Copy fcbin to fcbout byte by byte.
  92. copy:    lhld    @inbuff
  93.     call    .bfgetc;    get a byte
  94.     jc    done;        eof
  95.     mov    c,a
  96.     lhld    @outbuff;    Every byte passes thru here, so
  97.     call    .bfputc;    that any desired filters can be
  98.     jc    outerr;        implemented here.
  99.     jmp    copy
  100. ;
  101. ; done, close output file
  102. done:    lhld    @outbuff
  103.     call    .bfclose
  104.     jnc    boot;        no close error
  105. ;    "    "
  106. ; all the errors simplified to one message
  107. outerr:
  108. createrr:
  109. error
  110. noutfile:
  111. nofile:    lxi    d,errmsg
  112.     mvi    a,9
  113.     call    .dos
  114.     jmp    boot
  115. ;
  116. errmsg:    db    'Some sort of error occured$'
  117. ;
  118. ;    ---------    Data Segment    --------
  119. ;    Link this AFTER all the code segments
  120. ;
  121.     dseg
  122. fcbin:        ds    36;    input file fcb
  123. fcbout:        ds    36;    output file fcb
  124. @inbuff:    ds    2;    pointer to input buffer
  125. @outbuff:    ds    2;    pointer to output buffer
  126. ;
  127. ; This must be the last program storage, see linking above.
  128. ; An alternative is to use a separate dseg file.
  129. inbuff:        ds    0;    actually 1/2 of remainder
  130. ;
  131.     end
  132. ε