home *** CD-ROM | disk | FTP | other *** search
/ M.u.C.S. Disc 2000 / MUCS2000.iso / sigisoft / kaufmann / pk11.bas < prev    next >
BASIC Source File  |  1997-10-09  |  8KB  |  147 lines
  1. 1 WIDTH 80: COLOR 15,0,0
  2. 10 GOTO 100
  3. 15 LOCATE 20,1: PRINT STRING$(79,205)
  4. 16 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  5. 17 LOCATE 21,25: PRINT "PROGRAMM WIRD GELADEN.BITTE WARTEN": COLOR 15,0
  6. 18 LOCATE 22,1: PRINT STRING$(79,205): RETURN
  7. 19 GOSUB 15: RUN "MENUE"
  8. 20 ZZ$=LEFT$(ZZ$,L):ZZ$=ZZ$+STRING$(L-LEN(ZZ$),95):Z2=0:Y=1
  9. 21 LOCATE R,S,O:PRINT ZZ$;
  10. 22 LOCATE R,S+Y-1,1
  11. 23 Z$=INKEY$: IF Z$="" THEN 23 ELSE Z=ASC(Z$): Z1=0: IF Z=0 THEN Z1=ASC(RIGHT$(Z$,1))
  12. 24 IF Z<>13 THEN 28 ELSE IF Z2 >0 THEN 23
  13. 25 IF Y=1 THEN ZZ$=CHR$(13):RETURN
  14. 26 IF RIGHT$(ZZ$,1)="_" THEN ZZ$=LEFT$(ZZ$,INSTR(ZZ$,"_")-1)
  15. 27 RETURN
  16. 28 IF Z<>0 THEN 48
  17. 29 IF Z1<>71 THEN 31 ELSE IF Y=1 OR Z2 THEN 23
  18. 30 Y=1:GOTO 22
  19. 31 IF Z1<>75 THEN 33 ELSE IF Y=1 OR Z2 THEN 23
  20. 32 Y=Y-1:GOTO 22
  21. 33 IF Z1<>77 THEN 35 ELSE IF MID$(ZZ$,Y,1)="_" OR Y>L THEN 23
  22. 34 Y=Y+1:GOTO 22
  23. 35 IF Z1<>79 THEN 39 ELSE IF Y>L OR Z2 THEN 23
  24. 36 IF MID$(ZZ$,Y,1)="_" THEN 23
  25. 37 Y=Y+1
  26. 38 IF MID$(ZZ$,Y,1)="_" THEN 22 ELSE 37
  27. 39 IF Z1<>82 THEN 42 ELSE IF RIGHT$(ZZ$,1)<>"_" THEN 23
  28. 40 IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
  29. 41 ZZ$=LEFT$(ZZ$,Y-1)+"_"+MID$(ZZ$,Y,L-Y):Z2=Z2+1:GOTO 21
  30. 42 IF Z1<>83 THEN 44 ELSE IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
  31. 43 GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+MID$(ZZ$,Y+1)+"_":GOTO 21
  32. 44 IF Z1<>117 THEN 46 ELSE IF (Z2=0 AND MID$(ZZ$,Y,1)="_") OR Y>L THEN 23
  33. 45 GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+STRING$(L-Y+1,95):GOTO 21
  34. 46 IF Z1<>119 THEN 23 ELSE IF Y=1 THEN 23
  35. 47 ZZ$=MID$(ZZ$,Y)+STRING$(Y-1,95):Y=1:GOTO 21
  36. 48 IF Z<>8 THEN 50 ELSE IF Y=1 THEN 23
  37. 49 ZZ$=LEFT$(ZZ$,Y-2)+MID$(ZZ$,Y)+"_":Y=Y-1:GOTO 21
  38. 50 IF Z<>27 THEN 51 ELSE ZZ$=STRING$(L,95):Y=1:Z2=0: GOTO 21
  39. 51 IF Z=95 OR Y>L THEN 23
  40. 52 ON PK% GOTO 55,53,54
  41. 53 IF Z<46 OR Z>58 THEN 23 ELSE 55
  42. 54 IF Z<>106 AND Z<>110 THEN 23
  43. 55 IF Z=44 THEN 23 ELSE GOSUB 56:ZZ$=LEFT$(ZZ$,Y-1)+Z$+MID$(ZZ$,Y+1):PRINT Z$;:Y=Y+1:GOTO 22
  44. 56 IF Z2 THEN Z2=Z2-1
  45. 57 RETURN
  46. 60 CLS: LOCATE 2,1: PRINT STRING$(79,205)
  47. 61 LOCATE 3,1: COLOR 0,15: PRINT SPACE$(79): LOCATE 3,30: PRINT "KAUFMÄNNISCHES  RECHNEN": LOCATE 4,1: PRINT SPACE$(79)
  48. 62 LOCATE 4,30: PRINT "(C) BY SIEGFRIED HÜBNER       ESC =LADE MENÜ": LOCATE 5,1: PRINT SPACE$(79)
  49. 63 LOCATE 5,24: PRINT "B R E A K   E V E N  A N A L Y S E"
  50. 64 COLOR 15,0: LOCATE 6,1: PRINT STRING$(79,205): RETURN
  51. 70 LOCATE 20,1: PRINT STRING$(79,205)
  52. 71 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  53. 72 LOCATE 21,29: PRINT "BELIEBIGE TASTE DRÜCKEN": COLOR 15,0
  54. 73 LOCATE 22,1: PRINT STRING$(79,205)
  55. 75 E$=INKEY$: IF E$="" THEN 75
  56. 76 IF E$=CHR$(27) THEN 19
  57. 77 RETURN
  58. 90 LOCATE 20,1: PRINT STRING$(79,205)
  59. 91 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  60. 92 LOCATE 21,34: PRINT "FALSCHE EINGABE": COLOR 15,0
  61. 93 LOCATE 22,1: PRINT STRING$(79,205): RETURN
  62. 95 FOR T=1 TO 4: LOCATE 19+T,1: PRINT SPACE$(79): NEXT: RETURN
  63. 100 GOSUB 60
  64. 101 LOCATE 7,2: PRINT "Mit dieser Methode können Sie herausfinden, ab welcher verkauften"
  65. 102 LOCATE 8,2: PRINT "Stückzahl Sie überhaupt Gewinn machen. Ihre Kosten belaufen sich"
  66. 103 LOCATE 9,2: PRINT "jeden Monat für Miete, Telefon, Energie usw. auf 1.000 DM. Diese"
  67. 104 LOCATE 10,2: PRINT "Kosten entstehen Ihnen, ob Sie nun etwas verkaufen oder nicht. Man"
  68. 105 LOCATE 11,2: PRINT "spricht deshalb von fixen Kosten FK. Die Selbstkosten für ein Produkt"
  69. 106 LOCATE 12,2: PRINT "betragen etwa 1000 DM. Verkaufen können Sie dieses Produkt für 110 DM."
  70. 107 LOCATE 13,2: PRINT "Wenn Sie in einem Monat nicht mehr als ein Stück dieses Produktes"
  71. 108 LOCATE 14,2: PRINT "verkaufen, stellt sich Ihre Gewinn- und Verlustrechnung wie folgt dar:"
  72. 109 LOCATE 15,2: PRINT "Fixe Kosten DM 1.000,--"
  73. 110 LOCATE 16,2: PRINT "Selbstkosten des einen verkauften Stückes DM 100.--"
  74. 111 LOCATE 17,2: PRINT "Verkaufserlös dieses Stücks DM 110.--"
  75. 112 LOCATE 18,2: PRINT "Nach Abzug der Selbskosten von 100 DM verbleiben Ihnen ganze 10 DM zur"
  76. 113 LOCATE 19,2: PRINT "Deckung der Fixkosten. Umsatzverlust diesen Monat von 990 DM": GOSUB 70
  77. 120 GOSUB 60
  78. 121 LOCATE 7,2: PRINT "HÖHE DER FIXKOSTEN     : "
  79. 122 ZZ$="": R=7: S=29: L=5: PK%=2: GOSUB 20: FK$=ZZ$
  80. 123 FK=VAL(FK$): IF FK$=CHR$(13) OR FK<=0 THEN BEEP: GOSUB 90: GOTO 122
  81. 124 GOSUB 95
  82. 125 LOCATE 8,2: PRINT "HÖHE DER SELBTKOSTEN   : "
  83. 126 ZZ$="": R=8: S=29: L=5: PK%=2: GOSUB 20: VK$=ZZ$
  84. 127 VK=VAL(VK$): IF VK$=CHR$(13) OR VK<=0 THEN BEEP: GOSUB 90: GOTO 126
  85. 128 GOSUB 95
  86. 129 LOCATE 9,2: PRINT "VERKAUFSPREIS OHNE MWST: "
  87. 130 ZZ$="": R=9: S=29: L=7: PK%=2: GOSUB 20: VP$=ZZ$
  88. 131 VP=VAL(VP$): IF VP$=CHR$(13) OR VP<=0 THEN BEEP: GOSUB 90: GOTO 130
  89. 132 GOSUB 95
  90. 134 GOSUB 95
  91. 135 LOCATE 10,2: PRINT "AB STÜCKZAHL RECHNEN   : "
  92. 136 ZZ$="": R=10: S=29: L=3: PK%=2: GOSUB 20: M1$=ZZ$
  93. 137 M1=VAL(M1$): IF M1$=CHR$(13) OR M1<=0 THEN BEEP: GOSUB 90: GOTO 136
  94. 140 LOCATE 11,2: PRINT "BIS STÜCKZAHL RECHNEN  : "
  95. 141 ZZ$="": R=11: S=29: L=3: PK%=2: GOSUB 20: M2$=ZZ$
  96. 142 M2=VAL(M2$): IF M2$=CHR$(13) OR M2<=0 THEN BEEP: GOSUB 90: GOTO 141
  97. 143 GOSUB 95
  98. 144 QB=FK/(VP-VK): GOSUB 70
  99. 150 GOSUB 60
  100. 151 LOCATE 7,2: PRINT "ANZAHL","KOSTEN","KOSTEN/ST","GEWINN"
  101. 152 FOR M=M1 TO M2
  102. 153 U=VP*M: K=FK+(VK*M): KS=K/M: KS=INT(KS*100+.5)/100: G=U-K
  103. 154 IF M<QB THEN 157
  104. 155 PRINT TAB(2)"DER BREAK-EVEN-PUNKT LIEGT BEI EINER STÜCKZAHL VON :";INT(QB)
  105. 156 QB=999999999#
  106. 157 PRINT TAB(2)M,K,KS,G
  107. 158 NEXT M
  108. 159 GOSUB 500: GOSUB 75
  109. 160 GOSUB 60
  110. 161 LOCATE 7,2: PRINT "DAS PROGRAMM-LISTING"
  111. 162 LOCATE 9,2: PRINT " 10 CLS                                           'BILDSCHIRM FREI"
  112. 163 LOCATE 10,2: PRINT " 20 INPUT 'HÖHE DER FIXKOSTEN ';FK                'EINGABE KOSTEN"
  113. 164 LOCATE 11,2: PRINT " 30 INPUT 'HÖHE SELBSTKOSTEN  ';VK                'EINGABE KOSTEN"
  114. 165 LOCATE 12,2: PRINT " 40 INPUT 'VERKAUFSPREIS      ';VP                'EINGABE KOSTEN"
  115. 166 LOCATE 13,2: PRINT " 50 INPUT 'AB STÜCKZAHL       ';M1                'EINGABE KOSTEN"
  116. 167 LOCATE 14,2: PRINT " 60 INPUT 'BIS STÜCKZAHL      ';M2                'EINGABE KOSTEN"
  117. 168 LOCATE 15,2: PRINT " 70 QB=FK/(VP-VK)                                 'BERECHNUNG"
  118. 169 LOCATE 16,2: PRINT " 80 PRINT 'ANZAHL','KOSTEN',KOS/ST','GEWINN'      'AUSGABE TEXT"
  119. 170 LOCATE 17,2: PRINT " 90 FOR M=M1 TO M2                                'SCHLEIFEN BEGINN"
  120. 171 LOCATE 18,2: PRINT "100 U=VP*M                                        'BERECHNUNG"
  121. 172 LOCATE 19,2: PRINT "110 K=FK+(VK*M)                                   'BERECHNUNG": GOSUB 70
  122. 180 GOSUB 60
  123. 181 LOCATE 7,2:  PRINT "120 KS=K/M                                        'BERECHNUNG"
  124. 182 LOCATE 8,2:  PRINT "130 KS=INT(KS*100+.5)/100                         'AUFRUNDEN"
  125. 183 LOCATE 9,2:  PRINT "140 G=U-K                                         'BERECHNUNG"
  126. 184 LOCATE 10,2: PRINT "150 IF M<QB THEN 190                              'VERGLEICH"
  127. 185 LOCATE 11,2: PRINT "160 PRINT 'DER BREAK-EVEN-PUNKT LIEGT BEI'        'AUSGABE TEXT"
  128. 186 LOCATE 12,2: PRINT "170 PRINT 'EINER STÜCKZAHL VON ';INT(QB)          'AUSGABE TEXT"
  129. 187 LOCATE 13,2: PRINT "180 QB=999999999                                  'WERTZUWEISUNG"
  130. 188 LOCATE 14,2: PRINT "190 PRINT M,K,KS,G                                'AUSGABE DER WERTE"
  131. 189 LOCATE 15,2: PRINT "200 NEXT M                                        'SCHLEIFENENDE"
  132. 190 LOCATE 16,2: PRINT "210 END                                           'PROGRAMMENDE"
  133. 210 LOCATE 20,1: PRINT STRING$(79,205)
  134. 211 LOCATE 21,1: COLOR 0,15: PRINT SPACE$(79)
  135. 212 LOCATE 21,1: PRINT " ENDE DES TEILS   WIEDERHOLEN = W    BEENDEN = E    PROGRAMM-MENÜ LADEN = ESC ": COLOR 15,0
  136. 213 LOCATE 22,1: PRINT STRING$(79,205)
  137. 215 E$=INKEY$: IF E$="" THEN 215
  138. 216 IF E$=CHR$(27) THEN 19
  139. 217 IF E$="W" OR E$="w" THEN 100
  140. 218 IF E$="E" OR E$="e" THEN CLS: END
  141. 219 GOTO 215
  142. 500 PRINT STRING$(79,205)
  143. 501 COLOR 0,15
  144. 502 COLOR 0,15: PRINT "                            BELIEBIGE TASTE DRÜCKEN                            ": COLOR 15,0
  145. 503 PRINT STRING$(79,205): RETURN
  146.  
  147.