home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 2: Applications / Linux Cubed Series 2 - Applications.iso / editors / emacs / xemacs / xemacs-1.006 / xemacs-1 / lib / xemacs-19.13 / lisp / packages / avoid.el < prev    next >
Encoding:
Text File  |  1995-06-03  |  13.5 KB  |  349 lines
  1. ;;; avoid.el --- make mouse pointer stay out of the way of editing.
  2.  
  3. ;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Boris Goldowsky <boris@cs.rochester.edu>
  6. ;; Keywords: mouse
  7. ;; Version: 1.10
  8.  
  9. ;; This file is part of XEmacs.
  10.  
  11. ;; XEmacs is free software; you can redistribute it and/or modify it
  12. ;; under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; XEmacs is distributed in the hope that it will be useful, but
  17. ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19. ;; General Public License for more details.
  20.  
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  23. ;; Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24.  
  25. ;;; Commentary:
  26. ;;;
  27. ;;; For those who are annoyed by the mouse pointer obscuring text,
  28. ;;; this mode moves the mouse pointer - either just a little out of
  29. ;;; the way, or all the way to the corner of the frame. 
  30. ;;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31. ;;; To set up permanently, put this file on your load-path and put the
  32. ;;; following in your .emacs: 
  33. ;;;
  34. ;;; (cond (window-system
  35. ;;;        (require 'avoid)
  36. ;;;        (mouse-avoidance-mode 'animate)))
  37. ;;;
  38. ;;; The 'animate can be 'jump or 'banish or 'exile or 'protean if you prefer.
  39. ;;; See the documentation for function `mouse-avoidance-mode' for
  40. ;;; details of the different modes.
  41. ;;;
  42. ;;; For added silliness, make the animatee animate...
  43. ;;; put something similar to the following into your .emacs:
  44. ;;;
  45. ;;; (cond (window-system
  46. ;;;       (setq x-pointer-shape 
  47. ;;;         (eval (nth (random 4)
  48. ;;;            '(x-pointer-man x-pointer-spider
  49. ;;;              x-pointer-gobbler x-pointer-gumby))))
  50. ;;;       (set-mouse-color (cdr (assoc 'mouse-color (frame-parameters))))))
  51. ;;;
  52. ;;; For completely random pointer shape, replace the setq above with:
  53. ;;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  54. ;;; 
  55. ;;; Bugs / Warnings / To-Do:
  56. ;;;
  57. ;;; - Using this code does slow emacs down.  "banish" mode shouldn't
  58. ;;;   ever be too bad though, and on my workstation even "animate" doesn't
  59. ;;;   seem to have a noticable effect during editing.
  60. ;;;
  61. ;;; - It should find out where any overlapping frames are and avoid them,
  62. ;;;   rather than always raising the frame.
  63.  
  64. ;;; Credits:
  65. ;;; This code was helped by all those who contributed suggestions, 
  66. ;;;   fixes, and additions
  67. ;;; Joe Harrington (and his advisor), for the original inspiration.
  68. ;;; Ken Manheimer, for dreaming up the Protean mode.
  69. ;;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  70. ;;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  71. ;;; Simon Marshall, and M.S. Ashton, for their feedback.
  72. ;;;
  73. ;;; Code:
  74.  
  75. (provide 'avoid)
  76.  
  77. (defvar mouse-avoidance-mode nil
  78.   "Value is t or a symbol if the mouse pointer should avoid the cursor.
  79. See function `mouse-avoidance-mode' for possible values.  Changing this
  80. variable is NOT the recommended way to change modes; use that function 
  81. instead.")
  82.  
  83. (defvar mouse-avoidance-nudge-dist 15
  84.   "*Average distance that mouse will be moved when approached by cursor.
  85. Only applies in mouse-avoidance-mode `jump' and its derivatives.
  86. For best results make this larger than `mouse-avoidance-threshold'.")
  87.  
  88. (defvar mouse-avoidance-nudge-var 10
  89.   "*Variability of `mouse-avoidance-nudge-dist' (which see).")
  90.  
  91. (defvar mouse-avoidance-animation-delay .01
  92.   "Delay between animation steps, in seconds.")
  93.  
  94. (defvar mouse-avoidance-threshold 5
  95.   "*Mouse-pointer's flight distance.
  96. If the cursor gets closer than this, the mouse pointer will move away.
  97. Only applies in mouse-avoidance-modes `animate' and `jump'.")
  98.  
  99. ;; Internal variables
  100. (defvar mouse-avoidance-state nil)
  101. (defvar mouse-avoidance-pointer-shapes nil)
  102. (defvar mouse-avoidance-n-pointer-shapes 0)
  103.  
  104. ;;; Functions:
  105.  
  106. ;; XEmacs change -- this is so ugly.
  107. (defun mouse-avoidance-point-position ()
  108.   "Returns (WINDOW X . Y) of current point - analogous to mouse-position"
  109.   (let* ((beg (window-start))
  110.          (pos (point))
  111.          (col (current-column))
  112.          (row))
  113.     (setq row (count-lines beg pos))
  114.     (cons (selected-window) (cons col row))))
  115.  
  116. ;(defun mouse-avoidance-point-position-test ()
  117. ;  (interactive)
  118. ;  (message (format "point=%s mouse=%s" 
  119. ;           (cdr (mouse-avoidance-point-position))
  120. ;           (cdr (mouse-position)))))
  121.  
  122. (defun mouse-avoidance-set-mouse-position (pos)
  123.   ;; Carefully set mouse position to given position (X . Y)
  124.   ;; Ideally, should check if X,Y is in the current frame, and if not,
  125.   ;; leave the mouse where it was.  However, this is currently
  126.   ;; difficult to do, so we just raise the frame to avoid frame switches.
  127.   ;; Returns t if it moved the mouse.
  128.   (let ((f (selected-frame)))
  129.     (raise-frame f)
  130.     (set-mouse-position (frame-selected-window f) (car pos) (cdr pos))
  131.     t))
  132.       
  133. (defun mouse-avoidance-too-close-p (mouse)
  134.   ;;  Return t if mouse pointer and point cursor are too close.
  135.   ;; Acceptable distance is defined by mouse-avoidance-threshold.
  136.   (let ((point (mouse-avoidance-point-position)))
  137.     (and (eq (car mouse) (car point))
  138.      (car (cdr mouse))
  139.      (< (abs (- (car (cdr mouse)) (car (cdr point))))
  140.         mouse-avoidance-threshold)
  141.      (< (abs (- (cdr (cdr mouse)) (cdr (cdr point))))
  142.         mouse-avoidance-threshold))))
  143.  
  144. (defun mouse-avoidance-banish-destination ()
  145.   "The position to which mouse-avoidance-mode `banish' moves the mouse.
  146. You can redefine this if you want the mouse banished to a different corner."
  147.  (cons (1- (frame-width))
  148.        0))
  149.  
  150. (defun mouse-avoidance-banish-mouse ()
  151.   ;; Put the mouse pointer in the upper-right corner of the current frame.
  152.   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
  153.  
  154. (defsubst mouse-avoidance-delta (cur delta dist var min max)
  155.   ;; Decide how far to move in either dimension.
  156.   ;; Args are the CURRENT location, the desired DELTA for
  157.   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
  158.   ;; in distance allowed, and the MIN and MAX possible window positions.
  159.   ;; Returns something as close to DELTA as possible withing the constraints.
  160.   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
  161.     (R1                  (+ (- dist)    var ))
  162.     (L2                  (+    dist  (- var)))
  163.     (R2 (min (- max cur) (+    dist     var))))
  164.     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
  165.     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
  166.     (cond ((and L1 (< delta L1)) L1)
  167.       ((and R1 (< delta R1)) delta)
  168.       ((and R1 (< delta 0)) R1)
  169.       ((and L2 (< delta L2)) L2)
  170.       ((and R2 (< delta R2)) delta)
  171.       (R2)
  172.       ((or R1 L2))
  173.       (t 0))))
  174.  
  175. (defun mouse-avoidance-nudge-mouse () 
  176.   ;; Push the mouse a little way away, possibly animating the move
  177.   ;; For these modes, state keeps track of the total offset that we've
  178.   ;; accumulated, and tries to keep it close to zero.
  179.   (let* ((cur (mouse-position))
  180.      (cur-pos (cdr cur))
  181.      (deltax (mouse-avoidance-delta 
  182.           (car cur-pos) (- (random mouse-avoidance-nudge-var)
  183.                    (car mouse-avoidance-state))
  184.           mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
  185.           0 (frame-width)))
  186.      (deltay (mouse-avoidance-delta 
  187.           (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
  188.                    (cdr mouse-avoidance-state))
  189.           mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
  190.           0 (window-height))))
  191.     (setq mouse-avoidance-state
  192.       (cons (+ (car mouse-avoidance-state) deltax)
  193.         (+ (cdr mouse-avoidance-state) deltay)))
  194.     (if (or (eq mouse-avoidance-mode 'animate) 
  195.         (eq mouse-avoidance-mode 'proteus))
  196.     (let ((i 0.0)
  197.           (color (cdr (assoc 'mouse-color (frame-parameters)))))
  198.       (while (<= i 1)
  199.         (mouse-avoidance-set-mouse-position 
  200.          (cons (+ (car cur-pos) (round (* i deltax)))
  201.            (+ (cdr cur-pos) (round (* i deltay)))))
  202.             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
  203.         (if (eq mouse-avoidance-mode 'proteus)
  204.         (progn
  205.           (setq x-pointer-shape (mouse-avoidance-random-shape))
  206.           (set-mouse-color color)))
  207.         (sit-for mouse-avoidance-animation-delay)))
  208.       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
  209.                         (+ (cdr (cdr cur)) deltay))))))
  210.  
  211. (defun mouse-avoidance-random-shape ()
  212.   "Return a random cursor shape.
  213. This assumes that any variable whose name begins with x-pointer- and
  214. has an integer value is a valid cursor shape.  You might want to
  215. redefine this function to suit your own tastes."
  216.   (if (null mouse-avoidance-pointer-shapes)
  217.       (progn
  218.     (setq mouse-avoidance-pointer-shapes
  219.           (mapcar '(lambda (x) (symbol-value (intern x)))
  220.               (all-completions "x-pointer-" obarray
  221.                        '(lambda (x) 
  222.                       (and (boundp x)
  223.                            (integerp (symbol-value x)))))))
  224.     (setq mouse-avoidance-n-pointer-shapes 
  225.           (length mouse-avoidance-pointer-shapes))))
  226.   (nth (random mouse-avoidance-n-pointer-shapes)
  227.        mouse-avoidance-pointer-shapes))
  228.  
  229. (defun mouse-avoidance-banish-hook ()
  230.   (if (and (not executing-kbd-macro)    ; don't check inside macro
  231.        (mouse-avoidance-kbd-command (this-command-keys)))
  232.       (mouse-avoidance-banish-mouse)))
  233.  
  234. (defun mouse-avoidance-exile-hook ()
  235.   ;; For exile mode, the state is nil when the mouse is in its normal
  236.   ;; position, and set to the old mouse-position when the mouse is in exile.
  237.   (if (and (not executing-kbd-macro)
  238.        (mouse-avoidance-kbd-command (this-command-keys)))
  239.       (let ((mp (mouse-position)))
  240.     (cond ((and (not mouse-avoidance-state)
  241.             (mouse-avoidance-too-close-p mp))
  242.            (setq mouse-avoidance-state mp)
  243.            (mouse-avoidance-banish-mouse))
  244.           ((and mouse-avoidance-state
  245.             (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
  246.            (if (and (eq (car mp) (if (< emacs-minor-version 12)
  247.                      (selected-frame)
  248.                        (selected-window)))
  249.             (equal (cdr mp) (mouse-avoidance-banish-destination)))
  250.            (mouse-avoidance-set-mouse-position
  251.             ;; move back only if user has not moved mouse
  252.             (cdr mouse-avoidance-state)))
  253.            ;; but clear state anyway, to be ready for another move
  254.            (setq mouse-avoidance-state nil))))))
  255.  
  256. (defun mouse-avoidance-fancy-hook ()
  257.   ;; Used for the "fancy" modes, ie jump et al.
  258.   (if (and (not executing-kbd-macro)    ; don't check inside macro
  259.        (mouse-avoidance-kbd-command (this-command-keys))
  260.        (mouse-avoidance-too-close-p (mouse-position)))
  261.       (let ((old-pos (mouse-position)))
  262.     (mouse-avoidance-nudge-mouse)
  263.     (if (not (eq (if (< emacs-minor-version 12)
  264.              (selected-frame)
  265.                (selected-window)) (car old-pos))) ; move went awry
  266.         (set-mouse-position (car old-pos) ; sigh..
  267.                 (car (cdr old-pos))
  268.                 (cdr (cdr old-pos)))))))
  269.  
  270. (defun mouse-avoidance-kbd-command (key)
  271.   "Return t if the KEYSEQENCE is composed of keyboard events only.
  272. Return nil if there are any lists in the key sequence."
  273.   (cond ((null key) nil)        ; Null event seems to be
  274.                     ; returned occasionally.
  275.     ((not (vectorp key)) t)        ; Strings are keyboard events.
  276.     ((catch 'done
  277.        (let ((i 0)
  278.          (l (length key)))
  279.          (while (< i l)
  280.            (if (listp (aref key i))
  281.            (throw 'done nil))
  282.            (setq i (1+ i))))
  283.        t))))
  284.  
  285. (defun mouse-avoidance-mode (&optional mode)
  286.   "Set cursor avoidance mode to MODE.
  287. MODE should be one of the symbols `banish', `exile', `jump', `animate',
  288. `cat-and-mouse', `proteus', or `none'.
  289.  
  290. If MODE is nil, toggle mouse avoidance between `none` and `banish'
  291. modes.  Positive numbers and symbols other than the above are treated
  292. as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
  293.  
  294. Effects of the different modes: 
  295.  * banish: Move the mouse to the upper-right corner on any keypress.
  296.  * exile: Move the mouse to the corner only if the cursor gets too close,
  297.      and allow it to return once the cursor is out of the way.
  298.  * jump: If the cursor gets too close to the mouse, displace the mouse
  299.      a random distance & direction.
  300.  * animate: As `jump', but shows steps along the way for illusion of motion.
  301.  * cat-and-mouse: Same as `animate'.
  302.  * proteus: As `animate', but changes the shape of the mouse pointer too.
  303.  
  304. Whenever the mouse is moved, the frame is also raised.
  305.  
  306. \(see `mouse-avoidance-threshold' for definition of \"too close\",
  307. and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
  308. definition of \"random distance\".)"
  309.   (interactive
  310.    (list (intern (completing-read
  311.           "Select cursor avoidance technique (SPACE for list): "
  312.           '(("banish") ("exile") ("jump") ("animate")
  313.             ("cat-and-mouse") ("proteus") ("none"))
  314.           nil t))))
  315.   (if (eq mode 'cat-and-mouse)
  316.       (setq mode 'animate))
  317.   (setq post-command-hook
  318.     (delete 'mouse-avoidance-banish-hook (append post-command-hook nil)))
  319.   (setq post-command-hook
  320.     (delete 'mouse-avoidance-exile-hook (append post-command-hook nil)))
  321.   (setq post-command-hook
  322.     (delete 'mouse-avoidance-fancy-hook (append post-command-hook nil)))
  323.   (cond    ((eq mode 'none)
  324.      (setq mouse-avoidance-mode nil))
  325.     ((or (eq mode 'jump)
  326.          (eq mode 'animate)
  327.          (eq mode 'proteus))
  328.      (add-hook 'post-command-hook 'mouse-avoidance-fancy-hook)
  329.      (setq mouse-avoidance-mode mode
  330.            mouse-avoidance-state (cons 0 0)))
  331.     ((eq mode 'exile)
  332.      (add-hook 'post-command-hook 'mouse-avoidance-exile-hook)
  333.      (setq mouse-avoidance-mode mode
  334.            mouse-avoidance-state nil))
  335.     ((or (eq mode 'banish) 
  336.          (eq mode t)
  337.          (and (null mode) (null mouse-avoidance-mode))
  338.          (and mode (> (prefix-numeric-value mode) 0)))
  339.      (add-hook 'post-command-hook 'mouse-avoidance-banish-hook)
  340.      (setq mouse-avoidance-mode 'banish))
  341.     (t (setq mouse-avoidance-mode nil)))
  342.   (force-mode-line-update))
  343.  
  344. (or (assq 'mouse-avoidance-mode minor-mode-alist)
  345.     (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
  346.                  minor-mode-alist)))
  347.  
  348. ;;; End of avoid.el
  349.