Magazyn Amiga Shareware Floppies/ma56.dms/ma56.adf/StartMenu/Install_Update

Text File | 1996-06-12 | 8KB | 315 lines

; Install_Update
; Upgrade v1.0 of StartMenu
; Copyright © 1996 John Corigliano
; $VER: Install_Update 1.0

(set vers (+ (getenv "Kickstart")))

(welcome "Welcome to the StartMenu upgrade!")

(set dirhelp
   (cat
        "Select the place on your hard drive where you have version 1.0 of StartMemu.\n"
        "The installer will delete some old files that are no longer used and add new files. Also, it will update your \"start.pref\" file so that it is compatible with 2.0"
    )
)


(set new_dir
    (askdir
        (prompt "Where is the old version of StartMenu?")
        (help dirhelp)
        (default "Work:")
    )
)
(set @default-dest new_dir)

(set old_start (tackon @default-dest "StartMenu"))
(if (= 0 (exists old_start))
    (abort "Could not find StartMenu in the directory you specified\nUse the Install_New script to install for the first time.")
)

(tooltype
    (dest "Dist/StartMenu")
    (settooltype "PATH" @default-dest)
)

(tooltype
    (dest "Dist/StartMenuLite")
    (settooltype "PATH" @default-dest)
)

(tooltype
    (dest "Dist/StartMenuUltraLite")
    (settooltype "PATH" @default-dest)
)

(set ttypehelp
    (cat
        "To enable keyboard control of StartMenu, you must enter a key-combination for StartMenu to use.\n"
        "This key-combination can be any valid Commodities key sequence.\n"
        "The default value is \"rawkey ralt up\" which is the \"Right Alt Key plus Up Arrow Key\" key combination.\n"
        "You must enter a key sequence here."
    )
)
(set ttype
    (askstring
        (prompt "Please enter the hot-key combination to use with StartMenu")
        (help ttypehelp)
        (default "rawkey ralt up")
    )
)
(if (= ttype "")
    (set ttype "rawkey ralt up")
)

(tooltype
    (dest "Dist/StartMenu")
    (settooltype "HOTKEY" ttype)
)

(tooltype
    (dest "Dist/StartMenuLite")
    (settooltype "HOTKEY" ttype)
)

(tooltype
    (dest "Dist/StartMenuUltraLite")
    (settooltype "HOTKEY" ttype)
)

(set dfile (tackon @default-dest "Default.info"))
(delete dfile (optional "force"))

(set dfile (tackon @default-dest "Folder.info"))
(delete dfile (optional "force"))

(set dfile (tackon @default-dest "ScreenShot.iff"))
(delete dfile (optional "force"))

(set dfile (tackon @default-dest "Install.readme"))
(delete dfile (optional "force"))

(set dfile (tackon @default-dest "Install.readme.info"))
(delete dfile (optional "force"))

(copyfiles
    (prompt "Copying new files...")
    (source "Dist")
    (help @copyfiles-help)
    (dest @default-dest)
    (all)
    (infos)
    (optional "force")
)

(makedir (tackon @default-dest "StartUp") (infos))

(if (> 39 vers)
    (
        (copyfiles
            (prompt "Copying prefs...")
            (source "main.pref.20")
            (dest @default-dest)
            (newname "main.pref")
        )
        (copylib
            (prompt "Installing WBStartup-Handler to L:")
            (source "L/WBStart-Handler")
            (dest "L:")
            (confirm)
            (help "StartMenu uses this to launch programs.")
        )
        (protect "L:WBStart-Handler" "+e")
    )
    (
        (copyfiles
            (prompt "Copying prefs...")
            (source "main.pref.30")
            (dest @default-dest)
            (newname "main.pref")
        )
        (copylib
            (prompt "Installing wbstart.library to LIBS:")
            (source "Libs/wbstart.library")
            (dest "LIBS:")
            (confirm)
            (help "StartMenu uses this to launch programs.")
        )
    )
)

(run ("UpdatePrefs %s %s" @default-dest @default-dest))

