home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.A.po / FEATURES:BEAGLE / BEAGLE.BAG.SHK / BEAGLE.BAG / BUZZWORD.bas < prev    next >
BASIC Source File  |  2000-01-01  |  14KB  |  204 lines
  1. 44  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>==================<CTRL-M>BUZZWORD<CTRL-M>BY BERT KERSEY<CTRL-M>COPYRIGHT (C) 1980<CTRL-M>BEAGLE BROS<CTRL-M>==================<CTRL-M>
  2. 139  ONERR  GOTO 63900
  3. 140  GOSUB 20000: GOTO 1060
  4. 145  REM <CTRL-M><CTRL-M>PRINT STORY<CTRL-M>-----------
  5. 150  FOR I = 1 TO  LEN(A$):M$ =  MID$ (A$,I,1): IF M$ >"."  AND M$ <"8"  THEN  GOSUB 500: GOTO 230
  6. 155  IF ( PEEK(37) - INT( PEEK(37)/2) *2 = 1)  AND ( PEEK(37) < >23)  THEN  PRINT 
  7. 158  IF  PEEK(Q) = 155  THEN  POKE Q +16,0: POP : GOTO 1060
  8. 160  PRINT M$;: FOR J = 1 TO 3:S =  PEEK(Q +48): NEXT J: IF M$ < >" "  OR I =  LEN(A$)  THEN 220
  9. 169  REM <CTRL-M><CTRL-M>CARRIAGE RETURN?<CTRL-M>---------------- 
  10. 170 J = I +1
  11. 180 J = J +1: IF  MID$ (A$,J,1) < >" "  THEN 210
  12. 190  IF (J -I + PEEK(36)) <39  THEN 220
  13. 195  PRINT : PRINT : GOTO 220
  14. 210  IF J < LEN(A$)  THEN 180
  15. 220  IF  PEEK(37) >15  THEN  CALL  -958
  16. 227  IF M$ = "."  OR M$ = "!"  THEN  FOR J = 1 TO 444: NEXT J
  17. 230  NEXT : RETURN 
  18. 499  REM <CTRL-M><CTRL-M>GET BUZZWORD<CTRL-M>------------ 
  19. 500  IF M$ = "/"  THEN N$ = S$:I = I +1: RETURN 
  20. 530  IF M$ = "0"  THEN S$ = N$: GOTO 605
  21. 540 N =  ASC(M$) -48
  22. 550  IF  PEEK(36) <MRGN  THEN 570
  23. 560  PRINT : PRINT 
  24. 570  PRINT "***";: FOR J = 1 TO 50:S =  PEEK(Q +48): NEXT : HTAB  PEEK(36) -2: COLOR= 6: HLIN  PEEK(36), PEEK(36) +2 AT 2 * PEEK(37) +1
  25. 580 K =  PEEK(Q): IF (K <193  AND K < >155)  OR K >218  THEN 580
  26. 585  POKE Q +16,0: IF K = 155  THEN  POP : GOTO 1060
  27. 590 L = K -192
  28. 591  IF N = 1  THEN S$ = PRS$(L)
  29. 592  IF N = 2  THEN S$ = PLC$(L)
  30. 593  IF N = 4  THEN S$ = ADJ$(L)
  31. 594  IF N = 5  THEN S$ = VB$(L)
  32. 596  IF N = 6  THEN S$ = PST$(L)
  33. 597  IF N = 7  THEN S$ = ING$(L)
  34. 598  IF N < >3  THEN 605
  35. 599 S$ = T1$(L):R =  INT( RND(1) *3): IF R = 1  THEN S$ = T2$(L)
  36. 600  IF R = 2  THEN S$ = T3$(L)
  37. 605  IF  PEEK(36) > = MRGN  THEN  PRINT : PRINT 
  38. 610  FOR J = 1 TO  LEN(S$): PRINT  MID$ (S$,J,1);: IF  MID$ (S$,J,1) < >" "  THEN 630
  39. 620  IF  PEEK(36) > = MRGN  THEN  PRINT : PRINT 
  40. 630  FOR K = 1 TO 3:S =  PEEK(Q +48): NEXT K: FOR K = 1 TO 30: NEXT K,J
  41. 640  RETURN 
  42. 1010  REM <CTRL-M><CTRL-M>MENU<CTRL-M>----  
  43. 1060  TEXT : HOME : INVERSE :MRGN = 30:ESC = 0: VTAB 3: HTAB 3: PRINT " BEAGLE BROS ": ONERR  GOTO 63900
  44. 1070  FOR I = 1 TO 999: NEXT 
  45. 1080  INVERSE : VTAB 3: HTAB 3: PRINT " BUZZ";
  46. 1090  FOR I = 1 TO 50:S =  PEEK(Q +48) + PEEK(Q +48): NEXT 
  47. 1110  HTAB 8: PRINT "WORD! ";: NORMAL : PRINT "  "
  48. 1120  FOR I = 1 TO 66:S =  PEEK(Q +48): NEXT 
  49. 1130  VTAB 5: HTAB 3
  50. 1140  PRINT " PICK A STORY...          ": PRINT : NORMAL 
  51. 1150  PRINT " . 'THE ISLE OF ***'": GOSUB 1350
  52. 1160  PRINT " . 'NEVER TRUST A ***!'": GOSUB 1350
  53. 1170  PRINT " . 'REPAIRING YOUR ***'": GOSUB 1350
  54. 1180  PRINT " . 'MISTER ***'": GOSUB 1350
  55. 1190  PRINT " . '*** YOUR DOG'": GOSUB 1350
  56. 1200  INVERSE : HTAB 3: PRINT " OR...                    ": NORMAL : PRINT 
  57. 1210  PRINT " . CREATE YOUR OWN STORY.": VTAB 24: PRINT "(TYPE Q TO QUIT.)";: VTAB 1: PRINT : GOSUB 1350
  58. 1220  FOR I = 12 TO 28  STEP 4: COLOR= 2: PLOT 3,I: NEXT 
  59. 1230  PLOT 19,12: PLOT 22,16: PLOT 22,20: PLOT 14,24: PLOT 16,28
  60. 1240 A = 1:X = 0
  61. 1250  FOR I = 1 TO 6: VTAB 2 *I +5 +2 * INT(I/6): NORMAL : IF A = I  THEN  INVERSE 
  62. 1252  PRINT I: NEXT 
  63. 1260 A = A +1: IF A >6  THEN A = 1
  64. 1262 X = X +1: IF X < >36  THEN 1280
  65. 1270  INVERSE : VTAB 21: HTAB 3: PRINT " HURRY UP! ": FOR I = 1 TO 99:S =  PEEK(Q +48): NEXT 
  66. 1280  FOR I = 1 TO 50: NEXT 
  67. 1290 K =  PEEK(Q): IF K <177  OR (K >182  AND K < >209)  THEN 1250: POKE Q +16,0:K = K -176
  68. 1292  POKE Q +16,0:K = K -176
  69. 1295  IF K = 33  THEN 63900
  70. 1300  IF K = 6  THEN 1500
  71. 1310  INVERSE : HOME 
  72. 1320  VTAB 24: PRINT " TYPE A LETTER WHEN YOU HEAR THE BUZZ. ";: VTAB 1: HTAB 1
  73. 1330  ON K GOTO 9100,9200,9300,9400,9500
  74. 1349  REM <CTRL-M><CTRL-M>BUZZ<CTRL-M>---- 
  75. 1350  FOR J = 1 TO 9:S =  PEEK( -16336): NEXT J: PRINT : RETURN 
  76. 1500  REM <CTRL-M><CTRL-M>TYPE YOUR OWN STORY<CTRL-M>-------------------
  77. 1520  NORMAL : HOME :TRY = 0:V = 9
  78. 1560  TEXT : POKE 35,7: HOME : TEXT : VTAB 1: HTAB 1: ONERR  GOTO 63900
  79. 1580  PRINT "PERSON PLACE THING ADJ. VERB VB/PAST ING------ ----- ----- ---- ---- ------- ---";
  80. 1585  FOR I = 1 TO 182:A(I) = 0: NEXT 
  81. 1600  INVERSE : FOR I = 1 TO 7: HTAB 6 *I -4: PRINT " "; CHR$(I +32);" ";: NEXT : FOR I = 1 TO 7: HTAB 6 *I -4: PRINT " ";I;" ";: NEXT : NORMAL 
  82. 1700  PRINT : PRINT "@=GET/SAVE STORY  *,*=ERASE  ==CURSOR UP----------------------------------------<CTRL-G>";
  83. 1730  INVERSE : VTAB 6: HTAB 1: PRINT "@";: HTAB 19: PRINT "*";: HTAB 21: PRINT "*";: HTAB 30: PRINT "=": NORMAL 
  84. 1800  POKE 34,4: COLOR= 6: VTAB V: HTAB 1
  85. 1815  REM <CTRL-M><CTRL-M>PRINT-LETTER LOOP<CTRL-M>----------------- 
  86. 1820 ESC = 0
  87. 1840  IF ESC >1  THEN 1060
  88. 1846 A$ = M$: GET M$
  89. 1850  IF M$ = "*"  THEN  PRINT M$;"<CTRL-H>";:ESC = ESC +1: GOTO 1840
  90. 1860  IF M$ = "@"  THEN 3000
  91. 1870  IF M$ = "="  THEN  VTAB  PEEK(37) +( PEEK(37) = 0): HTAB  PEEK(36) +1: GOTO 1820
  92. 1880  IF M$ <"8"  AND M$ >"0"  THEN 2000
  93. 1890  PRINT M$;: GOTO 1820
  94. 1999  REM <CTRL-M><CTRL-M>GET A BUZZWORD<CTRL-M>--------------
  95. 2000  IF  PEEK(36) > = MRGN  THEN  PRINT 
  96. 2100 TRY = TRY +1: IF TRY >25  THEN TRY = 1: FOR I = 1 TO 182:A(I) = 0: NEXT 
  97. 2110 I =  INT( RND(1) *26) +1:N = 26 * VAL(M$) -26 +I: IF A(N) >0  THEN 2110
  98. 2120 A(N) = 1
  99. 2201  IF M$ = "1"  THEN S$ = PRS$(I)
  100. 2202  IF M$ = "2"  THEN S$ = PLC$(I)
  101. 2204  IF M$ = "4"  THEN S$ = ADJ$(I)
  102. 2205  IF M$ = "5"  THEN S$ = VB$(I)
  103. 2206  IF M$ = "6"  THEN S$ = PST$(I)
  104. 2207  IF M$ = "7"  THEN S$ = ING$(I)
  105. 2210  IF M$ < >"3"  THEN 2240
  106. 2215 S$ = T1$(I):N =  INT( RND(1) *3): IF N = 1  THEN S$ = T2$(I)
  107. 2220  IF N = 2  THEN S$ = T3$(I)
  108. 2240  PRINT M$;"<CTRL-H>"; SPC( (A$ >" "  AND A$ <"0")  OR (A$ >"9")  AND  PEEK(36) < >0);S$;" ";: FOR J = 1 TO 50:S =  PEEK(Q +48): NEXT J
  109. 2250  GOTO 1820
  110. 3000  REM <CTRL-M><CTRL-M>SAVE STORY<CTRL-M>----------
  111. 3010  TEXT : VTAB 1: HTAB 1: PRINT M$: POKE 35,6: HOME : PRINT "GET STORY FROM DISK OR SAVE STORY?";
  112. 3020  HTAB 1: FLASH : PRINT "G";: HTAB 24: PRINT "S": NORMAL : PRINT "^";: HTAB 24: PRINT "^"
  113. 3025  PRINT : PRINT "PRESS G OR S (OR ESC TO CANCEL)."
  114. 3030 K =  PEEK(Q): IF K < > ASC("G") +128  AND K < > ASC("S") +128  AND K < >155  THEN 3030
  115. 3040  POKE Q +16,0: IF K = 155  THEN 1560
  116. 3050  IF K =  ASC("G") +128  THEN 4000
  117. 3960  HOME : PRINT "NAME OF STORY TO BE SAVED": PRINT : PRINT "TYPE NAME & PRESS <RETURN>.": PRINT : PRINT "(<RETURN> ONLY TO CANCEL.)": VTAB 1: HTAB 26: INPUT P$
  118. 3965  IF P$ = ""  THEN 1560
  119. 3970  HOME : TEXT : VTAB 4: HTAB 20 - INT( LEN(P$))/2: PRINT P$
  120. 3980  PRINT "<CTRL-D>BSAVE ";P$;",A$400,L$400": GOTO 1560
  121. 4000  REM <CTRL-M><CTRL-M>GET STORY<CTRL-M>---------
  122. 4005  HOME : ONERR  GOTO 4444
  123. 4010  PRINT "GET WHICH STORY": PRINT : PRINT "TYPE STORY NAME & PRESS <RETURN>.": PRINT : PRINT "(<RETURN> ONLY FOR CATALOG)": VTAB 1: HTAB 16: INPUT P$
  124. 4015  IF P$ = ""  THEN  TEXT : POKE 34,7: PRINT "<CTRL-D>CATALOG": TEXT : VTAB 1: POKE 35,6: GOTO 4005
  125. 4020  TEXT : PRINT "<CTRL-D>BLOAD";P$: ONERR  GOTO 1060
  126. 4030 K =  PEEK(Q): IF K <32  THEN 4030
  127. 4040  POKE Q +16,0: GOTO 1560
  128. 4444  FLASH : TEXT : VTAB 1: HTAB 1: PRINT "<CTRL-G> ILLEGAL<CTRL-G> FILE<CTRL-G> NAME.<CTRL-G> TRY<CTRL-G> AGAIN.": NORMAL : FOR I = 1 TO 1500: NEXT : GOTO 1560
  129. 8250  REM <CTRL-M><CTRL-M>WAIT AFTER STORY<CTRL-M>----------------
  130. 8300  FOR I = 1 TO 999: NEXT I: VTAB 1: HTAB 35: FLASH : PRINT "RETURN": NORMAL 
  131. 8320 K =  PEEK(Q): IF K < >141  THEN 8320
  132. 8325  POKE Q +16,0:X = 1: HOME : GOTO 1060
  133. 9100  REM  <CTRL-M><CTRL-M>STORY #1<CTRL-M>--------
  134. 9105 A$ = " THE ISLE OF 3/  ": GOSUB 150: PRINT : NORMAL 
  135. 9110 A$ = "THE ISLE OF 0, RICH IN 2S AND FAMOUS FOR ITS 4 3S, WAS DISCOVERED BY A 1 NAMED HARRY 4. JUST AFTER THE WAR WITH THE "
  136. 9112  GOSUB 150
  137. 9120 A$ = "1S, HARRY AND A GROUP OF 1S (DISGUISED AS 3S) OCCUPIED THE ISLE OF 0 AND ALMOST 6 IT! THEY "
  138. 9122  GOSUB 150
  139. 9130 A$ = "FOUND A TRIBE OF 1S AND TRAINED THEM TO 5 3S! TO LEARN MORE, VISIT YOUR LOCAL 2. "
  140. 9132  GOSUB 150
  141. 9199  GOTO 8300
  142. 9200  REM <CTRL-M><CTRL-M>STORY #2<CTRL-M>--------  
  143. 9205 A$ = " NEVER TRUST A 1/  ": GOSUB 150: PRINT : NORMAL 
  144. 9210 A$ = "LADIES AND 1S-- THE 0S ARE EVERYWHERE! 0S IN THE 2, 0S IN THE 2...YOU MAY EVEN CATCH A 4 0 GOING DOOR-TO-DOOR SELLING 3S. DON'T LET HIM IN!  GET YOUR 3 OUT OF THE 2 AND 5 HIM! ": GOSUB 150
  145. 9220 A$ = "THEN SEND HIM TO THE 2 WHERE HE WON'T 5 AGAIN! ": GOSUB 150
  146. 9299  GOTO 8300
  147. 9300  REM <CTRL-M><CTRL-M>STORY #3<CTRL-M>--------
  148. 9310  INVERSE :A$ = " REPAIRING YOUR 3/  ": GOSUB 150: PRINT : NORMAL 
  149. 9320 A$ = "THERE IS NOTHING MORE 4 THAN A BROKEN 0. YOU CAN'T 5 WITH IT, AND 7 IS IMPOSSIBLE! HERE'S WHAT 1S DO TO REPAIR THEIR 0S: ": GOSUB 150: PRINT 
  150. 9340 A$ = "(A) MAKE SOME GLUE OUT OF 4 3S. (B) PUT YOUR 0 BY A 3 UNTIL IT'S 6 (UNLESS YOU LIVE IN A 2). (C) POUR THE GLUE ON YOUR 0 AND LIGHT IT! ": GOSUB 150
  151. 9350 A$ = "(D) GO BUY A NEW 0 FROM A 1 DOWN AT THE LOCAL 2. ": GOSUB 150
  152. 9399  GOTO 8300
  153. 9400  REM <CTRL-M><CTRL-M>STORY #4<CTRL-M>-------- 
  154. 9410  INVERSE :A$ = " MISTER 3/  ": GOSUB 150: PRINT : NORMAL 
  155. 9420 A$ = "KNOWN MOSTLY FOR HIS TIMELY INVENTION OF THE 0, GEORGE 3 ALSO INVENTED THE 3, THE 3, AND THE 4 3! HOW DID HE DO IT? ENDLESS HOURS OF 7 IN HIS 2 AND COMPLETE DISREGARD FOR HIS 3! ": GOSUB 150
  156. 9430 A$ = " NO 1 CAN MATCH MR. 0'S 4 DEDICATION. RUMOR HAS IT, HE WAS A LITTLE 4, THOUGH. ": GOSUB 150
  157. 9499  GOTO 8300
  158. 9500  REM <CTRL-M><CTRL-M>STORY #5<CTRL-M>--------  
  159. 9505 A$ = " 7/  YOUR DOG ": GOSUB 150: PRINT : PRINT : NORMAL 
  160. 9510 A$ = "0 YOUR DOG CAN BE A 4 EXPERIENCE IF DONE CORRECTLY. 0 EXPERTS TELL US THESE 4 RULES: ": GOSUB 150: PRINT : PRINT 
  161. 9520 A$ = "A. 0 A DOG NEAR A 3 CAN BE 4, ESPECIALLY WITH A 4 DOG! "
  162. 9522  GOSUB 150: PRINT 
  163. 9530 A$ = "B. STAY AWAY FROM 1S WHILE 0; DOGS LOVE TO 5 THEM! "
  164. 9532  GOSUB 150: PRINT 
  165. 9540 A$ = "C. WHEN FINISHED, GIVE YOUR DOG A TASTY 3 OR A 3 TO CHEW ON. HE'LL 5 YOU AND PROVE THAT HE'S MAN'S 4 1! "
  166. 9542  GOSUB 150
  167. 9599  GOTO 8300
  168. 10000  REM <CTRL-M><CTRL-M>VERBS<CTRL-M>-----
  169. 10001  DATA AX,BOOGIE,CALL,DISSECT,ELIMINATE,FUMIGATE,GRIND,HASSLE,INJURE,JUGGLE,KNOCK,LIKE,MURDER
  170. 10005  DATA  NAIL,OBLITERATE,PEEL,QUIZ,RIP,SLURP,TROUNCE,UNCOVER,VACUUM,WASTE,X-RAY,YANK,ZAP: REM  VB$(X)
  171. 10009  REM <CTRL-M><CTRL-M>ING VERBS<CTRL-M>---------
  172. 10010  DATA  APPLAUDING,BATHING,CARRYING,DEODORIZING,EMPTYING,FIXING,GREASING,HARMING,INKING,JAILING,KICKING,LOSING,MAILING
  173. 10015  DATA  NOODLING,OILING,PICKLING,QUIETING,RUNNING,SHOEING,TRAINING,UNDRESSING,VIBRATING,WAXING,X-RAYING,YANKING,ZAPPING: REM  ING$(X)
  174. 10019  REM <CTRL-M><CTRL-M>PAST TENSE VERBS<CTRL-M>---------------- 
  175. 10020  DATA  ALTERED,BURNED,CREMATED,DESTROYED,ENGULFED,FRIED,GORGED,HUMIDIFIED,INFESTED,JOLTED,KISSED,LAMBASTED,MARINATED
  176. 10025  DATA NEEDLED,OPENED,POUNDED,QUASHED,RUINED,STORMED,TORE UP,USED,VIOLATED,WASHED,XEROXED,YELLED AT,ZOOMED: REM PST$(X)
  177. 10039  REM <CTRL-M><CTRL-M>ADJECTIVES<CTRL-M>---------- 
  178. 10040  DATA  AWFUL,BUMMED OUT,CORNY,DUMB,EMPTY,FRUITY,GOOFY,HOT,INEPT,JUNKY,KINKY,LOOSE,MESSY
  179. 10045  DATA NORMAL,OLD,PUNY,QUEER,RADICAL,STICKY,TEENSY,UGLY,VOLUPTUOUS,WEIRD,XERIC,YUCKY,ZANY: REM ADJ$(X)
  180. 10049  REM <CTRL-M><CTRL-M>PERSON NOUNS<CTRL-M>------------
  181. 10050  DATA  APE,BOOGEYMAN,COP,DUNCE,ELF,FOOL,GOLFER,HIPPIE,IDIOT,JUGGLER,KING,LADY,MEANIE
  182. 10055  DATA NURD,OAF,PERVERT,QUACK,RAT,SINGER,TIGHTWAD,UNDERTAKER,VAMPIRE,WEIRDO,XENOPHOBE,YODELER,ZOMBIE: REM  PRS$(X)
  183. 10059  REM <CTRL-M><CTRL-M>PLACE NOUNS<CTRL-M>----------- 
  184. 10060  DATA ATTIC,BATHROOM,CUPBOARD,DUNGEON,ELEVATOR,FACTORY,GOLF COURSE,HOT TUB,IGLOO,JUNGLE,KITCHEN,LUMBER YARD,MOUNTAIN
  185. 10065  DATA NEST,OPERA HOUSE,PIANO BAR,QUICKSAND,RUNWAY,SANITARIUM,THEATER,USED CAR LOT,VOLVO,WIGWAM,XEROX MACHINE,YACHT,ZEBRA FARM: REM PLC$(X)
  186. 10069  REM <CTRL-M><CTRL-M>THING NOUNS (1)<CTRL-M>---------------
  187. 10070  DATA ANT,BROOMSTICK,COW,DOORKNOB,EDSEL,FENDER,GIANT,HARPOON,INDIAN CLUB,JAR,KITE STRING,LUNCH BUCKET,MARSHMALLOW
  188. 10075  DATA NECKTIE,ORANGE PEEL,PRUNE,QUARTER,ROWBOAT,SEWER,TOW TRUCK,UKULELE,VULTURE,WOMBAT,XYLOPHONE,YOKEL,ZITHER: REM  T2$(X)
  189. 10079  REM <CTRL-M><CTRL-M>THING NOUNS (2)<CTRL-M>--------------- 
  190. 10080  DATA  AWNING,BOW TIE,CRAYON,DINGBAT,ELEPHANT,FOG LIGHT,GARAGE,HAM,IRON,JURY,KITTEN,LADDER,MUFFIN
  191. 10085  DATA NIGHTSTAND,OAR,PACKARD,QUAGMIRE,ROOSTER,SNOW CONE,TON OF BRICKS,USED CAR,VIOLIN,WAGON,XEBEC,YAHOO,ZOOT SUIT: REM  T3$(X)
  192. 10089  REM <CTRL-M><CTRL-M>THING NOUNS (3)<CTRL-M>--------------- 
  193. 10090  DATA  ANIMAL,BARN,CUCKOO,DOUGHNUT,EARLOBE,FERN,GARBAGE,HOSE,ICEBOX,JAZZ BAND,KNEECAP,LEFTOVER,MOTHBALL
  194. 10095  DATA NUT,OVEN,POPCORN,QUILT,RADIO,SNAKE,TUTU,UMBRELLA,VALENTINE,WEENY,XYLOPHONE,YOYO,ZIPPER: REM T1$(X)<CTRL-M><CTRL-M><CTRL-M>
  195. 20000  DIM VB$(26),ING$(26),PST$(26),PLC$(26),T1$(26),PRS$(26),ADJ$(26),T2$(26),T3$(26),A(182),X$(26)
  196. 20010  FOR I = 1 TO 26: READ VB$(I): NEXT : PRINT "]": FOR I = 1 TO 26: READ ING$(I): NEXT : PRINT "]": FOR I = 1 TO 26: READ PST$(I): NEXT : PRINT "]": FOR I = 1 TO 26: READ ADJ$(I): NEXT : PRINT "]"
  197. 20030  FOR I = 1 TO 26: READ PRS$(I): NEXT I: PRINT "]": FOR I = 1 TO 26: READ PLC$(I): NEXT I: PRINT "]": FOR I = 1 TO 26: READ T1$(I): NEXT I: PRINT "]": FOR I = 1 TO 26: READ T2$(I): NEXT : PRINT "]": FOR I = 1 TO 26: READ T3$(I): NEXT 
  198. 20040 Q =  -16384: RETURN 
  199. 22222  FOR X = 1 TO 26: PRINT VB$(X): PRINT ING$(X): PRINT PST$(X): PRINT PLC$(X): PRINT PRS$(X): PRINT ADJ$(X): PRINT T1$(X): PRINT T2$(X): PRINT T3$(X): PRINT : NEXT : END 
  200. 63900  TEXT : HOME : NORMAL : VTAB 10: HTAB 5: PRINT "BEAGLE BAG": HTAB 5: PRINT "------------------"
  201. 63910  VTAB 12: PRINT "<M> MENU": PRINT "<C> CONTINUE THIS GAME": PRINT "<Q> QUIT": HTAB 5: PRINT "------------------": PRINT "    SELECT:";: GET A$: PRINT A$: IF A$ = "Q"  THEN  END 
  202. 63920  IF A$ = "M"  THEN  POKE 768,17: PRINT  CHR$(4);"RUN SHORT MENU"
  203. 63930  IF A$ = "C"  THEN  RUN 
  204. 63940  GOTO 63900