home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
M.u.C.S. Disc 2000
/
MUCS2000.iso
/
sigisoft
/
kaufmann
/
pk9.bas
< prev
next >
Wrap
BASIC Source File
|
1997-10-09
|
8KB
|
149 lines
1 WIDTH 80: COLOR 15,0,0
10 GOTO 100
15 LOCATE 20,1: PRINT STRING$(79,205)
16 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
17 LOCATE 21,25: PRINT "PROGRAMM WIRD GELADEN.BITTE WARTEN": COLOR 15,0
18 LOCATE 22,1: PRINT STRING$(79,205): RETURN
19 GOSUB 15: RUN "MENUE"
20 ZZ$=LEFT$(ZZ$,L):ZZ$=ZZ$+STRING$(L-LEN(ZZ$),95):Z2=0:Y=1
21 LOCATE R,S,O:PRINT ZZ$;
22 LOCATE R,S+Y-1,1
23 Z$=INKEY$: IF Z$="" THEN 23 ELSE Z=ASC(Z$): Z1=0: IF Z=0 THEN Z1=ASC(RIGHT$(Z$,1))
24 IF Z<>13 THEN 28 ELSE IF Z2 >0 THEN 23
25 IF Y=1 THEN ZZ$=CHR$(13):RETURN
26 IF RIGHT$(ZZ$,1)="_" THEN ZZ$=LEFT$(ZZ$,INSTR(ZZ$,"_")-1)
27 RETURN
28 IF Z<>0 THEN 48
29 IF Z1<>71 THEN 31 ELSE IF Y=1 OR Z2 THEN 23
30 Y=1:GOTO 22
31 IF Z1<>75 THEN 33 ELSE IF Y=1 OR Z2 THEN 23
32 Y=Y-1:GOTO 22
33 IF Z1<>77 THEN 35 ELSE IF MID$(ZZ$,Y,1)="_" OR Y>L THEN 23
34 Y=Y+1:GOTO 22
35 IF Z1<>79 THEN 39 ELSE IF Y>L OR Z2 THEN 23
36 IF MID$(ZZ$,Y,1)="_" THEN 23
37 Y=Y+1
38 IF MID$(ZZ$,Y,1)="_" THEN 22 ELSE 37
39 IF Z1<>82 THEN 42 ELSE IF RIGHT$(ZZ$,1)<>"_" THEN 23
40 IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
41 ZZ$=LEFT$(ZZ$,Y-1)+"_"+MID$(ZZ$,Y,L-Y):Z2=Z2+1:GOTO 21
42 IF Z1<>83 THEN 44 ELSE IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
43 GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+MID$(ZZ$,Y+1)+"_":GOTO 21
44 IF Z1<>117 THEN 46 ELSE IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
45 GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+STRING$(L-Y+1,95):GOTO 21
46 IF Z1<>119 THEN 23 ELSE IF Y=1 THEN 23
47 ZZ$=MID$(ZZ$,Y)+STRING$(Y-1,95):Y=1:GOTO 21
48 IF Z<>8 THEN 50 ELSE IF Y=1 THEN 23
49 ZZ$=LEFT$(ZZ$,Y-2)+MID$(ZZ$,Y)+"_":Y=Y-1:GOTO 21
50 IF Z<>27 THEN 51 ELSE ZZ$=STRING$(L,95):Y=1:Z2=0: GOTO 21
51 IF Z=95 OR Y>L THEN 23
52 ON PK% GOTO 55,53,54
53 IF Z<46 OR Z>58 THEN 23 ELSE 55
54 IF Z<>106 AND Z<>110 THEN 23
55 IF Z=44 THEN 23 ELSE GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+Z$+MID$(ZZ$,Y+1):PRINT Z$;:Y=Y+1:GOTO 22
56 IF Z2 THEN Z2=Z2-1
57 RETURN
60 CLS: LOCATE 2,1: PRINT STRING$(79,205)
61 LOCATE 3,1: COLOR 0,15: PRINT SPACE$(79): LOCATE 3,30: PRINT "KAUFMÄNNISCHES RECHNEN": LOCATE 4,1: PRINT SPACE$(79)
62 LOCATE 4,30: PRINT "(C) BY SIEGFRIED HÜBNER ESC =LADE MENÜ": LOCATE 5,1: PRINT SPACE$(79)
63 LOCATE 5,29: PRINT "E I G E N F E R T I G U N G"
64 COLOR 15,0: LOCATE 6,1: PRINT STRING$(79,205): RETURN
70 LOCATE 20,1: PRINT STRING$(79,205)
71 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
72 LOCATE 21,29: PRINT "BELIEBIGE TASTE DRÜCKEN": COLOR 15,0
73 LOCATE 22,1: PRINT STRING$(79,205)
75 E$=INKEY$: IF E$="" THEN 75
76 IF E$=CHR$(27) THEN 19
77 RETURN
90 LOCATE 20,1: PRINT STRING$(79,205)
91 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
92 LOCATE 21,34: PRINT "FALSCHE EINGABE": COLOR 15,0
93 LOCATE 22,1: PRINT STRING$(79,205): RETURN
95 FOR T=1 TO 4: LOCATE 19+T,1: PRINT SPACE$(79): NEXT: RETURN
100 GOSUB 60
101 LOCATE 7,2: PRINT "Sie wollen bsp.weise für einen Drucker ein Interface entwickeln. Auch"
102 LOCATE 8,2: PRINT "hier ist ein Verkaufspreis zu entwickeln. Sie vereinbaren mit dem "
103 LOCATE 9,2: PRINT "Entwickler einen festen Betrag für die Entwicklung. Der vereinbarte"
104 LOCATE 10,2: PRINT "Betrag geht in Ihre Kalkulation als Entwicklungskosten EK ein."
105 LOCATE 11,2: PRINT "Sie kaufen dazu passendes Material von einem Hersteller. Das fassen"
106 LOCATE 12,2: PRINT "Sie für Ihre Kalkulation zusammen unter Materialkosten MK."
107 LOCATE 13,2: PRINT "Damit sind Ihre Materialkosten noch nicht vollständig. Es fehlen die"
108 LOCATE 14,2: PRINT "Material-Gemeinkosten SG. Darunter fallen Kosten für die Eingangskontrolle,"
109 LOCATE 15,2: PRINT "für die Lagerung des Materials usw. Die gekauften Teile werden von einem"
110 LOCATE 16,2: PRINT "anderen Unternehmen zusammengebaut. Dafür fallen Lohnkosten LK an."
111 LOCATE 17,2: PRINT "Zu den Lohnkosten fallen noch Nebenkosten, die Lohngemeinkosten LG an."
112 LOCATE 18,2: PRINT "Das sind Kosten für Krankenkasse,Sozialversicherung usw. ": GOSUB 70
120 GOSUB 60
121 LOCATE 7,2: PRINT "MATERIALGEMEINKOSTEN IN % :"
122 ZZ$="25": R=7: S=35: L=2: PK%=2: GOSUB 20: SG$=ZZ$
123 IF SG$=CHR$(13) THEN SG$="25"
124 SG=VAL(SG$)
125 LOCATE 8,2: PRINT "LOHNGEMEINKOSTEN IN % :"
126 ZZ$="50": R=8: S=35: L=2: PK%=2: GOSUB 20: LG$=ZZ$
127 IF LG$=CHR$(13) THEN LG$="50"
128 LG=VAL(LG$)
129 LOCATE 9,2: PRINT "LOHNKOSTEN IN DM/STUNDE :"
130 ZZ$="14.25": R=9: S=35: L=5: PK%=2: GOSUB 20: LO$=ZZ$
131 IF LO$=CHR$(13) THEN LO$="14.25"
132 LO=VAL(LO$)
133 LOCATE 10,2: PRINT "ENTWICKLUNGSKOSTEN IN DM :"
134 ZZ$="": R=10: S=35: L=7: PK%=2: GOSUB 20: EK$=ZZ$
135 EK=VAL(EK$): IF EK$=CHR$(13) OR EK<=0 THEN BEEP: GOSUB 90: GOTO 134
136 GOSUB 95
137 LOCATE 11,2: PRINT "FERTIGUNGSMENGE IN STÜCK :"
138 ZZ$="": R=11: S=35: L=4: PK%=2: GOSUB 20: N$=ZZ$
139 N=VAL(N$): IF N$=CHR$(13) OR N<=0 THEN BEEP: GOSUB 90: GOTO 138
140 GOSUB 95
141 EA=EK/N: EA=INT(EA*100+.5)/100
142 LOCATE 12,2: PRINT "MATERIALKOSTEN IN STÜCK DM :"
143 ZZ$="": R=12: S=35: L=7: PK%=2: GOSUB 20: MK$=ZZ$
144 MK=VAL(MK$): IF MK$=CHR$(13) OR MK<=0 THEN BEEP: GOSUB 90: GOTO 143
145 GOSUB 95
147 LOCATE 13,2: PRINT "FERTIGUNGSZEIT IN MINUTEN :"
148 ZZ$="": R=13: S=35: L=4: PK%=2: GOSUB 20: FZ$=ZZ$
149 FZ=VAL(FZ$): IF FZ$=CHR$(13) OR FZ<=0 THEN BEEP: GOSUB 90: GOTO 148
150 GOSUB 95
151 FH=FZ/60: S=MK+(MK*(SG/100))
152 S=INT(S*100+.5)/100: L=(FH*LO): L=L+(L*(LG/100)): L=INT(L*100.5)/100
153 P=EA+S+L: P=INT(P*100+.5)/100
154 LOCATE 15,2: PRINT "DIE SELBSTKOSTEN BETRAGEN DM ";P;" STÜCK. DAVON SIND.."
155 LOCATE 16,2: PRINT "MATERIALKOSTEN : ";S;" DM"
156 LOCATE 17,2: PRINT "LOHNKOSTEN : ";L;" DM"
157 LOCATE 18,2: PRINT "ENTW.-KOSTENANTEIL : ";EA;" DM"
158 LOCATE 19,2: PRINT "DER VERKAUFSPREIS IST NOCH ZU KALKULIEREN !":GOSUB 70
160 GOSUB 60
161 LOCATE 7,2: PRINT "DAS PROGRAMM-LISTING"
162 LOCATE 8,2: PRINT " 10 CLS 'BILDSCHIRM FREI"
163 LOCATE 9,2: PRINT " 20 INPUT 'MATERIALGEMEINKOSTEN';SG 'EINGABE KOSTEN "
164 LOCATE 10,2: PRINT " 30 INPUT 'LOHNGEMEINKOSTEN ';LG 'EINGABE KOSTEN "
165 LOCATE 11,2: PRINT " 40 INPUT 'LOHNKOSTEN-STUNDE ';LO 'EINGABE KOSTEN "
166 LOCATE 12,2: PRINT " 50 INPUT 'ENTWICKLUNGSKOSTEN ';EK 'EINGABE KOSTEN "
167 LOCATE 13,2: PRINT " 60 INPUT 'FERTIGUNGSMENGE ';N 'EINGABE KOSTEN "
168 LOCATE 14,2: PRINT " 70 EA=EK/N 'BERECHNUNG "
169 LOCATE 15,2: PRINT " 80 EA=INT(EA*100+.5)/100 'AUFRUNDEN "
170 LOCATE 16,2: PRINT " 90 INPUT 'MATERIALKOSTEN DM/STÜCK';MK 'EINGABE KOSTEN"
171 LOCATE 17,2: PRINT "100 INPUT 'FERTIGUNG IN MINUTEN ';FZ 'EINGABE MINUTEN"
172 LOCATE 18,2: PRINT "110 FH=FZ/60 'STUNDEN ERRECHNEN"
173 LOCATE 19,2: PRINT "120 S=MK+(MK*(SG/100)) 'BERECHNUNG": GOSUB 70
180 GOSUB 60
181 LOCATE 7,2: PRINT "130 S=INT(S*100+.5)/100 'AUFRUNDEN"
182 LOCATE 8,2: PRINT "140 L=(FH*LO) 'LOHNKOSTEN"
183 LOCATE 9,2: PRINT "150 L=L+(L*(LG/100)) 'BERECHNUNG"
184 LOCATE 10,2: PRINT "160 L=INT(L*100+.5)/100 'AUFRUNDEN"
185 LOCATE 11,2: PRINT "170 P=EA+S+L 'SELBSTKOSTEN"
186 LOCATE 12,2: PRINT "180 P=INT(P*100+.5)/100 'AUFRUNDEN"
187 LOCATE 13,2: PRINT "190 PRINT 'SELBSTKOSTEN BETRAGEN DM ';P 'AUSGABE TEXT"
188 LOCATE 14,2: PRINT "200 PRINT 'MATERIALKOSTEN DM ';S 'AUSGABE TEXT"
189 LOCATE 15,2: PRINT "210 PRINT 'LOHNKOSTEN DM ';L 'AUSGABE TEXT"
190 LOCATE 16,2: PRINT "220 PRINT 'ENTW.-KOSTENANTEIL DM ';EA 'AUSGABE TEXT"
200 LOCATE 20,1: PRINT STRING$(79,205)
201 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
202 LOCATE 21,1: PRINT " ENDE DES TEILS WIEDERHOLEN = W BEENDEN = E PROGRAMM-MENÜ LADEN = ESC ": COLOR 15,0
203 LOCATE 22,1: PRINT STRING$(79,205)
205 E$=INKEY$: IF E$="" THEN 205
206 IF E$=CHR$(27) THEN 19
207 IF E$="W" OR E$="w" THEN 100
208 IF E$="E" OR E$="e" THEN CLS: END
209 GOTO 205