home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.A.po / FEATURES:BEAGLE / SHAPE.MECH1.SHK / SHAPE.MECHANIC / TEXT.TRICKS.bas < prev    next >
BASIC Source File  |  2000-01-01  |  4KB  |  37 lines
  1. 100  SPEED= 255: NOTRACE : GOSUB 60000
  2. 200 PAUSE = 22:DOT$ = "........................................": PRINT  CHR$(21)
  3. 300  REM <CTRL-M><CTRL-M>DOT WIPES<CTRL-M>=========
  4. 400 X =  INT( RND(1) *3) +1: ON X GOTO 500,600,700
  5. 500  FOR I = 1 TO 23: VTAB I: HTAB 1: PRINT DOT$;: NEXT : FOR I = 1 TO 39: PRINT ".";: NEXT : POKE 2039,174: GOTO 900
  6. 600  POKE 33,1: FOR I = 0 TO 39: POKE 32,I: VTAB 1: HTAB 1: PRINT  LEFT$(DOT$,24);: NEXT : TEXT : GOTO 900
  7. 700  VTAB 24: HTAB 1: FOR I = 1 TO 39: PRINT ".";: NEXT : POKE 2039,174: FOR I = 23 TO 1  STEP  -1: VTAB I: HTAB 1: PRINT DOT$;: NEXT 
  8. 800  REM <CTRL-M><CTRL-M>MENU<CTRL-M>====
  9. 900  POKE 32,5: POKE 33,35: VTAB 5: HTAB 5: INVERSE : PRINT " SCREEN WIPES ": PRINT : NORMAL : PRINT "<1> LEFT/RIGHT WIPE": PRINT "<2> RIGHT/LEFT WIPE": PRINT "<3> CENTER OUT WIPE": PRINT "<4> UP WIPE": PRINT "<5> DOWN WIPE": PRINT "<6> STRIPE WIPE"
  10. 1000  PRINT "<7> SCROLL WIPE": PRINT "<8> HYPE WIPE": PRINT "<9> CHECKERBOARD WIPE": PRINT "<0> IRRITATING WIPE": PRINT : PRINT "<Q> QUIT"
  11. 1100  TEXT : VTAB 20: HTAB 10: PRINT "SELECT: "; CHR$(8);: GET A$: PRINT A$: IF   NOT  VAL(A$)  AND A$ < >"0"  AND A$ < >"Q"  AND A$ < >"q"  THEN 1100
  12. 1200  REM <CTRL-M><CTRL-M>QUIT<CTRL-M>====
  13. 1300  IF A$ = "Q"  OR A$ = "q"  THEN  FOR V = 1 TO 23:H = 25 -V:A = 128 *V +H -(984 * INT((V -1)/8)) +895:B = A +1:PA =  PEEK(A):PB =  PEEK(B): POKE A,221: POKE B,96: POKE 0,10 *V: POKE 1,9: CALL 771: FOR J = 1 TO 25: NEXT : POKE A,PA: POKE B,PB: NEXT : VTAB 23: END 
  14. 1400  ON  VAL(A$) +1 GOSUB 3500,1700,1900,2100,2300,2500,2700,2900,3100,3300
  15. 1500  FOR I = 1 TO 999 -999 *(A$ = "0"): NEXT : GOTO 400
  16. 1600  REM <CTRL-M><CTRL-M>LEFT/RIGHT WIPE<CTRL-M>===============
  17. 1700  FOR I = 1 TO 40: POKE 33,I: HOME : GOSUB 3600: NEXT : RETURN 
  18. 1800  REM <CTRL-M><CTRL-M>RIGHT/LEFT WIPE<CTRL-M>===============
  19. 1900  FOR I = 39 TO 0  STEP  -1: POKE 32,I: POKE 33,40 -I: HOME : GOSUB 3600: NEXT : RETURN 
  20. 2000  REM <CTRL-M><CTRL-M>CENTER OUT WIPE<CTRL-M>===============
  21. 2100  FOR I = 1 TO 20: POKE 32,20 -I: POKE 33,2 *I: HOME : GOSUB 3600: NEXT : RETURN 
  22. 2200  REM <CTRL-M><CTRL-M>UP WIPE<CTRL-M>=======
  23. 2300  FOR I = 24 TO 1  STEP  -1: VTAB I: HTAB 1: CALL  -868: GOSUB 3600: NEXT : RETURN 
  24. 2400  REM <CTRL-M><CTRL-M>DOWN WIPE<CTRL-M>=========
  25. 2500  FOR I = 1 TO 24: VTAB I: HTAB 1: CALL  -868: GOSUB 3600: NEXT : RETURN 
  26. 2600  REM <CTRL-M><CTRL-M>STRIPE WIPE<CTRL-M>===========
  27. 2700  INVERSE : FOR I = 1 TO 24: VTAB I: HTAB 1: INVERSE : PRINT  SPC( 40): VTAB I: HTAB 1: NORMAL : PRINT  SPC( 40): NEXT : HOME : RETURN 
  28. 2800  REM <CTRL-M><CTRL-M>SCROLL WIPE<CTRL-M>===========
  29. 2900  FOR I = 1 TO 24: VTAB 24: PRINT : GOSUB 3600: NEXT : RETURN 
  30. 3000  REM <CTRL-M><CTRL-M>HYPE WIPE<CTRL-M>=========
  31. 3100  VTAB 1: HTAB 1: FOR I = 1 TO 23: PRINT "BUY BEAGLE BROS.     BUY BEAGLE BROS.    ";: NEXT : RETURN 
  32. 3200  REM <CTRL-M><CTRL-M>CHECKERBOARD WIPE<CTRL-M>=================
  33. 3300  INVERSE : FOR I = 24 TO 1  STEP  -1: VTAB I: FOR J = I - INT(I/2) *2 +1 TO 40  STEP 2: HTAB J: PRINT " ";: NEXT : NEXT : NORMAL : RETURN 
  34. 3400  REM <CTRL-M><CTRL-M>IRRITATING WIPE<CTRL-M>===============
  35. 3500  POKE  -16298,0: POKE  -16302,0: FOR I = 3 TO 72: POKE  -16304,0: FOR J = 1 TO 1: NEXT : POKE  -16303,0: NEXT : RETURN 
  36. 3600  FOR J = 1 TO PAUSE: NEXT : RETURN 
  37. 60000  POKE 771,173: POKE 772,48: POKE 773,192: POKE 774,136: POKE 775,208: POKE 776,4: POKE 777,198: POKE 778,1: POKE 779,240: POKE 780,8: POKE 781,202: POKE 782,208: POKE 783,246: POKE 784,166: POKE 785,0: POKE 786,76: POKE 787,3: POKE 788,3: POKE 789,96: RETURN