home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 2: Applications / Linux Cubed Series 2 - Applications.iso / editors / emacs / xemacs / xemacs-1.006 / xemacs-1 / lib / xemacs-19.13 / lisp / packages / server.el < prev    next >
Encoding:
Text File  |  1995-08-15  |  15.8 KB  |  407 lines
  1. ;;; server.el --- Lisp code for GNU Emacs running as server process.
  2.  
  3. ;; Copyright (C) 1986, 1987, 1992, 1994, 1995 Free Software Foundation, Inc.
  4.  
  5. ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
  6. ;; Keywords: processes
  7.  
  8. ;; Changes by peck@sun.com and by rms.
  9.  
  10. ;; This file is part of XEmacs.
  11.  
  12. ;; XEmacs is free software; you can redistribute it and/or modify it
  13. ;; under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation; either version 2, or (at your option)
  15. ;; any later version.
  16.  
  17. ;; XEmacs is distributed in the hope that it will be useful, but
  18. ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20. ;; General Public License for more details.
  21.  
  22. ;; You should have received a copy of the GNU General Public License
  23. ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  24. ;; Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25.  
  26. ;;; Commentary:
  27.  
  28. ;;; This Lisp code is run in Emacs when it is to operate as
  29. ;;; a server for other processes.
  30.  
  31. ;;; Load this library and do M-x server-edit to enable Emacs as a server.
  32. ;;; Emacs runs the program ../etc/emacsserver as a subprocess
  33. ;;; for communication with clients.  If there are no client buffers to edit, 
  34. ;;; server-edit acts like (switch-to-buffer (other-buffer))
  35.  
  36. ;;; When some other program runs "the editor" to edit a file,
  37. ;;; "the editor" can be the Emacs client program ../etc/emacsclient.
  38. ;;; This program transmits the file names to Emacs through
  39. ;;; the server subprocess, and Emacs visits them and lets you edit them.
  40.  
  41. ;;; Note that any number of clients may dispatch files to emacs to be edited.
  42.  
  43. ;;; When you finish editing a Server buffer, again call server-edit
  44. ;;; to mark that buffer as done for the client and switch to the next 
  45. ;;; Server buffer.  When all the buffers for a client have been edited 
  46. ;;; and exited with server-edit, the client "editor" will return
  47. ;;; to the program that invoked it.  
  48.  
  49. ;;; Your editing commands and Emacs's display output go to and from
  50. ;;; the terminal in the usual way.  Thus, server operation is possible
  51. ;;; only when Emacs can talk to the terminal at the time you invoke
  52. ;;; the client.  This is possible in four cases:
  53.  
  54. ;;; 1. On a window system, where Emacs runs in one window and the
  55. ;;; program that wants to use "the editor" runs in another.
  56.  
  57. ;;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  58. ;;; program that wants to use "the editor" runs on another.
  59.  
  60. ;;; 3. When the program that wants to use "the editor" is running
  61. ;;; as a subprocess of Emacs.
  62.  
  63. ;;; 4. On a system with job control, when Emacs is suspended, the program
  64. ;;; that wants to use "the editor" will stop and display
  65. ;;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  66. ;;; brought into the foreground for editing.  When done editing, Emacs is
  67. ;;; suspended again, and the client program is brought into the foreground.
  68.  
  69. ;;; The buffer local variable "server-buffer-clients" lists 
  70. ;;; the clients who are waiting for this buffer to be edited.  
  71. ;;; The global variable "server-clients" lists all the waiting clients,
  72. ;;; and which files are yet to be edited for each.
  73.  
  74. ;;; Synched up with FSF 19.29.
  75.  
  76. ;;; Code:
  77.  
  78. (defvar server-program (expand-file-name "emacsserver" exec-directory)
  79.   "*The program to use as the edit server.")
  80.  
  81. (defvar server-visit-hook nil
  82.   "*List of hooks to call when visiting a file for the Emacs server.")
  83.  
  84. (defvar server-switch-hook nil
  85.   "*List of hooks to call when switching to a buffer for the Emacs server.")
  86.  
  87. (defvar server-done-hook nil
  88.   "*List of hooks to call when done editing a buffer for the Emacs server.")
  89.  
  90. (defvar server-process nil 
  91.   "the current server process")
  92.  
  93. (defvar server-previous-string "")
  94.  
  95. (defvar server-clients nil
  96.   "List of current server clients.
  97. Each element is (CLIENTID BUFFERS...) where CLIENTID is a string
  98. that can be given to the server process to identify a client.
  99. When a buffer is marked as \"done\", it is removed from this list.")
  100.  
  101. (defvar server-buffer-clients nil
  102.   "List of clientids for clients requesting editing of current buffer.")
  103. (make-variable-buffer-local 'server-buffer-clients)
  104. ;; Changing major modes should not erase this local.
  105. (put 'server-buffer-clients 'permanent-local t)
  106.  
  107. (defvar server-window nil
  108.   "*The window to use for selecting Emacs server buffers.
  109. If nil, use the selected window.
  110. If it is a frame, use the frame's selected window.")
  111.  
  112. (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
  113.   "*Regexp which should match filenames of temporary files
  114. which are deleted and reused after each edit
  115. by the programs that invoke the emacs server.")
  116.  
  117. (or (assq 'server-buffer-clients minor-mode-alist)
  118.     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
  119.  
  120. ;; If a *server* buffer exists,
  121. ;; write STRING to it for logging purposes.
  122. (defun server-log (string)
  123.   (if (get-buffer "*server*")
  124.       (save-excursion
  125.     (set-buffer "*server*")
  126.     (goto-char (point-max))
  127.     (insert string)
  128.     (or (bobp) (newline)))))
  129.  
  130. (defun server-sentinel (proc msg)
  131.   (cond ((eq (process-status proc) 'exit)
  132.      (server-log (message "Server subprocess exited")))
  133.     ((eq (process-status proc) 'signal)
  134.      (server-log (message "Server subprocess killed")))))
  135.  
  136. ;;;###autoload
  137. (defun server-start (&optional leave-dead)
  138.   "Allow this Emacs process to be a server for client processes.
  139. This starts a server communications subprocess through which
  140. client \"editors\" can send your editing commands to this Emacs job.
  141. To use the server, set up the program `emacsclient' in the
  142. Emacs distribution as your standard \"editor\".
  143.  
  144. Prefix arg means just kill any existing server communications subprocess."
  145.   (interactive "P")
  146.   ;; kill it dead!
  147.   (if server-process
  148.       (progn
  149.     (set-process-sentinel server-process nil)
  150.     (condition-case () (delete-process server-process) (error nil))))
  151.   (condition-case () (delete-file "~/.emacs_server") (error nil))
  152.   (condition-case ()
  153.       (delete-file (format "/tmp/esrv%d-%s" (user-uid) (system-name)))
  154.     (error nil))
  155.   ;; If we already had a server, clear out associated status.
  156.   (while server-clients
  157.     (let ((buffer (nth 1 (car server-clients))))
  158.       (server-buffer-done buffer)))
  159.   (if leave-dead
  160.       nil
  161.     (if server-process
  162.     (server-log (message "Restarting server")))
  163.     ;; Using a pty is wasteful, and the separate session causes
  164.     ;; annoyance sometimes (some systems kill idle sessions).
  165.     (let ((process-connection-type nil))
  166.       (setq server-process (start-process "server" nil server-program)))
  167.     (set-process-sentinel server-process 'server-sentinel)
  168.     (set-process-filter server-process 'server-process-filter)
  169.     (process-kill-without-query server-process)))
  170.  
  171. ;Process a request from the server to edit some files.
  172. ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
  173. (defun server-process-filter (proc string)
  174.   (server-log string)
  175.   (setq string (concat server-previous-string string))
  176.   ;; If the input is multiple lines,
  177.   ;; process each line individually.
  178.   (while (string-match "\n" string)
  179.     (let ((request (substring string 0 (match-beginning 0)))
  180.       client
  181.       (files nil)
  182.       (lineno 1))
  183.       ;; Remove this line from STRING.
  184.       (setq string (substring string (match-end 0)))      
  185.       (if (string-match "^Error: " request)
  186.       (message (concat "Server error: " (substring request (match-end 0))))
  187.     (if (string-match "^Client: " request)
  188.         (setq request (substring request (match-end 0))))
  189.     (setq client (list (substring request 0 (string-match " " request))))
  190.     (setq request (substring request (match-end 0)))
  191.     (while (string-match "[^ ]+ " request)
  192.       (let ((arg
  193.          (substring request (match-beginning 0) (1- (match-end 0)))))
  194.         (setq request (substring request (match-end 0)))
  195.         (if (string-match "\\`\\+[0-9]+\\'" arg)
  196.         (setq lineno (read (substring arg 1)))
  197.           (setq files
  198.             (cons (list arg lineno)
  199.               files))
  200.           (setq lineno 1))))
  201.     (server-visit-files files client)
  202.     ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
  203.     (setq server-clients (cons client server-clients))
  204.     (server-switch-buffer (nth 1 client))
  205.     (run-hooks 'server-switch-hook)
  206.     (message (substitute-command-keys
  207.           "When done with a buffer, type \\[server-edit]")))))
  208.   ;; Save for later any partial line that remains.
  209.   (setq server-previous-string string))
  210.  
  211. (defun server-visit-files (files client)
  212.   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
  213. FILES is an alist whose elements are (FILENAME LINENUMBER)."
  214.   (let (client-record (obuf (current-buffer)))
  215.     ;; Restore the current buffer afterward, but not using save-excursion,
  216.     ;; because we don't want to save point in this buffer
  217.     ;; if it happens to be one of those specified by the server.
  218.     (unwind-protect
  219.     (while files
  220.       ;; If there is an existing buffer modified or the file is modified,
  221.       ;; revert it.
  222.       ;; If there is an existing buffer with deleted file, offer to write it.
  223.       (let* ((filen (car (car files)))
  224.          (obuf (get-file-buffer filen)))
  225.         (if (and obuf (set-buffer obuf))
  226.         (if (file-exists-p filen)
  227.             (if (or (not (verify-visited-file-modtime obuf))
  228.                 (buffer-modified-p obuf))
  229.             (revert-buffer t nil))
  230.           (if (y-or-n-p
  231.                (concat "File no longer exists: "
  232.                    filen
  233.                    ", write buffer to file? "))
  234.               (write-file filen)))
  235.           (set-buffer (find-file-noselect filen))
  236.           (run-hooks 'server-visit-hook)))
  237.       (goto-line (nth 1 (car files)))
  238.       (setq server-buffer-clients (cons (car client) server-buffer-clients))
  239.       (setq client-record (cons (current-buffer) client-record))
  240.       (setq files (cdr files)))
  241.       (set-buffer obuf))
  242.     (nconc client client-record)))
  243.  
  244. (defun server-buffer-done (buffer)
  245.   "Mark BUFFER as \"done\" for its client(s).
  246. This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
  247. NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
  248. or nil.  KILLED is t if we killed BUFFER (because it was a temp file)."
  249.   (let ((running (eq (process-status server-process) 'run))
  250.     (next-buffer nil)
  251.     (killed nil)
  252.     (first t)
  253.     (old-clients server-clients))
  254.     (while old-clients
  255.       (let ((client (car old-clients)))
  256.     (or next-buffer 
  257.         (setq next-buffer (nth 1 (memq buffer client))))
  258.     (delq buffer client)
  259.     ;; Delete all dead buffers from CLIENT.
  260.     (let ((tail client))
  261.       (while tail
  262.         (and (bufferp (car tail))
  263.          (null (buffer-name (car tail)))
  264.          (delq (car tail) client))
  265.         (setq tail (cdr tail))))
  266.     ;; If client now has no pending buffers,
  267.     ;; tell it that it is done, and forget it entirely.
  268.     (if (cdr client) nil
  269.       (if running
  270.           (progn
  271.         ;; Don't send emacsserver two commands in close succession.
  272.         ;; It cannot handle that.
  273.         (or first (sit-for 1))
  274.         (setq first nil)
  275.         (process-send-string server-process 
  276.                      (format "Close: %s Done\n" (car client)))
  277.         (server-log (format "Close: %s Done\n" (car client)))))
  278.       (setq server-clients (delq client server-clients))))
  279.       (setq old-clients (cdr old-clients)))
  280.     (if (and (bufferp buffer) (buffer-name buffer))
  281.     (progn
  282.       (save-excursion
  283.         (set-buffer buffer)
  284.         (setq server-buffer-clients nil)
  285.         (run-hooks 'server-done-hook))
  286.       (if (server-temp-file-p buffer)
  287.           (progn (kill-buffer buffer)
  288.              (setq killed t))
  289.         (bury-buffer buffer))))
  290.     (list next-buffer killed)))
  291.  
  292. (defun server-temp-file-p (buffer)
  293.   "Return non-nil if BUFFER contains a file considered temporary.
  294. These are files whose names suggest they are repeatedly
  295. reused to pass information to another program.
  296.  
  297. The variable `server-temp-file-regexp' controls which filenames
  298. are considered temporary."
  299.   (and (buffer-file-name buffer)
  300.        (string-match server-temp-file-regexp (buffer-file-name buffer))))
  301.  
  302. (defun server-done ()
  303.   "Offer to save current buffer, mark it as \"done\" for clients.
  304. This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
  305. NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
  306. or nil.  KILLED is t if we killed the BUFFER (because it was a temp file)."
  307.   (let ((buffer (current-buffer)))
  308.     (if server-buffer-clients
  309.     (progn
  310.        (if (server-temp-file-p buffer)
  311.           ;; For a temp file, save, and do make a non-numeric backup
  312.           ;; (unless make-backup-files is nil).
  313.           (let ((version-control nil)
  314.             (buffer-backed-up nil))
  315.         (save-buffer))
  316.         (if (and (buffer-modified-p)
  317.              (y-or-n-p (concat "Save file " buffer-file-name "? ")))
  318.         (save-buffer buffer)))
  319.       (server-buffer-done buffer)))))
  320.  
  321. ;; Ask before killing a server buffer.
  322. ;; It was suggested to release its client instead,
  323. ;; but I think that is dangerous--the client would proceed
  324. ;; using whatever is on disk in that file. -- rms.
  325. (defun server-kill-buffer-query-function ()
  326.   (or (not server-buffer-clients)
  327.       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
  328.                (buffer-name (current-buffer))))))
  329.  
  330. (add-hook 'kill-buffer-query-functions
  331.        'server-kill-buffer-query-function)
  332.  
  333. (defun server-kill-emacs-query-function ()
  334.   (let (live-client
  335.     (tail server-clients))
  336.     ;; See if any clients have any buffers that are still alive.
  337.     (while tail
  338.       (if (memq t (mapcar 'stringp (mapcar 'buffer-name (cdr (car tail)))))
  339.       (setq live-client t))
  340.       (setq tail (cdr tail)))
  341.     (or (not live-client)
  342.     (yes-or-no-p "Server buffers still have clients; exit anyway? "))))
  343.  
  344. (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
  345.  
  346. (defun server-edit (&optional arg)
  347.   "Switch to next server editing buffer; say \"Done\" for current buffer.
  348. If a server buffer is current, it is marked \"done\" and optionally saved.
  349. When all of a client's buffers are marked as \"done\", the client is notified.
  350.  
  351. Temporary files such as MH <draft> files are always saved and backed up,
  352. no questions asked.  (The variable `make-backup-files', if nil, still
  353. inhibits a backup; you can set it locally in a particular buffer to
  354. prevent a backup for it.)  The variable `server-temp-file-regexp' controls
  355. which filenames are considered temporary.
  356.  
  357. If invoked with a prefix argument, or if there is no server process running, 
  358. starts server process and that is all.  Invoked by \\[server-edit]."
  359.   (interactive "P")
  360.   (if (or arg
  361.       (not server-process)
  362.       (memq (process-status server-process) '(signal exit)))
  363.       (server-start nil)
  364.     (apply 'server-switch-buffer (server-done))))
  365.  
  366. (defun server-switch-buffer (&optional next-buffer killed-one)
  367.   "Switch to another buffer, preferably one that has a client.
  368. Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
  369.   ;; KILLED-ONE is t in a recursive call
  370.   ;; if we have already killed one temp-file server buffer.
  371.   ;; This means we should avoid the final "switch to some other buffer"
  372.   ;; since we've already effectively done that.
  373.   (cond ((and (windowp server-window)
  374.           (window-live-p server-window))
  375.      (select-window server-window))
  376.     ((framep server-window)
  377.      (if (not (frame-live-p server-window))
  378.          (setq server-window (make-frame)))
  379.      (select-window (frame-selected-window server-window))))
  380.   (if (window-minibuffer-p (selected-window))
  381.       (select-window (next-window nil 'nomini 0)))
  382.   ;; Move to a non-dedicated window, if we have one.
  383.   (let ((last-window (previous-window nil 'nomini 0)))
  384.     (while (and (window-dedicated-p (selected-window))
  385.         (not (eq last-window (selected-window))))
  386.       (select-window (next-window nil 'nomini 0))))
  387.   (set-window-dedicated-p (selected-window) nil)
  388.   (if next-buffer
  389.       (if (and (bufferp next-buffer)
  390.            (buffer-name next-buffer))
  391.       (switch-to-buffer next-buffer)
  392.     ;; If NEXT-BUFFER is a dead buffer,
  393.     ;; remove the server records for it
  394.     ;; and try the next surviving server buffer.
  395.     (apply 'server-switch-buffer
  396.            (server-buffer-done next-buffer)))
  397.     (if server-clients
  398.     (server-switch-buffer (nth 1 (car server-clients)) killed-one)
  399.       (if (not killed-one)
  400.       (switch-to-buffer (other-buffer))))))
  401.  
  402. (global-set-key "\C-x#" 'server-edit)
  403.  
  404. (provide 'server)
  405.  
  406. ;;; server.el ends here
  407.