home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 3: Developer Tools / Linux Cubed Series 3 - Developer Tools.iso / devel / lang / ada / gnat-3.05- / gnat-3 / gnat-3.05-i486-linux-elf-bin / rts / a-except.adb < prev    next >
Encoding:
Text File  |  1996-06-07  |  9.5 KB  |  291 lines

  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT COMPILER COMPONENTS                         --
  4. --                                                                          --
  5. --                       A D A . E X C E P T I O N S                        --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.13 $                             --
  10. --                                                                          --
  11. --   Copyright (C) 1992,1993,1994,1995,1996 Free Software Foundation, Inc.  --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22. -- MA 02111-1307, USA.                                                      --
  23. --                                                                          --
  24. -- As a special exception,  if other files  instantiate  generics from this --
  25. -- unit, or you link  this unit with other files  to produce an executable, --
  26. -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27. -- covered  by the  GNU  General  Public  License.  This exception does not --
  28. -- however invalidate  any other reasons why  the executable file  might be --
  29. -- covered by the  GNU Public License.                                      --
  30. --                                                                          --
  31. -- GNAT was originally developed  by the GNAT team at  New York University. --
  32. -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33. --                                                                          --
  34. ------------------------------------------------------------------------------
  35.  
  36. with Ada.IO_Exceptions;         use Ada.IO_Exceptions;
  37. with Ada.IO_Exceptions;         use Ada.IO_Exceptions;
  38. with System.Task_Specific_Data; use System.Task_Specific_Data;
  39. with System.Exception_Table;    use System.Exception_Table;
  40. with Unchecked_Conversion;
  41.  
  42. package body Ada.Exceptions is
  43.  
  44.    procedure Internal_Raise (X : Exception_Id);
  45.    pragma Import (C, Internal_Raise, "__gnat_raise_with_msg");
  46.  
  47.    type Buffer_Ptr is access SSL.Exception_Message_Buffer;
  48.    --  A thin pointer to String
  49.  
  50.    function To_Buffer_Ptr is
  51.      new Unchecked_Conversion (System.Address, Buffer_Ptr);
  52.    --  Conversion from address to string access for exception msg manipulation
  53.  
  54.    --------------------
  55.    -- Exception_Name --
  56.    --------------------
  57.  
  58.    function Exception_Name (X : Exception_Id) return String is
  59.    begin
  60.       if X = Null_Id then
  61.          raise Constraint_Error;
  62.       end if;
  63.  
  64.       return X.Full_Name.all (1 .. X.Name_Length - 1);
  65.    end Exception_Name;
  66.  
  67.    ---------------------
  68.    -- Raise_Exception --
  69.    ---------------------
  70.  
  71.    procedure Raise_Exception
  72.      (E       : in Exception_Id;
  73.       Message : in String       := "")
  74.    is
  75.       Len : constant Natural :=
  76.               Natural'Min
  77.                 (Message'Length, SSL.Exception_Message_Buffer'Length);
  78.  
  79.       --  ??? implementation of variable-length messages:
  80.       --  if the message is bigger than the actual Exception_Message_Buffer
  81.       --  the actual buffer should be freed and a bigger buffer should be
  82.       --  reallocated (it means that the size of the actual buffer should
  83.       --  be recorder int the TSD)
  84.  
  85.    begin
  86.       if E = Null_Id then
  87.          null;
  88.  
  89.       else
  90.          Set_Message_Length (Len);
  91.          To_Buffer_Ptr (Get_Message_Addr).all (1 .. Len) :=
  92.            Message (Message'First .. Message'First + Len - 1);
  93.          Internal_Raise (E);
  94.       end if;
  95.    end Raise_Exception;
  96.  
  97.    -----------------------
  98.    -- Exception_Message --
  99.    -----------------------
  100.  
  101.    function  Exception_Message (X : Exception_Occurrence) return String is
  102.    begin
  103.       if X.Id = Null_Id then
  104.          raise Constraint_Error;
  105.       end if;
  106.  
  107.       return X.Msg (1 .. X.Msg_Length);
  108.    end Exception_Message;
  109.  
  110.    ------------------------
  111.    -- Reraise_Occurrence --
  112.    ------------------------
  113.  
  114.    procedure Reraise_Occurrence (X : Exception_Occurrence) is
  115.    begin
  116.       if X.Id = Null_Id then
  117.          return;
  118.  
  119.       else
  120.          Raise_Exception (X.Id, X.Msg (1 .. X.Msg_Length));
  121.       end if;
  122.    end Reraise_Occurrence;
  123.  
  124.    ------------------------
  125.    -- Exception_Identity --
  126.    ------------------------
  127.  
  128.    function Exception_Identity
  129.      (X    : Exception_Occurrence)
  130.       return Exception_Id
  131.    is
  132.    begin
  133.       if X.Id = Null_Id then
  134.          raise Constraint_Error;
  135.       end if;
  136.  
  137.       return X.Id;
  138.    end Exception_Identity;
  139.  
  140.    --------------------
  141.    -- Exception_Name --
  142.    --------------------
  143.  
  144.    function Exception_Name (X : Exception_Occurrence) return String is
  145.    begin
  146.       if X.Id = Null_Id then
  147.          raise Constraint_Error;
  148.       end if;
  149.  
  150.       return X.Id.Full_Name.all (1 .. X.Id.Name_Length - 1);
  151.    end Exception_Name;
  152.  
  153.    ---------------------------
  154.    -- Exception_Information --
  155.    ---------------------------
  156.  
  157.    function Exception_Information (X : Exception_Occurrence) return String is
  158.    begin
  159.       if X.Id = Null_Id then
  160.          raise Constraint_Error;
  161.       end if;
  162.  
  163.       return "";
  164.    end Exception_Information;
  165.  
  166.    ---------------------------------------
  167.    -- Exception_Occurrence_Access_Input --
  168.    ---------------------------------------
  169.  
  170.    function Exception_Occurrence_Access_Input
  171.      (Stream : access Ada.Streams.Root_Stream_Type'Class)
  172.       return   Exception_Occurrence_Access
  173.    is
  174.       Max  : Natural      := Natural'Input      (Stream);
  175.       Name : String       := String'Input       (Stream);
  176.       Len  : Natural      := Natural'Input      (Stream);
  177.       Msg  : String       := String'Input       (Stream);
  178.  
  179.       Item : Exception_Occurrence_Access := new Exception_Occurrence (Max);
  180.  
  181.    begin
  182.       Item.Id := Exception_Id (Internal_Exception (Name));
  183.  
  184.       if Msg'Length /= Len or else Len > Max then
  185.          raise Data_Error;
  186.       end if;
  187.  
  188.       Item.Msg_Length := Len;
  189.       Item.Msg        := Msg;
  190.  
  191.       return Item;
  192.  
  193.    end Exception_Occurrence_Access_Input;
  194.  
  195.    -------------------------------
  196.    -- Exception_Occurrence_Read --
  197.    -------------------------------
  198.  
  199.    procedure Exception_Occurrence_Read
  200.      (Stream : access Ada.Streams.Root_Stream_Type'Class;
  201.       Item   : out Exception_Occurrence)
  202.    is
  203.       Name : String       := String'Input       (Stream);
  204.       Len  : Natural      := Natural'Input      (Stream);
  205.       Msg  : String       := String'Input       (Stream);
  206.  
  207.    begin
  208.       Item.Id := Exception_Id (Internal_Exception (Name));
  209.  
  210.       if Msg'Length /= Len then
  211.          raise Data_Error;
  212.       end if;
  213.  
  214.       --  Silently truncate message if it does not fit
  215.  
  216.       Item.Msg_Length := Natural'Min (Len, Item.Max_Length);
  217.       Item.Msg (1 .. Item.Msg_Length) := Msg (1 .. Item.Msg_Length);
  218.    end Exception_Occurrence_Read;
  219.  
  220.    --------------------------------
  221.    -- Exception_Occurrence_Write --
  222.    --------------------------------
  223.  
  224.    procedure Exception_Occurrence_Write
  225.      (Stream : access Ada.Streams.Root_Stream_Type'Class;
  226.       Item   : in Exception_Occurrence)
  227.    is
  228.    begin
  229.       String'Output       (Stream, Exception_Name (Item.Id));
  230.       Natural'Output      (Stream, Item.Msg_Length);
  231.       String'Output       (Stream, Item.Msg (1 .. Item.Msg_Length));
  232.  
  233.    end Exception_Occurrence_Write;
  234.  
  235.    ---------------------
  236.    -- Save_Occurrence --
  237.    ---------------------
  238.  
  239.    procedure Save_Occurrence
  240.      (Target : out Exception_Occurrence;
  241.       Source : in  Exception_Occurrence)
  242.    is
  243.    begin
  244.       Target.Id := Source.Id;
  245.  
  246.       --  Case of truncation required
  247.  
  248.       if Target.Max_Length < Source.Msg_Length then
  249.          Target.Msg_Length := Target.Max_Length;
  250.          Target.Msg        := Source.Msg (1 .. Target.Max_Length);
  251.  
  252.       --  Case of no truncation required
  253.  
  254.       else
  255.          Target.Msg_Length := Source.Msg_Length;
  256.          Target.Msg (1 .. Target.Msg_Length) :=
  257.            Source.Msg (1 .. Target.Msg_Length);
  258.       end if;
  259.    end Save_Occurrence;
  260.  
  261.    function Save_Occurrence
  262.      (Source : in Exception_Occurrence)
  263.       return   Exception_Occurrence_Access
  264.    is
  265.       X : Exception_Occurrence_Access;
  266.  
  267.    begin
  268.       X := new Exception_Occurrence (Source.Msg_Length);
  269.  
  270.       X.Id         := Source.Id;
  271.       X.Msg_Length := Source.Msg_Length;
  272.       X.Msg        := Source.Msg;
  273.  
  274.       return X;
  275.    end Save_Occurrence;
  276.  
  277.    ------------------------------
  278.    -- Set_Exception_Occurrence --
  279.    ------------------------------
  280.  
  281.    procedure Set_Exception_Occurrence (Occ : Exception_Occurrence_Access) is
  282.       use System.Task_Specific_Data;
  283.  
  284.       Len : constant Natural := Get_Message_Length;
  285.  
  286.    begin
  287.       Occ.Msg_Length := Len;
  288.       Occ.Msg (1 .. Len) := To_Buffer_Ptr (Get_Message_Addr).all (1 .. Len);
  289.    end Set_Exception_Occurrence;
  290. end Ada.Exceptions;
  291.