Inventor Labs: Technology/INVENTORLABS_TECHNOLOGY.BIN/pc/files/invest.dir/00695_Script_HeatAndTemperature

Text File | 1997-05-26 | 34KB | 1,037 lines

-- Heat and Temperature Object Parent Script (oHeatTemp)


property pHeatCapacityList
property pBoilingPointList
property pVapoReactionList
property pTemp1
property pTemp2
property pFuel
property pInitialPositionX
property pInitialPositionY
property pLiquidStart
property pVessel1H
property pVessel1V
property pVessel2H
property pVessel2V
property pPad
property pVessel1
property pVessel2
property pMP3
property pVesselStart
property pBoilMovieStart
property pMixMovieStart

--mCalcMix
property pTestTemp1
property pTestTemp2
property pValue1
property pValue2
property pLiquid1

--mChangeTemp1
property pBoilingFlag1
property pNewTemp1

--mChangeTemp2
property pBoilingFlag2
property pNewTemp2

--mSetLiquid
property pNowMe
property pPosition

property pMixLiquidsButton
property pAlcoholContainer
property pWaterContainer
property pWaxContainer

property pBeaker1
property pBeaker2

property pStand1QT
property pStand2QT

property pStand1QTLoop
property pStand2QTLoop

property pStand1QTTarget
property pStand2QTTarget

property pStand1QTFlag
property pStand2QTFlag

property pStand1QTH
property pStand1QTV
property pStand2QTH
property pStand2QTV

property pMeltWaxFlag
property pFirstBoilFlag1
property pFirstBoilFlag2

property pFirstFlame
property pDraggableSprite -- the sprite that gets dragged when user selects a liquid

property pFlame1
property pFlame2
property pFlameCount
property pFlame1State -- #FIRE or #OUT
property pFlame2State -- #FIRE or #OUT
property pFlameMod
property pFlameDuration

property pMixCastList
property pFirstDigit
property pDigitSprite
property pDigitWidth
property pMixTemp
property pLogs1Dig
property pLogs2Dig
property pTemp1H
property pTemp1V
property pTemp2H
property pTemp2V
property pMixH
property pMixV
property pLog1H
property pLog1V
property pLog2H
property pLog2V

