home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / p_supply / p-supply.bas
Encoding:
BASIC Source File  |  1987-10-01  |  17.0 KB  |  287 lines
  1. 10 KEY OFF:CLS:GOSUB 2300
  2. 20 LOCATE 5,28:PRINT"Linear power supply design"
  3. 30 KCM=6:LOCATE 8,KCM:PRINT"    This is a design simplification program for the design of standard"
  4. 40 LOCATE 9,KCM:PRINT"linear power supplies.  It will take a number of initial design"
  5. 50 LOCATE 10,KCM:PRINT"specifications and do all the boring mathematics for you.  In some cases"
  6. 60 LOCATE 11,KCM:PRINT"you must be very specific i.e. 'LM324' for a possible regulator"
  7. 70 LOCATE 12,KCM:PRINT"or 'Triad-Utrad FS16-800' for a transformer.  Be  ready with"
  8. 80 LOCATE 13,KCM:PRINT"manufacturers specs for transformers, and regulators, and various"
  9. 90 LOCATE 14,KCM:PRINT"diode rectifiers.  You may either view the results on screen or dump"
  10. 100 LOCATE 15,KCM:PRINT"to the printer, so as to have a hard copy."
  11. 110 LOCATE 18,17:PRINT"Originally by George Sayer - Updated by Quasatron"
  12. 120 LOCATE 23,16:PRINT" Hit any key to continue or (D) to return to DOS "
  13. 130 CC$=INKEY$:IF CC$="" THEN 130
  14. 140 IF CC$="D" OR CC$="d" THEN CLS:SYSTEM
  15. 150 GOSUB 2300
  16. 160 LOCATE 3,24:PRINT"Linear power supply specifications"
  17. 170 LOCATE 5,6:INPUT"Nominal transformer input voltage (eg. 115, 120, 230), volts ";VNL
  18. 180 LOCATE 6,6:INPUT"High line voltage (eg. 130, 250), volts ";VHL
  19. 190 LOCATE 7,6:INPUT"Low-line voltage (eg. 95, 190), volts ";VLL
  20. 200 LOCATE 8,6:INPUT"Line frequency (eg. 50, 60), Hz ";FRQ
  21. 210 LOCATE 9,6:INPUT"Required full load current (Amps) ";IDC
  22. 220 IDCL=IDC/.65:IDCL=IDCL*100:IDCL=CINT(IDCL):IDCL=IDCL/100
  23. 230 LOCATE 11,6:PRINT"Choose regulator with current limiting (Amps)=";IDCL;" or greater"
  24. 240 LOCATE 12,6:INPUT"Regulator chosen (ID #) ";RG$
  25. 250 LOCATE 13,6:INPUT"Maximum regulator output voltage (nominal + tolerance), volts ";VROM
  26. 260 LOCATE 14,6:INPUT"Minimum regulator output voltage (nominal - tolerance), volts ";VROMN
  27. 270 LOCATE 15,6:INPUT"Maximum regulator dropout voltage at maximum load, volts ";VR:PRINT
  28. 280 LOCATE 16,6:INPUT"Regulators minimum ripple attenuation, dB ";DBMNR
  29. 290 LOCATE 17,6:INPUT"Allowable P-P ripple at regulator output, millivolts ";RIPOM
  30. 300 RIPO=RIPOM/1000
  31. 310 RIP=RIPO*(10^(DBMNR/20))
  32. 320 RIPA=RIP*100:RIPA=CINT(RIPA):RIPA=RIPA/100
  33. 330 LOCATE 19,6:PRINT"Maximum filter output ripple, volts P-P = ";RIPA
  34. 340 IF RIP>.2*(VROM+VR) THEN 350 ELSE 380
  35. 350 LOCATE 20,10:PRINT"Ripple over 20% regulator minimum input voltage"
  36. 360 LOCATE 21,10:PRINT"Reduce allowable P-P ripple at regulator output"
  37. 370 GOTO 290
  38. 380 GOSUB 2400
  39. 390 GOSUB 2300
  40. 400 LOCATE 3,24:PRINT"Linear power supply specifications"
  41. 410 LOCATE 5,8:PRINT"Decide on Full Wave Bridge, or Full Wave Center Tapped connection"
  42. 420 LOCATE 6,14:PRINT"We suggest Full Wave Bridge for above 9.5 volts output"
  43. 430 LOCATE 7,18:PRINT"and Full Wave Center Tapped for under 9.5 volts."
  44. 440 LOCATE 9,8:PRINT"Number of individual silicon recifiers (4 for FWB and 2 for FWCT) "
  45. 450 CC$=INKEY$:IF CC$="" THEN 450
  46. 460 IF CC$="4" THEN D=4
  47. 470 IF CC$="2" THEN D=2
  48. 480 IF (D<>4) AND (D<>2) THEN 440
  49. 490 LOCATE 10,12:PRINT"Do you intend to use 1N4001 series rectifiers? (Y or N) "
  50. 500 R$=INKEY$:IF R$="" THEN 490
  51. 510 IF R$="N" OR R$="n" THEN 2150
  52. 520 IF R$="y" OR R$="Y" THEN 540
  53. 530 GOTO 490
  54. 540 RECT1=.0695:RECT2=8650000!:RECT3=.0695:RECT4=99900!:DX$="1N4001 series diodes"
  55. 550 VTR=VNL/VLL/1.414/.9*(VROM+VR+RIP+D/1.6):PRINT
  56. 560 GOSUB 2400
  57. 570 GOSUB 2300
  58. 580 LOCATE 3,24:PRINT"Linear power supply specifications"
  59. 590 LOCATE 5,13:PRINT"Will transformer have 1 or 2 secondaries (Enter 1 or 2)"
  60. 600 CC$=INKEY$:IF CC$="" THEN 600
  61. 610 IF CC$="1" THEN S=1
  62. 620 IF CC$="2" THEN S=2
  63. 630 IF S<1 OR S>2 THEN 590
  64. 640 RSRG=0
  65. 650 IF S=1 AND D=2 THEN 660 ELSE 670
  66. 660 IS1=IDC:VTRS=2*VTR:GOTO 680
  67. 670 IS1=2*IDC:VTRS=VTR
  68. 680 VTRS=CINT(VTRS)
  69. 690 LOCATE 7,6:PRINT"Suggested transformer secondary voltage = ";VTRS
  70. 700 LOCATE 8,6:PRINT"Suggested xformer secondary current (total if 2 seconaries)= ";IS1
  71. 710 LOCATE 9,6:PRINT"Choose a transformer from manufacturer's catalogs with ";S
  72. 720 LOCATE 10,6:PRINT"secondaries, and close to suggested secondary current and voltage"
  73. 730 LOCATE 11,10:INPUT"Transformer chosen (ID #) ";T$
  74. 740 LOCATE 13,6:INPUT"Actual Transformer rated secondary voltage, volts ";VTRTDC1
  75. 750 IF S=1 AND D=2 THEN VTRTDC2=.5*VTRTDC1 ELSE VTRTDC2=VTRTDC1
  76. 760 LOCATE 14,6:INPUT"Actual Xformer rated secondary current (Total if 2 secs.), amps ";ITRTD1
  77. 770 IF S=1 AND D=2 THEN ITRTD2=2*ITRTD1 ELSE ITRTD2=ITRTD1
  78. 780 LOCATE 15,6:INPUT"Transformer tempurature rise, degrees C ";TPRS
  79. 790 LOCATE 16,6:PRINT"Transformer rated cold regulation"
  80. 800 LOCATE 17,10:INPUT"(If 2 secondaries, when in parallel), decimal ";RGNC2
  81. 810 GOSUB 2400
  82. 820 GOSUB 2300
  83. 830 IF S=2 AND D=2 THEN K=1.5 ELSE K=1:IF S=1 AND D=2 THEN K=.375
  84. 840 N=0:RGNC=RGNC2:VTRTDC=VTRTDC2:ITRTD=ITRTD2
  85. 850 RGNH=1/((1+1/RGNC)/(.00393*TPRS+1)-1)
  86. 860 VTRTDH=VTRTDC*(RGNC+1)/(RGNH+1)
  87. 870 XC=K*RGNC/(RGNC+1)*IDC/ITRTD
  88. 880 XH=K*RGNH/(RGNH+1)*IDC/ITRTD
  89. 890 HACC=1.494*(XC^.333)+.111*XC
  90. 900 HACH=1.494*(XH^.333)+.111*XH
  91. 910 ITC=1.37*IDC/(HACC^.5)
  92. 920 ITH=1.37*IDC/(HACH^.5)
  93. 930 CMIN=IDC*(.5-HACC/3.1416)/(FRQ*RIP)
  94. 940 ICRMS=((ITC^2)-(IDC^2))^.5
  95. 950 VNMLX=1.414*VHL/VNL*VTRTDC*(RGNC+1)
  96. 960 IDPR=2.36*IDC/HACC
  97. 970 REM 1st overflow
  98. 980 VDMX=RECT1*LOG(RECT2*IDPR)
  99. 990 VDMN=RECT3*LOG(RECT4*IDPR)
  100. 1000 VDFA=RECT1*(2*LOG(RECT2*1.5*IDC)-LOG(RECT2*3*IDC))
  101. 1010 RDFA=.667*RECT1*(LOG(RECT2*3*IDC)-LOG(RECT2*1.5*IDC))/IDC
  102. 1020 IDRMS=.5*(ICRMS^2+IDC^2)^.5
  103. 1030 VFLMX=VNLMX*COS(HACC)-VDMN*D/2+RIP/2
  104. 1040 VFLMN=VLL/VHL*VNLMX*COS(HACH)-VDMX*D/2-RIP/2
  105. 1050 PRGMX=(VFLMX-RIP/2-VROMN)*IDC
  106. 1060 PD=VDFA*IDC/2+IDRMS^2*RDFA
  107. 1070 IINRSH=(VNLMX-D/2*VDMN)/(RGNC*K*VTRTDC/ITRTD+RFDA*D/2)
  108. 1080 IDCMAX=.87/K^.4*((RGNH/(RGNH+1))^.2*ITRTD)
  109. 1090 IINRSHA=CINT(IINRSH)
  110. 1100 LOCATE 3,24:PRINT"Linear power supply specifications"
  111. 1110 LOCATE 5,6:PRINT"Maximum inrush current in amps = ";IINRSHA
  112. 1120 LOCATE 6,6:PRINT"Can rectifiers handle this inrush current?  (Y or N)"
  113. 1130 A$=INKEY$:IF A$="" THEN 1130
  114. 1140 IF A$="Y" OR A$="y" OR A$="N" OR A$="n" THEN 1160
  115. 1150 GOTO 1120
  116. 1160 IF A$="Y" OR A$="y" THEN 1310 ELSE 1170
  117. 1170 N=N+1
  118. 1180 IF N=2 THEN 1190 ELSE 1220
  119. 1190 LOCATE 8,6:PRINT"NOTE: Program returns to original condition of no surge"
  120. 1200 LOCATE 9,12:PRINT"resistor.  Last new regulation was ";NRGNC
  121. 1210 GOTO 840
  122. 1220 LOCATE 8,6:PRINT"Transformer cold regulation, ";RGNC;" must be increased"
  123. 1230 LOCATE 9,10:PRINT"by addition of a surge resistor"
  124. 1240 LOCATE 11,6:INPUT"Estimate new cold regulation (Suggest 10% increments) ";NRGNC
  125. 1250 RSRG=(VTRTDC/ITRTD)*(NRGNC-RGNC)/(NRGNC+1)
  126. 1260 RGNC=NRGNC
  127. 1270 RGNH=(RGNH*VTRTDH+ITRTD*RSRG)/(VTRTDH-ITRTD*RSRG)
  128. 1280 VTRTDC=VTRTDC-ITRTD*RSRG
  129. 1290 GOSUB 2300
  130. 1300 GOTO 860
  131. 1310 VDMNR=5.66*VHL/VNL*(RGNH+1)*VTRTDH/D
  132. 1320 RSRGP=RSRG*(VNL/(VTRTDC2*(RGNC2+1)))^2
  133. 1330 IF D=2 AND S=1 THEN ITHA=.5*ITH ELSE ITHA=ITH
  134. 1340 PTPRS=TPRS*(.5+.5*(IDC/IDCMAX)^2)
  135. 1350 PRSRGP=RSRGP*((1+RNGC2)*VTRTDC1/VNL*ITHA)^2
  136. 1360 LOCATE 18,29:PRINT"Displayed results follow"
  137. 1370 LOCATE 20,20:PRINT"Dump Specifications to printer ? (Y or N)"
  138. 1380 LOCATE 21,17:PRINT"If 'yes', dump will occur after visual display"
  139. 1390 DUMP$=INKEY$:IF DUMP$="" THEN 1380
  140. 1400 GOSUB 2400
  141. 1410 GOSUB 2300
  142. 1420 KCM=68:LOCATE 1,27:PRINT"  Application specifications  "
  143. 1430 LOCATE 3,6:PRINT"Nominal transformer input voltage ----------------";VNL:LOCATE 3,KCM:PRINT"Volts"
  144. 1440 LOCATE 4,6:PRINT"High line voltage expectation --------------------";VHL:LOCATE 4,KCM:PRINT"Volts"
  145. 1450 LOCATE 5,6:PRINT"Low line voltage expectation----------------------";VLL:LOCATE 5,KCM:PRINT"Volts"
  146. 1460 LOCATE 6,6:PRINT"Nominal line frequency ---------------------------";FRQ:LOCATE 6,KCM:PRINT"Hertz"
  147. 1470 LOCATE 7,6:PRINT"Full load current requirement --------------------";IDC:LOCATE 7,KCM:PRINT"Amps"
  148. 1480 LOCATE 8,6:PRINT"Maximum regulator output voltage -----------------";VROM:LOCATE 8,KCM:PRINT"Volts"
  149. 1490 LOCATE 9,6:PRINT"Minimum regulator output voltage -----------------";VROMN:LOCATE 9,KCM:PRINT"Volts"
  150. 1500 LOCATE 10,6:PRINT"Maximum regulator dropout voltage (full load) ----";VR:LOCATE 10,KCM:PRINT"Volts"
  151. 1510 LOCATE 11,6:PRINT"Regulator minimum ripple attenuation -------------";DBMNR:LOCATE 11,KCM:PRINT"dB"
  152. 1520 LOCATE 12,6:PRINT"Allowable regulator P-P ripple output ------------";RIPO:LOCATE 12,KCM:PRINT"Millivolts"
  153. 1530 LOCATE 13,6:PRINT"Number of diodes ---------------------------------";D
  154. 1540 LOCATE 14,6:PRINT"Number of secondaries ----------------------------";SCNDRS
  155. 1550 LOCATE 15,6:PRINT"Actual rated voltage of secondary winding --------";VTRTDC1:LOCATE 15,KCM:PRINT"Volts"
  156. 1560 LOCATE 16,6:PRINT"Actual rated current of secondary winding --------";ITRTD1:LOCATE 16,KCM:PRINT"Amps"
  157. 1570 LOCATE 17,6:PRINT"Transformer temperature rise ---------------------";TPRS:LOCATE 17,KCM:PRINT"Deg. C"
  158. 1580 LOCATE 18,6:PRINT"Transformer regulation at ambient temperature ----";RGNC2:LOCATE 18,KCM:PRINT"Volts"
  159. 1590 LOCATE 19,6:PRINT"Regulator used ----- "RG$
  160. 1600 LOCATE 20,6:PRINT"Rectifiers used ---- ";DX$
  161. 1610 LOCATE 21,6:PRINT"Transformer used --- ";T$
  162. 1620 GOSUB 2400
  163. 1630 GOSUB 2300
  164. 1640 KCM=72:LOCATE 1,24:PRINT"  Final suggested specifications  "
  165. 1650 ITHA=ITHA*100:ITHA=CINT(ITHA):ITHA=ITHA/100
  166. 1660 LOCATE 3,6:PRINT"Transformer current at required full load --------------";ITHA:LOCATE 3,KCM:PRINT"Amps"
  167. 1670 IDCMAX=IDCMAX*100:IDCMAX=CINT(IDCMAX):IDCMAX=IDCMAX/100
  168. 1680 LOCATE 4,6:PRINT"Maximum allowable current output - when load is increased"
  169. 1690 LOCATE 5,7:PRINT"so that transformer load = load at full temp rise -----";IDCMAX:LOCATE 5,KCM:PRINT"Amps"
  170. 1700 CMIN=CMIN*100:CMIN=CINT(CMIN):CMIN=CMIN/100
  171. 1710 LOCATE 6,6:PRINT"Minimum capacity of filter capacitor -------------------";CMIN:LOCATE 6,KCM:PRINT"uF"
  172. 1720 ICRMS=ICRMS*100:ICRMS=CINT(ICRMS):ICRMS=ICRMS/100
  173. 1730 LOCATE 7,6:PRINT"RMS capacitor current ----------------------------------";ICRMS:LOCATE 7,KCM:PRINT"Amps"
  174. 1740 VNLMX=VNLMX*10:VNLMX=CIN(VNLMX):VNLMX=VNLMX/10
  175. 1750 LOCATE 8,6:PRINT"Maximum no load filter output voltage ------------------";VNLMX:LOCATE 8,KCM:PRINT"Volts"
  176. 1760 VFLMX=VFLMX*10:VFLMX=CINT(VFLMX):VFLMX=VFLMX/10
  177. 1770 LOCATE 9,6:PRINT"Maximum full load filter output voltage ----------------";VFLMX:LOCATE 9,KCM:PRINT"Volts"
  178. 1780 VFLMN=VFLMN*10:VFLMN=CINT(VFLMN):VFLMN=VFLMN/10
  179. 1790 LOCATE 10,6:PRINT"Minimum full load filter output voltage ----------------";VFLMN:LOCATE 10,KCM:PRINT"Volts"
  180. 1800 IF VFLMN<(VROM+VR) THEN 1900 ELSE 1880
  181. 1810 LOCATE 12,10:PRINT"Full load filter output voltage is less than maximum regulator"
  182. 1820 LOCATE 13,10:PRINT"output voltage plus maximium regulator dropout voltage at full"
  183. 1830 LOCATE 14,10:PRINT"load.  This requires either less allowable output ripple, or"
  184. 1840 LOCATE 15,10:PRINT"higher transformer voltage, or both."
  185. 1850 LOCATE 17,10:PRINT"Hit any key to re-enter preliminary values, remember, less ripple!"
  186. 1860 CC4=INKEY$:IF CC$="" THEN 1860
  187. 1870 GOTO 150
  188. 1880 PRGMX=PRGMX*10:PRGMX=CINT(PRGMX):PRGMX=PRGMX/10
  189. 1890 LOCATE 11,6:PRINT"Maximum regulator power dissipation --------------------";PRGMX:LOCATE 11,KCM:PRINT"Watts"
  190. 1900 PD=PD*100:PD=CINT(PD):PD=PD/100
  191. 1910 LOCATE 12,6:PRINT"Individual rectifier power dissipation -----------------";PD:LOCATE 12,KCM:PRINT"Watts"
  192. 1920 VDMNR=CINT(VDMNR)
  193. 1930 LOCATE 13,6:PRINT"Minimum rectifier reverse voltage ----------------------";VDMNR:LOCATE 13,KCM:PRINT"Volts"
  194. 1940 IINRSH=CINT(IINRSH)
  195. 1950 LOCATE 14,6:PRINT"Maximum inrush current ---------------------------------";IINRSH:LOCATE 14,KCM:PRINT"Amps"
  196. 1960 IDPR=IDPR*10:IDPR=CINT(IDPR):IDPR=IDPR/10
  197. 1970 LOCATE 15,6:PRINT"Repeditive peak rectifier current ----------------------";IDPR:LOCATE 15,KCM:PRINT"Amps"
  198. 1980 RSRGP=RSRGP*10:RSRGP=CINT(RSRGP):RSRGP=RSRGP/10
  199. 1990 LOCATE 16,6:PRINT"Surge resistor (if in tranformer primary) --------------";RSRGP:LOCATE 16,KCM:PRINT"Ohms"
  200. 2000 PRSRGP=PRSRGP*100:PRSRGP=CINT(PRSRGP):PRSRGP=PRSRGP/100
  201. 2010 LOCATE 17,6:PRINT"Power dissipated in surge resistor ---------------------";PRSRGP:LOCATE 17,KCM:PRINT"Watts"
  202. 2020 PTPRS=CINT(PTPRS)
  203. 2030 LOCATE 18,6:PRINT"Predicted transformer temperature rise -----------------";PTPRS:LOCATE 18,KCM:PRINT"Deg. C"
  204. 2040 LOCATE 19,6:PRINT"Would you like to try another transformer ? (Y or N)"
  205. 2050 B$=INKEY$:IF B$="" THEN 2050
  206. 2060 IF B$="Y" OR B$="y" THEN 150
  207. 2070 IF B$="N" OR B$="n" THEN 2080 ELSE 2040
  208. 2080 LOCATE 21,6:PRINT"Be sure to correctly fuse the supply and conform to normal safety specs"
  209. 2090 IF DUMP$="Y" OR DUMP$="y" THEN LOCATE 23,27:PRINT" Standby for printer dump ":FOR KCM=0 TO 7500:NEXT KCM:GOSUB 2430
  210. 2100 LOCATE 23,8:PRINT" This completes the program.  Again (A)   DOS (D)  Specs again (S) "
  211. 2110 CC$=INKEY$:IF CC$="" THEN 2110
  212. 2120 IF CC$="D" OR CC$="d" THEN CLS:SYSTEM
  213. 2130 IF CC$="A" OR CC$="a" THEN 150
  214. 2140 IF CC$="S" OR CC$="s" THEN 1410 ELSE 2110
  215. 2150 LOCATE 12,6:INPUT"type rectifier used (ID #)";DX$
  216. 2160 LOCATE 14,11:PRINT"Find two points on verticle part of rectifier maximum I vs V"
  217. 2170 LOCATE 15,20:PRINT"curve with a ratio of I1 to I2 that is 1:10"
  218. 2180 LOCATE 16,6:INPUT"I1 (amps)= ";I1X:LOCATE 16,40:INPUT"V1 (volts)= ";V1X
  219. 2190 LOCATE 17,6:INPUT"I2 (amps)= ";I2X:LOCATE 17,40:INPUT"V2 (volts)= ";V2X
  220. 2200 LOCATE 18,11:PRINT"Find two points on verticle part of rectifier minimum I vs V"
  221. 2210 LOCATE 19,20:PRINT"curve with a ratio of I1 to I2 that is 1:10"
  222. 2220 LOCATE 20,6:INPUT"I1 (amps)= ";I1N:LOCATE 20,40:INPUT"V1 (volts)= ";V1N
  223. 2230 LOCATE 21,6:INPUT"I2 (amps)= ";I2N:LOCATE 21,40:INPUT"V2 (volts)= ";V2N
  224. 2240 RECT1=1/(1/(V2X-V1X)*LOG(I2X/I1X))
  225. 2250 RECT2=1/(I1X*(2.718^-(V1X/(V2X-V1X)*LOG(I2X/I1X))))
  226. 2260 RECT3=1/(1/(V2N-V1N)*LOG(I2N/I1N))
  227. 2270 RECT4=1/(I1N*(2.718^-(V1N/(V2N-V1N)*LOG(I2N/I1N))))
  228. 2280 GOTO 550
  229. 2290 RUN
  230. 2300 REM Quasatron Electronics - K.C. Mazie  10-1-1987
  231. 2310 CLS:KCM=KCM+1
  232. 2320 LOCATE 1,2:PRINT CHR$(201);STRING$(76,205);CHR$(187):LET X=2
  233. 2330 LOCATE X,2:PRINT CHR$(186):LOCATE X,79:PRINT CHR$(186)
  234. 2340 X=X+1:IF X<23 THEN GOTO 2330
  235. 2350 LOCATE 23,2:PRINT CHR$(200);STRING$(76,205);CHR$(188)
  236. 2360 IF KCM>1 THEN RETURN
  237. 2370 LOCATE 3,30:PRINT"QUASATRON ELECTRONICS"
  238. 2380 LOCATE 4,29:PRINT STRING$(23,126)
  239. 2390 RETURN
  240. 2400 LOCATE 23,29:PRINT" Hit any key to continue "
  241. 2410 CC$=INKEY$:IF CC$="" THEN 2410
  242. 2420 RETURN
  243. 2430 GOSUB 2310:LOCATE 8,20:PRINT"Set printer and hit any key, (A) to abort"
  244. 2440 PRNT$=INKEY$:IF PRNT$="" THEN 2440
  245. 2450 IF PRNT$="A" OR PRNT$="a" THEN LOCATE 16,38:PRINT"Aborted":GOSUB 2400
  246. 2460 IF PRNT$="A" OR PRNT$="a" THEN DUMP$="":GOTO 1410
  247. 2470 LOCATE 16,30:PRINT"Printing.....Stand by"
  248. 2480 LPRINT"                 Linear power supply specifications":LPRINT
  249. 2490 LPRINT"Nominal transformer input voltage ------------------- ";VNL;"  Volts"
  250. 2500 LPRINT"Expected high line voltage -------------------------- ";VHL;"  Volts"
  251. 2510 LPRINT"Expected low line voltage --------------------------- ";VLL;"  Volts"
  252. 2520 LPRINT"Line frequency -------------------------------------- ";FRQ;"  Hz"
  253. 2530 LPRINT"Full load current ----------------------------------- ";IDC;"  Amps"
  254. 2540 LPRINT"Maximum regulator output voltage -------------------- ";VROM;"  Volts"
  255. 2550 LPRINT"Minimum regulator output voltage -------------------- ";VROMN;"  Volts"
  256. 2560 LPRINT"Max. regulator dropout V. at full load -------------- ";VR;"  Volts"
  257. 2570 LPRINT"Regulator minimum ripple attenuation ---------------- ";DBMNR;"  dB"
  258. 2580 LPRINT"Allowable regulator P-P ripple output --------------- ";RIPO;"  Milli V."
  259. 2590 LPRINT"Number of diodes used ------------------------------- ";D
  260. 2600 LPRINT"Number of secondaries ------------------------------- ";S
  261. 2610 LPRINT"Actual rated voltage of transformers secondary ------ ";VTRTDC1;"  Volts"
  262. 2620 LPRINT"Actual rated current of secondary winding ----------- ";ITRTD1;"  Amps"
  263. 2630 LPRINT"Tranformer temperature rise ------------------------- ";TPRS;"  Deg C."
  264. 2640 LPRINT"Transformer regulation at ambient temperature ------- ";RGNC2;"  Volts"
  265. 2650 LPRINT"Type regulator used -------- ";RG$
  266. 2660 LPRINT"Type rectifiers used ------- ";DX$
  267. 2670 LPRINT"Type transformer used ------ ";T$:LPRINT
  268. 2680 LPRINT:LPRINT"       Recommended final values"
  269. 2690 LPRINT"Transformer current at full load -------------(Amps)- ";ITHA
  270. 2700 LPRINT"Maximum allowable current output (when load is increased"
  271. 2710 LPRINT"so that Xfrmr load = load at full temp rise) -(Amps)- ";IDCMAX
  272. 2720 LPRINT"Minimum value of filter capacitor ------------( uF )- ";CMIN
  273. 2730 LPRINT"RMS capacitor current ------------------------(Amps)- ";ICRMS
  274. 2740 LPRINT"Maximum no load filter output voltage -------(Volts)- ";VNLMX
  275. 2750 LPRINT"Maximum full load filter output voltage -----(Volts)- ";VFLMX
  276. 2760 LPRINT"Minimum full load filter output voltage -----(Volts)- ";VFLMN
  277. 2770 LPRINT"Maximum regulator power dissipation ---------(Watts)- ";PRGMX
  278. 2780 LPRINT"Individual rectifier power dissipation ------(Watts)- ";PD
  279. 2790 LPRINT"Minimum rectifier reverse voltage -----------(Volts)- ";VDMNR
  280. 2800 LPRINT"Maximum inrush current -----------------------(Amps)- ";IINRSH
  281. 2810 LPRINT"Repeditive peak rectifier current ------------(Amps)- ";IDPR
  282. 2820 LPRINT"Surge resistor (if in Xfrmr. primary) --------(Ohms)- ";RSRGP
  283. 2830 LPRINT"Power dissipated in surge resistor ----------(Watts)- ";PRSRPG
  284. 2840 LPRINT"Predicted transformer temperature rise ------(Deg C)- ";PTPRS
  285. 2850 LPRINT:LPRINT"    End of Specifications"
  286. 2860 GOTO 2100
  287.