Inventor Labs: Technology/INVENTORLABS_TECHNOLOGY.BIN/pc/files/bell.dir/00227_Script_HarmonicTelegraph

Text File | 1997-05-26 | 23KB | 635 lines

--o Harmonic Telegraph Object Parent Script


-- game logic properties
property pLastSwitch -- #NEAR, #MIDDLE or #FAR
property pLastSwitchPosition -- ending state (#ON or #OFF) for the last zoom switch clicked on
property pSwitchQTChannel -- sprite channel of the last switch clicked on
property pSwitchQTStatus  -- #ON or #OFF; is the QT for a zoom switch playing or not
property pSwitchQTDuration -- the duration of the current Zoom switch QT

-- Mallet QT properties
property pMalletQTChannel -- channel of QT movie for striking mallet
property pMalletQTStatus -- #ON or #OFF; on if QT of mallet is playing
property pMalletQTDuration -- number of frames in mallet movie

-- On/Off Switch properties
-- NB: both the BigPicture frame and ZoomSwitches frame share the following six properties.  This means that the sprite channels for the various switches must be consistent between the two frames.  Thus, if in the BigPicture frame the Near switch is channel 10, the Near switch must be in channel 10 in the ZoomSwitches frame as well.
property pNearSwitchStatus
property pMiddleSwitchStatus
property pFarSwitchStatus

property pNearSwitchChannel -- sprite channel for near switch
property pMiddleSwitchChannel
property pFarSwitchChannel

-- BigPicture properties
property pBigPicNearSwitchOnCast -- cast for near switch "on" position in Big Picture frame
property pBigPicMiddleSwitchOnCast
property pBigPicFarSwitchOnCast

property pBigPicNearSwitchH -- locH and locV for three main switches in BigPicture frame
property pBigPicNearSwitchV
property pBigPicMiddleSwitchH
property pBigPicMiddleSwitchV
property pBigPicFarSwitchH
property pBigPicFarSwitchV

-- ZoomSwitch properties
property pZoomNearSwitchOnCast -- cast for near switch "on" position in Zoom frame
property pZoomMiddleSwitchOnCast -- the "off" position is next in the cast
property pZoomFarSwitchOnCast -- ie: "on" cast = 100, therefore "off" cast = 101

property pZoomNearSwitchH -- locH and locV for three main switches in Zoom frame
property pZoomNearSwitchV
property pZoomMiddleSwitchH
property pZoomMiddleSwitchV
property pZoomFarSwitchH
property pZoomFarSwitchV

property pNearSwitchOnToOff -- QT Castnumbers for the zoom frame toggling between on and off
property pNearSwitchOffToOn
property pMiddleSwitchOnToOff
property pMiddleSwitchOffToOn
property pFarSwitchOnToOff
property pFarSwitchOffToOn

-- ZoomReed properties

property pNearReedPosition -- 1, 2 or 3
property pMiddleReedPosition
property pFarReedPosition

property pNearTunedPosition -- the tuned state of the near reed
property pMiddleTunedPosition
property pFarTunedPosition

property pFirstNearReedCast -- first castNum of near reed in position 1
property pFirstMiddleReedCast
property pFirstFarReedCast

property pZoomNearReedH -- locH and locV for three main switches in Zoom frame
property pZoomNearReedV
property pZoomMiddleReedH
property pZoomMiddleReedV
property pZoomFarReedH
property pZoomFarReedV

-- Resolution properties
property pReedVibrationPattern -- the animation list for the vibrating reeds
property pReedTracker -- where in the animation list are we?
property pMaxReedAnimation -- number of entries in pReedVibrationPattern
property pVibrateStatus -- #VIBRATE or #STOPPED

property pSoundKey -- a symbol, such as #NEARFAR or #NEARMIDDLEFAR that is used to access the name of the soundfile for the resolution to be played
property pSoundList -- this property list associates combinations of correctly tuned reeds with their corresponding sound files

property pVibNearReedChannel -- sprite channels for vibrating tips of Reeds
property pVibMiddleReedChannel
property pVibFarReedChannel

property pVibNearReedH -- locH and locV for three vibrating reed tips in Resolution frame
property pVibNearReedV
property pVibMiddleReedH
property pVibMiddleReedV
property pVibFarReedH
property pVibFarReedV

property pNeutralNearReedCast -- the 4th of 7 animating reed PICTs; the middle one
property pNeutralMiddleReedCast
property pNeutralFarReedCast


property pNewReedSprite, pZoomReedH, pZoomReedV
property pSwitchDestinationFrame, pBaseCursors, pFrameFinderList

property pRolloverStartsprite
property pRolloverEndSprite
property plabels


global gSNDpath, gInterfaceMgrObj
------------------------------------------------------------------------------------------------------------
on mInit me

  mSetRolloverLabels (me, #Main)

  set pSoundList = [#NEAR:"BHTAUD1.AIF", #MIDDLE:"BHTAUD2.AIF", #FAR:"BHTAUD3.AIF", #NEARMIDDLE:"BHTAUD4.AIF", #NEARFAR:"BHTAUD5.AIF", #MIDDLEFAR:"BHTAUD6.AIF", #NEARMIDDLEFAR:"BHTAUD7.AIF"]

  set pFrameFinderList = [[#OFF,#OFF,#OFF], [#ON,#OFF,#OFF], [#OFF,#ON,#OFF], [#OFF,#OFF,#ON], [#ON,#ON,#OFF], [#OFF,#ON,#ON], [#ON,#OFF,#ON], [#ON,#ON,#ON]]

  set pNearSwitchChannel = 3
  set pMiddleSwitchChannel = 4
  set pFarSwitchChannel = 5


  set pVibNearReedChannel = 17
  set pVibMiddleReedChannel = 18
  set pVibFarReedChannel = 19

  set pNewReedSprite = 14

  set pFirstNearReedCast = the number of cast "BHTRD1S1.PIC"
  set pFirstMiddleReedCast = the number of cast "BHTRD2S1.PIC"
  set pFirstFarReedCast = the number of cast "BHTRD3S1.PIC"

  set pNeutralNearReedCast = the number of cast "BHT1VIB4.PIC"
  set pNeutralMiddleReedCast = the number of cast "BHT2VIB4.PIC"
  set pNeutralFarReedCast = the number of cast "BHT3VIB4.PIC"

  set pBigPicNearSwitchOnCast = the number of cast "BHTSW1N.PIC"
  set pBigPicMiddleSwitchOnCast = the number of cast "BHTSW2N.PIC"
  set pBigPicFarSwitchOnCast = the number of cast "BHTSW3N.PIC"

  set pReedVibrationPattern = [0, 1, 0, -1, 0, 1, 2, 0, -1, -2, -1, 0, 1, 2, 3, 2, 1, 0, -1, -2, -3, -2, -1, 0, 1, 2, 3, 2, 1, 0, -1, -2, -3, -2, -1, 0, 1, 2, 3, 2, 1, 0, -1, -2, -3, -2, -1, 0, 1, 2, 1, 0, -1, -2, -1, 0, 1, 0, -1, 0]
  set pMaxReedAnimation = count(pReedVibrationPattern)

  sound playfile 2, gSNDpath &  "BHTINTR.AIF" --rosebud

  set pSwitchQTChannel = 7
  set pMalletQTChannel = 23

  return me

end
------------------------------------------------------------------------------------------------------------
on mSetRolloverLabels me, whatarea

  if whatarea = #Main then
    set pRolloverStartsprite = 3
    set pRolloverEndSprite = 12
    set plabels  = the text of cast "Tele Main Screen labels"
  else if whatarea = #ReedCloseUp then
    set pRolloverStartsprite = 16
    set pRolloverEndSprite = 18
    set plabels  = the text of cast "Tele Reed closeup text"
  else if whatarea = #SwitchesCloseUp then
    set pRolloverStartsprite = 11
    set pRolloverEndSprite = 13
    set plabels  = the text of cast "Tele Switch closeup text"
  end if
  mSetLabelText( gUtilityObj, "")

end mSetRolloverLabels
------------------------------------------------------------------------------------------------------------
on mActivate me

  -- reset game status parameters
  set pMalletQTStatus = #OFF
  set pSwitchQTStatus = #OFF

  set pNearSwitchStatus = #ON
  set pMiddleSwitchStatus = #ON
  set pFarSwitchStatus = #ON

  set pNearReedPosition = 1
  set pMiddleReedPosition = 2
  set pFarReedPosition = 3

  -- these are the correct answers
  set pNearTunedPosition = 1
  set pMiddleTunedPosition  = 3
  set pFarTunedPosition = 2

  -- ditto for the reeds
  set ZoomNearReedChannel = 4
  set ZoomMiddleReedChannel = 5
  set ZoomFarReedChannel = 6

  set ResNearReedChannel = 7
  set ResMiddleReedChannel = 8
  set ResFarReedChannel = 9

  -- ditto for the BigPicture switches
  set BigPicNearSwitchChannel = 3
  set BigPicMiddleSwitchChannel = 4
  set BigPicFarSwitchChannel = 5


  -- get the locH and locV info for the three vibrating reeds in the Resolution frame
  set pVibNearReedH = 400
  set pVibNearReedV = 274
  set pVibMiddleReedH = 295
  set pVibMiddleReedV = 187
  set pVibFarReedH = 227
  set pVibFarReedV =121

  mUnsetCursors(gUtilityObj)
  set pBaseCursors = [15: #operate,16:#ZoomIN,17:#ZoomIN,18:#ZoomIN,19:#ZoomIN,21:#Return,22:#Return]
  mSetCursors(gUtilityObj, pBaseCursors)

  mSetToolBtns (gInterfaceMgrObj, #HarmTele, me)
end
------------------------------------------------------------------------------------------------------------
on mClose me



  mUnsetCursors(gUtilityObj)
  mSetCursors(gUtilityObj, [21:#Return,22:#Return])
  set the locv of sprite pNearSwitchChannel = -1000
  set the locv of sprite pMiddleSwitchChannel = -1000
  set the locv of sprite pFarSwitchChannel = -1000
    set the locv of sprite pNewReedSprite = -1000
  --updatestage
  puppetsprite pVibNearReedChannel, False
  puppetsprite pVibMiddleReedChannel, False
  puppetsprite pVibFarReedChannel, False
  puppetsprite pNearSwitchChannel, False
  puppetsprite pMiddleSwitchChannel, False
  puppetsprite pFarSwitchChannel, False
  puppetsprite pNewReedSprite, False

end mClose
------------------------------------------------------------------------------------------------------------
on mTeleMainLoop me

  -- called from Big Picture Frame Script to check if Mallet QT has stopped playing
  if pMalletQTStatus = #ON then

    if the movierate of sprite pMalletQTChannel = 0 then  mStopMalletMovie me

  else

    set spritetoCheck = pRolloverStartsprite
    set found = FALSE
    repeat while (not found) and (spritetoCheck <= pRolloverEndSprite)
      if rollover(spritetoCheck) then
        set labelText = line (spritetoCheck - pRolloverStartsprite + 1) of plabels
        mSetLabelText( gUtilityObj, labelText)
        set found = TRUE
      end if
      set spritetoCheck = spritetoCheck + 1
    end repeat
    if (not found) then mSetLabelText( gUtilityObj, "")

  end if

  go the frame

end mTeleMainLoop
------------------------------------------------------------------------------------------------------------
on mPlayMalletMovie me

  sound stop 1
  sound stop 2
  updatestage

  if pMalletQTStatus = #OFF then

    set pMalletQTStatus = #ON
    set the movieTime of sprite pMalletQTChannel = 0
    set the movieRate of sprite pMalletQTChannel = 1

  end if

end mPlayMalletMovie
------------------------------------------------------------------------------------------------------------
on mStopMalletMovie me

  set pMalletQTStatus = #OFF
  mResolution me

end mStopMalletMovie
--------------------------------------------88-------------------------------------------------------------
on mZoomSwitches me

  sound stop 2
  cursor 4
  if pMalletQTStatus = #OFF then
    mUnsetCursors(gUtilityObj)
    mSetRolloverLabels (me, #SwitchesCloseUp)
    set NewFrame = mSetupZoomSwitches (me)
    set the puppet of sprite pNearSwitchChannel = 0
    set the puppet of sprite pMiddleSwitchChannel = 0
    set the puppet of sprite pFarSwitchChannel = 0
    go frame NewFrame
    mSetCursors(gUtilityObj, [21:#Return,22:#Return,11:#Operate,12:#Operate,13:#Operate])
  end if
  cursor -1

end mZoomSwitches
------------------------------------------------------------------------------------------------------------
on mZoomReeds me, WhichReed

  sound stop 2

  if pMalletQTStatus = #OFF then
    mUnsetCursors(gUtilityObj)
    mSetUpZoomReeds me, WhichReed
    go frame WhichReed & "Reed"
    mSetCursors(gUtilityObj, [21:#Return,22:#Return,15:#Zoomout,16:#Finger,17:#Finger,18:#Finger])
  end if

end mZoomReeds
------------------------------------------------------------------------------------------------------------
on mResolution me

  -- turn the puppet of the main switches to off
  set the puppet of sprite pNearSwitchChannel = 0
  set the puppet of sprite pMiddleSwitchChannel = 0
  set the puppet of sprite pFarSwitchChannel = 0
  mUnsetCursors(gUtilityObj)

  mSetLabelText( gUtilityObj, "")
  go frame "HT_RESOLUTION"
  -- setup info for vibrating tips, if any are active, and create pSoundKey
  mSetupVibratingTips me

  -- play sound file
  set SoundFile = getAProp(pSoundList, pSoundKey)
  if not(voidP(SoundFile)) then sound playfile 2, gSNDpath & SoundFile

  -- setup animation parameters
  set pReedTracker = 1 -- first animation number in pReedVibrationPattern
  set pVibrateStatus = #VIBRATE -- allows animation to take place
  mSetCursors(gUtilityObj, [21:#Return,22:#Return])

end
---------------------------------------------------------------------------------------------------------
on mVibrateReeds me

  if pVibrateStatus = #VIBRATE then

    set NextModifier = getAt(pReedVibrationPattern, pReedTracker)
    set the castNum of sprite pVibNearReedChannel = pNeutralNearReedCast + NextModifier
    set the castNum of sprite pVibMiddleReedChannel = pNeutralMiddleReedCast + NextModifier
    set the castNum of sprite pVibFarReedChannel = pNeutralFarReedCast + NextModifier
    set pReedTracker = pReedTracker + 1

    if pReedTracker > pMaxReedAnimation then
      puppetsprite pVibNearReedChannel, False
      puppetsprite pVibMiddleReedChannel, False
      puppetsprite pVibFarReedChannel, False
      set pVibrateStatus = #STOPPED
      set done = true
    end if

  end if

  go the frame

end mVibrateReeds
-----------------------------------------------------88-------------------------------------------
on mGoToBigPictureFrameFromSwitches me

  if pSwitchQTStatus = #OFF then
    mUnsetCursors(gUtilityObj)
    mSetupBigPictureSwitches me
    go frame "HT_BIGPICTURE"
    mSetCursors(gUtilityObj, pBaseCursors)
  end if

end mGoToBigPictureFrameFromSwitches
-----------------------------------------------------88-------------------------------------------
on mGoToBigPictureFrameFromReeds me

  set the puppet of sprite pNewReedSprite = 0
  mSetupBigPictureSwitches me
  mUnsetCursors(gUtilityObj)
  go frame "HT_BIGPICTURE"
  mSetCursors(gUtilityObj,pBaseCursors)

end mGoToBigPictureFrameFromReeds
---------------------------------------------------------------------------------------------------
on mGoToBigPictureFrameFromVibratingReeds me

  mUnsetCursors(gUtilityObj)
  sound stop 1

  set the puppet of sprite pVibNearReedChannel = 0
  set the puppet of sprite pVibMiddleReedChannel = 0
  set the puppet of sprite pVibFarReedChannel = 0
  mSetupBigPictureSwitches me
  go frame "HT_BIGPICTURE"
  mSetCursors(gUtilityObj,pBaseCursors)

end mGoToBigPictureFrameFromVibratingReeds
---------------------------------------------------------------------------------------------------
on mSetupBigPictureSwitches me

  -- puppet all three main switches]

  mSetRolloverLabels (me, #Main)
  set the puppet of sprite pNearSwitchChannel = 1
  set the puppet of sprite pMiddleSwitchChannel = 1
  set the puppet of sprite pFarSwitchChannel = 1

  -- setup near, middle and far switches
  if pNearSwitchStatus = #ON then set the castNum of sprite pNearSwitchChannel = pBigPicNearSwitchOnCast
  else set the castNum of sprite pNearSwitchChannel = pBigPicNearSwitchOnCast + 1

  if pMiddleSwitchStatus = #ON then set the castNum of sprite pMiddleSwitchChannel = pBigPicMiddleSwitchOnCast
  else set the castNum of sprite pMiddleSwitchChannel = pBigPicMiddleSwitchOnCast + 1

  if pFarSwitchStatus = #ON then set the castNum of sprite pFarSwitchChannel = pBigPicFarSwitchOnCast
  else set the castNum of sprite pFarSwitchChannel = pBigPicFarSwitchOnCast + 1

end
------------------------------------------------------------------------------------------------------------
on mSetupZoomReeds me, WhichReed

  mSetRolloverLabels( me,#ReedCloseUp)
  -- puppet all three main switches
  set the puppet of sprite pNewReedSprite = 1
  -- set the locH and locV values for three main reeds
  set the locH of sprite pNewReedSprite = pZoomReedH
  set the locV of sprite pNewReedSprite = pZoomReedV
  -- setup near, middle and far reeds

  if WhichReed = "Near" then
    set NextCast = pFirstNearReedCast + (pNearReedPosition * 2) - 2
  else if WhichReed = "Middle" then
    set NextCast = pFirstMiddleReedCast + (pMiddleReedPosition * 2) - 2
  else if WhichReed = "Far" then
    set NextCast = pFirstFarReedCast + (pFarReedPosition * 2) - 2
  end if
  set the castNum of sprite pNewReedSprite = NextCast
  set the locH of sprite pNewReedSprite = 319
  set the locV of sprite pNewReedSprite = 268
  updateStage

end
------------------------------------------------------------------------------------------------------------
on mSetupVibratingTips me

  -- AnswerString is converted into a string to get the appropriate sound file to play later
  set AnswerString = ""
  -- check for near, middle and far reeds vibrating
  if pNearSwitchStatus = #ON then
    if pNearReedPosition = pNearTunedPosition then
      put "Near" after AnswerString
      set the puppet of sprite pVibNearReedChannel = 1
      set the castNum of sprite pVibNearReedChannel = pNeutralNearReedCast
      set the locH of sprite pVibNearReedChannel = pVibNearReedH
      set the locV of sprite pVibNearReedChannel = pVibNearReedV
    end if
  end if

  if pMiddleSwitchStatus = #ON then
    if pMiddleReedPosition = pMiddleTunedPosition then
      put "Middle" after AnswerString
      set the puppet of sprite pVibMiddleReedChannel = 1
      set the castNum of sprite pVibMiddleReedChannel = pNeutralMiddleReedCast
      set the locH of sprite pVibMiddleReedChannel = pVibMiddleReedH
      set the locV of sprite pVibMiddleReedChannel = pVibMiddleReedV
    end if
  end if

  if pFarSwitchStatus = #ON then
    if pFarReedPosition = pFarTunedPosition then
      put "Far" after AnswerString
      set the puppet of sprite pVibFarReedChannel = 1
      set the castNum of sprite pVibFarReedChannel = pNeutralFarReedCast
      set the locH of sprite pVibFarReedChannel = pVibFarReedH
      set the locV of sprite pVibFarReedChannel = pVibFarReedV
    end if
  end if

  set pSoundKey = value("#" & AnswerString)

end
----------------------------------------88------------------------------------------------------------------
on mSetupZoomSwitches me

  set CurrentSettingsList = [pNearSwitchStatus,pMiddleSwitchStatus,pFarSwitchStatus]
  set FrameIndexNum = 0
  set numofFrame = count (pFrameFinderList)
  repeat with loopCounter = 1 to numofFrame
    if CurrentSettingsList = getAt (pFrameFinderList, loopCounter) then set FrameIndexNum = loopCounter
  end repeat
  set NewFrameLabel = FrameIndexNum & "ZSW"
  Return NewFrameLabel

end
--------------------------------------------------88-------------------------------------------------------
on mZoomSwitchClicked me, SwitchPosition

  cursor 4
  set VitalInfoList = [[#ON:["BHTSWZ3F.MOV",324,329], #OFF:["BHTSWZ3N.MOV",324,328]],[#ON:["BHTSWZ2F.MOV",354,218], #OFF:["BHTSWZ2N.MOV",354,218]],[#ON:["BHTSWZ1F.MOV",370,151], #OFF:["BHTSWZ1N.MOV",370,151]]]


  if pSwitchQTStatus = #OFF then

    set listIndex = getPos ([#NEAR, #MIDDLE, #FAR], SwitchPosition)
    set SwitchState = getAt ([pNearSwitchStatus,pMiddleSwitchStatus,pFarSwitchStatus], listIndex)
    set infolist = getProp(getAt (VitalInfoList, listIndex), SwitchState)
    puppetSprite pSwitchQTChannel, true
    set the castNum of sprite pSwitchQTChannel = the number of cast (getAt(infolist, 1))
    set the locH of sprite pSwitchQTChannel = getAt(infolist, 2)
    set the locV of sprite pSwitchQTChannel = getAt(infolist, 3)
    updateStage

    if SwitchState = #ON then set SwitchState = #OFF
    else set SwitchState = #ON

    if SwitchPosition = #NEAR then
      set pNearSwitchStatus = SwitchState
    else if SwitchPosition = #MIDDLE then
      set pMiddleSwitchStatus = SwitchState
    else if SwitchPosition = #FAR then
      set pFarSwitchStatus = SwitchState
    end if

  end if

  set pSwitchQTStatus = #ON
  set pSwitchDestinationFrame = mSetupZoomSwitches (me)

  cursor -1

end
------------------------------------------------88---------------------------------------------------------
on mCheckSwitchMovie me

  if pSwitchQTStatus = #ON then

    if the movieRate of sprite pSwitchQTChannel = 0 then

      puppetsprite pSwitchQTChannel, false
      set the locv of sprite pSwitchQTChannel = -1000

      go frame pSwitchDestinationFrame
      set pSwitchQTStatus = #OFF
    end if
    go the frame

  else mTeleMainLoop me

end mCheckSwitchMovie
------------------------------------------------------------------------------------------------------------
on mReedClicked me, Reed, Destination

  set listIndex = getpos( [0,0,0,#NEAR,#MIDDLE,#FAR],Reed)
  if Reed = #NEAR then
    set ReedAnimList = mBuildReedList(me, pNearReedPosition, Destination, pFirstNearReedCast)
    set pNearReedPosition = Destination
  else if Reed = #MIDDLE then
    set ReedAnimList = mBuildReedList(me, pMiddleReedPosition, Destination, pFirstMiddleReedCast)
    set pMiddleReedPosition = Destination
  else if Reed = #FAR then
    set ReedAnimList = mBuildReedList(me, pFarReedPosition, Destination, pFirstFarReedCast)
    set pFarReedPosition = Destination
  end if

  set RepeatValue = count(ReedAnimList)
  repeat with n = 1 to RepeatValue
    set the castNum of sprite pNewReedSprite = getAt(ReedAnimList, n)
    updateStage
    set TargetTime = the timer + 12
    repeat while the timer < TargetTime
    end repeat
  end repeat


end
------------------------------------------------------------------------------------------------------------
on mBuildReedList me, Position, Destination, FirstCast

  set ReedMoveList = []
  if Position > Destination then
    repeat with n = (Position * 2) - 1 down to (Destination * 2) - 1
      add(ReedMoveList, (FirstCast + n - 1))
    end repeat
  else
    repeat with n = (Position * 2) - 1 to (Destination * 2) - 1
      add(ReedMoveList, (FirstCast + n - 1))
    end repeat
  end if
  return ReedMoveList

end mBuildReedList
------------------------------------------------------------------------------------------------------------
on mOperate me, whatselection

  set the puppet of sprite pVibNearReedChannel = 0
  set the puppet of sprite pVibMiddleReedChannel = 0
  set the puppet of sprite pVibFarReedChannel = 0
  mGoToBigPictureFrameFromReeds ( me )
  mPlayMalletMovie  ( me )
  mClearToolHilite (gInterfaceMgrObj)

end mOperate
------------------------------------------------------------------------------------------------------------
on mZoom me, whatselection

  if (whatselection <= 3) then
    mZoomReeds me, "Near"
    mSetupZoomReeds me, "Near"
    mReedClicked me, #NEAR, whatselection
  else if (whatselection <= 6) then
    mZoomReeds me, "Middle"
    mSetupZoomReeds me, "Middle"
    mReedClicked me, #MIDDLE, (whatselection - 3)
  else if (whatselection <= 9) then
    mZoomReeds me, "Far"
    mSetupZoomReeds me, "Far"
    mReedClicked me, #FAR, (whatselection - 6)
  end if

  mClearToolHilite (gInterfaceMgrObj)

end mZoom