Global Amiga Experience/globalamigaexperience.iso/compressed/applications/fkm20demod.lha/Install-FKM

Text File | 1994-08-31 | 5KB | 216 lines

; Installationsscript für den FKM 2.0

(set install
  (askbool
     (prompt 'Wollen Sie den FKM neu installieren oder von einer bestehenden Version ein Update machen?')
     (help @askchoice-help)
     (choices 'Neu installieren' 'Update')
     (default 1)
  )
)

(set quel (pathonly @icon))
(complete 0)

(if install
  (
    (set ziel
      (tackon
        (askdir
          (prompt 'Wohin soll das Verzeichnis für den FKM kopiert werden?')
          (help @askdir-help)
          (default 'Work:')
        )
        'FKM'
      )
    )
    (set @default-dest ziel)
    (copyfiles
      (prompt (cat 'Die Datei \"FKM\" wird nach \"' ziel '\" kopiert.'))
      (help @copyfiles-help)
      (source quel)
      (dest ziel)
      (pattern 'FKM')
      (files)
      (infos)
    )
    (complete 25)

    (copyfiles
      (prompt (cat 'Die Datei \"FKM.guide\" (die Online-Hilfe und Anleitung des FKM) wird nach \"' ziel '\" kopiert.'))
      (help @copyfiles-help)
      (source quel)
      (dest ziel)
      (pattern 'FKM.guide')
      (files)
      (infos)
    )
    (complete 50)

    (makedir
      (tackon ziel 'Wagen')
      (prompt 'Das Verzeichnis für die Wagen-Dateien wird eingerichtet')
      (help @makedir-help)
      (infos)
    )
    (complete 55)

    (if
      (askbool
         (prompt 'Soll die Beispiel Wagen-Datei kopiert werden?')
         (help @askchoice-help)
         (choices 'Ja' 'Nein')
         (default 1)
      )

      (copyfiles
        (prompt 'Die Beispiel Wagen-Datei wird kopiert')
        (help @copyfiles-help)
        (source (tackon quel 'Wagen'))
        (dest (tackon ziel 'Wagen'))
        (all)
        (files)
      )
    )
    (complete 65)

    (makedir
      (tackon ziel 'Listen')
      (prompt 'Das Verzeichnis für die Listen wird eingerichtet')
      (help @makedir-help)
      (infos)
    )
    (complete 70)

    (copyfiles
       (prompt (cat 'Die vorgegebenen Listen werden nach \"' (tackon ziel 'Listen') '\" kopiert.'))
       (help @copyfiles-help)
       (source (tackon quel 'Listen'))
       (dest (tackon ziel 'Listen'))
       (all)
    )
    (complete 75)

  )
  (
    (set ziel
      (askdir
        (prompt 'In welchem Verzeichnis befindet sich der FKM?')
        (help @askdir-help)
        (default 'Work:FKM')
      )
    )
    (set @default-dest ziel)

    (if (= (exists (tackon ziel 'FKM')) 1)
      (
        (if (<> (getsize (tackon quel 'FKM')) (getsize (tackon ziel 'FKM')))
          (
            (delete
               (tackon ziel 'FKM')
               (prompt 'Die Datei \"FKM\" wird gelöscht.')
               (help @delete-help)
            )
            (copyfiles
              (prompt (cat 'Die Datei \"FKM\" wird nach \"' ziel '\" kopiert.'))
              (help @copyfiles-help)
              (source quel)
              (dest ziel)
              (pattern 'FKM')
              (files)
            )
          )
        )
        (complete 25)

        (if (<> (getsize (tackon quel 'FKM.guide')) (getsize (tackon ziel 'FKM.guide')))
          (
            (delete
               (tackon ziel 'FKM.guide')
               (prompt 'Die Datei \"FKM.guide\" wird gelöscht.')
               (help @delete-help)
            )
            (copyfiles
              (prompt (cat 'Die Datei \"FKM.guide\" (die Online-Hilfe und Anleitung des FKM) wird nach \"' ziel '\" kopiert.'))
              (help @copyfiles-help)
              (source quel)
              (dest ziel)
              (pattern 'FKM.guide')
              (files)
            )
          )
        )

        (makedir
          (tackon ziel 'Wagen')
          (prompt 'Das Verzeichnis für die Wagen-Dateien wird eingerichtet')
          (help @makedir-help)
          (infos)
        )
        (complete 55)

        (copyfiles
          (prompt (cat 'Die bestehenden Wagen-Dateien werden werden nach \"' (tackon ziel 'Wagen') '\" kopiert.'))
          (help @copyfiles-help)
          (source ziel)
          (dest (tackon ziel 'Wagen'))
          (pattern '#?.(FKM|BAK)')
          (files)
        )
        (copyfiles
          (help @copyfiles-help)
          (source (tackon ziel 'FKM-Startup'))
          (dest (tackon ziel 'Wagen'))
          (newname 'FKM-Wagenliste')
          (files)
        )
        (complete 60)

        (run
           (cat 'delete \"' (tackon ziel '#?.(FKM|BAK)') '\" all')
        )

        (delete
           (tackon ziel 'FKM-Startup')
        )
        (complete 65)

        (makedir
          (tackon ziel 'Listen')
          (prompt 'Das Verzeichnis für die Listen wird eingerichtet')
          (help @makedir-help)
          (infos)
        )
        (complete 70)

        (copyfiles
           (prompt (cat 'Die vorgegebenen Listen werden nach \"' (tackon ziel 'Listen') '\" kopiert.'))
           (help @copyfiles-help)
           (source (tackon quel 'Listen'))
           (dest (tackon ziel 'Listen'))
           (all)
        )
        (complete 75)
      )

      (abort 'Im gewählten Verzeichnis kann der FKM nicht gefunden werden.\n\nDas Installationsprogramm bricht ab.')
    )
  )
)
(copylib
  (prompt 'Die AmigaGuide-Library wird gegebenfalls nach LIBS: kopiert.')
  (help @copylib-help)
  (source (tackon quel 'libs/amigaguide.library'))
  (dest 'LIBS:');
)
(complete 100)

(exit 'Der FKM 2.0 wurde erfolgreich installiert!\n\nViel Spaß mit dem FKM wünscht\nStefan Thomé');