home *** CD-ROM | disk | FTP | other *** search
/ GEMini Atari / GEMini_Atari_CD-ROM_Walnut_Creek_December_1993.iso / zip / gnu / mntlib16.lzh / MNTLIB16 / BCOPY.S < prev    next >
Text File  |  1993-07-29  |  2KB  |  85 lines
  1. #APP
  2.  
  3. | void bcopy(void *src, void *dst, long cnt)
  4. |    handle overlap (both ways), odd/even alignment etc
  5. |    ++jrb    bammi@dsrgsun.ces.cwru.edu
  6. | 
  7.     .text
  8.     .even
  9.     .globl _bcopy
  10. _bcopy:
  11.     movl    sp@(4),a0    | src -> a0
  12.     movl    sp@(8),a1    | dst -> a1
  13.     movl    sp@(12),d0    | cnt -> d0
  14.     jle    return        | cnt <= 0
  15.     movl    d2,sp@-        | save d2
  16.  
  17.     | check overlap
  18.     movl    a0,d1        | (abs(src - dst)) < cnt =>  overlap
  19.     subl    a1,d1
  20.     jge    L1
  21.     negl    d1
  22. L1:    cmpl    d1,d0
  23.     jgt    overlap
  24.  
  25.     | check for odd src or dst
  26.     movw    a0,d1
  27.     movw    a1,d2
  28.     eorb    d1,d2
  29.     btst    #0,d2
  30.     jne    oddeven
  31.     btst    #0,d1
  32.     jeq    eveneven
  33.     movb    a0@+,a1@+    | odd  odd
  34.     subql    #1,d0        | now even even 
  35.  
  36. eveneven:            | may want long alignment for 020/030 etc
  37.     movl    d0,d1
  38.     andl    #0x1c,d1    | 4 bytes/copy  32 bytes max/iter
  39.     lsrl    #1,d1        | calc index into loop (each movl == 2bytes)
  40.     negl    d1        |  
  41.     addl    #18,d1        | 16 + 2 bytes for jmp ext word - d1 == index
  42.     jmp    pc@(0,d1)    |  dive into loop at appro spot
  43. loop1:
  44.     movl    a0@+,a1@+
  45.     movl    a0@+,a1@+
  46.     movl    a0@+,a1@+
  47.     movl    a0@+,a1@+
  48.  
  49.     movl    a0@+,a1@+
  50.     movl    a0@+,a1@+
  51.     movl    a0@+,a1@+
  52.     movl    a0@+,a1@+
  53.  
  54.     subl    #32,d0
  55.     jge    loop1
  56.  
  57.     btst    #1,d0
  58.     jeq    L4
  59.     movw    a0@+,a1@+    | residual word
  60. L4:    btst    #0,d0
  61.     jeq    ret
  62.     movb    a0@,a1@        | residual byte
  63.  
  64. ret:    movl    sp@+,d2
  65. return:    rts
  66.  
  67. oddeven:
  68. upcopy:                | byte-by-byte forward
  69.     subql    #1,d0
  70.     jlt    ret
  71.     movb    a0@+,a1@+
  72.     jra    upcopy
  73.  
  74. overlap:
  75.     cmpl    a0,a1
  76.     jmi    upcopy        | (src > dst) go do byte/byte forward copy
  77.     addl    d0,a0        | otherwise backwards copy
  78.     addl    d0,a1        | note we use predec so 1 is not sub from addr
  79.  
  80. downcopy:            | byte-by-byte backward
  81.     subql    #1,d0
  82.     jlt    ret
  83.     movb    a0@-,a1@-
  84.     jra    downcopy
  85.