home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magazyn Amiga Shareware Floppies
/
ma45.dms
/
ma45.adf
/
OrderMaker
/
Instalacja_HD
next >
Wrap
Text File
|
2002-10-23
|
4KB
|
171 lines
; Skrypt sîuûâcy do zainstalowania OrderMakera IV na twardy dysk.
; $VER: Instalacja_HD 37.8 (10.10.95)
; Copyright (C) 1994, 1995 Kamil Iskra
; Wybór katalogu do zainstalowania.
(set nadrzednykatdoc
(askdir
(prompt "Gdzie ma zostaê utworzony katalog \"OrderMaker\"?")
(help "W katalogu, który wybierzesz, zostanie utworzony podkatalog "
"\"OrderMaker\", do którego zostanie skopiowany ten program.\n\n"
"Jeûeli masz juû zainstalowanâ wczeôniejszâ wersjë OrderMakera, "
"to wybierz katalog nadrzëdny w stosunku do katalogu zawierajâcego "
"OrderMakera.\n\n"
@askdir-help
)
(default @default-dest)
)
)
(set @default-dest (tackon nadrzednykatdoc "OrderMaker"))
(if (= (exists @default-dest) 2)
; Katalog juû istnieje
(if (askbool
(prompt "Katalog \"OrderMaker\" juû istnieje. Czy mam skasowaê "
"znajdujâce sië w nim pliki?")
(help "Najprawdopodobniej masz juû zainstalowanâ wczeôniejszâ "
"wersjë OrderMakera. Przed instalacjâ nowej wersji program "
"instalacyjny wolaîby usunâê z katalogu pliki ze starej wersji. "
"Skasowane zostanâ wszystkie pliki poza ew. kluczem i jego "
"dokumentacjâ (wzorzec kasowania: \"~(OrderMaker.key#?)\").")
)
(run "Delete" (cat "\"" (tackon @default-dest "~(OrderMaker.key#?)")
"\""))
)
; Proôba o potwierdzenie, utworzenie katalogu.
(makedir @default-dest
(prompt ("\"Order Maker\" zostanie zainstalowany w katalogu \"%s\""
@default-dest)
)
(help @makedir-help)
(infos)
(confirm)
)
)
; Wybierz czëôci pakietu do zainstalowania.
(set czesci_pakietu
(askoptions
(prompt "Które elementy programu majâ zostaê zainstalowane?")
(choices "Program gîówny" "Dokumentacja")
(default %11)
(help
"Program gîówny - zostanie skopiowana gîówna czëôê programu, czyli "
"plik \"OrderMaker\" wraz z ikonâ.\n\n"
"Dokumentacja - zostanie skopiowana dokumentacja OnLine-Help "
"(plik \"OrderMaker.guide\") wraz z ikonâ.\n\n"
@askoptions-help
)
)
)
; Ustal wersjë programu do zainstalowania.
(set wersjaos
(askchoice
(prompt "Która wersja programu ma zostaê zainstalowana?")
(choices "Dla OS 1.3-" "Dla OS 2.04+")
(help
"OrderMaker jest rozprowadzany w dwóch wersjach: jedna dziaîa z "
"wszystkimi systemami operacyjnymi (OS 1.3-), druga, wymagajâca "
"OS 2.04+, jest nieco krótsza, szybsza i bardziej rozbudowana.\n\n"
@askchoice-help
)
(default
(if (< (/ (getversion) $10000) 37)
0
1
)
)
)
)
; Jeûeli OS 2.0, ustal wersjë ikon do zainstalowania.
(if (= wersjaos 1)
(set typikon
(askchoice
(prompt "Który typ ikon ma zostaê zainstalowany?")
(choices "Standardowe" "MagicWB")
(help
"Standardowe - zainstalowane zostanâ typowe, 4-kolorowe ikony."
"\n\n"
"MagicWB - zainstalowane zostanâ 8-kolorowe ikony MagicWB.\n\n"
@askchoice-help
)
(default
(exists "ENV:MagicWB")
)
)
)
(set typikon 0)
)
; OS->Katalog.
(set zrodkat
(if (= wersjaos 0)
"OS13"
"OS20"
)
)
; Skopiujmy program gîówny.
(if (IN czesci_pakietu 0)
(copyfiles
(source (tackon zrodkat "OrderMaker"))
(dest @default-dest)
(infos)
)
)
; Skopiujmy dokumentacjë.
(if (IN czesci_pakietu 1)
(copyfiles
(source "OrderMaker.guide")
(dest @default-dest)
(infos)
)
)
; Instaluj ikony MagicWB.
(if (= typikon 1)
(
(if (IN czesci_pakietu 0)
(copyfiles
(source "OS20/MagicWB/OrderMaker.info")
(dest @default-dest)
)
)
(if (IN czesci_pakietu 1)
(copyfiles
(source "OS20/MagicWB/OrderMaker.guide.info")
(dest @default-dest)
)
)
(copyfiles
(source "OS20/MagicWB.info")
(dest nadrzednykatdoc)
(newname "OrderMaker.info")
)
)
)
; Skoryguj defaulttool dla dokumentacji pod OS 3.0+.
(if (AND (IN czesci_pakietu 1) (> (/ (getversion) $10000) 38))
(tooltype
(dest (tackon @default-dest "OrderMaker.guide"))
(setdefaulttool "MultiView")
)
)
; Sprawdúmy, czy jest amigaguide.library w OS 2.0-.
(if (< (/ (getversion) $10000) 39)
(if (NOT (exists "LIBS:amigaguide.library"))
(message
"Nie posiadasz w katalogu \"LIBS:\" biblioteki "
"\"amigaguide.library\". Ta biblioteka jest OrderMakerowi "
"niezbëdna do obsîugi dokumentacji. Musisz jâ skâdô zdobyê!"
)
)
)