home *** CD-ROM | disk | FTP | other *** search
/ Mega CD-ROM 1 / megacd_rom_1.zip / megacd_rom_1 / MAGAZINE / MSJOURNA / MSJV4_2B.ZIP / PROJECT.ZOO / act / proj.act < prev    next >
Text File  |  1988-11-30  |  5KB  |  169 lines
  1. /* proj.act       --miscelaneous methods, initializations
  2. */
  3.  
  4.  
  5. /* globals for conditional compilation during debugging etc */
  6.  
  7. Actor[#Debug] := false;     /* debugging enable/disable */
  8. Actor[#Trace] := false;     /* trace recalc calls */      
  9. Actor[#CurPos] := 0;        /* text dump of network uses this */ 
  10. !!
  11.  
  12. /* methods for system classes */
  13.  
  14. now(Window)!!
  15.  
  16. /* Set the current cursor position in client coords.
  17.    This is useful when implementing a keyboard interface. */
  18. Def  setCursorPos(self, pos | scrnPos)
  19. { 
  20.   scrnPos := clientToScreen(self, pos);
  21.   Call SetCursorPos(scrnPos.x, scrnPos.y);
  22. }!!
  23.  
  24. /* Return a point of the current cursor position in client coords.
  25.    This is useful when implementing a keyboard interface. */
  26. Def  getCursorPos(self | struct, scrnPos, lpr)
  27. { 
  28.   struct := new(Struct,4);          /* to store the point */
  29.   lpr := lP(struct);                /* long pointer */
  30.   Call GetCursorPos(lpr);           /* device coords */
  31.   scrnPos := pointAt(lpr);          /* get the data */
  32.   freeHandle(struct);               /* free up memory */
  33.   ^screenToClient(self, scrnPos);   /* screen coords */
  34. }!!
  35.  
  36. /* Return a point giving the text width and height
  37.    in the given display context. 
  38.    e.g. for system font the return value might be 
  39.    8@15 for 8 pixels wide, 15 high, depending on the
  40.    Windows drivers. */
  41. Def  textSize(self, hDC | tm1, tm2)
  42. { 
  43.   tm1 := new(Struct, 31);            /* to hold the info */
  44.   Call GetTextMetrics(hDC, lP(tm1)); /* call Windows fn */
  45.   tm2 := getData(tm1);               /* get the data back */
  46.   freeHandle(tm1);                   /* free up memory */
  47.   ^point(low(tm2[10]), low(tm2[0])); /* width@height */
  48. }!!
  49.  
  50. now(Dialog);!!
  51.  
  52. /* Run the dialog with the appropriate resource
  53.    and parent.  Display a warning if it fails. */
  54. Def  checkRunModal(self, res, parent | retValue)
  55. {
  56.   retValue := runModal(self, res, parent);
  57.   if retValue == NOMEM
  58.     beep();
  59.     errorBox(loadString(PW_WARNING),
  60.              loadString(PW_ERRMEM1) + CR_LF +
  61.              loadString(PW_ERRMEM2));
  62.   endif;
  63.   ^retValue;
  64. }!!
  65.  
  66. now(String);!!
  67.  
  68. /* Return the string in a field of fieldSize.
  69.    Truncate or pad with blanks as necessary.
  70. */
  71. Def  field(self, fieldSize | size)
  72. {
  73.   if fieldSize < size := size(self)
  74.     ^subString(self, 0, fieldSize)            /* truncate */
  75.   else
  76.     ^self + stringOf(' ', fieldSize - size);  /* pad */
  77.   endif;
  78. }!!
  79.  
  80. /* Convert to decimal.  Safe if length = 0. */
  81. Def  asDec(self)
  82. {
  83.   if size(self) = 0
  84.     ^ 0;
  85.   else
  86.     ^asInt(self,10);
  87.   endif;
  88. }!!
  89.  
  90. /* Show a yesNoBox with self as the caption, str as message.  
  91.    Return value of 6 = Yes, 7 = No. */
  92. Def yesNoBox(self, str)
  93. {  ^new(ErrorBox, ThePort, str, self, 4);
  94. }!!
  95.  
  96.  
  97. /* Report an error if the date string is invalid,
  98.    otherwise return the Date object.  Ignore empty strings.
  99.    Report the error according to international date format. */
  100. Def  checkDate(self | retValue, iDate, format)
  101. { 
  102.   if self <> ""
  103.   cand not(retValue := asDate(self))
  104.     beep();
  105.     iDate := getProfileString("intl", "iDate");
  106.     select
  107.       case iDate = "2"
  108.         format := loadString(PW_YYMMDD);
  109.       endCase
  110.       case iDate = "1"
  111.         format := loadString(PW_DDMMYY);
  112.       endCase
  113.       default                               /* "0" or unspecified */
  114.         format := loadString(PW_MMDDYY);
  115.     endSelect;
  116.     errorBox(loadString(PW_ERRDATE1),
  117.              asString(self) + loadString(PW_ERRDATE2) + format +
  118.              loadString(PW_ERRDATE3));
  119.   endif;
  120.   ^retValue;
  121. }!!
  122.  
  123. now(NilClass)!!
  124.  
  125. /* Return an empty string.  For compatibility
  126.    with the Date class so you can checkString(nil)
  127.    or checkString(aDate) and get a string. */
  128. Def  checkString(self)
  129. { 
  130.   ^"";
  131. }!!
  132.  
  133. now(Collection)!!
  134.  
  135. /* Returns true (the position) if the elem is in the collection.
  136.    Uses a sequential search.  Descendent classes redefine this
  137.    using more efficient means where possible. */
  138. Def  in(self, elem)
  139. {
  140.   do(size(self),
  141.     {using(i) 
  142.      if self[i] = elem ^i; endif;   /* found */
  143.   });
  144.   ^false;    /* not found */
  145. }!!
  146.  
  147. now(Dictionary)!!
  148.  
  149. /* Returns the value (true) if the key is in the Dictionary. */
  150. Def  in(self, key | assoc)
  151. {
  152.   assoc := assocAt(self, key);
  153.   if assoc
  154.     ^assoc.value;
  155.   else
  156.     ^false;
  157.   endif;
  158. }!!
  159.  
  160. now(Date)!!
  161.  
  162. /* Convert a date to a string.  NilClass:checkString
  163.    returns an empty string. */
  164. Def  checkString(self)
  165. { 
  166.   ^asString(self);
  167. }!!
  168.  
  169.