home *** CD-ROM | disk | FTP | other *** search
/ M.u.C.S. Disc 2000 / MUCS2000.iso / sigisoft / kaufmann / pk6.bas < prev    next >
BASIC Source File  |  1997-10-09  |  15KB  |  246 lines
  1. 1 WIDTH 80: COLOR 15,0,0
  2. 10 GOTO 100
  3. 15 LOCATE 20,1: PRINT STRING$(79,205)
  4. 16 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  5. 17 LOCATE 21,25: PRINT "PROGRAMM WIRD GELADEN.BITTE WARTEN": COLOR 15,0
  6. 18 LOCATE 22,1: PRINT STRING$(79,205): RETURN
  7. 19 GOSUB 15: RUN "MENUE"
  8. 20 ZZ$=LEFT$(ZZ$,L):ZZ$=ZZ$+STRING$(L-LEN(ZZ$),95):Z2=0:Y=1
  9. 21 LOCATE R,S,O:PRINT ZZ$;
  10. 22 LOCATE R,S+Y-1,1
  11. 23 Z$=INKEY$: IF Z$="" THEN 23 ELSE Z=ASC(Z$): Z1=0: IF Z=0 THEN Z1=ASC(RIGHT$(Z$,1))
  12. 24 IF Z<>13 THEN 28 ELSE IF Z2 >0 THEN 23
  13. 25 IF Y=1 THEN ZZ$=CHR$(13):RETURN
  14. 26 IF RIGHT$(ZZ$,1)="_" THEN ZZ$=LEFT$(ZZ$,INSTR(ZZ$,"_")-1)
  15. 27 RETURN
  16. 28 IF Z<>0 THEN 48
  17. 29 IF Z1<>71 THEN 31 ELSE IF Y=1 OR Z2 THEN 23
  18. 30 Y=1:GOTO 22
  19. 31 IF Z1<>75 THEN 33 ELSE IF Y=1 OR Z2 THEN 23
  20. 32 Y=Y-1:GOTO 22
  21. 33 IF Z1<>77 THEN 35 ELSE IF MID$(ZZ$,Y,1)="_" OR Y>L THEN 23
  22. 34 Y=Y+1:GOTO 22
  23. 35 IF Z1<>79 THEN 39 ELSE IF Y>L OR Z2 THEN 23
  24. 36 IF MID$(ZZ$,Y,1)="_" THEN 23
  25. 37 Y=Y+1
  26. 38 IF MID$(ZZ$,Y,1)="_" THEN 22 ELSE 37
  27. 39 IF Z1<>82 THEN 42 ELSE IF RIGHT$(ZZ$,1)<>"_" THEN 23
  28. 40 IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
  29. 41 ZZ$=LEFT$(ZZ$,Y-1)+"_"+MID$(ZZ$,Y,L-Y):Z2=Z2+1:GOTO 21
  30. 42 IF Z1<>83 THEN 44 ELSE IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
  31. 43 GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+MID$(ZZ$,Y+1)+"_":GOTO 21
  32. 44 IF Z1<>117 THEN 46 ELSE IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
  33. 45 GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+STRING$(L-Y+1,95):GOTO 21
  34. 46 IF Z1<>119 THEN 23 ELSE IF Y=1 THEN 23
  35. 47 ZZ$=MID$(ZZ$,Y)+STRING$(Y-1,95):Y=1:GOTO 21
  36. 48 IF Z<>8 THEN 50 ELSE IF Y=1 THEN 23
  37. 49 ZZ$=LEFT$(ZZ$,Y-2)+MID$(ZZ$,Y)+"_":Y=Y-1:GOTO 21
  38. 50 IF Z<>27 THEN 51 ELSE ZZ$=STRING$(L,95):Y=1:Z2=0: GOTO 21
  39. 51 IF Z=95 OR Y>L THEN 23
  40. 52 ON PK% GOTO 55,53,54
  41. 53 IF Z<46 OR Z>58 THEN 23 ELSE 55
  42. 54 IF Z<>106 AND Z<>110 THEN 23
  43. 55 IF Z=44 THEN 23 ELSE GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+Z$+MID$(ZZ$,Y+1):PRINT Z$;:Y=Y+1:GOTO 22
  44. 56 IF Z2 THEN Z2=Z2-1
  45. 57 RETURN
  46. 60 CLS: LOCATE 2,1: PRINT STRING$(79,205)
  47. 61 LOCATE 3,1: COLOR 0,15: PRINT SPACE$(79): LOCATE 3,30: PRINT "KAUFMÄNNISCHES  RECHNEN": LOCATE 4,1: PRINT SPACE$(79)
  48. 62 LOCATE 4,30: PRINT "(C) BY SIEGFRIED HÜBNER       ESC =LADE MENÜ": LOCATE 5,1: PRINT SPACE$(79)
  49. 63 LOCATE 5,32: PRINT "H Y P O T H E K E N"
  50. 64 COLOR 15,0: LOCATE 6,1: PRINT STRING$(79,205): RETURN
  51. 70 LOCATE 20,1: PRINT STRING$(79,205)
  52. 71 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  53. 72 LOCATE 21,29: PRINT "BELIEBIGE TASTE DRÜCKEN": COLOR 15,0
  54. 73 LOCATE 22,1: PRINT STRING$(79,205)
  55. 75 E$=INKEY$: IF E$="" THEN 75
  56. 76 IF E$=CHR$(27) THEN 19
  57. 77 RETURN
  58. 90 LOCATE 20,1: PRINT STRING$(79,205)
  59. 91 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  60. 92 LOCATE 21,34: PRINT "FALSCHE EINGABE": COLOR 15,0
  61. 93 LOCATE 22,1: PRINT STRING$(79,205): RETURN
  62. 95 FOR T=1 TO 4: LOCATE 19+T,1: PRINT SPACE$(79): NEXT: RETURN
  63. 100 GOSUB 60
  64. 101 LOCATE 7,2: PRINT "Ein langfristiges Darlehen - etwa zum Bau eines Hauses - wird  "
  65. 102 LOCATE 8,2: PRINT "Hypothekendarlehen genannt. Die Konditionen dafür mögen lauten:"
  66. 103 LOCATE 9,2: PRINT "Zins 7.5 %    Tilgung 1 %"
  67. 104 LOCATE 10,2: PRINT "Für eine Hypothek von 100 000 DM bedeutet das:"
  68. 105 LOCATE 11,2: PRINT "- die jährlichen Zinsen betragen 7.500 DM"
  69. 106 LOCATE 12,2: PRINT "- die jährlicheTilgung - Rückzahlung der Schuld - 1.000 DM"
  70. 107 LOCATE 13,2: PRINT "- die Summe beider Größen - 8.500 DM müssen jährlich zurückgezahlt"
  71. 108 LOCATE 14,2: PRINT "  werden. Diesen über die ganze Laufzeit gleichen Jahresbetrag "
  72. 109 LOCATE 15,2: PRINT "  nennt man ANNUITÄT."
  73. 110 LOCATE 18,2: PRINT "  Es folgt ein Programm, das Ihnen die mühsame Berechnung abnimmt.": GOSUB 70
  74. 120 GOSUB 60
  75. 121 LOCATE 8,2: PRINT "HÖHE DER HYPOTHEK IN DM  :"
  76. 122 ZZ$="": R=8: S=30: L=7: PK%=2: GOSUB 20: H$=ZZ$
  77. 123 H=VAL(H$):IF H$=CHR$(13) OR H<=0 THEN BEEP: GOSUB 90: GOTO 122
  78. 124 GOSUB 95
  79. 125 LOCATE 9,2: PRINT "ZINSSATZ IN % / JAHR     :"
  80. 126 ZZ$="": R=9: S=30: L=3: PK%=2: GOSUB 20: ZINS$=ZZ$
  81. 127 ZINS=VAL(ZINS$):IF ZINS$=CHR$(13) OR ZINS<=0 THEN BEEP: GOSUB 90: GOTO 126
  82. 128 GOSUB 95
  83. 129 LOCATE 10,2: PRINT "TILGUNG  IN %            :"
  84. 130 ZZ$="": R=10: S=30: L=3: PK%=2: GOSUB 20: T$=ZZ$
  85. 131 T=VAL(T$):IF T$=CHR$(13) OR T<=0 THEN BEEP: GOSUB 90: GOTO 130
  86. 132 GOSUB 95
  87. 135 A=(H*ZINS/100)+(H*T/100)
  88. 136 LOCATE 12,2: PRINT "DIE JÄHRLICHE BELASTUNG BETRÄGT :";A;" DM.": GOSUB 70: GOSUB 60
  89. 137 LOCATE 7,2: PRINT "DER ZEITLICHE ABBAU DER HYPOTHEK IST:"
  90. 138 LOCATE 8,2: PRINT "JAHR","DARLEHEN","ZINSEN","TILGUNG"
  91. 139 J=J+1
  92. 140 ZS=H*ZINS/100:TI=H*T/100
  93. 141 PRINT TAB(2)J,H,ZS,TI
  94. 142 J=J+1: H=H-TI: ZS=H*ZINS/100: ZS=INT(ZS*100+.5)/100: TI=A-ZS: TI=INT(TI*100+.5)/100
  95. 143 IF H<A THEN GOSUB 70: GOTO 153
  96. 144 IF J=9 THEN GOSUB 70: GOTO 150
  97. 146 GOTO 141
  98. 150 GOSUB 60
  99. 151 LOCATE 7,2: PRINT "JAHR","DARLEHEN","ZINSEN","TILGUNG"
  100. 152 PRINT TAB(2)J,H,ZS,TI
  101. 153 H=INT(H*100+.5)/100
  102. 154 PRINT TAB(2)"LETZTE RATE IM ";J;" JAHR MIT DM ";H: GOSUB 70
  103. 160 GOSUB 60
  104. 161 LOCATE 7,2: PRINT "DAS PROGRAMM-LISTING"
  105. 162 LOCATE 9,2: PRINT " 10 CLS                                           'BILDSCHIRM FREI"
  106. 163 LOCATE 10,2: PRINT " 20 INPUT 'HÖHE DER HYPOTHEK';H                   'EINGABE SUMME  "
  107. 164 LOCATE 11,2: PRINT " 30 INPUT 'HÖHE ZINSSATZ %  ';Z                   'EINGABE ZINSSATZ"
  108. 165 LOCATE 12,2: PRINT " 40 INPUT 'HÖHE TILGUNG  %  ';T                   'EINGABE TILGUNG"
  109. 166 LOCATE 13,2: PRINT " 50 A=(H*Z/100)+(H*T/100)                         'BERECHNUNG"
  110. 167 LOCATE 14,2: PRINT " 60 PRINT 'JÄHRLICHE BELASTUNG';A;'DM'            'TEXTAUSGABE"
  111. 168 LOCATE 15,2: PRINT " 70 PRINT 'ZEITLICHE ABBAU DER HYPOTHEK'          'TEXTAUSGABE"
  112. 169 LOCATE 16,2: PRINT " 80 PRINT 'JAHR','DARLEHEN','ZINS','TILGUNG'      'TEXT FORMATIEREN"
  113. 170 LOCATE 17,2: PRINT " 90 J=J+1                                         'JAHRE ZÄHLEN"
  114. 171 LOCATE 18,2: PRINT "100 ZS=H*Z/100                                    'BERECHNUNG"
  115. 172 LOCATE 19,2: PRINT "110 TI=H*T/100                                    'BERECHNUNG": GOSUB 70
  116. 175 GOSUB 60
  117. 176 LOCATE 7,2:  PRINT "120 PRINT J,H,ZS,TI                               'AUSGABE WERTE"
  118. 177 LOCATE 8,2:  PRINT "130 J=J+1                                         'ZÄHLER"
  119. 178 LOCATE 9,2:  PRINT "140 H=H-TI                                        'BERECHNUNG"
  120. 179 LOCATE 10,2: PRINT "150 ZS=H*Z/100                                    'BERECHNUNG"
  121. 180 LOCATE 11,2: PRINT "160 ZS=INT(ZS*100+.5)/100                         'AUFRUNDEN"
  122. 181 LOCATE 12,2: PRINT "170 TI=A-ZS                                       'BERECHNUNG"
  123. 182 LOCATE 13,2: PRINT "180 TI=INT(TI*100+.5)/100                         'AUFRUNDEN"
  124. 183 LOCATE 14,2: PRINT "190 IF H<A THEN  210                              'VERGLEICHEN"
  125. 184 LOCATE 15,2: PRINT "200 GOTO 176                                      'RÜCKSPRUNG"
  126. 185 LOCATE 16,2: PRINT "210 H=INT(H*100+.5)/100                           'AUFRUNDEN"
  127. 186 LOCATE 17,2: PRINT "220 PRINT 'LETZTE RATE';J;'MIT';H;'DM'            'TEXTAUSGABE": GOSUB 70
  128. 190 GOSUB 60
  129. 191 LOCATE 7,2: PRINT "Bei diesem Programm ist etwas unberücksichtigt geblieben."
  130. 192 LOCATE 8,2: PRINT "Üblicherweise zahlt die Bank die Hypothek nicht voll - nicht zu 100 % -"
  131. 193 LOCATE 9,2: PRINT "aus. Sie zieht Ihnen GELDBESCHAFFUNGSKOSTEN ab. Das sieht dann so aus: "
  132. 194 LOCATE 10,2: PRINT "HYPOTHEK      50.000 DM"
  133. 195 LOCATE 11,2: PRINT "ZINSSATZ      9.5 % "
  134. 196 LOCATE 12,2: PRINT "TILGUNG        2  % "
  135. 197 LOCATE 13,2: PRINT "AUSZAHLUNG    97  % "
  136. 198 LOCATE 14,2: PRINT "Obwohl Ihr Darlehen über 50.000 DM lautet, zahlt Ihnen die Bank davon nur"
  137. 199 LOCATE 15,2: PRINT "97 % aus, das sind 48.500 DM. Sind Sie auf den vollen Betrag von 50.000 "
  138. 200 LOCATE 16,2: PRINT "angewiesen, dann können Sie mit der Bank eine Vereinbarung treffen,die "
  139. 201 LOCATE 17,2: PRINT "Fachleute AUFSTOCKUNG des Darlehens unter gleichzeitiger Tilgungs- "
  140. 202 LOCATE 18,2: PRINT "streckung nennen. Sie erhalten die vollen 50.000 ausgezahlt,müssen "
  141. 203 LOCATE 19,2: PRINT "aber die 1.500 mitfinanzieren.": GOSUB 70
  142. 210 GOSUB 60
  143. 211 LOCATE 7,2: PRINT "HÖHE DER HYPOTHEK IN DM  :"
  144. 212 ZZ$="": R=7: S=30: L=7: PK%=2: GOSUB 20: H$=ZZ$
  145. 213 H=VAL(H$): IF H$=CHR$(13) OR H<=0 THEN BEEP: GOSUB 90: GOTO 212
  146. 214 GOSUB 95
  147. 215 LOCATE 8,2: PRINT "HÖHE ZINSSATZ % / JAHR   :"
  148. 216 ZZ$="": R=8: S=30: L=3: PK%=2: GOSUB 20: ZINS$=ZZ$
  149. 217 ZINS=VAL(ZINS$): IF ZINS$=CHR$(13) OR ZINS<=0 THEN BEEP: GOSUB 90: GOTO 216
  150. 218 GOSUB 95
  151. 220 LOCATE 9,2: PRINT "HÖHE TILGUNG  %          :"
  152. 221 ZZ$="": R=9: S=30: L=3: PK%=2: GOSUB 20: T$=ZZ$
  153. 222 T=VAL(T$): IF T$=CHR$(13) OR T<=0 THEN BEEP: GOSUB 90: GOTO 221
  154. 223 GOSUB 95
  155. 225 LOCATE 10,2: PRINT "AUSZAHLUNGSPROZENTSATZ   :"
  156. 226 ZZ$="": R=10: S=30: L=5: PK%=2: GOSUB 20: AZ$=ZZ$
  157. 227 AZ=VAL(AZ$): IF AZ$=CHR$(13) OR AZ<=0 THEN BEEP: GOSUB 90: GOTO 226
  158. 228 GOSUB 95
  159. 229 Z1=100-AZ: H1=H*Z1/100
  160. 230 LOCATE 11,2: PRINT "TILGUNG IN JAHREN        :"
  161. 231 ZZ$="": R=11: S=30: L=2: PK%=2: GOSUB 20: J1$=ZZ$
  162. 232 J1=VAL(J1$): IF J1$=CHR$(13) OR J1<=0 THEN BEEP: GOSUB 90: GOTO 231
  163. 233 GOSUB 95
  164. 234 A=(H*ZINS/100)+(H*T/100)
  165. 235 LOCATE 13,2: PRINT "DIE JÄHRLICHE BELASTUNG BETRÄGT AB DEM ";J1+1;".TEN JAHR DM ";A: GOSUB 70
  166. 240 GOSUB 60
  167. 241 LOCATE 7,2: PRINT "DER ZEITLICHE ABBAU DER HYPOTHEK IST:"
  168. 242 LOCATE 8,2: PRINT "JAHR","DARLEHEN","ZINSEN","TILGUNG"
  169. 243 J=J+1: Z1=H1*ZINS/100: ZS=H*ZINS/100: ZS=ZS+Z1: ZS=INT(ZS*100+.5)/100
  170. 244 TI=H1/J1
  171. 245 PRINT TAB(2)J,H,ZS,TI
  172. 246 J=J+1
  173. 247 H=H: H1=H1-TI: Z1=H1*ZINS/100: ZS=H*ZINS/100: ZS=ZS+Z1
  174. 248 IF J=J1+1 THEN 251
  175. 250 GOTO 245
  176. 251 ZS=H*ZINS/100: ZS=INT(ZS*100+.5)/100: TI=H*T/100: TI=INT(TI*100+.5)/100
  177. 252 PRINT TAB(2) J,H,ZS,TI
  178. 253 J=J+1: H=H-TI: ZS=H*ZINS/100: ZS=INT(ZS*100+.5)/100
  179. 254 TI=A-ZS: TI=INT(TI*100+.5)/100
  180. 255 IF H<A THEN 257
  181. 256 GOTO 252
  182. 257 PRINT TAB(2)"LETZTE RATE IM ";J;".TEN JAHR MIT DM ";H
  183. 258 PRINT: PRINT STRING$(79,205)
  184. 259 COLOR 0,15
  185. 260 PRINT TAB(29)"BELIEBIGE TASTE DRÜCKEN                            ": COLOR 15,0
  186. 261 PRINT STRING$(79,205): GOSUB 75
  187. 270 GOSUB 60
  188. 271 LOCATE 7,2: PRINT "DAS PROGRAMM-LISTING"
  189. 272 LOCATE 9,2: PRINT " 10 CLS                                             'BILDSCHIRM FREI"
  190. 273 LOCATE 10,2: PRINT " 20 INPUT 'HÖHE DER HYPOTHEK      ';H               'EINGABE HYPOTHEK"
  191. 274 LOCATE 11,2: PRINT " 30 INPUT 'ZINSSATZ % / JAHR      ';Z               'EINGABE ZINSSATZ"
  192. 275 LOCATE 12,2: PRINT " 40 INPUT 'TILGUNG  %             ';T               'EINGABE TILGUNG "
  193. 276 LOCATE 13,2: PRINT " 50 INPUT 'AUSZAHLUNGS-%-SATZ     ';AZ              'EINGABE AUSZAHLUNG"
  194. 277 LOCATE 14,2: PRINT " 60 Z1=100-AZ                                       'BERECHNUNG        "
  195. 278 LOCATE 15,2: PRINT " 70 H1=H*Z1/100                                     'BERECHNUNG        "
  196. 279 LOCATE 16,2: PRINT " 80 INPUT 'TILGUNGSSTRECKE % ';J1                   'EINGABE TILGUNG   "
  197. 280 LOCATE 17,2: PRINT " 90 A=(H*Z/100)+(H*T/100)                           'BERECHNUNG        "
  198. 281 LOCATE 18,2: PRINT "100 PRINT 'JÄHRLICHE BELASTUNG BETRÄGT'             'TEXTAUSGABE       "
  199. 282 LOCATE 19,2: PRINT "110 PRINT 'DEM';J1+1;'JAHR DM';A                    'TEXTAUSGABE       ": GOSUB 70
  200. 290 GOSUB 60
  201. 291 LOCATE 7,2:  PRINT "120 PRINT 'ZEITLICHER ABBAU DER HYPOTHEK            'TEXTAUSGABE"
  202. 292 LOCATE 8,2:  PRINT "130 PRINT 'JAHR',DARLEHEN','ZINS','TILGUNG'         'TEXT FORMATIERT"
  203. 293 LOCATE 9,2:  PRINT "140 J=J+1                                           'JAHRE ZÄHLEN"
  204. 294 LOCATE 10,2: PRINT "150 Z1=H1*Z/100                                     'BERECHNUNG "
  205. 295 LOCATE 11,2: PRINT "160 ZS=H*Z/100                                      'BERECHNUNG "
  206. 296 LOCATE 12,2: PRINT "170 ZS=ZS+Z1                                        'BERECHNUNG "
  207. 297 LOCATE 13,2: PRINT "180 ZS=INT(ZS*100+.5)/100                           'AUFRUNDEN  "
  208. 298 LOCATE 14,2: PRINT "190 TI=H1/J1                                        'BERECHNUNG "
  209. 299 LOCATE 15,2: PRINT "200 PRINT J,H,ZS,TI                                 'AUSGABE DER WERTE"
  210. 300 LOCATE 16,2: PRINT "210 J=J+1                                           'JAHRE ZÄHLEN "
  211. 301 LOCATE 17,2: PRINT "220 H=H                                             'WERTZUWEISUNG"
  212. 302 LOCATE 18,2: PRINT "230 H1=H1-TI                                        'BERECHNUNG"
  213. 303 LOCATE 19,2: PRINT "240 Z1=H1*Z/100                                     'BERECHNUNG": GOSUB 70
  214. 310 GOSUB 60
  215. 311 LOCATE 7,2:  PRINT "250 ZS=H*Z/100                                      'BERECHNUNG"
  216. 312 LOCATE 8,2:  PRINT "260 ZS=ZS+Z1                                        'BERECHNUNG"
  217. 313 LOCATE 9,2:  PRINT "270 IF J=J1+1 THEN 290                              'VERGLEICH "
  218. 314 LOCATE 10,2: PRINT "280 GOTO 200                                        'RÜCKSPRUNG"
  219. 315 LOCATE 11,2: PRINT "290 ZS=H*Z/100                                      'BERECHNUNG"
  220. 316 LOCATE 12,2: PRINT "300 ZS=INT(ZS*100+.5)/100                           'AUFRUNDEN "
  221. 317 LOCATE 13,2: PRINT "310 TI=H*T/100                                      'BERECHNUNG"
  222. 318 LOCATE 14,2: PRINT "320 TI=INT(TI*100+.5)/100                           'AUFRUNDEN "
  223. 319 LOCATE 15,2: PRINT "330 PRINT J,H,ZS,TI                                 'AUSGABE DER WERTE"
  224. 320 LOCATE 16,2: PRINT "340 J=J+1                                           'ZÄHLER JAHRE"
  225. 321 LOCATE 17,2: PRINT "350 H=H-TI                                          'BERECHNUNG"
  226. 322 LOCATE 18,2: PRINT "360 ZS=H*Z/100                                      'BERECHNUNG": GOSUB 70
  227. 330 GOSUB 60
  228. 331 LOCATE 7,2:  PRINT "370 ZS=INT(ZS*100+.5)/100                           'AUFRUNDEN "
  229. 332 LOCATE 8,2:  PRINT "380 TI=A-ZS                                         'BERECHNUNG"
  230. 333 LOCATE 9,2:  PRINT "390 TI=INT(TI*100+.5)/100                           'AUFRUNDEN "
  231. 334 LOCATE 10,2: PRINT "400 H=INT(H*100+.5)/100                             'AUFRUNDEN "
  232. 335 LOCATE 11,2: PRINT "410 IF H<A THEN 430                                 'VERGLEICH "
  233. 336 LOCATE 12,2: PRINT "420 GOTO 330                                        'RÜCKSPRUNG"
  234. 337 LOCATE 13,2: PRINT "430 PRINT 'LETZTE RATE IM ';J;'.TEN JAHR'           'END TEXTAUSGABE"
  235. 338 LOCATE 14,2: PRINT "440 PRINT 'MIT DM ';H                               'END TEXTAUSGABE"
  236. 340 LOCATE 20,1: PRINT STRING$(79,205)
  237. 341 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  238. 342 LOCATE 21,1: PRINT " ENDE DES TEILS    WIEDERHOLEN = W    BEENDEN  = E   PROGRAMM-MENÜ LADEN = ESC ": COLOR 15,0
  239. 343 LOCATE 22,1: PRINT STRING$(79,205)
  240. 350 E$=INKEY$: IF E$="" THEN 350
  241. 351 IF E$="W"  OR E$="w" THEN 100
  242. 352 IF E$="E"  OR E$="e" THEN CLS: END
  243. 353 IF E$=CHR$(27) THEN 19
  244. 354 GOTO 350
  245.  
  246.