home *** CD-ROM | disk | FTP | other *** search
/ Media Share 9 / MEDIASHARE_09.ISO / progmisc / nfsrc21.zip / RESTATT.ASM < prev    next >
Assembly Source File  |  1992-10-03  |  6KB  |  168 lines
  1. ; File......: RESTATT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   03 Oct 1992 14:33:46  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   C:/nanfor/src/restatt.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   C:/nanfor/src/restatt.asv  $
  14. ;  
  15. ;     Rev 1.2   03 Oct 1992 14:33:46   GLENN
  16. ;  Ted Means made modifications so these functions will work with
  17. ;  dispBegin() and dispEnd().
  18. ;  
  19. ;     Rev 1.1   15 Aug 1991 23:08:02   GLENN
  20. ;  Forest Belt proofread/edited/cleaned up doc
  21. ;  
  22. ;     Rev 1.0   12 Jun 1991 01:30:14   GLENN
  23. ;  Initial revision.
  24. ;
  25.  
  26.  
  27. ;  $DOC$
  28. ;  $FUNCNAME$
  29. ;     FT_RESTATT()
  30. ;  $CATEGORY$
  31. ;     Video
  32. ;  $ONELINER$
  33. ;     Restore the attribute bytes of a specified screen region.
  34. ;  $SYNTAX$
  35. ;     FT_RESTATT( <nTop>, <nLeft>, <nBottom>, <nRight>, <cAttributes> ) -> NIL
  36. ;  $ARGUMENTS$
  37. ;     <nTop>, <nLeft>, <nBottom>, and <nRight> define the screen region.
  38. ;     <cAttributes> is a character string containing the attribute bytes
  39. ;                   for the screen region.  This will most often be a string
  40. ;                   previously returned by FT_SAVEATT(), but any character
  41. ;                   string may be used (provided it is of the proper size).
  42. ;  $RETURNS$
  43. ;     NIL
  44. ;  $DESCRIPTION$
  45. ;     This function is similar to Clipper's RestScreen(), except that it only
  46. ;     restores the attribute bytes.  This is useful if you want to change the
  47. ;     screen color without affecting the text.
  48. ;
  49. ;     *** INTERNALS ALERT ***
  50. ;
  51. ;     This function calls the Clipper internals __gtSave and __gtRest to
  52. ;     manipulate the the screen image.  If you're too gutless to use
  53. ;     internals, then this function isn't for you.
  54. ;  $EXAMPLES$
  55. ;     // Restore attributes of row 4
  56. ;     FT_RESTATT( 4, 0, 4, maxcol(), cBuffer)
  57. ;
  58. ;     // Restore attributes to middle of screen
  59. ;     FT_RESTATT(10,20,14,59,cBuffer)
  60. ;  $SEEALSO$
  61. ;     FT_SAVEATT()
  62. ;  $END$
  63. ;
  64.  
  65. IDEAL
  66.  
  67. Public   FT_RestAtt
  68.  
  69. Extrn    __ParNI:Far
  70. Extrn    __ParC:Far
  71. Extrn    __XGrab:Far
  72. Extrn    __XFree:Far
  73. Extrn    __gtSave:Far                      ; INTERNAL!!  INTERNAL!!
  74. Extrn    __gtRest:Far                      ; INTERNAL!!  INTERNAL!!
  75.  
  76. nTop     EQU       Word Ptr BP - 2
  77. nLeft    EQU       Word Ptr BP - 4
  78. nBottom  EQU       Word Ptr BP - 6
  79. nRight   EQU       Word Ptr BP - 8
  80. nAttr    EQU       Byte Ptr BP - 10
  81. nBufLen  EQU       Word Ptr BP - 12
  82.  
  83. cBuffer  EQU       DWord Ptr BP - 16
  84. nBufOfs  EQU       Word Ptr BP - 16
  85. nBufSeg  EQU       Word Ptr BP - 14
  86.  
  87. Segment  _NanFor   Word      Public    "CODE"
  88.          Assume    CS:_NanFor
  89.  
  90. Proc     FT_RestAtt          Far
  91.  
  92.          Push      BP                        ; Save BP
  93.          Mov       BP,SP                     ; Set up stack reference
  94.          Sub       SP,16                     ; Allocate locals
  95.  
  96.          Mov       CX,4                      ; Set param count
  97. @@Coord: Push      CX                        ; Put on stack
  98.          Call      __ParNI                   ; Retrieve param
  99.          Pop       CX                        ; Get count back
  100.          Push      AX                        ; Put value on stack
  101.          Loop      @@Coord                   ; Get next value
  102.  
  103.          Pop       [nTop]                    ; Store top coordinate
  104.          Pop       [nLeft]                   ; Store left coordinate
  105.          Pop       [nBottom]                 ; Store bottom coordinate
  106.          Pop       [nRight]                  ; Store right coordinate
  107.  
  108.          Mov       AX,[nBottom]              ; Load bottom coordinate
  109.          Sub       AX,[nTop]                 ; Subtract top
  110.          Inc       AX                        ; Calc length
  111.  
  112.          Mov       CX,[nRight]               ; Load right coordinate
  113.          Sub       CX,[nLeft]                ; Subtract left
  114.          Inc       CX                        ; Calc width
  115.          Mul       CX                        ; Multiply length by width
  116.          SHL       AX,1                      ; Calc buffer size
  117.          Mov       [nBufLen],AX              ; Store buffer size
  118.  
  119. @@Alloc: Push      AX                        ; Put size on stack
  120.          Call      __xGrab                   ; Allocate memory
  121.          Add       SP,2                      ; Realign stack
  122.          Mov       [nBufSeg],DX              ; Store segment
  123.          Mov       [nBufOfs],AX              ; Store offset
  124.  
  125.          Push      DX                        ; Load parameters for __gtSave
  126.          Push      AX                        ; onto stack
  127.          Push      [nRight]
  128.          Push      [nBottom]
  129.          Push      [nLeft]
  130.          Push      [nTop]
  131.          Call      __gtSave                  ; Grab screen image
  132.  
  133.          Push      DS                        ; Save required registers
  134.          Push      SI
  135.          Push      DI
  136.  
  137.          Mov       AX,5                      ; Specify 5th param
  138.          Push      AX                        ; Put on stack
  139.          Call      __ParC                    ; Get pointer to attr string
  140.          Add       SP,2                      ; Realign stack
  141.  
  142.          Mov       DS,DX                     ; Load pointer to string
  143.          Mov       SI,AX                     ; into DS:SI
  144.          Mov       ES,[nBufSeg]              ; Load pointer to buffer
  145.          Mov       DI,[nBufOfs]              ; into ES:DI
  146.          Mov       CX,[nBufLen]              ; Load buffer length
  147.          SHR       CX,1                      ; Divide by two
  148.  
  149. @@Attr:  Inc       DI                        ; Point DI to attribute
  150.          Lodsb                               ; Grab an attribute byte
  151.          Stosb                               ; Store attribute
  152.          Loop      @@Attr                    ; Do next
  153.  
  154.          Pop       DI                        ; Restore registers
  155.          Pop       SI
  156.          Pop       DS
  157.          Call      __gtRest                  ; Restore screen image
  158.  
  159. Done:    Push      [nBufSeg]                 ; Put segment on stack
  160.          Push      [nBufOfs]                 ; Put offset on stack
  161.          Call      __xFree                   ; Free memory
  162.          Mov       SP,BP                     ; Realign stack
  163.          Pop       BP                        ; Restore BP
  164.          Ret
  165. Endp     FT_RestAtt
  166. Ends     _NanFor
  167. End
  168.