home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magazyn Exec 5
/
CD_Magazyn_EXEC_nr_5.iso
/
Gry
/
ToTDemo.lha
/
talesdemo1
/
ToT-Install
< prev
next >
Wrap
Text File
|
2000-07-21
|
5KB
|
155 lines
;$VER: ToT-Install (2000-07-05)
;Sebastian Huebner <cyco@baud.de>
;check for installer version >=44 (OS3.5))
(set #instver (/ @installer-version 65536))
(if (>= #instver 44)
(
(effect "lower_right" "radial" $AA0000 $0000AA)
(showmedia "symbol" "Goodies/Title.iff" "upper_left" "none" 0)
)
)
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
(set #totversion "Demo 0.29 R1")
(set #totdirname "TalesDemo1" )
(set #totassign "ToTDemo1" )
(set #deletedatafiles "(DEMO1_TCPIPReq.dat|DEMO1_TCPIPReq.RAWB)")
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; altes assign vorhanden? wenn nicht: "games:" vorhanden?
(set #oldplace (getassign #totassign))
(set #games (getassign "games" ))
(if (and (<> "" #oldplace) (exists #oldplace))
( (set #oldassignfound 1) (set @default-dest (pathonly #oldplace)) )
(if (and (<> "" #games) (exists #games))
(set @default-dest "Games:")
)
)
(complete 0)
;~~~~~~~~~~~~~~~~~~Englische Texte~~~~~~~~~~~~~~~~~~
(set #introduction
(cat "\nWelcome to the Installation of\n\nT A L E S\nO F\nT A M A R\n\n\n\nVersion: "
#totversion "\n\nhttp://www.tamar.net\nMartin Wolf <eternity@pride.de>"))
(set #ask-path (cat "Where should the directory \"" #totdirname "\" be created?\n"
"An existing directory will be used."
))
(set #ask-path-help (cat "A new directory \"" #totdirname
"\" will be created or an existing one will be used."))
(set #ask-assign (cat "Should the assign \"" #totassign ":\" be added to your "
"\"S:user-startup\"?"))
(set #ask-assign-help (cat "The assign \"" #totassign ":\" can be added to your "
"\"S:user-startup\".\n\n"
"Because it is needed by " @app-name ", "
"you should really do this. Otherwise you have to "
"perform the addition by hand:\n\n "
))
(set #fileatplace (cat "Unable to create new directory:"
"A file exists at that position ") )
(set #goodbye "\n\n\n\nGoodbye and have fun with Tales of Tamar!")
;~~~~~~~~~~~~~~~~~~Deutsche Texte~~~~~~~~~~~~~~~~~~
(if (= @language "deutsch")
(
(set #introduction
(cat "\nWillkommen zur Installation von\n\nT A L E S\nO F\nT A M A R\n\n\n\nVersion: "
#totversion "\n\nhttp://www.tamar.net\nMartin Wolf <eternity@pride.de>"))
(set #ask-path (cat "Wo soll das Verzeichnis \"" #totdirname "\" angelegt werden?\n"
"Ein schon existierendes Verzeichnis wird weiter benutzt."
))
(set #ask-path-help (cat "A neues Verzeichnis \"" #totdirname
"\" wird erstellt oder ein bereits vorhandenes weiter benutzt."))
(set #ask-assign (cat "Soll die Zuweisung \"" #totassign ":\" zu Ihrer "
"\"S:user-startup\" hinzugefügt werden?"))
(set #ask-assign-help (cat "Die Zuweisung \"" #totassign ":\" kann zu Ihrer "
"\"S:user-startup\" hinzugefügt werden.\n\n"
"Da die Zuweisung von " @app-name " benötigt wird, "
"sollten Sie die Ergänzung zulassen, andernfalls müssen sie "
"diese per Hand durchführen:\n\n "
))
(set #fileatplace (cat "Kann neues Verzeichnis nicht erstellen:"
"Eine Datei befindet sich an der Position ") )
(set #goodbye "\n\n\n\nViel Spaß mit Tales of Tamar!")
)
)
;~~~~~~~~~~~~~~~~~~Installation~~~~~~~~~~~~~~~~~~
(complete 1)
; introduction
(message #introduction (all))
(complete 10)
;choose user level
(welcome)
(complete 20)
; wo installieren?
(set #totpath (askdir (prompt #ask-path) (help #ask-path-help)
(default @default-dest))
)
; tot-verzeichnis anhaengen
(set #totpath (tackon #totpath #totdirname))
(complete 30)
; platz schon belegt oder alte schublade vorhanden?
(set #checkplace (exists #totpath))
(if (= #checkplace 1)
(abort (cat #fileatplace #totpath))
)
(complete 50)
; evtl. alte files loeschen, die nicht mit neuen ueberschrieben werden
(if (= 2 #checkplace)
(if #deletedatafiles
(foreach (tackon #totpath "data")
#deletedatafiles
(delete (tackon (tackon #totpath "data") @each-name)
(prompt "") (help ""))
)
)
)
(complete 70)
; alles ausser #?install#? kopieren (wenn noetig: neues Verzeichnis)
(copyfiles (prompt "") (help "") (source "") (dest #totpath)
(pattern "~(#?install#?)") (infos) (noposition)
)
(complete 90)
; assign in die user-startup und auch gleich aktivieren
(set #assigntext (cat "Assign \"" #totassign ":\" \"" #totpath "\""))
(startup @app-name (prompt #ask-assign)
(help (cat #ask-assign-help #assigntext))
(command #assigntext))
(makeassign #totassign #totpath)
(complete 100)
; und weg...
(set @default-dest #totpath)
(exit #goodbye)