home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.B.po / GAMES:BASIC.3 / NUKE.POWER.bas < prev    next >
BASIC Source File  |  2010-05-14  |  14KB  |  336 lines
  1. 2 Q =  -16336: TEXT : HOME 
  2. 3  FOR J = 1 TO 2: VTAB J *4 +2: HTAB 4: FOR I = 1 TO 34: PRINT "*";: NEXT : PRINT : NEXT 
  3. 4 A$ = "NUCLEAR POWER PLANT"
  4. 5  FOR I = 1 TO 19 + LEN(A$)/2
  5. 6  FOR J = 1 TO  INT(5 * RND(1) +.5):P =  PEEK(Q): FOR T = 1 TO 20: NEXT T,J
  6. 7  VTAB 8: HTAB 40 -I: PRINT  LEFT$(A$,I)" ": NEXT I
  7. 8  FOR I = 1 TO 2500: NEXT I
  8. 10  HOME : PRINT  SPC( 11)"NUCLEAR POWER PLANT": PRINT 
  9. 20  REM FROM C.C. DEC 80 P.128
  10. 50  PRINT : PRINT "THIS PROGRAM SIMULATES THE OPERATION OF A NUCLEAR POWER REACTOR.  THE OBJECT    IS TO OPERATE THE PLANT AT A MAXIMUM
  11. 80  PRINT "AVERAGE POWER OUTPUT WITHOUT CAUSING    A REACTOR MELTDOWN.": PRINT 
  12. 110  PRINT "THE CONTROL RODS ADJUST THE AMOUNT OF   HEAT PRODUCED BY THE REACTOR.  PRIMARY  COOLANT TRANSFERS THIS HEAT TO THE HEAT EXCHANGER.  SECONDARY COOLANT TRANSFERS
  13. 150  PRINT "HEAT FROM THE HEAT EXCHANGER TO THE     TURBINE, WHERE POWER IS PRODUCED, AND   FINALLY TO THE COOLING TOWER.  THE      EMERGENCY COOLANT IS USED TO HELP SHUT
  14. 190  PRINT "DOWN THE REACTOR WHEN OTHER SYSTEMS     FAIL.  UNLIKE THE OTHER COOLANTS,       EMERGENCY COOLANT IS NOT RECYCLED.
  15. 220  PRINT : INPUT "ENTER 'D' TO SEE REACTOR DIAGRAM        ENTER 'I' FOR WORKING INSTRUCTIONS      ENTER 'S' TO START OPERATION: ";A$
  16. 221  IF A$ = "D"  OR A$ = "d"  THEN  GOSUB 6000: GOTO 220
  17. 222  IF A$ = "S"  OR A$ = "s"  THEN 390
  18. 223  IF A$ < >"I"  AND A$ < >"i"  THEN  HOME : GOTO 220
  19. 225  TEXT : HOME 
  20. 230  PRINT "THE CONTROLS ARE OPERATED BY TYPING IN  THE DESIRED CONTROL ROD SETTING AND     FLOW RATES.(USE VALUES FROM 0 TO 100)   IF NO ENTRY IS MADE, THE VALUES WILL
  21. 250  PRINT "NOT CHANGE.  USE THE SPACE BAR TO STEP  TO THE DIFFERENT FUNCTIONS.  WHEN THE   DESIRED ENTRIES HAVE BEEN MADE, USE THE 'RETURN' KEY TO ADVANCE TO THE NEXT DAY.
  22. 270  PRINT "THE REACTOR CAN BE OPERATED UNTIL A     MELTDOWN OCCURS OR THE REACTOR FUEL IS  EXHAUSTED.  THE FUEL WILL LAST FOR      ABOUT 100 TO 150 DAYS.  WHEN THE FUEL
  23. 290  PRINT "IS EXHAUSTED, YOUR PERFORMANCE WILL BE  EVALUATED.
  24. 298  PRINT : INPUT "   (PRESS RETURN TO CONTINUE)";A$
  25. 300  HOME : PRINT : PRINT "IF YOU WANT TO REPAIR DAMAGE OR REPLACE COOLANT, BRING THE REACTOR TEMPERATURE  DOWN BELOW 100 AND SHUT OFF THE COOLANT FLOWS.  THIS WILL CAUSE AN AUTOMATIC
  26. 320  PRINT "MAINTENANCE SHUTDOWN AND ALL COOLANT    WILL BE REPLENISHED AND REPAIRS MADE.   THE GREATER THE DAMAGE, THE LONGER THE  REPAIRS WILL TAKE.": PRINT 
  27. 350  PRINT "     WARNING: THIS POWER PLANT HAS           NO AUTOMATIC SAFETY DEVICES!": PRINT 
  28. 380  GOTO 220
  29. 390  REM INITIATE
  30. 400  GOSUB 2000
  31. 410 RH = 0
  32. 420 RL = 0
  33. 430 DAY% = 0
  34. 440 TT = 0
  35. 450 DMGE% = 0
  36. 455 A% = 0:A1% = 0:A2% = 0
  37. 460  REM WRITE REPORT
  38. 470  TEXT : HOME 
  39. 475 DAY% = DAY% +1
  40. 480  PRINT  SPC( 7)"APPLE NUCLEAR POWER PLANT                STATUS REPORT - DAY ";DAY%
  41. 500  PRINT : PRINT "WARNINGS:
  42. 520  IF RT% >800  THEN  PRINT " REACTOR OVERHEATED":RD% = RD% +1 +(RT% >850) +(RT% >900) +2 *(RT% >950):PD% = PD% +1:ED% = ED% +1 +(RT% >850)
  43. 530  IF XT% >500  THEN  PRINT " HEAT EXCHANGER OVERHEATED":XD% = XD% +1 +(XT% >600):PD% = PD% +1:SD% = SD% +1
  44. 540  IF GO% >2000  THEN  PRINT " TURBINE OVERLOADED":TD% = TD% +1 +(GO% >2500):SD% = SD% +1
  45. 550  IF CT% >300  THEN  PRINT " COOLING TOWER OVERHEATED":SD% = SD% +1
  46. 560  IF GO% <1000  THEN  PRINT " POWER OUTPUT LOW"
  47. 570  IF EV% <200  THEN  PRINT " EMERGENCY COOLANT LOW
  48. 580  IF PV% <100  THEN  PRINT " PRIMARY COOLANT LOW":PD% = PD% +1
  49. 590  IF SV% <100  THEN  PRINT " SECONDARY COOLANT LOW":SD% = SD% +1
  50. 600  PRINT 
  51. 610  PRINT "DAMAGE:
  52. 620  IF RD% >3  THEN  PRINT " REACTOR CORE DAMAGED
  53. 630  IF PD% >4  THEN  PRINT "PRIMARY COOLANT LEAK - ";PD%;"/DAY":PV% = (PV% -PD%) *((PV% -PD%) >0)
  54. 640  IF SD% >4  THEN  PRINT " SECONDARY COOLANT LEAK - ";SD%;"/DAY":SV% = (SV% -SD%) *((SV% -SD%) >0)
  55. 650  IF ED% >2  THEN  PRINT " EMERGENCY COOLANT LEAK - ";2 *ED%;"/DAY":EV% = (EV% -2 *ED%) *((EV% -2 *ED%) >0)
  56. 660  IF PB%  THEN  PRINT " PRIMARY COOLANT PUMP FAILURE - ";10 *PD% *(PD% <10) +100 *(PD% > = 10);"%
  57. 670  IF SB%  THEN  PRINT " SECONDARY COOLANT PUMP FAILURE - ";10 *SD% *(SD% <10) +100 *(SD% > = 10);"%
  58. 680  IF X%  THEN  PRINT " HEAT EXCHANGER FAILURE
  59. 690  IF GB%  THEN  PRINT " TURBINE FAILURE
  60. 710  PRINT : IF RD% >5  THEN  PRINT "     MELTDOWN!  MELTDOWN!  MELTDOWN!": GOTO 3000
  61. 720  PRINT "INDICATORS:
  62. 730  PRINT " REACTOR TEMP. (MAX 800) ";RT%
  63. 740  PRINT " HEAT EXCHANGER TEMP. (MAX 500) ";XT%
  64. 750  PRINT " COOLING TOWER TEMP. (MAX 300) ";CT%
  65. 760  PRINT " POWER OUTPUT (MAX 2000 KW) ";GO%;" KW
  66. 765 KW% = TT/DAY%
  67. 770  PRINT " AVERAGE POWER OUTPUT ";KW%;" KW/DAY
  68. 800  PRINT " CONTROL RODS- ";A%
  69. 810  PRINT " COOLANTS
  70. 820  PRINT " EMERGENCY LEVEL- ";EV%;"  FLOW- ";EF%
  71. 830  PRINT " PRIMARY   LEVEL- ";PV%;"  FLOW- ";PF%
  72. 840  PRINT " SECONDARY LEVEL- ";SV%;"  FLOW- ";SF%;
  73. 850  IF (100 -RL) <5  THEN  PRINT : PRINT : PRINT "REACTOR FUEL EXHAUSTED": GOTO 4000
  74. 900  REM GET NEW CONTROL VALUES
  75. 910 P =  PEEK(37)
  76. 920  VTAB (P -3)
  77. 930  HTAB (20)
  78. 950 A2% = A1%:A1% = A%
  79. 955 B$ = "": FOR I = 1 TO 4
  80. 960  GET A$:Z =  ASC(A$)
  81. 965  IF (Z < >13  AND Z < >32)  AND (Z >57  OR Z <48)  THEN 960
  82. 970 B$ = B$ +A$: IF Z = 13  THEN 1170
  83. 975  IF Z = 32  THEN 990
  84. 980 A% =  VAL(B$):A% = A% +(100 -A%) *(A% >100)
  85. 985  PRINT A$;: NEXT I
  86. 990  VTAB (P -1)
  87. 1000  HTAB (35)
  88. 1005 B$ = "": FOR I = 1 TO 4
  89. 1010  GET A$:Z =  ASC(A$)
  90. 1015  IF (Z < >13  AND Z < >32)  AND (Z >57  OR Z <48)  THEN 1010
  91. 1020 B$ = B$ +A$: IF Z = 13  THEN 1170
  92. 1025  IF Z = 32  THEN 1050
  93. 1030 EF% =  VAL(B$):EF% = EF% +(100 -EF%) *(EF% >100)
  94. 1035  IF EF% >EV%  THEN EF% = EV%
  95. 1040  PRINT A$;: NEXT I
  96. 1050  VTAB (P)
  97. 1060  HTAB (35)
  98. 1065 B$ = "": FOR I = 1 TO 4
  99. 1070  GET A$:Z =  ASC(A$)
  100. 1075  IF (Z < >13  AND Z < >32)  AND (Z >57  OR Z <48)  THEN 1070
  101. 1080 B$ = B$ +A$: IF Z = 13  THEN 1170
  102. 1085  IF Z = 32  THEN 1110
  103. 1090 PF% =  VAL(B$):PF% = PF% +(100 -PF%) *(PF% >100)
  104. 1100  PRINT A$;: NEXT I
  105. 1110  VTAB (P +1)
  106. 1120  HTAB (35)
  107. 1125 B$ = "": FOR I = 1 TO 4
  108. 1130  GET A$:Z =  ASC(A$)
  109. 1135  IF (Z < >13  AND Z < >32)  AND (Z >57  OR Z <48)  THEN 1130
  110. 1140 B$ = B$ +A$: IF Z = 13  THEN 1170
  111. 1145  IF Z = 32  THEN 1165
  112. 1150 SF% =  VAL(B$):SF% = SF% +(100 -SF%) *(SF% >100)
  113. 1160  PRINT A$;: NEXT I
  114. 1165  HTAB (1): VTAB (P -3): CALL  -958: GOTO 800
  115. 1170  IF PF% = 0  AND SF% = 0  AND RH <1  AND RT% <100  AND A% = 0  THEN  GOSUB 2000: HTAB (1): VTAB (24): CALL  -922: PRINT "         MAINTENANCE SHUTDOWN - ";MD%;" DAYS": FOR I = 0 TO 5000: NEXT 
  116. 1180  IF EF% >EV%  THEN EF% = EV%
  117. 1200  REM DAMAGE ASSESSMENT AND OPERATION CALCULATIONS
  118. 1205 EV% = EV% -EF% -2 *ED% *(ED% >3)
  119. 1210 PD% = PD% +(PF% >90) *( RND(20) >.95)
  120. 1220 SD% = SD% +(SF% >90) *( RND(20) >.92)
  121. 1230 PB% = PD% >5
  122. 1240 SB% = SD% >5
  123. 1250  IF PF% >(100 -PD% *10)  AND PB%  THEN PF% = (100 -PD% *10) *(100 -PD% *10 >0)
  124. 1260  IF SF% >(100 -SD% *10)  AND SB%  THEN SF% = (100 -SD% *10) *(100 -SD% *10 >0)
  125. 1270 RL = RL +RH/50
  126. 1280 RH = (A% *30 +A1% *60 +A2% *10)/2500 *(100 -RL)
  127. 1300 PH = PF% *(100 *(PV% >100) +PV% *(PV% < = 100))/350
  128. 1310 EH = EF%/200 *(RT% -25)
  129. 1320 RT% = RT% +RH -EH -PH -5 *(RT% >25)
  130. 1325 RT% = 25 +(RT% -25) *(RT% >25)
  131. 1330 XT% = ((RT% -25) *PF% +(CT% -25) *SF%)/(PF% +SF% +1) +25
  132. 1340  IF XB%  THEN XT% = RT% *.8 +5
  133. 1350 SH = SF% *(100 *(PV% >100) +PV% *(PV% < = 100))/350 *(XT% -CT%)
  134. 1360  IF XB%  THEN SH = SH *.2
  135. 1370 GO% = SH/XT% *(XT% -CT%) *2/3
  136. 1375  IF GO% >2600  THEN GO% = 2600
  137. 1380 GO% = GO% *(GO% >0) *(GB% = 0)
  138. 1390 CT% = 25 +((XT% -25) *(SH -GO%)/(SH +1) *.75)
  139. 1395 CT% = 25 *(CT% < = 25) +CT% *(CT% >25)
  140. 1400  IF XB% <1  THEN XB% = (XD% >2) *( RND(4) >.9)
  141. 1410  IF GB% <1  THEN GB% = (GD% >4) *( RND(4) >.9)
  142. 1420 TT = TT +GO%
  143. 1430  GOTO 470
  144. 2000  REM MAINTENANCE REPAIR SUBROUTINE
  145. 2010 EV% = 300
  146. 2020 PV% = 120
  147. 2030 SV% = 120
  148. 2040 RT% = 25
  149. 2050 XT% = 25
  150. 2060 CT% = 25
  151. 2070 DMGE% = DMGE% +2 *RD% +ED% +PD% +XD% +SD% +GD%
  152. 2080 MD% = 5 +3 *(10 *(RD% >3) +(ED% >3) +(PD% >3) +(SD% >3) +2 *PB% +2 *SB% +3 *XB% +3 *GB%):DAY% = DAY% +MD%
  153. 2090 RD% = 0
  154. 2100 ED% = 0
  155. 2110 PD% = 0
  156. 2120 XD% = 0
  157. 2130 SD% = 0
  158. 2140 GD% = 0
  159. 2150 PB% = 0
  160. 2160 SB% = 0
  161. 2170 XB% = 0
  162. 2180 GB% = 0
  163. 2190 EF% = 0:PF% = 0:SF% = 0
  164. 2195 GO% = 0
  165. 2200  RETURN 
  166. 3000  REM MELTDOWN ENDING
  167. 3010  PRINT 
  168. 3020  IF RD% >6  THEN 3100
  169. 3030  PRINT "THE REACTOR CORE HAS BEEN DESTROYED BY
  170. 3040  PRINT "UNCONTROLLED THERMAL RUNAWAY.  HOWEVER,
  171. 3050  PRINT "THE CONTAINMENT BUILDING HAS NOT YET
  172. 3060  PRINT "RUPTURED.": PRINT 
  173. 3080  PRINT "INITIATE YOUR EVACUATION PLAN.
  174. 3090  GOTO 5000
  175. 3100  PRINT "THE REACTOR CORE HAS MELTED DOWN AND
  176. 3110  PRINT "PRODUCED A STEAM EXPLOSION.  THE
  177. 3120  PRINT "CONTAINMENT BUILDING HAS RUPTURED.
  178. 3130  PRINT "LETHAL RADIOACTIVE GASES AND DEBRIS
  179. 3140  PRINT "HAVE ESCAPED.": PRINT 
  180. 3160  PRINT "INITIATE YOUR EVACUATION AND RADIATION
  181. 3170  PRINT "CLEANUP PLANS AND GET MEDICAL
  182. 3180  PRINT "ASSISTANCE.
  183. 3190  GOTO 5000
  184. 4000  REM EVALUATION OF GAME RESULTS
  185. 4020  PRINT : PRINT "OVER A PERIOD OF ";DAY%;" DAYS, YOU HAVE
  186. 4030  PRINT "PRODUCED AN AVERAGE POWER OUTPUT OF
  187. 4040  PRINT KW%;" KILOWATTS PER DAY.
  188. 4050 AKW% = 1 +(KW% >1000) +(KW% >1200) +(KW% >1500) +(KW% >1800)
  189. 4070  PRINT : PRINT "YOUR AVERAGE POWER PRODUCTION RATE IS
  190. 4080  ON AKW% GOTO 4090,4100,4110,4120,4140
  191. 4090  PRINT "HORRIBLE! FIND A LESS DEMANDING JOB.": GOTO 4200
  192. 4100  PRINT "WAY BELOW YOUR AREA'S POWER NEEDS.": GOTO 4200
  193. 4110  PRINT "ADEQUATE. YOU COULD DO BETTER.": GOTO 4200
  194. 4120  PRINT "EXCELLENT! POWER COSTS IN YOUR AREA
  195. 4130  PRINT "WILL NOT BE INCREASED.": GOTO 4200
  196. 4140  PRINT "NEAR THE MAXIMUM!  POWER COSTS IN YOUR
  197. 4150  PRINT "AREA WILL DROP SIGNIFICANTLY.
  198. 4200  REM  DAMAGE EVALUATION
  199. 4215  PRINT : GOSUB 2000
  200. 4220 D% = 1 +(DMGE% >10) +(DMGE% >20) +(DMGE% >30)
  201. 4230  PRINT "THE EQUIPMENT DAMAGE SUSTAINED DURING
  202. 4240  PRINT "THIS PERIOD WAS ";
  203. 4250  ON D% GOTO 4260,4270,4280,4290
  204. 4260  PRINT "VERY LIGHT.": GOTO 5000
  205. 4270  PRINT "MODERATE.": GOTO 5000
  206. 4280  PRINT "HEAVY.": GOTO 5000
  207. 4290  PRINT "SEVERE.
  208. 5000  REM END
  209. 5020  PRINT : PRINT "WOULD YOU LIKE TO TRY AGAIN? (Y OR N) ";
  210. 5030  INPUT A$
  211. 5040  IF A$ = ""  THEN 5030
  212. 5050  IF A$ = "Y"  OR A$ = "y"  THEN  GOSUB 2000: GOTO 390
  213. 5055  IF A$ < >"n"  AND A$ < >"N"  THEN  GOTO 5020
  214. 5060  PRINT : PRINT  CHR$(4)"-STARTUP"
  215. 5100 B$ = ""
  216. 5105  FOR I = 1 TO 4
  217. 5110  GET A$
  218. 5130  IF  ASC(A$) < >32  THEN 5140
  219. 5134  IF B$ = ""  THEN  RETURN 
  220. 5136 OUT% =  VAL(B$)
  221. 5138  RETURN 
  222. 5140  IF  ASC(A$) = 13  THEN  POP : GOTO 1170
  223. 5150 B$ = B$ +A$
  224. 5160  PRINT A$;
  225. 5170  NEXT I
  226. 5180  RETURN 
  227. 6000  GR : COLOR= 15: FOR I = 0 TO 39: HLIN 0,39 AT I: NEXT 
  228. 6005 DE = 6000
  229. 6010  HOME : VTAB 23
  230. 6020  PRINT "  THIS IS THE REACTOR VESSEL
  231. 6030  RESTORE 
  232. 6035  COLOR= 1
  233. 6040  FOR I = 1 TO 29
  234. 6050  READ X1,X2,Y
  235. 6060  HLIN X1,X2 AT Y
  236. 6070  NEXT 
  237. 6080  DATA 7,9,6,15,17,6,6,18,7,5,19,8,5,7,9,17,19,9,5,6,10,18,19,10,5,6,11,18,19,11,5,6,12,18,19,12,5,6,13,18,19,13,5,6,14
  238. 6090  DATA 18,19,14,5,6,15,18,19,15,5,6,16,18,19,16,5,6,17,18,19,17,5,6,18,18,19,18,5,7,19,17,19,19,6,18,20,7,17,21,8,16,22
  239. 6100  COLOR= 0
  240. 6110  HLIN 13,14 AT 6
  241. 6120  COLOR= 12
  242. 6130  HLIN 14,15 AT 5
  243. 6140  HLIN 16,15 AT 4
  244. 6150  HLIN 15,16 AT 3
  245. 6160  FOR I = 1 TO DE: NEXT 
  246. 6170  VTAB 23
  247. 6180  PRINT "  THIS IS THE REACTOR CORE    
  248. 6190  COLOR= 8
  249. 6200  FOR I = 9 TO 15
  250. 6210  VLIN 11,17 AT I
  251. 6220  NEXT 
  252. 6230  FOR I = 1 TO DE: NEXT 
  253. 6240  VTAB 23
  254. 6250  PRINT "  THESE ARE THE CONTROL RODS  "
  255. 6260  COLOR= 13
  256. 6270  VLIN 2,17 AT 11
  257. 6280  VLIN 2,17 AT 13
  258. 6290  FOR I = 1 TO DE: NEXT 
  259. 6300  VTAB 23
  260. 6310  PRINT " THE EMERGENCY COOLANT CAN COOL THE
  261. 6320  PRINT " REACTOR IN AN EMERGENCY.
  262. 6330  COLOR= 2
  263. 6340  FOR I = 1 TO 36
  264. 6350  READ X,Y
  265. 6360  PLOT X,Y
  266. 6370  FOR J = 1 TO 200: NEXT J
  267. 6380  NEXT I
  268. 6390  DATA 4,2,4,4,5,2,5,3,5,4,6,2,6,3,6,4,7,3,8,3,9,3,10,3,11,3,12,3,12,4,12,5,12,6,12,7,12,8,12,9
  269. 6400  DATA 13,9,14,9,15,9,16,9,16,8,16,7,16,6,16,5,16,4,16,3,17,3,18,3,19,3,20,3,22,3,24,3
  270. 6410  FOR I = 1 TO DE: NEXT I
  271. 6420  HOME : VTAB 23
  272. 6430  PRINT " THE PRIMARY COOLANT CARRIES HEAT FROM
  273. 6440  PRINT " THE REACTOR CORE TO THE HEAT EXCHANGER
  274. 6450  FOR I = 1 TO 52
  275. 6460  READ Y,X
  276. 6470  PLOT X,Y
  277. 6480  FOR J = 1 TO 200: NEXT J
  278. 6490  NEXT I
  279. 6500  FOR I = 1 TO DE: NEXT I
  280. 6510  DATA 4,25,4,27,5,25,5,26,5,27,6,25,6,26,6,27,7,26,8,26,9,26,10,26,11,26,12,26,12,25,12,24,12,23,12,22,12,21,12,20,12,19
  281. 6515  DATA 12,18,12,17,12,16,12,15,13,15,14,15,15,15,16,15,16,16,16,17,16,18
  282. 6520  DATA 16,19,16,20,16,21,16,22,16,23,16,24,16,25,16,26,16,27,16,28,16,29,16,30,15,30,14,30,13,30,13,30,12,30,12,29,12,28,12,27
  283. 6540  HOME : VTAB 23
  284. 6550  PRINT " THIS IS THE HEAT EXCHANGER
  285. 6560  COLOR= 5
  286. 6570  HLIN 28,34 AT 10
  287. 6580  VLIN 10,18 AT 34
  288. 6590  HLIN 28,34 AT 18
  289. 6600  VLIN 10,18 AT 28
  290. 6605  COLOR= 2: PLOT 28,12: PLOT 28,16: COLOR= 5
  291. 6610  FOR I = 1 TO DE: NEXT I
  292. 6620  VTAB 23
  293. 6630  PRINT " THIS IS THE GENERATOR TURBINE
  294. 6640  HLIN 5,18 AT 30
  295. 6650  VLIN 30,36 AT 18
  296. 6660  HLIN 5,18 AT 36
  297. 6670  VLIN 30,36 AT 5
  298. 6680  COLOR= 0
  299. 6690  HLIN 2,17 AT 33
  300. 6700  FOR I = 7 TO 15  STEP 2
  301. 6710  PLOT I,34: PLOT I +1,32
  302. 6720  NEXT I
  303. 6730  FOR I = 1 TO DE: NEXT I
  304. 6740  VTAB 23
  305. 6750  PRINT " THIS IS THE COOLING TOWER            "
  306. 6760  COLOR= 5
  307. 6770  VLIN 23,25 AT 24
  308. 6780  VLIN 23,25 AT 36
  309. 6790  VLIN 25,26 AT 25
  310. 6800  VLIN 25,26 AT 35
  311. 6810  VLIN 26,28 AT 26
  312. 6820  VLIN 26,28 AT 34
  313. 6830  VLIN 28,36 AT 27
  314. 6840  VLIN 28,36 AT 33
  315. 6850  PLOT 34,36
  316. 6860  PLOT 26,36
  317. 6870  HLIN 25,35 AT 38
  318. 6880  FOR I = 1 TO DE: NEXT I
  319. 6890  VTAB 23
  320. 6900  PRINT " THE SECONDARY COOLANT CARRIES HEAT
  321. 6910  PRINT " FROM THE HEAT EXCHANGER TO THE "
  322. 6920  PRINT " TURBINE AND THEN TO THE COOLING TOWER
  323. 6925  COLOR= 2
  324. 6930  FOR I = 1 TO 123
  325. 6940  READ Y,X
  326. 6950  PLOT X,Y
  327. 6960  FOR J = 1 TO 200: NEXT J
  328. 6970  NEXT I
  329. 6980  DATA   4,35,4,37,5,35,5,36,5,37,6,35,6,36,6,37,7,36,8,36,9,36,10,36,11,36,12,36,12,35,12,34,12,33,12,32,13,32,14,32,15,32,16,32
  330. 6990  DATA 16,33,16,34,16,35,16,36,17,36,18,36,19,36,20,36,20,35,20,34,20,33,20,32,20,31,20,30,20,29,20,28,20,27,20,26,20,25,20,24,20,23,20,22,20,21
  331. 7000  DATA 21,21,22,21,23,21,24,21,25,21,26,21,27,21,27,20,27,19,27,18,27,17,27,16,27,15,27,14,27,13,27,12,27,11,27,10,27,9,27,8,27,7
  332. 7010  DATA  28,7,29,7,30,7,31,7,32,7,34,10,32,13,34,16,35,16,35,17,35,18,35,19,35,20,35,21,35,22,35,23,35,24,35,25,35,26,35,27,35,28
  333. 7020  DATA 34,28,34,29,34,30,35,30,35,31,35,32,34,32,34,33,34,34,34,35,34,36,34,37,34,38,33,38,32,38,31,38,30,38,29,38,28,38,27,38,26,38,25,38,24,38,23,38
  334. 7030  DATA 22,38,21,38,20,38,19,38,18,38,17,38,16,38,15,38,14,38,13,38,12,38,12,37
  335. 7040  HOME : VTAB 23
  336. 7060  RETURN