home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / misc / hamscan / vhf-yagi.bas < prev   
Encoding:
BASIC Source File  |  1987-03-26  |  3.5 KB  |  86 lines
  1. 10 'This program calculates the demensions of a VHF Yagi antenna.
  2. 20 '
  3. 30 'Design assumptions are:
  4. 40 '  1. Driven element length in inches is 5600/frequency in MHZ.
  5. 50 '  2. The reflector is 5% longer than the driven element.
  6. 60 '  3. Reflector and first director spacing is 0.2 wavelengths from driven.
  7. 70 '  4. The first director is 5% shorter than the driven element.
  8. 80 '     Subsequent director lengths are calculated by adding 1% to
  9. 90 '     the shortening factor of the previous director. For example,
  10. 100 '     the 2nd director is 6% shorter than the driven element,
  11. 110 '     the 3rd is 7% shorter, the 4th, 8% shorter, etc.
  12. 120 '  5. Director spacing is 110% of previous spacing. Spacing starts
  13. 130 '     at 0.2 wavelengths.
  14. 140 '
  15. 150 ' The program is well documented via remarks, so any of the above
  16. 160 ' assumptions may be easily changed.
  17. 170 '
  18. 180 '-------------------- PROGRAM BEGINS --------------------------------------
  19. 190 '
  20. 200 DEFINT I
  21. 210 CLS
  22. 220 PRINT:PRINT "This program calculates the demensions of a VHF Yagi antenna."
  23. 230 PRINT "YOU MAY SELECT FOR OUTPUT OF THIS PROGRAM TO GO TO A PRINTER,"
  24. 240 PRINT ,"OR TO GO TO THE SCREEN."
  25. 250 PRINT "WHICH WOULD YOU LIKE? <P/S>";:P$=INPUT$(1):IF INSTR("PSps",P$)=0 THEN 250
  26. 260 PRINT P$:IF P$="P" OR P$="p" THEN FL=0 ELSE FL=-1
  27. 270 IF NOT(FL) THEN PRINT "TURN PRINTER ON AND ALIGN PAPER BEFORE PROCEEDING."
  28. 280 INPUT"WHAT FREQUENCY (MHZ) ";FREQ
  29. 290 INPUT"HOW MANY ELEMENTS (3 MINIMUM) ";ELNO
  30. 300 WL = 11808/FREQ 'wavelength in free space (inches)
  31. 310 DR = 5600/FREQ 'driven element length (inches)
  32. 320 RF = DR * 1.05 'reflector length
  33. 330 SPR = WL * .2 'reflector spacing
  34. 340 PL(1) = DR * .95'first director length
  35. 350 SPP(1) = WL * .2 'first director spacing
  36. 360 FOR I = 2 TO (ELNO -2)
  37. 370 PRINT
  38. 380 SPP(I) = SPP(I-1) * 1.1 'each director spacing 10% greater than previous
  39. 390 PL(I) = DR * (100 - (4 + I))*.01 'director length
  40. 400 LN1 = LN1 + SPP(I) 'keep track of overall length
  41. 410 NEXT
  42. 420 DEF FNX(X) = INT(X*100+.5)*.01 'function to round off printing to 2 dec.
  43. 430 LNT = SPR + SPP(1) + LN1 'total beam length
  44. 440 IF FL THEN 650
  45. 450 LPRINT"DESIGN DATA FOR VHF YAGI BEAM ANTENNA: "
  46. 460 LPRINT
  47. 470 LPRINT"---- DESIGN FREQUENCY IS";FREQ;" MHZ"
  48. 480 LPRINT"---- TOTAL NUMBER OF ELEMENTS IS";ELNO
  49. 490 LPRINT
  50. 500 LPRINT
  51. 510 LPRINT TAB(35);"LENGTH IN INCHES"
  52. 520 LPRINT "REFLECTOR";TAB(40);FNX(RF)
  53. 530 LPRINT "REFLECTOR TO DRIVEN";TAB(41);FNX(SPR)
  54. 540 LPRINT "DRIVEN";TAB(40);FNX(DR)
  55. 550 LPRINT "DRIVEN TO 1st DIRECTOR";TAB(41);FNX(SPP(1))
  56. 560 LPRINT "1st DIRECTOR LENGTH";TAB(40);FNX(PL(1))
  57. 570 LPRINT
  58. 580 FOR I = 2 TO (ELNO -2)
  59. 590 LPRINT"DIRECTOR No.";I;" LENGTH IS";FNX(PL(I));" INCHES"
  60. 600 LPRINT "SPACED";FNX(SPP(I));" INCHES FROM DIRECTOR No.";I-1
  61. 610 LPRINT
  62. 620 NEXT
  63. 630 LPRINT "------ OVERALL BEAM LENGTH IS";FNX(LNT);" INCHES ------"
  64. 640 GOTO 840
  65. 650 PRINT"DESIGN DATA FOR VHF YAGI BEAM ANTENNA: "
  66. 660 PRINT
  67. 670 PRINT"---- DESIGN FREQUENCY IS";FREQ;" MHZ"
  68. 680 PRINT"---- TOTAL NUMBER OF ELEMENTS IS";ELNO
  69. 690 PRINT
  70. 700 PRINT
  71. 710 PRINT TAB(35);"LENGTH IN INCHES"
  72. 720 PRINT "REFLECTOR";TAB(40);FNX(RF)
  73. 730 PRINT "REFLECTOR TO DRIVEN";TAB(41);FNX(SPR)
  74. 740 PRINT "DRIVEN";TAB(40);FNX(DR)
  75. 750 PRINT "DRIVEN TO 1st DIRECTOR";TAB(41);FNX(SPP(1))
  76. 760 PRINT "1st DIRECTOR LENGTH";TAB(40);FNX(PL(1))
  77. 770 PRINT
  78. 780 FOR I = 2 TO (ELNO -2)
  79. 790 PRINT"DIRECTOR No.";I;" LENGTH IS";FNX(PL(I));" INCHES"
  80. 800 PRINT "SPACED";FNX(SPP(I));" INCHES FROM DIRECTOR No.";I-1
  81. 810 PRINT
  82. 820 NEXT
  83. 830 PRINT "------ OVERALL BEAM LENGTH IS";FNX(LNT);" INCHES ------"
  84. 840 PRINT "End of program."
  85. 850 END
  86.