home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 2: Applications / Linux Cubed Series 2 - Applications.iso / editors / emacs / xemacs / xemacs-1.006 / xemacs-1 / lib / xemacs-19.13 / lisp / modes / outline.el < prev    next >
Encoding:
Text File  |  1995-05-20  |  19.2 KB  |  553 lines
  1. ;;; outline.el --- outline mode commands for Emacs
  2.  
  3. ;; Copyright (C) 1986, 1993, 1994 Free Software Foundation, Inc.
  4. ;; Keywords: outlines
  5.  
  6. ;; Maintainer: Tim Bradshaw <tfb@ed.ac.uk>
  7.  
  8. ;; This file is part of XEmacs.
  9.  
  10. ;; XEmacs is free software; you can redistribute it and/or modify it
  11. ;; under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation; either version 2, or (at your option)
  13. ;; any later version.
  14.  
  15. ;; XEmacs is distributed in the hope that it will be useful, but
  16. ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18. ;; General Public License for more details.
  19.  
  20. ;; You should have received a copy of the GNU General Public License
  21. ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  22. ;; Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23.  
  24. ;;; Commentary:
  25.  
  26. ;; This package is a major mode for editing outline-format documents.
  27. ;; An outline can be `abstracted' to show headers at any given level,
  28. ;; with all stuff below hidden.  See the Emacs manual for details.
  29.  
  30. ;; This is taken from the FSF 19.23 outline.el and modified to work
  31. ;; with XEmacs 19.10+.  Changes are marked with a comment with
  32. ;; `#+XEmacs' in it. --tfb
  33.  
  34. ;;; Code:
  35.  
  36. ;; Jan '86, Some new features added by Peter Desnoyers and rewritten by RMS.
  37.   
  38. (defvar outline-regexp nil
  39.   "*Regular expression to match the beginning of a heading.
  40. Any line whose beginning matches this regexp is considered to start a heading.
  41. The recommended way to set this is with a Local Variables: list
  42. in the file it applies to.  See also outline-heading-end-regexp.")
  43.  
  44. ;; Can't initialize this in the defvar above -- some major modes have
  45. ;; already assigned a local value to it.
  46. (or (default-value 'outline-regexp)
  47.     (setq-default outline-regexp "[*\^L]+"))
  48.   
  49. (defvar outline-heading-end-regexp (purecopy "[\n\^M]")
  50.   "*Regular expression to match the end of a heading line.
  51. You can assume that point is at the beginning of a heading when this
  52. regexp is searched for.  The heading ends at the end of the match.
  53. The recommended way to set this is with a \"Local Variables:\" list
  54. in the file it applies to.")
  55.  
  56. (defvar outline-mode-map nil "")
  57.  
  58. (if outline-mode-map
  59.     nil
  60.   ;; #+XEmacs: this replaces some horrid nconcing in FSF
  61.   (setq outline-mode-map (make-sparse-keymap))
  62.   (set-keymap-name outline-mode-map 'outline-mode-map)
  63.   (set-keymap-parents outline-mode-map (list text-mode-map))
  64.   (define-key outline-mode-map "\C-c\C-n" 'outline-next-visible-heading)
  65.   (define-key outline-mode-map "\C-c\C-p" 'outline-previous-visible-heading)
  66.   (define-key outline-mode-map "\C-c\C-i" 'show-children)
  67.   (define-key outline-mode-map "\C-c\C-s" 'show-subtree)
  68.   (define-key outline-mode-map "\C-c\C-d" 'hide-subtree)
  69.   (define-key outline-mode-map "\C-c\C-u" 'outline-up-heading)
  70.   (define-key outline-mode-map "\C-c\C-f" 'outline-forward-same-level)
  71.   (define-key outline-mode-map "\C-c\C-b" 'outline-backward-same-level)
  72.   (define-key outline-mode-map "\C-c\C-t" 'hide-body)
  73.   (define-key outline-mode-map "\C-c\C-a" 'show-all)
  74.   (define-key outline-mode-map "\C-c\C-c" 'hide-entry)
  75.   (define-key outline-mode-map "\C-c\C-e" 'show-entry)
  76.   (define-key outline-mode-map "\C-c\C-l" 'hide-leaves)
  77.   (define-key outline-mode-map "\C-c\C-k" 'show-branches)
  78.   (define-key outline-mode-map "\C-c\C-q" 'hide-sublevels)
  79.   (define-key outline-mode-map "\C-c\C-o" 'hide-other))
  80.  
  81. ;;; #+XEmacs
  82. (defvar outline-mode-menu
  83.   ;; This is the RB menu which also makes 3 menus in the menubar (like
  84.   ;; FSF rather than because it's good)
  85.   '("Outline"
  86.     ("Headings"
  87.      ["Up" outline-up-heading t]
  88.      ["Next" outline-next-visible-heading t]
  89.      ["Previous" outline-previous-visible-heading t]
  90.      ["Next Same Level" outline-forward-same-level t]
  91.      ["Previous Same Level" outline-backward-same-level t])
  92.     ("Show"
  93.      ["Show All" show-all t]
  94.      ["Show Entry" show-entry t]
  95.      ["Show Branches" show-branches t]
  96.      ["Show Children" show-children t]
  97.      ["Show Subtree" show-subtree t])
  98.     ("Hide"
  99.      ["Hide Leaves" hide-leaves t]
  100.      ["Hide Body" hide-body t]
  101.      ["Hide Entry" hide-entry t]
  102.      ["Hide Subtree" hide-subtree t]
  103.      ["Hide Other" hide-other t]
  104.      ["Hide Sublevels" hide-sublevels t])))
  105.  
  106. ;;; #+XEmacs
  107. (defun outline-mode-menu ()
  108.   (interactive)
  109.   (popup-menu outline-mode-menu))
  110.   
  111. ;;; #+XEmacs
  112. ;;; ?? Is this OK & if so should it be in minor mode too?
  113. (define-key outline-mode-map [button3] 'outline-mode-menu)
  114.  
  115. ;;; #+XEmacs
  116. (defun outline-install-menubar (&optional remove)
  117.   ;; install or remove the outline menus
  118.   (let ((menus (cdr outline-mode-menu)) path)
  119.     (and (not remove)
  120.     (set-buffer-menubar (copy-sequence current-menubar)))
  121.     (while menus
  122.       (setq path (list (car (car menus))))
  123.       (if (and remove (find-menu-item current-menubar path))
  124.       (delete-menu-item path)
  125.     (or (car (find-menu-item current-menubar path))
  126.         (add-menu nil (car (car menus)) (cdr (car menus)) nil)))
  127.       (setq menus (cdr menus)))))
  128.  
  129. (defvar outline-minor-mode nil
  130.   "Non-nil if using Outline mode as a minor mode of some other mode.")
  131. (make-variable-buffer-local 'outline-minor-mode)
  132. (put 'outline-minor-mode 'permanent-local t)
  133. (or (assq 'outline-minor-mode minor-mode-alist)
  134.     (setq minor-mode-alist (append minor-mode-alist
  135.                    (list '(outline-minor-mode " Outl")))))
  136.  
  137. ;;;###autoload
  138. (defun outline-mode ()
  139.   "Set major mode for editing outlines with selective display.
  140. Headings are lines which start with asterisks: one for major headings,
  141. two for subheadings, etc.  Lines not starting with asterisks are body lines. 
  142.  
  143. Body text or subheadings under a heading can be made temporarily
  144. invisible, or visible again.  Invisible lines are attached to the end 
  145. of the heading, so they move with it, if the line is killed and yanked
  146. back.  A heading with text hidden under it is marked with an ellipsis (...).
  147.  
  148. Commands:\\<outline-mode-map>
  149. \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
  150. \\[outline-previous-visible-heading]   outline-previous-visible-heading
  151. \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
  152. \\[outline-backward-same-level]   outline-backward-same-level
  153. \\[outline-up-heading]   outline-up-heading            move from subheading to heading
  154.  
  155. \\[hide-body]    make all text invisible (not headings).
  156. \\[show-all]    make everything in buffer visible.
  157.  
  158. The remaining commands are used when point is on a heading line.
  159. They apply to some of the body or subheadings of that heading.
  160. \\[hide-subtree]   hide-subtree    make body and subheadings invisible.
  161. \\[show-subtree]   show-subtree    make body and subheadings visible.
  162. \\[show-children]   show-children    make direct subheadings visible.
  163.          No effect on body, or subheadings 2 or more levels down.
  164.          With arg N, affects subheadings N levels down.
  165. \\[hide-entry]       make immediately following body invisible.
  166. \\[show-entry]       make it visible.
  167. \\[hide-leaves]       make body under heading and under its subheadings invisible.
  168.              The subheadings remain visible.
  169. \\[show-branches]  make all subheadings at all levels visible.
  170.  
  171. The variable `outline-regexp' can be changed to control what is a heading.
  172. A line is a heading if `outline-regexp' matches something at the
  173. beginning of the line.  The longer the match, the deeper the level.
  174.  
  175. Turning on outline mode calls the value of `text-mode-hook' and then of
  176. `outline-mode-hook', if they are non-nil."
  177.   (interactive)
  178.   (kill-all-local-variables)
  179.   (setq selective-display t)
  180.   (use-local-map outline-mode-map)
  181.   (setq mode-name "Outline")
  182.   (setq major-mode 'outline-mode)
  183.   (define-abbrev-table 'text-mode-abbrev-table ())
  184.   (setq local-abbrev-table text-mode-abbrev-table)
  185.   (set-syntax-table text-mode-syntax-table)
  186.   (make-local-variable 'paragraph-start)
  187.   (setq paragraph-start (concat paragraph-start "\\|^\\("
  188.                 outline-regexp "\\)"))
  189.   ;; Inhibit auto-filling of header lines.
  190.   (make-local-variable 'auto-fill-inhibit-regexp)
  191.   (setq auto-fill-inhibit-regexp outline-regexp)
  192.   (make-local-variable 'paragraph-separate)
  193.   (setq paragraph-separate (concat paragraph-separate "\\|^\\("
  194.                    outline-regexp "\\)"))
  195.   ;; #+XEmacs
  196.   (outline-install-menubar)
  197.   (add-hook 'change-major-mode-hook 'show-all)
  198.   (run-hooks 'text-mode-hook 'outline-mode-hook))
  199.  
  200. (defvar outline-minor-mode-prefix "\C-c\C-o"
  201.   "*Prefix key to use for Outline commands in Outline minor mode.")
  202.  
  203. (defvar outline-minor-mode-map nil)
  204. (if outline-minor-mode-map
  205.     nil
  206.   (setq outline-minor-mode-map (make-sparse-keymap))
  207.   (define-key outline-minor-mode-map outline-minor-mode-prefix
  208.     (lookup-key outline-mode-map "\C-c")))
  209.  
  210. (or (assq 'outline-minor-mode minor-mode-map-alist)
  211.     (setq minor-mode-map-alist
  212.       (cons (cons 'outline-minor-mode outline-minor-mode-map)
  213.         minor-mode-map-alist)))
  214.  
  215. ;;;###autoload
  216. (defun outline-minor-mode (&optional arg)
  217.   "Toggle Outline minor mode.
  218. With arg, turn Outline minor mode on if arg is positive, off otherwise.
  219. See the command `outline-mode' for more information on this mode."
  220.   (interactive "P")
  221.   (setq outline-minor-mode
  222.     (if (null arg) (not outline-minor-mode)
  223.       (> (prefix-numeric-value arg) 0)))
  224.   (if outline-minor-mode
  225.       (progn
  226.     (setq selective-display t)
  227.     ;; #+XEmacs
  228.     (outline-install-menubar)
  229.     (run-hooks 'outline-minor-mode-hook))
  230.     (setq selective-display nil)
  231.     ;; When turning off outline mode, get rid of any ^M's.
  232.     (or outline-minor-mode
  233.     (outline-flag-region (point-min) (point-max) ?\n))
  234.     (set-buffer-modified-p (buffer-modified-p))
  235.     ;; #+XEmacs
  236.     (outline-install-menubar 'remove)))
  237.  
  238. (defvar outline-level 'outline-level
  239.   "Function of no args to compute a header's nesting level in an outline.
  240. It can assume point is at the beginning of a header line.")
  241.  
  242. ;; This used to count columns rather than characters, but that made ^L
  243. ;; appear to be at level 2 instead of 1.  Columns would be better for
  244. ;; tab handling, but the default regexp doesn't use tabs, and anyone
  245. ;; who changes the regexp can also redefine the outline-level variable
  246. ;; as appropriate.
  247. (defun outline-level ()
  248.   "Return the depth to which a statement is nested in the outline.
  249. Point must be at the beginning of a header line.  This is actually
  250. the column number of the end of what `outline-regexp' matches."
  251.   (save-excursion
  252.     (looking-at outline-regexp)
  253.     (- (match-end 0) (match-beginning 0))))
  254.  
  255. (defun outline-next-preface ()
  256.   "Skip forward to just before the next heading line."
  257.   (if (re-search-forward (concat "[\n\^M]\\(" outline-regexp "\\)")
  258.              nil 'move)
  259.       (progn
  260.       (goto-char (match-beginning 0))
  261.       (if (memq (preceding-char) '(?\n ?\^M))
  262.        (forward-char -1)))))
  263.  
  264. (defun outline-next-heading ()
  265.   "Move to the next (possibly invisible) heading line."
  266.   (interactive)
  267.   (if (re-search-forward (concat "[\n\^M]\\(" outline-regexp "\\)")
  268.              nil 'move)
  269.       (goto-char (1+ (match-beginning 0)))))
  270.  
  271. (defun outline-back-to-heading ()
  272.   "Move to previous heading line, or beg of this line if it's a heading.
  273. Only visible heading lines are considered."
  274.   (beginning-of-line)
  275.   (or (outline-on-heading-p)
  276.       (re-search-backward (concat "^\\(" outline-regexp "\\)") nil t)
  277.       (error "before first heading")))
  278.  
  279. (defun outline-on-heading-p ()
  280.   "Return t if point is on a (visible) heading line."
  281.   (save-excursion
  282.     (beginning-of-line)
  283.     (and (bolp)
  284.      (looking-at outline-regexp))))
  285.  
  286. (defun outline-end-of-heading ()
  287.   (if (re-search-forward outline-heading-end-regexp nil 'move)
  288.       (forward-char -1)))
  289.  
  290. (defun outline-next-visible-heading (arg)
  291.   "Move to the next visible heading line.
  292. With argument, repeats or can move backward if negative.
  293. A heading line is one that starts with a `*' (or that
  294. `outline-regexp' matches)."
  295.   (interactive "p")
  296.   (if (< arg 0)
  297.       (beginning-of-line)
  298.     (end-of-line))
  299.   (or (re-search-forward (concat "^\\(" outline-regexp "\\)") nil t arg)
  300.       (error ""))
  301.   (beginning-of-line))
  302.  
  303. (defun outline-previous-visible-heading (arg)
  304.   "Move to the previous heading line.
  305. With argument, repeats or can move forward if negative.
  306. A heading line is one that starts with a `*' (or that
  307. `outline-regexp' matches)."
  308.   (interactive "p")
  309.   (outline-next-visible-heading (- arg)))
  310.  
  311. (defun outline-flag-region (from to flag)
  312.   "Hides or shows lines from FROM to TO, according to FLAG.
  313. If FLAG is `\\n' (newline character) then text is shown,
  314. while if FLAG is `\\^M' (control-M) the text is hidden."
  315.   (let (buffer-read-only)
  316.     (subst-char-in-region from to
  317.               (if (= flag ?\n) ?\^M ?\n)
  318.               flag t)))
  319.  
  320. (defun hide-entry ()
  321.   "Hide the body directly following this heading."
  322.   (interactive)
  323.   (outline-back-to-heading)
  324.   (outline-end-of-heading)
  325.   (save-excursion
  326.    (outline-flag-region (point) (progn (outline-next-preface) (point)) ?\^M)))
  327.  
  328. (defun show-entry ()
  329.   "Show the body directly following this heading."
  330.   (interactive)
  331.   (save-excursion
  332.    (outline-flag-region (point) (progn (outline-next-preface) (point)) ?\n)))
  333.  
  334. (defun hide-body ()
  335.   "Hide all of buffer except headings."
  336.   (interactive)
  337.   (hide-region-body (point-min) (point-max)))
  338.  
  339. (defun hide-region-body (start end)
  340.   "Hide all body lines in the region, but not headings."
  341.   (save-excursion
  342.     (save-restriction
  343.       (narrow-to-region start end)
  344.       (goto-char (point-min))
  345.       (if (outline-on-heading-p)
  346.       (outline-end-of-heading))
  347.       (while (not (eobp))
  348.     (outline-flag-region (point)
  349.                  (progn (outline-next-preface) (point)) ?\^M)
  350.     (if (not (eobp))
  351.         (progn
  352.           (forward-char
  353.            (if (looking-at "[\n\^M][\n\^M]")
  354.            2 1))
  355.           (outline-end-of-heading)))))))
  356.  
  357. (defun show-all ()
  358.   "Show all of the text in the buffer."
  359.   (interactive)
  360.   (outline-flag-region (point-min) (point-max) ?\n))
  361.  
  362. (defun hide-subtree ()
  363.   "Hide everything after this heading at deeper levels."
  364.   (interactive)
  365.   (outline-flag-subtree ?\^M))
  366.  
  367. (defun hide-leaves ()
  368.   "Hide all body after this heading at deeper levels."
  369.   (interactive)
  370.   (outline-back-to-heading)
  371.   (outline-end-of-heading)
  372.   (hide-region-body (point) (progn (outline-end-of-subtree) (point))))
  373.  
  374. (defun show-subtree ()
  375.   "Show everything after this heading at deeper levels."
  376.   (interactive)
  377.   (outline-flag-subtree ?\n))
  378.  
  379. (defun hide-sublevels (levels)
  380.   "Hide everything but the top LEVELS levels of headers, in whole buffer."
  381.   (interactive "p")
  382.   (if (< levels 1)
  383.       (error "Must keep at least one level of headers"))
  384.   (setq levels (1- levels))
  385.   (save-excursion
  386.     (goto-char (point-min))
  387.     ;; Keep advancing to the next top-level heading.
  388.     (while (or (and (bobp) (outline-on-heading-p))
  389.            (outline-next-heading))
  390.       (let ((end (save-excursion (outline-end-of-subtree) (point))))
  391.     ;; Hide everything under that.
  392.     (outline-flag-region (point) end ?\^M)
  393.     ;; Show the first LEVELS levels under that.
  394.     (if (> levels 0)
  395.         (show-children levels))
  396.     ;; Move to the next, since we already found it.
  397.     (goto-char end)))))
  398.  
  399. (defun hide-other ()
  400.   "Hide everything except for the current body and the parent headings."
  401.   (interactive)
  402.   (hide-sublevels 1)
  403.   (let ((last (point)))
  404.     (while (save-excursion
  405.          (and (re-search-backward "[\n\r]" nil t)
  406.           (eq (following-char) ?\r)))
  407.       (save-excursion
  408.     (beginning-of-line)
  409.     (if (eq last (point))
  410.         (progn
  411.           (outline-next-heading)
  412.           (outline-flag-region last (point) ?\n))
  413.       (show-children)
  414.       (setq last (point)))))))
  415.  
  416. (defun outline-flag-subtree (flag)
  417.   (save-excursion
  418.     (outline-back-to-heading)
  419.     (outline-end-of-heading)
  420.     (outline-flag-region (point)
  421.               (progn (outline-end-of-subtree) (point))
  422.               flag)))
  423.  
  424. (defun outline-end-of-subtree ()
  425.   (outline-back-to-heading)
  426.   (let ((first t)
  427.     (level (funcall outline-level)))
  428.     (while (and (not (eobp))
  429.         (or first (> (funcall outline-level) level)))
  430.       (setq first nil)
  431.       (outline-next-heading))
  432.     (if (memq (preceding-char) '(?\n ?\^M))
  433.     (progn
  434.       ;; Go to end of line before heading
  435.       (forward-char -1)
  436.       (if (memq (preceding-char) '(?\n ?\^M))
  437.           ;; leave blank line before heading
  438.           (forward-char -1))))))
  439.  
  440. (defun show-branches ()
  441.   "Show all subheadings of this heading, but not their bodies."
  442.   (interactive)
  443.   (show-children 1000))
  444.  
  445. (defun show-children (&optional level)
  446.   "Show all direct subheadings of this heading.
  447. Prefix arg LEVEL is how many levels below the current level should be shown.
  448. Default is enough to cause the following heading to appear."
  449.   (interactive "P")
  450.   (setq level
  451.     (if level (prefix-numeric-value level)
  452.       (save-excursion
  453.         (outline-back-to-heading)
  454.         (let ((start-level (funcall outline-level)))
  455.           (outline-next-heading)
  456.           (if (eobp)
  457.           1
  458.         (max 1 (- (funcall outline-level) start-level)))))))
  459.   (save-excursion
  460.     (save-restriction
  461.       (outline-back-to-heading)
  462.       (setq level (+ level (funcall outline-level)))
  463.       (narrow-to-region (point)
  464.             (progn (outline-end-of-subtree)
  465.                    (if (eobp) (point-max) (1+ (point)))))
  466.       (goto-char (point-min))
  467.       (while (and (not (eobp))
  468.           (progn
  469.             (outline-next-heading)
  470.             (not (eobp))))
  471.     (if (<= (funcall outline-level) level)
  472.         (save-excursion
  473.           (outline-flag-region (save-excursion
  474.                      (forward-char -1)
  475.                      (if (memq (preceding-char) '(?\n ?\^M))
  476.                      (forward-char -1))
  477.                      (point))
  478.                    (progn (outline-end-of-heading) (point))
  479.                    ?\n)))))))
  480.  
  481. (defun outline-up-heading (arg)
  482.   "Move to the heading line of which the present line is a subheading.
  483. With argument, move up ARG levels."
  484.   (interactive "p")
  485.   (outline-back-to-heading)
  486.   (if (eq (funcall outline-level) 1)
  487.       (error ""))
  488.   (while (and (> (funcall outline-level) 1)
  489.           (> arg 0)
  490.           (not (bobp)))
  491.     (let ((present-level (funcall outline-level)))
  492.       (while (not (< (funcall outline-level) present-level))
  493.     (outline-previous-visible-heading 1))
  494.       (setq arg (- arg 1)))))
  495.  
  496. (defun outline-forward-same-level (arg)
  497.   "Move forward to the ARG'th subheading at same level as this one.
  498. Stop at the first and last subheadings of a superior heading."
  499.   (interactive "p")
  500.   (outline-back-to-heading)
  501.   (while (> arg 0)
  502.     (let ((point-to-move-to (save-excursion
  503.                   (outline-get-next-sibling))))  
  504.       (if point-to-move-to
  505.       (progn
  506.         (goto-char point-to-move-to)
  507.         (setq arg (1- arg)))
  508.     (progn
  509.       (setq arg 0)
  510.       (error ""))))))
  511.  
  512. (defun outline-get-next-sibling ()
  513.   "Move to next heading of the same level, and return point or nil if none."
  514.   (let ((level (funcall outline-level)))
  515.     (outline-next-visible-heading 1)
  516.     (while (and (> (funcall outline-level) level)
  517.         (not (eobp)))
  518.       (outline-next-visible-heading 1))
  519.     (if (< (funcall outline-level) level)
  520.     nil
  521.       (point))))
  522.     
  523. (defun outline-backward-same-level (arg)
  524.   "Move backward to the ARG'th subheading at same level as this one.
  525. Stop at the first and last subheadings of a superior heading."
  526.   (interactive "p")
  527.   (outline-back-to-heading)
  528.   (while (> arg 0)
  529.     (let ((point-to-move-to (save-excursion
  530.                   (outline-get-last-sibling))))
  531.       (if point-to-move-to
  532.       (progn
  533.         (goto-char point-to-move-to)
  534.         (setq arg (1- arg)))
  535.     (progn
  536.       (setq arg 0)
  537.       (error ""))))))
  538.  
  539. (defun outline-get-last-sibling ()
  540.   "Move to next heading of the same level, and return point or nil if none."
  541.   (let ((level (funcall outline-level)))
  542.     (outline-previous-visible-heading 1)
  543.     (while (and (> (funcall outline-level) level)
  544.         (not (bobp)))
  545.       (outline-previous-visible-heading 1))
  546.     (if (< (funcall outline-level) level)
  547.     nil
  548.         (point))))
  549.  
  550. (provide 'outline)
  551.  
  552. ;;; outline.el ends here
  553.