home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.B.po / GAMES:BASIC.4 / SLOTS.bas < prev    next >
BASIC Source File  |  2010-05-14  |  7KB  |  171 lines
  1. 100  REM   :*** SLOTS ***
  2. 110  HOME 
  3. 120  DIM R$(7),P$(3),W(3,9),C(3)
  4. 130 D = 0:B = 20:Y = 0:WT = 100
  5. 140  DATA  "JACKPOT","CHERRY","LEMON","ORANGE","APPLE","PEAR","PEACH"
  6. 150  FOR R = 1 TO 7
  7. 160  READ R$(R): NEXT R
  8. 170  DATA  1,2,2,3,3,4,5,5,5
  9. 180  DATA  1,2,3,3,4,4,5,5,5
  10. 190  DATA  1,2,3,4,4,5,5,6,7
  11. 200  FOR X = 1 TO 3
  12. 210  FOR Y = 1 TO 9
  13. 220  READ W(X,Y)
  14. 230  NEXT Y
  15. 240  NEXT X
  16. 250  PRINT ,: FLASH : PRINT "$  S L O T S  $": NORMAL 
  17. 260  PRINT : PRINT : PRINT : PRINT ,"(6/21/84  J.G.)"
  18. 270  PRINT : PRINT : PRINT : PRINT : INPUT " (WANT COMPUTER TO PLAY YOUR $$ ? ) ";AA$: PRINT : PRINT : PRINT : PRINT 
  19. 280  INPUT "NEED INSTRUCTIONS? (Y/N):";I$
  20. 290  IF I$ = "N"  THEN  GOTO 370
  21. 300  PRINT "JACKPOT--A SIMULATED SLOT"
  22. 310  PRINT "MACHINE.  EACH PLAY IS $.25--"
  23. 320  PRINT : PRINT : PRINT "PAYOFFS: 3 OF A KIND,"
  24. 330  PRINT "  2 OF KIND (FIRST 2 WHEELS),"
  25. 340  PRINT "  OR CHERRIES LAST 2 WHEELS."
  26. 350  PRINT : PRINT : PRINT "OBJECTS ARE JACKPOTS,CHERRIES,LEMONS,ORANGES,APPLES,PEARS,& PEACHES."
  27. 360  PRINT : PRINT 
  28. 370  IF D <0  THEN  PRINT "YOU OWE HOUSE  $";D * -1
  29. 380  IF D > = 0  THEN  PRINT "HOUSE OWES YOU  $";D
  30. 390  IF I$ = "QUIT"  THEN I$ = "": GOTO 900
  31. 400  IF AA$ <"Y"  THEN  INPUT "  'Q'= QUIT ...  <RETURN> = PLAY ";G$
  32. 410  IF G$ = "Q"  THEN  GOTO 890
  33. 420  HOME 
  34. 425  IF D >MX  THEN MX = D
  35. 427  IF D <MN  THEN MN = D
  36. 430 NN = NN +1: PRINT "   THE LEVER HAS BEEN PULLED...    "NN,"  $ "D,"$ ("MX"/"MN")"
  37. 440 D = D -.25:B = B +.25
  38. 450  FOR R = 1 TO 3
  39. 460 C(R) =  INT(9 * RND(1) +1)
  40. 470 P$(R) = R$(W(R,C(R)))
  41. 480 M = 1 +13 *(R -1)
  42. 490  FOR V = 4 TO 18
  43. 500  VTAB (V): HTAB (M): PRINT "|": NEXT V
  44. 510  IF P$(R) = "JACKPOT"  THEN  GOSUB 980
  45. 520  IF P$(R) = "CHERRY"  THEN  GOSUB 1130
  46. 530  IF P$(R) = "LEMON"  THEN  GOSUB 1240
  47. 540  IF P$(R) = "ORANGE"  THEN  GOSUB 1310
  48. 550  IF P$(R) = "APPLE"  THEN  GOSUB 1420
  49. 560  IF P$(R) = "PEAR"  THEN  GOSUB 1530
  50. 570  IF P$(R) = "PEACH"  THEN  GOSUB 1680
  51. 580  VTAB (18): HTAB (M +3): PRINT P$(R)
  52. 590 BZ = 49200: FOR BB = 1 TO 3:ZZ =  PEEK(BZ): NEXT BB: REM    BUZZ SOUND
  53. 600  NEXT R
  54. 610  FOR V = 4 TO 18
  55. 620  VTAB (V): HTAB (40): PRINT "|": NEXT V
  56. 630  PRINT 
  57. 640  IF P$(1) = P$(2)  AND P$(1) < >P$(3)  THEN 690
  58. 650  IF P$(1) = P$(2)  AND P$(1) = P$(3)  THEN 700
  59. 660  IF P$(2) = "CHERRY"  AND P$(3) = "CHERRY"  THEN 760
  60. 670 S = 49200: FOR BR = 1 TO 20:BT =  PEEK(S) + PEEK(S) + PEEK(S) + PEEK(S): NEXT : REM     BUZZ SOUND
  61. 680  INVERSE : PRINT "  YOU  LOSE !!!  ": NORMAL : FOR T = 1 TO WT: NEXT T: GOTO 370
  62. 690 I = .1: GOTO 770
  63. 700  IF P$(1) = "JACKPOT"  THEN I = .75
  64. 710  IF P$(1) = "CHERRY"  THEN I = .55
  65. 720  IF P$(1) = "LEMON"  THEN I = .4
  66. 730  IF P$(1) = "ORANGE"  THEN I = .4
  67. 740  IF P$(1) = "APPLE"  THEN I = .3
  68. 750  GOTO 770
  69. 760 I = .2
  70. 770 P1 = B *.4
  71. 780 P2 = P1 *I
  72. 790 Y =  INT(P2/.25) *.25
  73. 800  FLASH : PRINT "    YOU  WIN !!! --- $";Y: NORMAL 
  74. 810  FOR BL = 1 TO Y/.25: CALL  -1052: NEXT BL: FOR T = 1 TO WT: NEXT T: REM  BELL SOUND
  75. 820 D = D +Y
  76. 830 B = B -Y
  77. 840  IF B < = 0  THEN 870
  78. 850 Y = 0
  79. 860  GOTO 370
  80. 870  PRINT "YOU HAVE BROKEN THE BANK !!!"
  81. 880  STOP 
  82. 890 I$ = "QUIT": GOTO 370
  83. 900  PRINT "THE JACKPOT STANDS AT $";B
  84. 910 D = 0: PRINT : PRINT "  NEW  GAME !!": PRINT : GOTO 400
  85. 920  REM  : HOUSE STARTS WITH $20.;ODDS ARE SET IN 530-600; PAYOUTS VARY AS AMOUNT IN JACKPOT (610-630).THESE ARE FAIRLY HIGH.
  86. 930  REM  : CAN CHANGE ODDS FOR PAYOUTS BY CHANGING I VALUES.
  87. 940  REM  : DATA SHOW WHEEL 1 HAS 1 JACKPOT,2 CHERRIES, 2 LEMONS, 1 ORANGE, & 3 APPLES.
  88. 950  REM  : WHEEL 2 HAS 1 JACKPOT, 1 CHERRY, 2 LEMONS, 2 ORANGES, AND 3 APPLES.
  89. 960  REM  : WHEEL 3 HAS 1 JACKPOT, 1 CHERRY, 1 LEMON, 2 ORANGES, 2 APPLES, 1 PEAR, AND 1 PEACH.
  90. 970  END 
  91. 980  VTAB (5): HTAB (M +2): PRINT "**********"
  92. 990  REM  :  DRAW JACKPOT THEN RETURN.
  93. 1000  VTAB (6): HTAB (M +2): PRINT "*        *"
  94. 1010  VTAB (7): HTAB (M +2): PRINT "*        *"
  95. 1020  VTAB (8): HTAB (M +2): PRINT "**********"
  96. 1030  VTAB (9): HTAB (M +2): PRINT "*        *"
  97. 1040  VTAB (10): HTAB (M +2): PRINT "*   ||$$ *"
  98. 1050  VTAB (11): HTAB (M +2): PRINT "* $$||   *"
  99. 1060  VTAB (12): HTAB (M +2): PRINT "* $$||$$ *"
  100. 1070  VTAB (13): HTAB (M +2): PRINT "*   ||$$ *"
  101. 1080  VTAB (14): HTAB (M +2): PRINT "* $$||   *"
  102. 1090  VTAB (15): HTAB (M +2): PRINT "*        *"
  103. 1100  VTAB (16): HTAB (M +2): PRINT "*        *"
  104. 1110  VTAB (17): HTAB (M +2): PRINT "**********"
  105. 1120  RETURN 
  106. 1130  REM  :DRAW CHERRY 5-17,12 MAX WIDE.
  107. 1140  VTAB (5): HTAB (M +9): PRINT "/"
  108. 1150  HTAB (M +8): PRINT "/"
  109. 1160  HTAB (M +4): PRINT "** /"
  110. 1170  HTAB (M +3): PRINT "*  * **"
  111. 1180  HTAB (M +3): PRINT "*  **  *"
  112. 1190  HTAB (M +3): PRINT " ** *  *"
  113. 1200  HTAB (M +3): PRINT "*  * **"
  114. 1210  HTAB (M +3): PRINT "*  *"
  115. 1220  HTAB (M +3): PRINT " **"
  116. 1230  RETURN 
  117. 1240  REM  :DRAWLEMON5-17,M+1-12.
  118. 1250  VTAB (9): HTAB (M +2): PRINT "  <<<>>>"
  119. 1260  HTAB (M +2): PRINT " <      >"
  120. 1270  HTAB (M +2): PRINT "<        >"
  121. 1280  HTAB (M +2): PRINT " <      >"
  122. 1290  HTAB (M +2): PRINT "  <<<>>>"
  123. 1300  RETURN 
  124. 1310  REM  :SUB TO DRAW ORANGE,V5-17,M+1-11.
  125. 1320  VTAB (7): HTAB (M +2): PRINT "   ****"
  126. 1330  HTAB (M +2): PRINT "  *....*"
  127. 1340  HTAB (M +2): PRINT " *......*"
  128. 1350  HTAB (M +2): PRINT "*........*"
  129. 1360  HTAB (M +2): PRINT "*........*"
  130. 1370  HTAB (M +2): PRINT "*........*"
  131. 1380  HTAB (M +2): PRINT " *......*"
  132. 1390  HTAB (M +2): PRINT "  *....*"
  133. 1400  HTAB (M +2): PRINT "   ****"
  134. 1410  RETURN 
  135. 1420  REM  :SUB TO DRAW APPLE,V5-17,M+1-12.
  136. 1430  VTAB (5): HTAB (M +4): PRINT "**  /"
  137. 1440  HTAB (M +2): PRINT " *  */ **"
  138. 1450  HTAB (M +2): PRINT "*    **  *"
  139. 1460  HTAB (M +2): PRINT "*         *"
  140. 1470  HTAB (M +2): PRINT "*         *"
  141. 1480  HTAB (M +2): PRINT " *        *"
  142. 1490  HTAB (M +2): PRINT "  *      *"
  143. 1500  HTAB (M +2): PRINT "   * *  *"
  144. 1510  HTAB (M +2): PRINT "    * **"
  145. 1520  RETURN 
  146. 1530  REM  : SUB TO DRAW PEAR,V5-17,M+1-12.
  147. 1540  VTAB (5): HTAB (M +5): PRINT "00 00"
  148. 1550  HTAB (M +2): PRINT "   0 0 0"
  149. 1560  HTAB (M +2): PRINT "  0     0"
  150. 1570  HTAB (M +2): PRINT "  0     0"
  151. 1580  HTAB (M +2): PRINT "  0     0"
  152. 1590  HTAB (M +2): PRINT " 0       0"
  153. 1600  HTAB (M +2): PRINT " 0       0"
  154. 1610  HTAB (M +2): PRINT "0         0"
  155. 1620  HTAB (M +2): PRINT "0         0"
  156. 1630  HTAB (M +2): PRINT "0         0"
  157. 1640  HTAB (M +2): PRINT " 0       0"
  158. 1650  HTAB (M +2): PRINT "  0     0"
  159. 1660  HTAB (M +2): PRINT "   00000"
  160. 1670  RETURN 
  161. 1680  REM  :SUB DRAW PEACH,V5-17,M+1-12.
  162. 1690  VTAB (6): HTAB (M +5): PRINT "## ##"
  163. 1700  HTAB (M +2): PRINT "  #  #  #"
  164. 1710  HTAB (M +2): PRINT " #    #  #"
  165. 1720  HTAB (M +2): PRINT "#     #   #"
  166. 1730  HTAB (M +2): PRINT "#     #   #"
  167. 1740  HTAB (M +2): PRINT "#     #   #"
  168. 1750  HTAB (M +2): PRINT " #    #  #"
  169. 1760  HTAB (M +2): PRINT "  #  #  #"
  170. 1770  HTAB (M +2): PRINT "   ## ##"
  171. 1780  RETURN