property pOldMiniBurner1
property pOldMiniBurner2
property pMixButtonSprite
property pMixButtonCast
-----------------------------
on mInit me

  cursor 4

  set pFirstFlame = the number of cast "IHTFIR1.PIC"
  set pFirstDigit = the number of cast "IHTNUM0.PIC"
  set pDigitSprite = 4 -- sprite channel
  set pDigitWidth = 8 -- pixels

  set pMixCastList = [#IHTALWT1: the number of cast "IHTALWT1.MOV", #IHTALWT2: the number of cast "IHTALWT2.MOV", #IHTALWT3: the number of cast "IHTALWT3.MOV", #IHTALWT4: the number of cast "IHTALWT4.MOV", #IHTALWX1: the number of cast "IHTALWX1.MOV", #IHTALWX2: the number of cast "IHTALWX2.MOV", #IHTALWX3: the number of cast "IHTALWX3.MOV", #IHTALWX4: the number of cast "IHTALWX4.MOV", #IHTWXWT1: the number of cast "IHTWXWT1.MOV", #IHTWXWT2: the number of cast "IHTWXWT2.MOV", #IHTWXWT3: the number of cast "IHTWXWT3.MOV", #IHTWXWT4: the number of cast "IHTWXWT4.MOV", #IHTMEAL1: the number of cast "IHTMEAL1.MOV", #IHTMEAL2: the number of cast "IHTMEAL2.MOV", #IHTMEAL3: the number of cast "IHTMEAL3.MOV", #IHTMEAL4: the number of cast "IHTMEAL4.MOV", #IHTMEWT1: the number of cast "IHTMEWT1.MOV", #IHTMEWT2: the number of cast "IHTMEWT2.MOV", #IHTMEWT3: the number of cast "IHTMEWT3.MOV", #IHTMEWT4: the number of cast "IHTMEWT4.MOV", #IHTMEWX1: the number of cast "IHTMEWX1.MOV", #IHTMEWX2: the number of cast "IHTMEWX2.MOV", #IHTMEWX3: the number of cast "IHTMEWX3.MOV", #IHTMEWX4: the number of cast "IHTMEWX4.MOV"]

  set pMixButtonSprite = 8
  set pMixButtonCast = the number of cast "MixButton.Op state"
  set pBeaker1 = 13
  set pBeaker2 = 14
  set pStand1QT = 5
  set pStand2QT = 6
  set pFlame1 = 23
  set pFlame2 = 24

  -- establish lists init
  set pHeatCapacityList = [.95,1.,.8,.445]
  set pBoilingPointList = [78.,100.,324.,1000.]
  set pVapoReactionList = [153.,414.,40.,1000.]

  -- set melting point (for wax only) init
  set pMP3 = 56

  -- set initial values for vessels (value indicates which liquid it contains)
  set pVessel1 = 0
  set pVessel2 = 0

  -- set the amount of pFuel added per click
  set pFuel = 10

  -- set the sprite location of the top liquid container
  set pLiquidStart = 17

  -- set castnum of first vessel pict
  set pVesselStart = the number of cast "alcohol.pict"

  -- set number of first boiling movie
  set pBoilMovieStart = the number of cast "IHTALBL.MOV"

  -- set number of first mix movie
  set pMixMovieStart = the number of cast "IHTALWT1.MOV"

  -- set up lists for initial positions of liquid containers
  set pInitialPositionX = [4]
  set pInitialPositionY = [4]

  -- set positions of vessels
  set pVessel1H = 255
  set pVessel1V = 224
  set pVessel2H = 558
  set pVessel2V = 224

  -- set the tolerance for locating a container on the burner
  set pPad = 40

  -- set fire parameters
  set pFlameMod = 1
  set pFlame1State = #OUT
  set pFlame2State = #OUT
  set pFlameDuration = 15 -- @15fps = 1 second

  set pDraggableSprite = 21
  set pMixTemp = 0
  set pLogs1Dig = 0
  set pLogs2Dig = 0

  return me

end mInit
-----------------------------
on mActivate me

  -- set puppetSprites
  puppetSprite pMixLiquidsButton,true
  puppetSprite pAlcoholContainer,true
  puppetSprite pWaterContainer,true
  puppetSprite pMercuryContainer,true
  puppetSprite pWaxContainer,true
  puppetSprite pFlame1,true
  puppetSprite pFlame2,true

  set pMeltWaxFlag = #NOMELT
  set pFirstBoilFlag1 = #DONTBOIL
  set pFirstBoilFlag2 = #DONTBOIL

  -- get QT locations for burner stands
  set pStand1QTH = the locH of sprite 5 -- pStand1QT
  set pStand1QTV = the locV of sprite 5 -- pStand1QT
  set pStand2QTH = the locH of sprite 6 -- pStand2QT
  set pStand2QTV = the locV of sprite 6 -- pStand2QT

  set pStand1QTFlag = #OFF
  set pStand2QTFlag = #OFF

  set the puppet of sprite pStand1QT = 1
  set the puppet of sprite pStand2QT = 1

  -- now move the QTs out of the way
  set the loc of sprite pStand1QT = point(-100, -100)
  set the loc of sprite pStand2QT = point(-100, -100)

  -- turn off flames
  set the visible of sprite pFlame1 to false
  set the visible of sprite pFlame2 to false

  -- set initial temps of vessels
  set pTemp1 = 35
  set pTemp2 = 35

  -- constrain draggable sprite
  set the constraint of sprite pDraggableSprite = 3

  -- set initial positions of liquid containers
  repeat with x = pLiquidStart to pLiquidStart+3
    setAt(pInitialPositionX,x-16,the loch of sprite x)
    setAt(pInitialPositionY,x-16,the locv of sprite x)
  end repeat

  set pTemp1H = the locH of sprite 7
  set pTemp1V = the locV of sprite 7

  set pTemp2H = the locH of sprite 8
  set pTemp2V = the locV of sprite 8

  set pMixH = the locH of sprite 9
  set pMixV = the locV of sprite 9

  set pLog1H = the locH of sprite 10
  set pLog1V = the locV of sprite 10

  set pLog2H = the locH of sprite 11
  set pLog2V = the locV of sprite 11

  cursor -1

end mActivate
-----------------------------
on mClose me
  puppetSprite pMixLiquidsButton,false
  puppetSprite pAlcoholContainer,false
  puppetSprite pWaterContainer,false
  puppetSprite pMercuryContainer,false
  puppetSprite pWaxContainer,false
  puppetSprite pFlame1,false
  puppetSprite pFlame2,false
  set the visible of sprite pMixLiquidsButton to true
  set the visible of sprite pFlame1 to true
  set the visible of sprite pFlame2 to true

  --tj&dl
  repeat with n = 2 to 20
    set the puppet of sprite n = 0
    set the visible of sprite n = 1
  end repeat

  set the constraint of sprite pDraggableSprite = 0
  puppetsprite 33,  false
end mClose
-----------------------------
on mDisplayDigits me
  -- pTemp1Dig, pTemp2Dig, pMixTempDig, pLogs1Dig, pLogs2Dig
  set pTemp1Dig = integer(pTemp1)
  set pTemp2Dig = integer(pTemp2)
  set pMixTempDig = integer(pMixTemp)

  set the trails of sprite pDigitSprite = 1

  if not(sprite pDraggableSprite intersects 7) then
    -- display pTemp1Dig
    set TheNumber = pTemp1Dig
    if TheNumber > 999 then set TheNumber = 999
    set Hundreds = TheNumber/100
    set TheNumber = TheNumber mod 100
    set Tens = TheNumber/10
    set TheNumber = TheNumber mod 10
    set Ones = TheNumber

    repeat while TRUE
      set the castNum of sprite pDigitSprite = pFirstDigit + Hundreds
      set the locH of sprite pDigitSprite = pTemp1H
      set the locV of sprite pDigitSprite = pTemp1V
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Tens
      set the locH of sprite pDigitSprite = pTemp1H + pDigitWidth
      set the locV of sprite pDigitSprite = pTemp1V
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Ones
      set the locH of sprite pDigitSprite = pTemp1H + (pDigitWidth * 2)
      set the locV of sprite pDigitSprite = pTemp1V
      updateStage
      exit repeat
    end repeat
  end if

  -- display pTemp2Dig
  if not(sprite pDraggableSprite intersects 9) then
    set TheNumber = pTemp2Dig
    if TheNumber > 999 then set TheNumber = 999
    set Hundreds = TheNumber/100
    set TheNumber = TheNumber mod 100
    set Tens = TheNumber/10
    set TheNumber = TheNumber mod 10
    set Ones = TheNumber

    repeat while TRUE
      set the castNum of sprite pDigitSprite = pFirstDigit + Hundreds
      set the locH of sprite pDigitSprite = pTemp2H
      set the locV of sprite pDigitSprite = pTemp2V
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Tens
      set the locH of sprite pDigitSprite = pTemp2H + pDigitWidth
      set the locV of sprite pDigitSprite = pTemp2V
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Ones
      set the locH of sprite pDigitSprite = pTemp2H + (pDigitWidth * 2)
      set the locV of sprite pDigitSprite = pTemp2V
      updateStage
      exit repeat
    end repeat
  end if

  -- display pMixTempDig
  if not(sprite pDraggableSprite intersects 12) then
    set TheNumber = pMixTempDig
    if TheNumber > 999 then set TheNumber = 999
    set Hundreds = TheNumber/100
    set TheNumber = TheNumber mod 100
    set Tens = TheNumber/10
    set TheNumber = TheNumber mod 10
    set Ones = TheNumber

    repeat while TRUE
      set the castNum of sprite pDigitSprite = pFirstDigit + Hundreds
      set the locH of sprite pDigitSprite = pMixH
      set the locV of sprite pDigitSprite = pMixV
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Tens
      set the locH of sprite pDigitSprite = pMixH + pDigitWidth
      set the locV of sprite pDigitSprite = pMixV
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Ones
      set the locH of sprite pDigitSprite = pMixH + (pDigitWidth * 2)
      set the locV of sprite pDigitSprite = pMixV
      updateStage
      exit repeat
    end repeat
  end if

  -- display pLogs1Dig
  if not(sprite pDraggableSprite intersects 16) then
    set TheNumber = pLogs1Dig
    if TheNumber > 99 then set TheNumber = 99
    set Tens = TheNumber/10
    set TheNumber = TheNumber mod 10
    set Ones = TheNumber

    repeat while TRUE
      set the castNum of sprite pDigitSprite = pFirstDigit + Tens
      set the locH of sprite pDigitSprite = pLog1H
      set the locV of sprite pDigitSprite = pLog1V
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Ones
      set the locH of sprite pDigitSprite = pLog1H + pDigitWidth
      set the locV of sprite pDigitSprite = pLog1V
      updateStage
      exit repeat
    end repeat
  end if

  -- display pLogs2Dig
  if not(sprite pDraggableSprite intersects 22) then
    set TheNumber = pLogs2Dig
    if TheNumber > 99 then set TheNumber = 99
    set Tens = TheNumber/10
    set TheNumber = TheNumber mod 10
    set Ones = TheNumber

    repeat while TRUE
      set the castNum of sprite pDigitSprite = pFirstDigit + Tens
      set the locH of sprite pDigitSprite = pLog2H
      set the locV of sprite pDigitSprite = pLog2V
      updateStage
      set the castNum of sprite pDigitSprite = pFirstDigit + Ones
      set the locH of sprite pDigitSprite = pLog2H + pDigitWidth
      set the locV of sprite pDigitSprite = pLog2V
      updateStage
      exit repeat
    end repeat
  end if
end mDisplayDigits
-----------------------------
on mGenericDisplay me, TheNumber, H, V
  set the trails of sprite pDigitSprite = 1
  if TheNumber > 999 then set TheNumber = 999
  set Hundreds = TheNumber/100
  set TheNumber = TheNumber mod 100
  set Tens = TheNumber/10
  set TheNumber = TheNumber mod 10
  set Ones = TheNumber
  repeat while TRUE
    set the castNum of sprite pDigitSprite = pFirstDigit + Hundreds
    set the locH of sprite pDigitSprite = H
    set the locV of sprite pDigitSprite = V
    updateStage
    set the castNum of sprite pDigitSprite = pFirstDigit + Tens
    set the locH of sprite pDigitSprite = H + pDigitWidth
    set the locV of sprite pDigitSprite = V
    updateStage
    set the castNum of sprite pDigitSprite = pFirstDigit + Ones
    set the locH of sprite pDigitSprite = H + (pDigitWidth * 2)
    set the locV of sprite pDigitSprite = V
    updateStage
    exit repeat
  end repeat
end mGenericDisplay
-----------------------------
on mMixButtonClicked me
  if pVessel1 <> 0 and pVessel2 <> 0 then
    if pVessel1 = 3 then
      if pFirstBoilFlag1 = #GARBAGE or pFirstBoilFlag1 = #ALREADYBOILING then
        set the puppet of sprite pMixButtonSprite = 1
        set the castNum of sprite pMixButtonSprite = (pMixButtonCast + 1)
        mCalcMix me
      end if
    else if pVessel2 = 3 then
      if pFirstBoilFlag2 = #GARBAGE or pFirstBoilFlag2 = #ALREADYBOILING then
        set the puppet of sprite pMixButtonSprite = 1
        set the castNum of sprite pMixButtonSprite = (pMixButtonCast + 1)
        mCalcMix me
      end if
    else
      set the puppet of sprite pMixButtonSprite = 1
      set the castNum of sprite pMixButtonSprite = (pMixButtonCast + 1)
      mCalcMix me
    end if
  end if
end mMixButtonClicked
-----------------------------
on mPassClickOn me, ClickedItem
  set pNowMe = ClickedItem
end
-----------------------------
on mCheckForQTDone me
  if pStand1QTFlag = #ON then
    if the movieTime of sprite pStand1QT >= pStand1QTTarget then
      set pStand1QTFlag = #OFF
      set the movieRate of sprite pStand1QT = 0
      set the movieTime of sprite pStand1QT = pStand1QTTarget -- pStand1QTLoop
    end if
  end if
  if pStand2QTFlag = #ON then
    if the movieTime of sprite pStand2QT >= pStand2QTTarget then
      set pStand2QTFlag = #OFF
      set the movieRate of sprite pStand2QT = 0
      set the movieTime of sprite pStand2QT = pStand2QTTarget -- pStand2QTLoop
    end if
  end if
end
-----------------------------
on mTurnOffQTStand me
  if pStand1QTFlag = #ON then
    set the movieRate of sprite pStand1QT = 0
    set pStand1QTFlag = #OFF
  end if
  if pStand2QTFlag = #ON then
    set the movieRate of sprite pStand2QT = 0
    set pStand2QTFlag = #OFF
  end if
end
-----------------------------
on mCalcMix me
  -- determine values for model based on which liquid is in which vessel
  mDetermineValues me

  set BP1 = getAt(pBoilingPointList,pValue1)
  set BP2 = getAt(pBoilingPointList,pValue2)
  set HCP1 = getAt(pHeatCapacityList,pValue1)
  set HCP2 = getAt(pHeatCapacityList,pValue2)
  set VAP1 = getAt(pVapoReactionList,pValue1)

  -- determine the delta energy change for each vessel from current state to boiling point of
  -- liquid in vessel 1. If there is more heat in vessel 2, then liquid in vessel 1 will boil
  -- when mixed

  set deltaH1 = (BP1-pTestTemp1)*HCP1
  set deltaH2 = (pTestTemp2-BP1)*HCP2

  -- if there is not enough energy in vessel 2 to make the liquid in vessel 1 boil, then
  -- calculate the mix temp from the vessel temperatures

  if deltaH2 < deltaH1 then
    set tempMix = (pTestTemp2*HCP2+pTestTemp1*HCP1)/(HCP1+HCP2)
    set pLiquid1 = 1
    set vapor1 = 0
  else

    -- if there is excess heat in liquid 2, then determine the amount of boiling

    if deltaH2 < VAP1+deltaH1 then

      -- if there is not enough excess heat in liquid 2 to boil off all of liquid 1,
      -- then calculate the fraction of liquid 1 left

      set tempMix = BP1
      set Vapor1 = ((pTestTemp1-tempMix)*HCP1+(pTestTemp2-tempMix)*HCP2)/VAP1
      set pLiquid1 = 1-Vapor1
    else

      -- if there is enough excess heat in liquid 2 to boil off liquid 1, then
      -- calculate temperature of liquid 2 that remains

      set Vapor1 = 1
      set pLiquid1 = 0
      set tempMix = (HCP2*pTestTemp2+HCP1*pTestTemp1-VAP1)/(HCP1+HCP2)
    end if
  end if

  set pMixTemp = integer(tempMix)

  mDisplayDigits me

  set the puppet of sprite pStand1QT to 0
  set the puppet of sprite pStand2QT to 0
  set the puppet of sprite pBeaker1 to 0
  set the puppet of sprite pBeaker2 to 0
  set the puppet of sprite pFlame1 to 0
  set the puppet of sprite pFlame2 to 0
  set the visible of sprite pFlame1 to 0
  set the visible of sprite pFlame2 to 0

  go frame "HT_MIXLIQUIDS"

end mCalcMix
-----------------------------------
on mChangeTemp1 me
  -- check to see if vessel 1 has liquid
  if pVessel1 = 0 then
  else

    -- mReset boiling flag
    set pBoilingFlag1 = 0

    -- increment number of logs
    set pLogs1Dig = pLogs1Dig + 1

    -- if temperature is less than boiling point, increase temperature
    if pTemp1 < getAt(pBoilingPointList,pVessel1) then
      set pNewTemp1 = pTemp1 + pFuel/getAt(pHeatCapacityList,pVessel1)
      repeat with TheNumber = integer(pTemp1) to integer(pNewTemp1)
        mGenericDisplay me, TheNumber, pTemp1H, pTemp1V
      end repeat
    end if

    -- if vessel 1 contains wax and temp is just below melting point
    -- then don't increase temperature on this round and play melting animation

    if pVessel1 = 3 then -- wax
      if pTemp1 > pMP3-pFuel and pTemp1 < pMP3 then -- wax is melting
        set pNewTemp1 = pMP3
        set pMeltWaxFlag = #MELTWAX -- play melting animation
      end if
    else -- not wax, so wax can't melt
      set pMeltWaxFlag = #NOMELT
    end if

    if pNewTemp1 > getAt(pBoilingPointList,pVessel1) then
      set pNewTemp1 = getAt(pBoilingPointList,pVessel1)
      set pBoilingFlag1 = 1
    end if

    mDoLiquidAnimation1 me

    set pTemp1 = pNewTemp1

  end if

end mChangeTemp1
-----------------------------------
on mChangeTemp2 me
  -- check to see if pVessel2 has a liquid
  if pVessel2 = 0 then
  else

    -- mReset boiling flag
    set pBoilingFlag2 = 0

    -- increment number of logs
    set pLogs2Dig = pLogs2Dig + 1

    if pTemp2 < getAt(pBoilingPointList,pVessel2) then
      set pNewTemp2 = pTemp2 + pFuel/getAt(pHeatCapacityList,pVessel2)
      repeat with TheNumber = integer(pTemp2) to integer(pNewTemp2)
        mGenericDisplay me, TheNumber, pTemp2H, pTemp2V
      end repeat
    end if

    -- if vessel 2 contains wax and temp is just below melting point
    -- then don't increase temperature on this round and play melting animation

    if pVessel2 = 3 then -- wax
      if pTemp2 > pMP3 and pTemp2 < pMP3+pFuel/(getAt(pHeatCapacityList,pVessel2)) then
        set pNewTemp2 = pMP3
        set pMeltWaxFlag = #MELTWAX -- play melting animation
      end if
    else -- not wax, so wax can't melt
      set pMeltWaxFlag = #NOMELT
    end if

    if pNewTemp2 > getAt(pBoilingPointList,pVessel2) then
      set pNewTemp2 = getAt(pBoilingPointList,pVessel2)
      set pBoilingFlag2 = 1
    end if

    mDoLiquidAnimation2 me

    set pTemp2 = pNewTemp2

  end if
end mChangeTemp2
-----------------------------------
on mReset me
  repeat with x = 2 to 24
    puppetSprite x,false
  end repeat

  set the visible of sprite pOldMiniBurner1 = 1
  set the visible of sprite pOldMiniBurner2 = 1
  set the visible of sprite pFlame1 = 0
  set the visible of sprite pFlame2 = 0

  set pMeltWaxFlag = #NOMELT
  set pFirstBoilFlag1 = #DONTBOIL
  set pFirstBoilFlag2 = #DONTBOIL

  set pTemp1 = 35
  set pTemp2 = 35
  set pMixTemp = 0
  set pVessel1 = 0
  set pVessel2 = 0
  set pLogs1Dig = 0
  set pLogs2Dig = 0

  set the visible of sprite pMixLiquidsButton to true

  go to frame "HT_Main"

end mReset

-----------------------------------

on mDetermineValues me
  -- this handler set the values for the mixCalc handler based on the
  -- liquids in the vessels. this is necessary because the mixCalc
  -- handler needs to know which liquid is in which vessel. The liquid with
  -- the lower boiling point (the lowest number) is placed in pPosition 1 (pValue1)

  if pVessel1 <= pVessel2 then
    set pValue1 = pVessel1
    set pValue2 = pVessel2
    set pTestTemp1 = pTemp1
    set pTestTemp2 = pTemp2
  else
    set pValue1 = pVessel2
    set pValue2 = pVessel1
    set pTestTemp1 = pTemp2
    set pTestTemp2 = pTemp1
  end if

end mDetermineValues

-----------------------------
--DL
on mSetLiquid me
  set xtemp = the mouseh
  set ytemp = the mousev

  set the castnum of sprite pNowMe to 0 -- (pNowMe-pLiquidStart+pVesselStart)
  set the castNum of sprite pDraggableSprite = (pNowMe-pLiquidStart+pVesselStart)

  if the castNum of sprite pBeaker1 = the castNum of sprite pDraggableSprite then
    nothing
  else if the castNum of sprite pBeaker2 = the castNum of sprite pDraggableSprite then
    nothing
  else
    repeat while the mousedown
      set the loch of sprite pDraggableSprite = mouseH()
      set the locv of sprite pDraggableSprite = mousev()
      mDisplayDigits me
      updateStage
    end repeat

    set liquidNum = pNowMe-pLiquidStart+1

    mCheckPosition me

    if pPosition = 1 then
      set pFirstBoilFlag1 = #DONTBOIL -- make sure paramter is reset for new liquid
      set pVessel1 = liquidNum
      set the puppet of sprite pBeaker1 = 1
      set the loch of sprite pBeaker1 to pVessel1H
      set the locv of sprite pBeaker1 to pVessel1V
      set the castNum of sprite pBeaker1 = the castNum of sprite pDraggableSprite
      set pTemp1 = 35

      -- check to see if vessel 1 is already occupied
      if pVessel1 = 0 then
        nothing
      else
        repeat with n = pLiquidStart to (pLiquidStart + 3)
          set the puppet of sprite n = 0
        end repeat
      end if
    else if pPosition = 2 then
      set pFirstBoilFlag2 = #DONTBOIL -- make sure paramter is reset for new liquid
      set pVessel2 = liquidNum
      set the puppet of sprite pBeaker2 = 1
      set the loch of sprite pBeaker2 to pVessel2H
      set the locv of sprite pBeaker2 to pVessel2V
      set the castNum of sprite pBeaker2 = the castNum of sprite pDraggableSprite
      set pTemp2 = 35

      -- check to see if vessel 2 is already occupied
      if pVessel2 = 0 then
        nothing
      else
        repeat with n = pLiquidStart to (pLiquidStart + 3)
          set the puppet of sprite n = 0
        end repeat
      end if
    else
      set the castNum of sprite pDraggableSprite = 0
      set the loch of sprite pDraggableSprite to getAt(pInitialPositionX,liquidNum)
      set the locv of sprite pDraggableSprite to getAt(pInitialPositionY,liquidNum)
    end if

  end if

end mSetLiquid
---------------------------------
on mCheckPosition me
  set pPosition = 0

  set testx = the loch of sprite pDraggableSprite
  set testy = the locv of sprite pDraggableSprite

  -- check to see if mouseUp was over boiler pPad 1
  if testx > pVessel1H-pPad and testx < pVessel1H+pPad then
    if testy > pVessel1V-pPad and testy < pVessel1V+pPad then
      set the visible of sprite pOldMiniBurner1 = 1
      set pOldMiniBurner1 = pNowMe
      set the visible of sprite pOldMiniBurner1 = 0
      set pPosition = 1
      set pLogs1Dig = 0
    end if
  end if

  -- check to see if mouseUp was over boiler pPad 2
  if testx > pVessel2H-pPad and testx < pVessel2H+pPad then
    if testy >pVessel2V-pPad and testy < pVessel2V+pPad then
      set the visible of sprite pOldMiniBurner2 = 1
      set pOldMiniBurner2 = pNowMe
      set the visible of sprite pOldMiniBurner2 = 0
      set pPosition = 2
      set pLogs2Dig = 0
    end if
  end if

end mCheckPosition
--------------------------
on mDoLiquidAnimation1 me

  if pVessel1 = 1 then set WhichLiq = "Alcohol"
  else if pVessel1 = 2 then set WhichLiq = "Water"
  else if pVessel1 = 3 then set WhichLiq = "Wax"
  else set WhichLiq = "Mercury"

  if pMeltWaxFlag = #MELTWAX then
    -- Wax is melting
    mSetupQT me, 1, "IHTWXBL.MOV", 0, 120
    set pMeltWaxFlag = #NOMELT
    set pFirstBoilFlag1 = #GARBAGE

  else if pFirstBoilFlag1 = #FIRSTBOIL then
    mSetupQT me, 1, "IHTWXBL.MOV", 121, 180
    set pMeltWaxFlag = #NOMELT
    set pFirstBoilFlag1 = #ALREADYBOILING

  else if pBoilingFlag1 = 1 then
    -- something is boiling
    -- this is the first time it's boiling
    if pVessel1 = 1 then
      mSetupQT me, 1, "IHTALBL.MOV", 0, 60
      set pMeltWaxFlag = #NOMELT
      set pFirstBoilFlag1 = #ALREADYBOILING
    else if pVessel1 = 2 then
      mSetupQT me, 1, "IHTWTBL.MOV", 0, 60
      set pMeltWaxFlag = #NOMELT
      set pFirstBoilFlag1 = #ALREADYBOILING
    else if pVessel1 = 3 then
      mSetupQT me, 1, "IHTWXBL.MOV", 181, 300
      set pMeltWaxFlag = #NOMELT
      set pFirstBoilFlag1 = #ALREADYBOILING
    end if

  else if pFirstBoilFlag1 = #ALREADYBOILING then
    -- whatever it is, it's boiled already
    if pVessel1 = 1 then
      mSetupQT me, 1, "IHTALBL.MOV", 61, 240
      set pMeltWaxFlag = #NOMELT
    else if pVessel1 = 2 then
      mSetupQT me, 1, "IHTWTBL.MOV", 61, 240
      set pMeltWaxFlag = #NOMELT
    else if pVessel1 = 3 then
      mSetupQT me, 1, "IHTWXBL.MOV", 181, 300
    end if

  else
    nothing
  end if

  mStartFlame me, 1

  set xtemp = pTemp1

end mDoLiquidAnimation1
--------------------------
on mDoLiquidAnimation2 me

  if pVessel2 = 1 then set WhichLiq = "Alcohol"
  else if pVessel2 = 2 then set WhichLiq = "Water"
  else if pVessel2 = 3 then set WhichLiq = "Wax"
  else set WhichLiq = "Mercury"

  if pMeltWaxFlag = #MELTWAX then
    -- Wax is melting
    mSetupQT me, 2, "IHTWXBL.MOV", 0, 120
    set pMeltWaxFlag = #NOMELT
    set pFirstBoilFlag2 = #GARBAGE

  else if pFirstBoilFlag2 = #FIRSTBOIL then
    mSetupQT me, 2, "IHTWXBL.MOV", 121, 180
    set pMeltWaxFlag = #NOMELT
    set pFirstBoilFlag2 = #ALREADYBOILING

  else if pBoilingFlag2 = 1 then
    -- something is boiling
    -- this is the first time it's boiling
    if pVessel2 = 1 then
      mSetupQT me, 2, "IHTALBL.MOV", 0, 60
      set pMeltWaxFlag = #NOMELT
      set pFirstBoilFlag2 = #ALREADYBOILING
    else if pVessel2 = 2 then
      mSetupQT me, 2, "IHTWTBL.MOV", 0, 60
      set pMeltWaxFlag = #NOMELT
      set pFirstBoilFlag2 = #ALREADYBOILING
    else if pVessel2 = 3 then
      mSetupQT me, 2, "IHTWXBL.MOV", 181, 300
      set pMeltWaxFlag = #NOMELT
      set pFirstBoilFlag2 = #ALREADYBOILING
    end if

  else if pFirstBoilFlag2 = #ALREADYBOILING then
    -- whatever it is, it's boiled already
    if pVessel2 = 1 then
      mSetupQT me, 2, "IHTALBL.MOV", 61, 240
      set pMeltWaxFlag = #NOMELT
    else if pVessel2 = 2 then
      mSetupQT me, 2, "IHTWTBL.MOV", 61, 240
      set pMeltWaxFlag = #NOMELT
    else if pVessel2 = 3 then
      mSetupQT me, 2, "IHTWXBL.MOV", 181, 300
    end if

  else
    nothing
  end if

  mStartFlame me, 2

  set xtemp = pTemp2

end mDoLiquidAnimation2
--------------------------
on mStartFlame me, WhichFlame
  set pFlameCount = 0
  if WhichFlame = 1 then
    set pFlame1State = #FIRE
    set the puppet of sprite pFlame1 = TRUE
    set the visible of sprite pFlame1 = TRUE
  else if WhichFlame = 2 then
    set pFlame2State = #FIRE
    set the puppet of sprite pFlame2 = TRUE
    set the visible of sprite pFlame2 = TRUE
  end if
end mStartFlame
--------------------------
on mFlameAnimation me
  set pFlameCount = pFlameCount + 1

  if pFlame1State = #FIRE then
    if pFlameCount mod pFlameMod = 0 then set the castNum of sprite pFlame1 = (pFirstFlame + random(2))
  end if
  if pFlame2State = #FIRE then
    if pFlameCount mod pFlameMod = 0 then set the castNum of sprite pFlame2 = (pFirstFlame + random(2))
  end if

  if pFlameCount >= pFlameDuration then
    set pFlame1State = #OUT
    set pFlame2State = #OUT
    set the visible of sprite pFlame1 = FALSE
    set the visible of sprite pFlame2 = FALSE
  end if
end mFlameAnimation
--------------------------
on mSetupQT me, WhichStand, QTName, QTStart, QTStop
  if WhichStand = 1 then
    set the puppet of sprite pStand1QT = 1
    set QTCastNum = the number of cast QTName
    set the castNum of sprite pStand1QT = QTCastNum
    set pStand1Duration = the duration of cast QTName
    set the locH of sprite pStand1QT = pStand1QTH
    set the locV of sprite pStand1QT = pStand1QTV
    updateStage
    set the movieTime of sprite pStand1QT = QTStart
    set the movieRate of sprite pStand1QT = 1
    set pStand1QTLoop = QTStart
    set pStand1QTTarget = QTStop
    set pStand1QTFlag = #ON
  else
    set the puppet of sprite pStand2QT = 1
    set QTCastNum = the number of cast QTName
    set the castNum of sprite pStand2QT = QTCastNum
    set pStand2Duration = the duration of cast QTName
    set the locH of sprite pStand2QT = pStand2QTH
    set the locV of sprite pStand2QT = pStand2QTV
    updateStage
    set the movieTime of sprite pStand2QT = QTStart
    set the movieRate of sprite pStand2QT = 1
    set pStand2QTLoop = QTStart
    set pStand2QTTarget = QTStop
    set pStand2QTFlag = #ON
  end if
end
--------------------------
on mDoMixAnimation me
  -- this routine will play the appropriate mix animation depending on which
  -- liquids are in the containers and the value of pLiquid1 (as determined in
  -- the mCalcMix routine)
  --
  -- you might try squaring the values of vessel 1 and 2 and then
  -- adding them. This should result in a unique number that you can then use to set the castnum
  -- of the movies. For example: testnum = pVessel1*pVessel1+pVessel2*pVessel2
  -- possible values: 17 (alcohol & water)
  --                  82 (alcohol & wax)
  --                 257 (alcohol & mercury)
  --                  97 (water & wax)
  --                 272 (water & mercury)
  --                 337 (wax & mercury)
  --
  -- if alcohol and water are mixed and ...
  --    pLiquid1 = 1 then play movie "IHTALWT1.MOV"
  --    pLiquid1 < .7 then play movie "IHTALWT2.MOV"
  --    pLiquid1 < .5 then play movie "IHTALWT3.MOV"
  --    pLiquid1 = 0 then play movie "IHTALWT4.MOV"
  --
  -- if alcohol and wax are mixed and ...
  --    pLiquid1 = 1 then play movie "IHTALWX1.MOV"
  --    pLiquid1 < .7 then play movie "IHTALWX2.MOV"
  --    pLiquid1 < .5 then play movie "IHTALWX3.MOV"
  --    pLiquid1 = 0 then play movie "IHTALWX4.MOV"
  --
  -- if water and wax are mixed and ...
  --    pLiquid1 = 1 then play movie "IHTWXWT1.MOV"
  --    pLiquid1 < .7 then play movie "IHTWXWT2.MOV"
  --    pLiquid1 < .5 then play movie "IHTWXWT3.MOV"
  --    pLiquid1 = 0 then play movie "IHTWXWT4.MOV"
  --
  -- if alcohol and mercury are mixed and ...
  --    pLiquid1 = 1 then play movie "IHTMEAL1.MOV"
  --    pLiquid1 < .7 then play movie "IHTMEAL2.MOV"
  --    pLiquid1 < .5 then play movie "IHTMEAL3.MOV"
  --    pLiquid1 = 0 then play movie "IHTMEAL4.MOV"
  --
  -- if water and mercury are mixed and ...
  --    pLiquid1 = 1 then play movie "IHTMEWT1.MOV"
  --    pLiquid1 < .7 then play movie "IHTMEWT2.MOV"
  --    pLiquid1 < .5 then play movie "IHTMEWT3.MOV"
  --    pLiquid1 = 0 then play movie "IHTMEWT4.MOV"
  --
  -- if waX and mercury are mixed and ...
  --    pLiquid1 = 1 then play movie "IHTMEWX1.MOV"
  --    pLiquid1 < .7 then play movie "IHTMEWX2.MOV"
  --    pLiquid1 < .5 then play movie "IHTMEWX3.MOV"
  --    pLiquid1 = 0 then play movie "IHTMEWX4.MOV"
  --
  -- please note that these movies appear in this exact order in the cast window

  -- figure out which mix movie to play
  set IDList = ["AL", "WT", "WX", "ME"]
  set FirstString = getAt(IDList, pVessel1)
  set SecondString = getAt(IDList, pVessel2)

  if pLiquid1 = 0 then set LiquidID = 4
  else if pLiquid1 < 0.5 then set LiquidID = 3
  else if pLiquid1 < 0.7 then set LiquidID = 2
  else if pLiquid1 <= 1 then set LiquidID = 1

  set SearchSymbol1 = value("#" & "IHT" & FirstString & SecondString & LiquidID)
  set SearchSymbol2 = value("#" & "IHT" & SecondString & FirstString & LiquidID)

  set CastPos = getAProp(pMixCastList, SearchSymbol1)
  if voidP(CastPos) then set CastPos = getAProp(pMixCastList, SearchSymbol2)

  set the puppet of sprite 9 = 1
  set the castnum of sprite 9 = CastPos
  set the movieTime of sprite 9 = 0
  set the movieRate of sprite 9 = 1

end mDoMixAnimation