(set starthelp
    (cat
        "If you want StartMenu to run everytime you boot your computer pick one of the first three items.\n"
        "The three choices are:\n"
        "  \" StartMenu\" - this is the full version.\n"
        "  \"StartMenuLite\" - this is just the menus and no taskbar.\n"
        "  \" StartMenuUltraLite\" - this is just the menus and no taskbar and no graphics.\n\n"
        "Select \"Skip this part\" if you do not want to copy anything to WBStartUp.  If you find you like StartMenu, you can always drag-n-drop it to the WBStartUp drawer at a later time."
    )
)
(set rc
    (askchoice
        (prompt "Do you want me to copy StartMenu to Sys:WBStartup?")
        (choices "StartMenu" "StartMenuLite" "StartMenuUltraLite" "Skip this part")
        (help starthelp)
    )
)

(select rc
    (copyfiles
        (source (tackon @default-dest "StartMenu"))
        (dest "Sys:WBStartUp")
        (infos)
    )
    (copyfiles
        (source (tackon @default-dest "StartMenuLite"))
        (dest "Sys:WBStartUp")
        (infos)
    )
    (copyfiles
        (source (tackon @default-dest "StartMenuUltraLite"))
        (dest "Sys:WBStartUp")
        (infos)
    )
    (set nop 1)
)

(set rc
    (askchoice
        (prompt "Which icons?")
        (choices "Standard 4 color" "8 color (NewIcons)" "8 color MWB")
        (help "Select which icon set StartMenu should use in the menus")
    )
)

(select rc
    (copyfiles
        (source "icons4")
        (dest @default-dest)
        (all)
        (optional "force")
    )
    (copyfiles
        (source "icons8")
        (dest @default-dest)
        (all)
        (infos)
        (optional "force")
    )
    (copyfiles
        (source "iconsMWB")
        (dest @default-dest)
        (all)
        (optional "force")
    )

)

(if (> vers 37)
    (
        (set rc
            (askchoice
                (prompt "Choose a language:")
                (choices "Deutsch" "Français)" "Italiano" "Svenska" "English")
                (help "Select which language to use for StartSetup and FindFile")
            )
        )
        (select rc
            (copyfiles
                (source "locale/Deutsch")
                (dest "Locale:catalogs/Deutsch")
                (all)
                (optional "force")
            )
            (copyfiles
                (source "locale/Français")
                (dest "Locale:catalogs/Français")
                (all)
                (optional "force")
            )
            (copyfiles
                (source "locale/Italiano")
                (dest "Locale:catalogs/Italiano")
                (all)
                (optional "force")
            )
            (copyfiles
                (source "locale/Svenska")
                (dest "Locale:catalogs/Svenska")
                (all)
                (optional "force")
            )
            (set nop 1)
        )

    )
)

(set rc
    (askoptions
        (prompt "What \"Extras\" programs would you like to install?")
        (choices "WinControl" "WinMaster" "MemMeter" "AudMon" "SMRexx")
        (help "These programs use the TaskBar, so you should only install them if you use the full version of Startmenu")
    )
)

(if (BITAND rc 1)
    (copyfiles
        (source "Extras/WinControl/WinControl")
        (dest (tackon @default-dest "StartUp"))
        (infos)
        (optional "force")
    )
    (copyfiles
        (source "Extras/WinControl/WCPrefs")
        (dest "Sys:Prefs")
        (infos)
        (optional "force")
    )
)

(if (BITAND rc 2)
    (copyfiles
        (source "Extras/WinMaster/WinMaster")
        (dest (tackon @default-dest "StartUp"))
        (infos)
        (optional "force")
    )
)

(if (BITAND rc 4)
    (copyfiles
        (source "Extras/MemMeter/MemMeter")
        (dest (tackon @default-dest "StartUp"))
        (infos)
        (optional "force")
    )
)

(if (BITAND rc 8)
    (copyfiles
        (source "Extras/AudMon")
        (dest (tackon @default-dest "StartUp"))
        (infos)
        (all)
        (optional "force")
    )
)

(if (BITAND rc 16)
    (copyfiles
        (source "Extras/SMRexx/SMRexx")
        (dest (tackon @default-dest "StartUp"))
        (infos)
        (optional "force")
    )
)


(exit bye)