home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Global Amiga Experience
/
globalamigaexperience.iso
/
compressed
/
misc
/
amiatlas.lha
/
HDInstall
< prev
next >
Wrap
Text File
|
1995-03-07
|
12KB
|
328 lines
; Installationsskript für AmiAtlas Pro Demo V1.3
; erstellt für Installer V1.24, 7.3.95, Autor: Andreas Regul
; (nur für Installation aus aktuellem Verzeichnis geeignet)
; Copyright-Hinweise für Installer:
; Installer and Installer project icon
; (c) Copyright 1991-93 Commodore-Amiga, Inc. All Rights Reserved.
; Reproduced and distributed under license from Commodore.
; INSTALLER SOFTWARE IS PROVIDED "AS-IS" AND SUBJECT TO CHANGE;
; NO WARRANTIES ARE MADE. ALL USE IS AT YOUR OWN RISK. NO LIABILITY
; OR RESPONSIBILITY IS ASSUMED.
(set @user-level 2)
(set @language "deutsch")
(set @abort-button "Installation abbrechen")
(set @special-msg "Ein fataler Fehler ist aufgetreten !\nBitte wiederholen Sie die Installation.")
(set @error-msg (cat "'AmiAtlas Pro' wurde nicht komplett installiert. Bitte wiederholen Sie die Installation, "
"um eine lauffähige Version auf Ihrer Festplatte zu erhalten."))
(set sysdir (expandpath "SYS:"))
(set owndevice (expandpath ":"))
(set osversion (/ (getversion) 65536))
(set isKick20 (>= osversion 36))
(complete 0)
(welcome "Willkommen zur Festplatten-Installation von 'AmiAtlas Pro'.\n")
(set mydir
(askdir
(prompt "Bitte wählen Sie das Laufwerk für 'AmiAtlas Pro'")
(help "\nHilfe zur Laufwerksauswahl\n\n"
"Für 'AmiAtlas Pro' wird ein eigenes Verzeichnis auf der Festplatte benötigt. "
"Um dieses Verzeichnis anlegen zu können, müssen Sie hier die Festplatte "
"angeben, auf der es installiert werden soll (z.B. Work:, DH0:, etc)."
)
(newpath)
(default @default-dest)
(disk)
)
)
(set @default-dest (tackon mydir "AmiAtlas"))
(set routedir (tackon @default-dest "Routen"))
(set mapdir (tackon @default-dest "germany"))
(set icondir (tackon @default-dest "Icons"))
(if (NOT (exists @default-dest))
(makedir @default-dest
(prompt "\nVerzeichnis für 'AmiAtlas Pro' erzeugen\n\n"
"Bitte klicken Sie 'Proceed' an, um für 'AmiAtlas Pro' das Verzeichnis '"
@default-dest "' zu erzeugen.")
(confirm)
(help "\nHilfe zu 'Verzeichnis erzeugen'\n\n"
"Auf dem von Ihnen ausgewählten Laufwerk wird das Unterverzeichnis "
"für 'AmiAtlas Pro' angelegt. Sollten Sie doch einen anderen Pfad als "
"'" @default-dest "' verwenden wollen, können Sie das Installationsprogramm "
"an dieser Stelle abbrechen. Beim Neustart geben Sie dann den von Ihnen "
"gewünschten Pfad an.\n\n"
"Als Verzeichnisname wird jedoch in jedem Fall 'AmiAtlas' verwendet.\n")
(infos)
)
(message "\nHinweis...\n\n"
"Es existiert schon eine Version von AmiAtlas auf Ihrem System. "
"Die neue Installation wird alte Dateien von AmiAtlas überschreiben.\n\n"
"Wenn Sie dies nicht wünschen, brechen Sie bitte an dieser Stelle die "
"Installation ab. Beim erneuten Starten der Festplatteninstallation "
"wählen Sie dann ein anderes Verzeichnis.\n")
)
; Verzeichnis für Icons erzeugen
(if (NOT (exists icondir))
(makedir icondir
(infos)
)
)
(complete 2)
; Verzeichnis für Deutschland-Karte erzeugen
(if (NOT (exists mapdir))
(makedir mapdir
(infos)
)
)
(complete 4)
; Verzeichnis für Routen erzeugen
(if (NOT (exists routedir))
(makedir routedir
(infos)
)
)
(complete 6)
(message "\nProgrammdateien kopieren\n\n"
"Bitte klicken Sie 'Proceed' an, um die Programmdateien von 'AmiAtlas Pro' "
"zu installieren.")
; Programmdateien kopieren
(copyfiles
(prompt "Kopiere Programmdateien.")
(help "")
(source "")
(dest @default-dest)
(choices "AmiAtlas"
"AmiAtlas.info"
"AmiAtlas.countries")
(optional force askuser)
)
(complete 30)
; Icons kopieren
(copyfiles
(prompt "Kopiere Icons")
(help "")
(source "Icons")
(dest icondir)
(optional force askuser)
(all)
)
(complete 35)
; Voreinstellung kopieren
(if (< osversion 36)
(copyfiles
(prompt "Kopiere Voreinstellung.")
(help "")
(source "presets")
(dest @default-dest)
(choices "AmiAtlas.prefs"
"AmiAtlas.prefs.info")
)
(copyfiles
(prompt "Kopiere Voreinstellung.")
(help "")
(source "presets")
(dest "ENVARC:")
(choices "AmiAtlas.prefs"
"AmiAtlas.prefs.info")
)
)
(complete 40)
(if (NOT (exists "LIBS:reqtools.library"))
(set copyReqTools
(askbool
(prompt "\nHinweis\n\nAuf Ihrer Festplatte befindet sich noch nicht die 'reqtools.library' "
"von Nico François.\n\n"
"Es handelt sich hierbei um eine Bibliothek zur verbesserten Darstellung von "
"Requestern, die auf Wunsch auch von 'AmiAtlas Pro' verwendet werden kann.\n\n"
"Soll die 'reqtools.library' installiert werden ?")
(help "\nHilfe zur 'reqtools.library'\n\n"
"Die 'reqtools.library' wurde von Nico François programmiert und verbessert "
"das Aussehen aller Requester, die vom Amiga verwendet werden. Insbesondere "
"erscheinen Requester nicht mehr in der linken, oberen Ecke, sondern werden "
"mittig auf dem Bildschirm zentriert.")
(choices "Ja" "Nein")
(default 0)
)
)
(set copyReqTools TRUE)
)
(if copyReqTools
(if (< osversion 36)
(
(copylib
(prompt "Kopiere Datei 'reqtools.library'")
(help "")
(source "support/libs1.3/reqtools.library")
(dest "LIBS:")
)
)
(
(copylib
(prompt "Kopiere Datei 'AmiAtlas.prefs'")
(help "")
(source "support/libs2.0/reqtools.library")
(dest "LIBS:")
)
)
)
)
(complete 50)
(if (askbool
(prompt "\nBeispielrouten kopieren\n\n"
"Auf der Diskette zu 'AmiAtlas Pro' befinden sich einige abgespeicherte "
"Beispielrouten.\n\n"
"Sollen diese Routen kopiert werden ?")
(help "\nHilfe zu Beispielrouten\n\n"
"Die gespeicherten Routen können Sie selbstverständlich auch selber in der "
"Dialogbox für die Streckenbestimmung eingeben. Sie sollen nur als Hilfe "
"dienen, um zu zeigen, wie abgespeicherte Routendefinitionen aussehen.")
(choices "Ja" "Nein")
(default 0)
)
(copyfiles
(prompt "Kopiere Beispielrouten.")
(help "")
(source "Routen")
(dest routedir)
(optional force askuser)
(all)
)
)
(complete 60)
(message "\nDeutschland-Karte kopieren\n\n"
"Bitte klicken Sie 'Proceed' an, um die Kartendaten von Deutschland zu kopieren.")
(complete 65)
; Deutschland-Karte kopieren
(copyfiles
(prompt "Kopiere Deutschland-Karte")
(help "")
(source "germany")
(dest mapdir)
(pattern "~(#?.info)")
(optional force askuser)
)
(complete 75)
(if (askbool
(prompt "\nIcons erzeugen\n\n"
"'AmiAtlas Pro' ermöglicht es, Icons zu den Kartendaten zu benutzen. "
"Karten mit Icons können direkt über diese Icons geöffnet werden.\n\n"
"Sollen Icons erzeugt werden ?")
(help "\nHilfe zu Icons erzeugen\n\n"
"'AmiAtlas Pro' verwaltet seine Karten in mehreren Einzeldateien. Diese werden "
"normalerweise beim Starten von 'AmiAtlas Pro' direkt nachgeladen und die "
"entsprechende Karte sofort dargestellt.\n\n"
"Wenn hingegen mehrere Karten vorhanden sind, kann immer nur eine Karte zum "
"sofortigen Nachladen bestimmt werden. Die zweite und alle weiteren Karten "
"werden dann über die 'Laden'-Funktion aus dem Menü geöffnet.\n\n"
"Alternativ dazu können zu den Kartendateien Icons erzeugt werden, über die "
"es dann möglich ist, gezielt eine Karte - unanhängig von der Voreinstellung - "
"zu laden.")
(choices "Ja" "Nein")
(default 0)
)
(copyfiles
(prompt "Kopiere Icons zu Kartendateien.")
(help "")
(source "germany")
(dest mapdir)
(pattern "#?.info")
(optional force askuser)
)
)
(complete 80)
(if (askbool
(prompt "\nAnleitung kopieren\n\n"
"Zu AmiAtlas Pro existiert eine umfangreiche Dokumentation, die alle "
"Funktionen des Programms ausführlich beschreibt. Soll diese Anleitung "
"kopiert werden ?\n\n"
"Hinweis: In der Demoversion stehen nicht alle Funktionen uneingeschränkt "
"zur Verfügung.")
(help "")
(choices "Ja" "Nein")
(default 0)
)
(copyfiles
(prompt "Kopiere Anleitung.")
(help "")
(source "")
(dest @default-dest)
(choices "Anleitung"
"Anleitung.info"
"Lies Mich"
"Lies Mich.info"
"Drucke Formular"
"Drucke Formular.info"
"More"
"PrintOut")
(optional force askuser)
)
)
(complete 90)
(set assigncmd (cat "Assign AmiAtlas: \"" @default-dest "\""))
(startup "AmiAtlas"
(prompt "\nAssign für 'AmiAtlas Pro'\n\n"
"Es wird ein Assign in der Datei 'user-startup' benötigt. "
"Bitte 'Proceed' anklicken, um diese Ergänzung automatisch "
"durchführen zu lassen.\n\n"
"Betätigen Sie stattdessen 'Skip this Part', so wird der "
"entsprechende Befehl nicht eingefügt. Ergänzen Sie in diesem "
"Fall selber die 'startup-sequence' bzw. die 'user-startup' "
"durch folgenden Befehl:\n\n"
"Assign AmiAtlas: <Pfad>")
(help "\nHilfe zu Assign\n\n"
"'AmiAtlas Pro' wird über das logische Laufwerk \"AmiAtlas:\" "
"angesprochen und benötigt deshalb einen Verweis auf "
"das entsprechende Festplattenverzeichnis. Dieser Verweis "
"wird beim Amiga in der Datei 'user-startup' durch einen "
"Assign-Befehl hergestellt. Die Installation kann den "
"benötigten Befehl selbständig einfügen.")
(command assigncmd)
)
(complete 100)
(message "\nInstallation beendet\n\n"
"'AmiAtlas Pro' befindet sich nun im Verzeichnis:\n'" @default-dest "'\n\n"
"Bitte booten Sie jetzt Ihren Amiga erneut.")
(exit (quiet))