home *** CD-ROM | disk | FTP | other *** search
/ Mega Top 1 / os2_top1.zip / os2_top1 / APPS / TEKST / TEXDISK / MF3.ZIP / EMTEX / MFINPUT / SROMANU.MF < prev    next >
Text File  |  1989-11-06  |  37KB  |  756 lines
  1. % This is the file sromanu.mf for the SLITeX fonts: lcmss8, lcmssb8, lcmssi8.
  2.  
  3. % Computer Modern Roman upper case: (with a special uppercase I)
  4. % These letters were originally coded by D. E. Knuth in November, 1979,
  5. % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
  6. % Sans serif designs by Richard Southall were added in April, 1982.
  7. % The programs were revised for the new \MF\ conventions in 1985.
  8.  
  9. % The uppercase I was added by Pierre A. MacKay, in June l986.
  10. % All other designs are unchanged from Computer Modern.
  11. % The I has slab serifs based on the proportions of the upper and lower
  12. % horizontals of upper case E.  
  13.  
  14. % Character codes \0101 through \0132 are generated.
  15.  
  16. cmchar "The letter A";
  17. beginchar("A",13u#,cap_height#,0);
  18. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  19. numeric left_stem,right_stem,outer_jut,alpha;
  20. right_stem=cap_stem-stem_corr;
  21. left_stem=min(cap_hair if hefty: -3stem_corr fi,right_stem);
  22. outer_jut=.8cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
  23. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  24. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  25. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  26. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  27. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  28. if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  29.  fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  30.   --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  31.   ...{up}z0+.5left--cycle; % left and right diagonals
  32. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  33.   --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  34. penpos5(whatever,angle(z2-z1)); z5=whatever[z1,z2];
  35. penpos6(whatever,angle(z3-z4)); z6=whatever[z3,z4]; y6=y5;
  36. if hefty: y5r else: y5 fi =5/12y0;
  37. y5r-y5l=y6r-y6l=cap_band; penstroke z5e--z6e; % bar line
  38. if serifs: numeric inner_jut; pickup tiny.nib;
  39.  prime_points_inside(1,2); prime_points_inside(4,3);
  40.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  41.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  42.  dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  % left serif
  43.  dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi  % right serif
  44. penlabels(0,1,2,3,4,5,6); endchar;
  45.  
  46. cmchar "The letter B";
  47. beginchar("B",12.5u#,cap_height#,0);
  48. italcorr .75cap_height#*slant-.5u#;
  49. adjust_fit(cap_serif_fit#,0);
  50. numeric left_stem,right_curve,middle_weight;
  51. left_stem=cap_stem-hround 2stem_corr; middle_weight=.6vair+.5;
  52. pickup tiny.nib; pos1(left_stem,0); pos2(left_stem,0);
  53. lft x1l=lft x2l=hround max(2u,3u-.5left_stem); top y1=h; bot y2=0;
  54. filldraw stroke z1e--z2e; % stem
  55. penpos3(cap_band,90); penpos4(cap_band,90);
  56. penpos6(middle_weight,-90); penpos7(middle_weight,-90);
  57. penpos8(middle_weight,90); penpos9(middle_weight,90);
  58. penpos5(right_curve-stem_corr,0); penpos10(right_curve,0);
  59. penpos11(cap_band,-90); penpos12(cap_band,-90);
  60. z3r=top z1; y4=y3; y5=.5[y4,y6]; y6=y7; y7l-y8l=vair;
  61. z12r=bot z2; y11=y12; y10=.5[y11,y9]; y8=y9; .5[y7l,y8l]=.52h;
  62. x4=x6; x9=x11=x4+.5u; x7=x8=x1; x9l:=x4+.25u;
  63. x5r=hround(w-1.5u); x10r=hround(w-u);
  64. if serifs: right_curve=cap_curve-stem_corr; x4=.5[x1,w-1.5u];
  65. else: right_curve=cap_curve-3stem_corr; x4=.5[x1,w-2.5u];
  66.  x4l:=x4l-.5u; x9l:=x9l-.5u; fi
  67. x6l:=x6l-.5u; x11l:=x11l-.5u;
  68. fill stroke z3e..super_arc.e(4,5) & super_arc.e(5,6)..z7e;  % upper lobe
  69. fill stroke z8e..super_arc.e(9,10) & super_arc.e(10,11)..z12e;  % lower lobe
  70. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  71.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  72. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  73.  
  74. cmchar "The letter C";
  75. if serifs: beginchar("C",13u#,cap_height#,0);
  76.  italcorr cap_height#*slant-.5u#;
  77.  adjust_fit(0,0);
  78.  pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
  79.  pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
  80.  rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
  81.  top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
  82.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  83.  y5=max(good.y .95(h-y1),y4l+eps);
  84.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  85.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  86.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  87.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
  88.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
  89.  x1r-x1'=2cap_curve-fine; y1'=y1;
  90.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  91.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  92.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  93. else: beginchar("C",11.5u#,cap_height#,0);
  94.  italcorr cap_height#*slant-.5u#;
  95.  adjust_fit(0,0);
  96.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  97.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
  98.  rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
  99.  lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
  100.  top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
  101.  bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
  102.  filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
  103.   & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
  104. math_fit(-.3cap_height#*slant-.5u#,.5ic#);
  105. penlabels(1,1',2,3,4,5,6); endchar;
  106.  
  107. cmchar "The letter D";
  108. beginchar("D",13.5u#,cap_height#,0);
  109. italcorr .7cap_height#*slant-.5u#;
  110. adjust_fit(cap_serif_fit#,0);
  111. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  112. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  113. filldraw stroke z1e--z2e; % stem
  114. penpos3(cap_band,90); penpos4(cap_band,90);
  115. penpos5(cap_curve-stem_corr,0);
  116. penpos6(cap_band,-90); penpos7(cap_band,-90);
  117. z3r=top z1; y4=y3; y5=.51[y4,y6]; y6=y7;
  118. z7r=bot z2; x4=x6=.5w+.25u; x5r=hround(w-u);
  119. x4l:=x6l:=x4-.25cap_curve;
  120. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  121. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  122.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  123. math_fit(0,ic#-.5u#); penlabels(1,2,3,4,5,6,7); endchar;
  124.  
  125. cmchar "The letter E";
  126. beginchar("E",12u#-width_adj#,cap_height#,0);
  127. italcorr cap_height#*slant-beak_jut#-.5u#;
  128. adjust_fit(cap_serif_fit#,0);
  129. h:=vround(h-stem_corr);
  130. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  131. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  132. filldraw stroke z1e--z2e; % stem
  133. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  134. top y3r=h; x3=x1; rt x4r=hround(w-u); y4=good.y(y3l-beak)-eps;
  135. arm(3,4,e,beak_darkness,beak_jut);  % upper arm and beak
  136. pos5(cap_bar,-90); pos6(hair,0);
  137. top y5l=vround(.52[y2,y1]+.5cap_bar); x5=x1;
  138. pos0(cap_bar,90); pos7(hair,0);
  139. z0=z5; x6=x7; y6-y5l=y0l-y7;
  140. if serifs: rt x6r=hround(w-4.4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  141.  rt x9r=hround(w-.5u);
  142. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  143. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  % middle arm and serif
  144. pos8(slab if not serifs:+2stem_corr fi,-90); pos9(hair,0);
  145. bot y8r=0; x8=x2; y9=good.y(y8l+7/6beak)+eps;
  146. arm(8,9,h,beak_darkness,1.5beak_jut);  % lower arm and beak
  147. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  148.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  149. math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  150.  
  151. cmchar "The letter F";
  152. beginchar("F",11.5u#-width_adj#,cap_height#,0);
  153. italcorr cap_height#*slant-beak_jut#-.25u#;
  154. adjust_fit(cap_serif_fit#,0);
  155. h:=vround(h-stem_corr);
  156. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  157. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  158. filldraw stroke z1e--z2e; % stem
  159. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  160. top y3r=h; x3=x1; rt x4r=hround(w-.75u); y4=good.y(y3l-beak)-eps;
  161. arm(3,4,e,beak_darkness,beak_jut);  % upper arm and beak
  162. pos5(cap_bar,-90); pos6(hair,0);
  163. top y5l=vround(.5[y2,y1]+.5cap_bar); x5=x1;
  164. pos0(cap_bar,90); pos7(hair,0);
  165. z0=z5; x6=x7; y6-y5l=y0l-y7;
  166. if serifs: rt x6r=hround(w-4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  167.  rt x9r=hround(w-.5u);
  168. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  169. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  % middle arm and serif
  170. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  171.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,1.25cap_jut); fi  % lower serif
  172. math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  173.  
  174. cmchar "The letter G";
  175. if serifs: beginchar("G",14u#,cap_height#,0);
  176.  italcorr cap_height#*slant-1.5u#-.5cap_serif_fit#;
  177.  adjust_fit(0,.5cap_serif_fit#);
  178.  pickup tiny.nib; pos0(cap_stem,0); pos7(cap_stem,0);
  179.  rt x0r=hround(w-2u); y0=good.y(.1[bar_height,x_height]+1); x7=x0;
  180.  pickup fine.nib;
  181.  if hefty: bot y7=0; pos5(cap_stem,0); x5=x0; top y5=tiny.top y0;
  182.  else: pos5(cap_hair,0); pos8(cap_stem,0);
  183.   y7=.5bar_height; z5l=z8l; z8=z7; x9=x8r; bot y9=0;
  184.   filldraw z8l{down}..{4(x9-x8),y9-y8}z9--z8r--cycle; fi % spur
  185.  pos1(cap_hair,0); pos2(cap_band,90);
  186.  pos3(cap_curve,180); pos4(cap_band,270);
  187.  rt x1r=hround(w-2u); lft x3r=hround u; x2=x4=.55[x3,x1];
  188.  top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
  189.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  190.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  191.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  192.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  193.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...z5e{up}; % arc
  194.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
  195.  x1r-x1'=2cap_curve-fine; y1'=y1;
  196.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  197.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  198.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  199.  pickup tiny.nib; filldraw stroke z0e--z7e;  % stem
  200.  dish_serif(0,7,a,1/3,max(cap_jut,2.25u),b,1/3,1.25u);  % serif
  201.  math_fit(-.3cap_height#*slant-.5u#,ic#);
  202. else: beginchar("G",12u#,cap_height#,0);
  203.  italcorr cap_height#*slant-.5u#;
  204.  adjust_fit(0,0);
  205.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  206.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,270);
  207.  rt x1r=hround(w-1.35u); x2=x4=.5w+u;
  208.  lft x3r=hround max(u,2u-.5cap_curve); rt x5l=hround(w-1.2u);
  209.  top y1r=vround .93h+o; top y2r=h+o; y3=.5h;
  210.  bot y4r=-o; bot y5r=vround .07h-o;
  211.  filldraw stroke rterm.e(2,1,right,.9,4)&super_arc.e(2,3)
  212.   & super_arc.e(3,4) & term.e(4,5,right,1,4); % arc and terminals
  213.  pos0(stem,0); pos7(stem,0);
  214.  z7r=z5r; x0=x7; top y0=1+vround .35[bar_height,x_height];
  215.  filldraw stroke z0e--z7e;  % stem
  216.  pos8(cap_bar,90); pos9(cap_bar,90);
  217.  z0r=z9r; y8=y9; lft x8=hround x4;
  218.  filldraw stroke z8e--z9e;  % bar
  219.  math_fit(-.3cap_height#*slant-.5u#,.5ic#); fi
  220. penlabels(0,1,1',2,3,4,5,6,7,8,9); endchar;
  221.  
  222. cmchar "The letter H";
  223. beginchar("H",13u#+width_adj#,cap_height#,0);
  224. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  225. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  226. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  227. pos3(cap_stem,0); pos4(cap_stem,0);
  228. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  229. top y1=top y3=h; bot y2=bot y4=0;
  230. filldraw stroke z1e--z2e; % left stem
  231. filldraw stroke z3e--z4e; % right stem
  232. penpos5(cap_bar,90); penpos6(cap_bar,90);
  233. x5=x1; x6=x3; y5=y6=.52h;
  234. fill stroke z5e--z6e;  % bar
  235. if serifs: numeric inner_jut;
  236.  if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
  237.  else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
  238.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut);  % upper left serif
  239.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
  240.  dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut);  % upper left serif
  241.  dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi  % lower left serif
  242. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  243.  
  244. cmchar "The letter I";
  245. beginchar("I",max(6u#,4u#+cap_stem#),cap_height#,0);
  246. italcorr cap_height#*slant-.25u#;
  247. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  248. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  249. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  250. filldraw stroke z1e--z2e;   % stem
  251. pickup crisp.nib;           % arms based on proportions of uppercase E
  252. pos3(slab,90); pos4(slab if not serifs:+2stem_corr fi,-90); 
  253. x3=x4=x1; top y3r=h; bot y4r=0;
  254. pos5(hair,0); pos6(hair,0); % top and bottom right arms
  255. rt x5r=rt x6r=hround(w-u);
  256. pos7(hair,180); pos8(hair,180); % top and bottom left arms
  257. lft x7r=lft x8r=hround(u);
  258. y5=y7=good.y(y3l-beak)-eps; % beak in case we ever want a beaked serif!
  259. y6=y8=good.y(y4l+beak)+eps; % watch that this doesn't get too heavy
  260. arm(3,5,a,darkness,jut); arm(3,7,b,darkness,jut); % top left and right arms
  261. arm(4,6,c,darkness,jut); arm(4,8,d,darkness,jut); % bottom left and right
  262. if serifs: dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut);  % upper serif
  263.  dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut);  fi % lower serif
  264. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); endchar;
  265.  
  266. cmchar "The letter J";
  267. beginchar("J",9u#,cap_height#,0);
  268. italcorr cap_height#*slant-cap_serif_fit#
  269.  +.75cap_jut#-2.5u#+min(.5cap_stem#,u#);
  270. adjust_fit(0,cap_serif_fit#);
  271. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  272. top y1=h; rt x1r=hround(w-2u); x2=x1; y2=.21h;
  273. if serifs: pos3(vair,-90); pos4(cap_hair,-180);
  274.  pos5(flare+(cap_stem-stem),-180);
  275.  bot y3r=-o; x3=.5[x4,x2]; y5=1/6h; rt x5l=hround 2.75u; z5r=z4r;
  276.  filldraw stroke z1e--z2e&super_arc.e(2,3);  % stem and arc
  277.  dish_serif(1,2,a,1/3,1.3cap_jut,b,1/3,.75cap_jut);  % serif
  278.  bulb(3,4,5);  % bulb
  279. else: filldraw stroke z1e--z2e;  % stem
  280.  pickup fine.nib; pos3(cap_stem',0); z3=z2;
  281.  pos4(flare,angle(6.5u,-h)); pos5(1.1flare,-100);
  282.  bot y4r=-o; x4r=.5[x5r,x3r]; lft x5r=hround.75u; bot y5r=vround.06h-o;
  283.  filldraw stroke z3e{down}....term.e(4,5,left,1,4); fi % arc and terminal
  284. math_fit(0,.5ic#-.5u#); penlabels(1,2,3,4,5); endchar;
  285.  
  286. cmchar "The letter K";
  287. beginchar("K",13.5u#,cap_height#,0);
  288. italcorr cap_height#*slant-.5u#;
  289. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  290. numeric right_jut,stem[],alpha[];
  291. if serifs: right_jut=.6cap_jut;
  292. else: right_jut=.4tiny; fi
  293. pickup tiny.nib; pos1(fudged.cap_stem,0); pos2(fudged.cap_stem,0);
  294. lft x1l=lft x2l=hround max(2u,3u-.5fudged.cap_stem); top y1=h; bot y2=0;
  295. filldraw stroke z1e--z2e; % stem
  296. stem2=max(tiny.breadth,fudged.cap_stem-3stem_corr);
  297. stem1=max(tiny.breadth,fudged.hair if hefty:-3stem_corr fi);
  298. top y3=h; rt x3r=hround(r-letter_fit-u-right_jut);
  299. bot y6=0; rt x6r=hround(r-letter_fit-.75u-right_jut);
  300. x4=x1; y4=1/3h;
  301. alpha1=diag_ratio(1,.5(stem1-tiny),y3-y4,x3r-x4);
  302. penpos3(alpha1*(stem1-tiny),0); penpos4(whatever,-90);
  303. alpha2=diag_ratio(1,.5(stem2-tiny),y1-y6,x6r-x1);
  304. penpos6(alpha2*(stem2-tiny),0);
  305. forsuffixes $=l,r: y3'$=h; y6'$=0; z4$=z3'$+whatever*(z3-z4);
  306.  z5$=z6'$+whatever*(z1-z6)=whatever[z3,z4]; endfor
  307. z5=.5[z5l,z5r];
  308. z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
  309. % we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
  310. z6'r=z6r+penoffset z1-z6 of currentpen+whatever*(z1-z6);
  311. z6'l=z6l+penoffset z6-z1 of currentpen+whatever*(z1-z6);
  312. fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle;  % upper diagonal
  313. fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle;  % lower diagonal
  314. if serifs: numeric inner_jut;
  315.  if rt x2r+cap_jut+.5u+1<=lft x6l-cap_jut: inner_jut=cap_jut;
  316.  else: rt x2r+cap_jut+.5u+1=lft x6l-inner_jut; fi
  317.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % upper stem serif
  318.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower stem serif
  319.  dish_serif(3,4,e,2/3,1.2cap_jut,f,1/2,right_jut)(dark); % upper diagonal serif
  320.  dish_serif(6,5,g,1/2,inner_jut,h,1/3,right_jut)(dark);fi % lower diagonal serif
  321. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  322.  
  323. cmchar "The letter L";
  324. beginchar("L",11u#-width_adj#,cap_height#,0);
  325. adjust_fit(cap_serif_fit#,0);
  326. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  327. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  328. filldraw stroke z1e--z2e; % stem
  329. pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
  330. bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
  331. arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
  332. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
  333.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  334. math_fit(0,u#); penlabels(1,2,3,4); endchar;
  335.  
  336. cmchar "The letter M";
  337. beginchar("M",16u#+width_adj#,cap_height#,0);
  338. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  339. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  340. numeric stem[]; % thicknesses of the four strokes
  341. stem1=hround(fudged.hair+stem_corr);
  342. stem2=hround(fudged.cap_stem-4stem_corr);
  343. stem3=hround(fudged.hair-stem_corr);
  344. stem4=hround(fudged.cap_stem-3stem_corr);
  345. if stem4<stem1: stem4:=stem1; fi
  346. pickup tiny.nib; pos1(stem1,0); pos2(stem1,0);
  347. pos3(stem4,0); pos4(stem4,0);
  348. x1=x2; x3=x4; x1l=w-x3r; rt x3r=hround min(w-2u,w-3u+.5stem4);
  349. top y1=top y3=h; bot y2=bot y4=0;
  350. filldraw stroke z1e--z2e; % left stem
  351. filldraw stroke z3e--z4e; % right stem
  352. penpos5(stem2,0); penpos6(stem2,0); penpos7(stem3,0); penpos8(stem3,0);
  353. x5l=x1; x6l=x7l; x8=lft x3l; x6-x5=x8-x7; y5=y8=h; y6=y7;
  354. if hefty: y6=if monospace: vround 1/3h else: o fi;
  355.  numeric upper_notch,lower_notch;
  356.  upper_notch=h-cap_notch_cut; lower_notch=y6+cap_notch_cut;
  357.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x3'=lft x3l; z3'=whatever[z7r,z8r];
  358.  z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  359.  fill z5l..
  360.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  361.   {z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  362.   if y3'<upper_notch: ...{up}(x3'-1,upper_notch){right} fi
  363.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}
  364.   if y0<=lower_notch: ..{z7-z8}z0{z5-z6}..
  365.   else: ...{down}(x0+.5,lower_notch)--(x0-.5,lower_notch){up}... fi
  366.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  % diagonals
  367. else: y6=0; z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  368.  fill z5l..{z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  369.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}..{z7-z8}z0{z5-z6}
  370.   ..{z5-z6}diag_in(6r,5r,1,5l)--cycle; fi  % diagonals
  371. if serifs: serif(1,2,a,1/3,-cap_jut);  % upper left serif
  372.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  373.  serif(3,4,d,1/3,cap_jut); %  upper right serif
  374.  dish_serif(4,3,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower right serif
  375. math_fit(0,max(.5ic#-.5u#,0));
  376. penlabels(0,1,1',2,3,3',4,5,6,7,8); endchar;
  377.  
  378. cmchar "The letter N";
  379. beginchar("N",13u#+width_adj#,cap_height#,0);
  380. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  381. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  382. numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
  383. pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
  384. pos3(thin_stem,0); pos4(thin_stem,0);
  385. pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
  386. x1=x2; x3=x4; x1l=w-x3r;
  387. rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
  388. filldraw stroke z1e--z2e; % left stem
  389. filldraw stroke z3e--z4e; % right stem
  390. if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
  391.  x5l=x1; x6r=x4; y5=h; y6=0;
  392.  numeric upper_notch,lower_notch;
  393.  upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
  394.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
  395.  fill z5l..
  396.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  397.   {z6-z5}diag_in(5l,6l,1,6r)--z6r..
  398.   if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
  399.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  % diagonal
  400. else: penpos5(whatever,0); penpos6(whatever,90);
  401.  z5l=z1l; z6l=z4l;
  402.  z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
  403.  z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
  404.  filldraw stroke z5e..z6e; fi  % diagonal
  405. if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
  406.  else: serif(5,6,a,1/3,-cap_jut); fi  % upper left serif
  407.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  408.  dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi  % upper right serif
  409. math_fit(0,max(.5ic#-.5u#,0)); penlabels(1,1',2,3,4,4',5,6,7); endchar;
  410.  
  411. cmchar "The letter O";
  412. beginchar("O",14u#-width_adj#,cap_height#,0);
  413. italcorr .7cap_height#*slant-.5u#;
  414. adjust_fit(0,0);
  415. penpos1(vair',90); penpos3(vround(vair+1.5vair_corr),-90);
  416. penpos2(cap_curve,180); penpos4(cap_curve,0);
  417. if monospace: x2r=hround 1.5u;
  418.  interim superness:=sqrt superness;  % make |"O"|, not |"0"|
  419. else: x2r=hround u; fi
  420. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y3r=-o;
  421. y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  422. penstroke pulled_super_arc.e(1,2)(.5superpull)
  423.  & pulled_super_arc.e(2,3)(.5superpull)
  424.  & pulled_super_arc.e(3,4)(.5superpull)
  425.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  426. math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#); penlabels(1,2,3,4); endchar;
  427.  
  428. cmchar "The letter P";
  429. beginchar("P",12u#,cap_height#,0);
  430. italcorr .75cap_height#*slant-.5u#;
  431. adjust_fit(cap_serif_fit#,0);
  432. pickup tiny.nib; penpos1(cap_stem'-tiny,0); penpos2(cap_stem-tiny,0);
  433. pos0(cap_stem',0); pos0'(cap_stem,0);
  434. lft x1l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  435. x1l=x2l=x0l=x0'l; y0=y0'=y7;
  436. penpos3(cap_band,90); penpos4(cap_band,90);
  437. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  438. penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
  439. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  440. x7=x2; y7l=vround .5h; x4=x6=.5w+.75u; x5r=hround(w-u);
  441. x4l:=x6l:=x4-.25cap_curve;
  442. filldraw stroke z1e--z0e--z0'e--z2e; % stem
  443. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  444. if serifs: nodish_serif(1,0,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  445.  dish_serif(2,0',c,1/3,cap_jut,d,1/3,cap_jut); fi  % lower serif
  446. math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7); endchar;
  447.  
  448. cmchar "The letter Q";
  449. beginchar("Q",14u#-width_adj#,cap_height#,comma_depth#);
  450. italcorr .7cap_height#*slant-.5u#;
  451. adjust_fit(0,0);
  452. numeric light_curve; light_curve=cap_curve-hround stem_corr;
  453. penpos1(vair',90); penpos3(vair',-90);
  454. penpos2(light_curve,180); penpos4(light_curve,0);
  455. if monospace: x2r=hround 1.5u;
  456.  interim superness:=sqrt superness;  % make |"Q"| like |"O"|
  457. else: x2r=hround u; fi
  458. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y2=y4=.5h-vair_corr; y3r=-o;
  459. penstroke pulled_super_arc.e(1,2)(.5superpull)
  460.  & pulled_super_arc.e(2,3)(.5superpull)
  461.  & pulled_super_arc.e(3,4)(.5superpull)
  462.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  463. pickup tiny.nib;
  464. if hefty: penpos5(1.2(.5[cap_bar,light_curve]),0); penpos6(1.2light_curve,0);
  465.  x5=.5w; x6r=hround(w-1.5u);
  466.  y5=vround .28h; y6=-d;
  467.  fill diag_end(6r,5r,.25,1,5l,6l)--diag_end(5l,6l,.5,1,6r,5r)--cycle;  % tail
  468. else: pos3'(vair,270); pos5(vair,180); pos6(vair,90);
  469.  pos7(cap_curve,85); penpos8(eps,180);
  470.  z3'=z3; x6=x3; top y6r=vround(.2h+.5vair);
  471.  lft x5r=hround(.5w-1.25u-.5vair); y5=.5[y3,y6];
  472.  bot y7l=-d; x7l=2/3[x6,x8]; y8=0; rt x8=hround(x4r+.1u);
  473.  filldraw stroke z3'e{left}...z5e{up}...z6e{right}
  474.   ..z7e{right}...z8e{up}; fi % tail
  475. math_fit(-.3cap_height#*slant-.5u#,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  476.  
  477. cmchar "The letter R";
  478. beginchar("R",if serifs: 12u#+.5max(2u#,cap_curve#)
  479.  else:12.5u#-.5width_adj# fi,cap_height#,0);
  480. italcorr .75cap_height#*slant- if serifs: 1.75 else: .5 fi\\ u#;
  481. adjust_fit(cap_serif_fit#,0);
  482. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  483. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  484. filldraw stroke z1e--z2e; % stem
  485. penpos3(cap_band,90); penpos4(cap_band,90);
  486. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  487. penpos6(vair,-90); penpos7(vair,-90);
  488. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  489. x7=x2; y7l=vround(.5h+.5vair); x4=x6;
  490. if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
  491. else: x4=.5w+.5u; x5r=hround(w-u); fi
  492. x4l:=x6l:=x4-.125cap_curve;
  493. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  494. if serifs: pos6'(vair,-90); pos0(cap_stem,180);
  495.  pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
  496.  z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
  497.  y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
  498.  bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
  499.  filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up};  % tail
  500.  nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  501.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower serif
  502. else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
  503.  x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
  504.  fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi  % tail
  505. math_fit(0,.75ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  506.  
  507. cmchar "The letter S";
  508. beginchar("S",10u#,cap_height#,0);
  509. italcorr cap_height#*slant-u#;
  510. adjust_fit(0,0);
  511. numeric theta; theta=90-angle(50u,h); slope:=-h/50u;  % angle at middle
  512. numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
  513. numeric ess'; ess'=max(fine.breadth,cap_ess);
  514. pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
  515. pos0(ess',theta); pos7(s_slab,-90);
  516. x2+x7=2x0=w; x7-x2=if serifs: u else: 0 fi; top y2l=h+o; bot y7r=-o;
  517. y0=.52h; lft x3l=hround u; rt x6r=hround(w-u);
  518. x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
  519. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  520. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  521. filldraw stroke super_arc.e(2,3) & z3e{down}
  522.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  523. if serifs: pos1(hair,180); pos8(hair,180);
  524.  rt x1l=hround(w-1.5u); lft x8r=hround u;
  525.  bot y1=vround 2/3h+1; top y8=vround 1/3h-1;
  526.  filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e;  % upper arc
  527.  filldraw stroke z7e{left}....{up}z8e;  % lower arc
  528.  path upper_arc, lower_arc;
  529.  upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
  530.  lower_arc=z7{left}....{up}z8;
  531.  pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
  532.  x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
  533.  x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
  534.  numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
  535.  filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle;  % upper barb
  536.  t:=xpart(lower_arc intersectiontimes(z9r--z8'));
  537.  filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle;  % lower barb
  538. else: pos1(1.2flare,-100); pos8(1.2flare,-100);
  539.  x1l=good.x(x1l+w-1.75u-rt x1); lft x8r=hround .8u;
  540.  top y1l=vround .93h+o; bot y8r=vround .1h-o;
  541.  filldraw stroke term.e(2,1,right,.9,4);  % upper arc and terminal
  542.  filldraw stroke term.e(7,8,left,1,4); fi  % lower arc and terminal
  543. math_fit(0,.5ic#); penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10); endchar;
  544.  
  545. cmchar "The letter T";
  546. beginchar("T",13u#-width_adj#,cap_height#,0);
  547. italcorr cap_height#*slant-beak_jut#-.25u#;
  548. adjust_fit(0,0);
  549. h:=vround(h-2stem_corr);
  550. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  551. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  552. filldraw stroke z1e--z2e; % stem
  553. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  554. top y3r=h; x3=x1; rt x4r=hround(w-.65u); y4=good.y(y3l-beak)-eps;
  555. arm(3,4,e,beak_darkness,.7beak_jut);  % right arm and beak
  556. pos5(hair,180); x5=w-x4; y5=y4;
  557. arm(3,5,f,beak_darkness,-.7beak_jut);  % left arm and beak
  558. if serifs: dish_serif(2,1,c,1/3,1.414cap_jut,d,1/3,1.414cap_jut);  % lower serif
  559.  nodish_serif(1,2,a,1/3,.5cap_jut,b,1/3,.5cap_jut); fi  % upper bracketing
  560. math_fit(-.75cap_height#*slant,ic#-2.5u#); penlabels(1,2,3,4,5,6); endchar;
  561.  
  562. cmchar "The letter U";
  563. beginchar("U",13u#+.5width_adj#,cap_height#,0);
  564. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  565. if monospace: adjust_fit(cap_serif_fit#-.5u#,cap_serif_fit#-.5u#)
  566. else: adjust_fit(cap_serif_fit#,cap_serif_fit#) fi;
  567. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  568. pos2'(cap_stem,180); z2'=z2;
  569. pos3(cap_band,-90);
  570. pos4(cap_hair,0); pos5(cap_hair,0);
  571. x1=x2; x3=.5[x1,x5]; x4=x5; x1l=w-x5r;
  572. top y1=top y5=h; y2=y4=1/3h; bot y3r=-o;
  573. lft x1l=hround max(2u,3u-.5cap_stem);
  574. filldraw stroke z1e--z2e; % left stem
  575. filldraw stroke pulled_arc.e(2',3)
  576.  & pulled_arc.e(3,4)&z4e--z5e; % arc and right stem
  577. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % left serif
  578.  dish_serif(5,4,c,1/2,cap_jut,d,1/2,cap_jut)(dark); fi  % right serif
  579. math_fit(-cap_serif_fit#-.3cap_height#*slant-min(cap_height#*slant,u#),
  580.  max(.5ic#-.5u#,0)); penlabels(1,2,3,4,5); endchar;
  581.  
  582. cmchar "The letter V";
  583. beginchar("V",13u#,cap_height#,0);
  584. italcorr cap_height#*slant+.25u#;
  585. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  586. numeric left_stem,right_stem,outer_jut,alpha;
  587. left_stem=cap_stem-stem_corr;
  588. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  589. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4=h;
  590. x2-x1=x4-x3; x2l+apex_corr=x3l; y2=y3=-apex_o;
  591. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  592. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  593. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  594. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  595. if y0>cap_notch_cut: y0:=cap_notch_cut;
  596.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  597.     --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  598.     ...{down}z0+.5left--cycle; % left and right diagonals
  599. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  600.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  601. if serifs: numeric inner_jut; pickup tiny.nib;
  602.  prime_points_inside(1,2); prime_points_inside(4,3);
  603.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  604.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  605.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % left serif
  606.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); fi  % right serif
  607. math_fit(.75u#-cap_height#*slant,ic#-4u#); penlabels(0,1,2,3,4); endchar;
  608.  
  609. cmchar "The letter W";
  610. beginchar("W",18u#,cap_height#,0);
  611. italcorr cap_height#*slant+.25u#;
  612. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  613. numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
  614. outer_jut=.7cap_jut; x1l=w-x8r=l+letter_fit+outer_jut+.25u;
  615. stem1=fudged.cap_stem-stem_corr;
  616. stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
  617. stem2=stem4 if hefty:-2stem_corr fi;
  618. stem3=stem1 if hefty:-2stem_corr fi;
  619. x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
  620. y1=y8=h; y2=y3=y6=y7=-apex_o; y4=y5=if monospace: vround .6 fi\\ h;
  621. mid_corr=if monospace or hefty:-apex_corr else: 1/3jut fi;
  622. alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
  623. penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
  624. penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
  625. penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
  626. penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
  627. x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r+mid_corr| $\approx$ |x4r|
  628. z23=whatever[z1r,z2r]=whatever[z3l,z4l];
  629. z45=whatever[z3r,z4r]=whatever[z5l,z6l];
  630. z67=whatever[z5r,z6r]=whatever[z7l,z8l]; upper_notch=y4-cap_notch_cut;
  631. fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
  632.  ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
  633.    --(x45,upper_notch)+.5right{down} else: z45&z45 fi
  634.  ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
  635.  ...if y67>cap_notch_cut:(x67,cap_notch_cut)+.5right{down}
  636.    --(x67,cap_notch_cut)+.5left{up} else: z67&z67 fi
  637.  ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
  638.  ...if y23>cap_notch_cut:(x23,cap_notch_cut)+.5right{down}
  639.    --(x23,cap_notch_cut)+.5left{up} else: z23&z23 fi
  640.  ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle;  % diagonals
  641. if serifs: numeric inner_jut[]; pickup tiny.nib;
  642.  prime_points_inside(1,2); prime_points_inside(5,6); prime_points_inside(8,7);
  643.  if monospace: inner_jut1=inner_jut4=1.5cap_jut;
  644.  elseif hefty: inner_jut1=inner_jut4=cap_jut;
  645.  else: fill diag_end(6r,5r,1,1,5l,6l)
  646.   --.5[z5l,z6l]--.5[z5r,z6r]--cycle; % middle stem
  647.   inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
  648.   if rt x1'r+cap_jut+.5u+1<=lft x5'l-.7cap_jut: inner_jut1=cap_jut;
  649.   else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
  650.   if rt x5'r+cap_jut+.5u+1<=lft x8'l-1.1cap_jut: inner_jut3=cap_jut;
  651.   else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
  652.   dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi  % middle serif
  653.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut1);  % left serif
  654.  dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); fi  % right serif
  655. math_fit(.75u#-cap_height#*slant,ic#-2.5u#);
  656. penlabels(0,1,2,3,4,5,6,7,8,23,45,67); endchar;
  657.  
  658. cmchar "The letter X";
  659. beginchar("X",13u#,cap_height#,0);
  660. italcorr cap_height#*slant-.25u#;
  661. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  662. numeric stem[],outer_jut,xjut,alpha[];
  663. stem1=cap_stem-2stem_corr; stem2=min(cap_hair,stem1);
  664. outer_jut=.75cap_jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
  665. x1l=l+letter_fit+.5u+outer_jut; x2r=r-letter_fit-u-outer_jut-xjut;
  666. x3l=l+letter_fit+.25u+outer_jut+xjut; x4r=r-letter_fit-.25u-outer_jut;
  667. y1=y2=h; y3=y4=0;
  668. alpha1=diag_ratio(1,stem1,h,x4r-x1l);
  669. alpha2=diag_ratio(1,stem2,h,x2r-x3l);
  670. penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
  671. penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
  672. if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
  673.  x12=x34=x0; y13=y24=y0;
  674.  z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
  675.  z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
  676.  forsuffixes $=13,24,34: z$'=.1[z$,z0]; endfor
  677.  fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
  678.   --diag_end(34',4l,.5,1,4r,24')--z24'
  679.   --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
  680. else: fill diag_end(4r,1r,.5,1,1l,4l)
  681.   --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
  682.  fill diag_end(2l,3l,.5,1,3r,2r)
  683.   --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi  % right diagonal
  684. if serifs: numeric inner_jut[]; pickup tiny.nib;
  685.  prime_points_inside(1,4); prime_points_inside(2,3);
  686.  prime_points_inside(3,2); prime_points_inside(4,1);
  687.  if rt x1'r+cap_jut+.5u+1<=lft x2'l-cap_jut-xjut: inner_jut1=cap_jut;
  688.  else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
  689.  if rt x3'r+cap_jut+.5u+1<=lft x4'l-cap_jut-xjut: inner_jut2=cap_jut;
  690.  else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
  691.  dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1);  % upper left serif
  692.  dish_serif(4',1,c,2/3,inner_jut2,d,1/3,outer_jut);  % lower right serif
  693.  dish_serif(2',3,e,2/3,inner_jut1+xjut,
  694.   f,1/2,outer_jut+xjut)(dark);  % upper right serif
  695.  dish_serif(3',2,g,1/2,outer_jut+xjut,
  696.   h,2/3,inner_jut2+xjut)(dark); fi  % lower left serif
  697. math_fit(0,.5ic#); penlabels(0,1,2,3,4,12,13,24,34); endchar;
  698.  
  699. cmchar "The letter Y";
  700. beginchar("Y",13u#,cap_height#,0);
  701. italcorr cap_height#*slant+.45u#;
  702. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  703. numeric left_stem,right_stem,outer_jut,dy,alpha;
  704. left_stem=cap_stem-stem_corr;
  705. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  706. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.05u;
  707. x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h; y2=y3=y5=.4h;
  708. dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
  709. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  710. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  711. penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
  712. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  713. if y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
  714.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
  715.     --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  716.     ...{down}z0+.5left--cycle; % diagonals and stem
  717. else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
  718.     --diag_end(5r,6r,1,1,6l,5l)--z5l
  719.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi  % diagonals and stem
  720. if serifs: numeric inner_jut; pickup tiny.nib;
  721.  prime_points_inside(1,2); prime_points_inside(4,3); prime_points_inside(6,5);
  722.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  723.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  724.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % upper left serif
  725.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);  % upper right serif
  726.  dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower serif
  727. math_fit(.5u#-cap_height#*slant,ic#-4u#);
  728. penlabels(0,1,2,3,4,5,6); endchar;
  729.  
  730. cmchar "The letter Z";
  731. beginchar("Z",11u#,cap_height#,0);
  732. italcorr cap_height#*slant-.5u#;
  733. adjust_fit(0,0);
  734. numeric arm_thickness[],z_stem;
  735. if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
  736.  z_stem=.8[vair,cap_stem];
  737. else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
  738.  z_stem=.9[vair,cap_stem]; fi
  739. pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
  740. top y1=h; y2=min(y1,h-2/3arm_thickness1);
  741. bot y4=0; y3=max(y4,2/3arm_thickness2);
  742. numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
  743. penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  744. penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  745. pair delta; delta=penoffset z3-z2 of currentpen;
  746. fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  747.  ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  748.  ---cycle;  % diagonal
  749. pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  750. top y5r=h; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
  751. arm(5,6,a,beak_darkness**.8,-.4beak_jut);  % upper arm and beak
  752. pos7(arm_thickness2,-90); pos8(hair,0);
  753. bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
  754. arm(7,8,b,beak_darkness**.9,.6beak_jut);  % lower arm and beak
  755. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); endchar;
  756.