home *** CD-ROM | disk | FTP | other *** search
/ Garbo / Garbo.cdr / pc / source / cpu.zoo / cpu.2 < prev    next >
Internet Message Format  |  1989-08-18  |  9KB
  1. From santra!kth!sunic!mcvax!uunet!cs.utexas.edu!csd4.csd.uwm.edu!mailrus!jarvis.csri.toronto.edu!utgpu!utzoo!mnetor!tmsoft!mshiels Fri Aug 18 10:31:35 EET DST 1989
  2. Article 7095 of comp.sys.ibm.pc:
  3. Path: chyde!santra!kth!sunic!mcvax!uunet!cs.utexas.edu!csd4.csd.uwm.edu!mailrus!jarvis.csri.toronto.edu!utgpu!utzoo!mnetor!tmsoft!mshiels
  4. >From: mshiels@tmsoft.uucp (Michael A. Shiels)
  5. Newsgroups: comp.sys.ibm.pc
  6. Subject: CPU Identification 2 of 4
  7. Message-ID: <1989Aug16.110529.340@tmsoft.uucp>
  8. Date: 16 Aug 89 11:05:29 GMT
  9. Reply-To: mshiels@tmsoft.UUCP (Michael A. Shiels)
  10. Followup-To: comp.sys.ibm.pc
  11. Organization: MaS Network Software and Consulting
  12. Lines: 184
  13.  
  14.  
  15.          TITLE   CPU - PRINT INTEL CPU TYPE ON CONSOLE
  16. ; PGMID.  CPU.ASM
  17. ; AUTHOR. UNKNOWN INTEL EMPLOYEE (MASM V5.0 MAINLINE ADDED BY DON HIGGINS)
  18. ;                                (COMPUSERVE 73047,1113)
  19. ; DATE.   11/13/87.
  20. ;
  21. ; Fixed 05/25/88 73710,3667 TRT
  22. ; CMP     AX,386 changed to CMP    AX,386H
  23. ; this change allows this program to identify '386 machines
  24. ; much more accurately.
  25. ; 
  26. DATA     SEGMENT PUBLIC
  27. system_type_opt db IBM  ;IS THERE A BYTE IN ROM BIOS FOR THIS ?
  28. IBM      equ 0
  29. NC_type  equ 1
  30. MSGNC    DB    'CPU NON COMPATIBLE$'
  31. MSG086   DB    'CPU IS 8086/8088$'
  32. MSG186   DB    'CPU IS 80186$'
  33. MSG286   DB    'CPU IS 80286$'
  34. MSG386   DB    'CPU IS 80386$'
  35. DATA     ENDS
  36. STACK    SEGMENT STACK
  37.          DB      200 DUP(?)
  38. STACK    ENDS
  39. CODE     SEGMENT PUBLIC
  40.          ASSUME  CS:CODE,DS:DATA
  41.          PUBLIC  CPU
  42. CPU      LABEL   NEAR
  43.          MOV     AX,DATA
  44.          MOV     DS,AX
  45.          CALL    get_cpu_type
  46.          CMP     AX,86H
  47.          JE      CPU086
  48.          CMP     AX,186H
  49.          JE      CPU186
  50.          CMP     AX,286H
  51.          JE      CPU286
  52.          CMP     AX,386H
  53.          JE      CPU386
  54. CPUNC    LABEL   NEAR
  55.          MOV     DX,OFFSET MSGNC
  56. WTO      LABEL   NEAR
  57.          MOV     AH,9
  58.          INT     21H
  59.          MOV     AH,4CH
  60.          INT     21H
  61. CPU086   LABEL   NEAR
  62.          MOV     DX,OFFSET MSG086
  63.          JMP     WTO
  64. CPU186   LABEL   NEAR
  65.          MOV     DX,OFFSET MSG186
  66.          JMP     WTO
  67. CPU286   LABEL   NEAR
  68.          MOV     DX,OFFSET MSG286
  69.          JMP     WTO
  70. CPU386   LABEL   NEAR
  71.          MOV     DX,OFFSET MSG386
  72.          JMP     WTO
  73. ;-----------------------------------------------------------------------------;
  74. ;                                                                             ;
  75. ;   Procedure Name:   get_cpu_type                                            ;
  76. ;           Author:   Anonymous Intel Employee                                ;
  77. ;             Date:   7/7/87                                                  ;
  78. ;      Description:   This procedure returns the hex value of the processor   ;
  79. ;                     type to the calling procedure.  It is able to identify  ;
  80. ;                     the 8086, 80186, 80286, 80386.                          ;
  81. ;                                                                             ;
  82. ;     Parms Passed:   None                                                    ;
  83. ;                                                                             ;
  84. ;   Results/Status                                                            ;
  85. ;         Returned:   AX = hex digits for the CPU type.                       ;
  86. ;                                                                             ;
  87. ; Calling Sequence:   CALL      get_CPU_type                                  ;
  88. ;                                                                             ;
  89. ;        Called By:   delete_defective_expanded_memory_pages                  ;
  90. ;                                                                             ;
  91. ;            Calls:   Nothing                                                 ;
  92. ;                                                                             ;
  93. ;        Registers                                                            ;
  94. ;         Modified:   AX                                                      ;
  95. ;                                                                             ;
  96. ;          Globals                                                            ;
  97. ;        Modified/                                                            ;
  98. ;       Referenced:   None                                                    ;
  99. ;                                                                             ;
  100. ;-----------------------------------------------------------------------------;
  101. get_cpu_type                PROC        NEAR
  102. PUBLIC                        get_cpu_type
  103.  
  104.         ;---------------------------------------------------------------------;
  105.         ;   If the system type is non-compatible then                         ;
  106.         ;     return (cpu type = 0)                                           ;
  107.         ;---------------------------------------------------------------------;
  108.         CMP                WORD PTR system_type_opt, NC_type
  109.         JNE                determine_cpu_type
  110.         XOR                AX, AX
  111.         RET
  112.  
  113. determine_cpu_type:
  114.         ;---------------------------------------------------------------------;
  115.         ;   Save registers used.                                              ;
  116.         ;---------------------------------------------------------------------;
  117.         PUSHF
  118.  
  119.         ;---------------------------------------------------------------------;
  120.         ;   Pop a zero into the FLAGS register and attempt to set bits 15-12  ;
  121.         ;   to zero.                                                          ;
  122.         ;   If bits 15-12 = 0 then                                            ;
  123.         ;     the cpu type is an 8018X or an 808X.                            ;
  124.         ;---------------------------------------------------------------------;
  125.         XOR                AX, AX
  126.         PUSH               AX
  127.         POPF
  128.         PUSHF
  129.         POP                AX
  130.         AND                AX, 0F000h
  131.         CMP                AX, 0F000h
  132.         JNE                check_for_80286
  133.  
  134. check_for_8086_80186:
  135.         ;---------------------------------------------------------------------;
  136.         ;   Cpu type is an 8086 or 80186.                                     ;
  137.         ;   Shift a pattern of all ones left 33 times.                        ;
  138.         ;   If shift result = 0 then                                          ;
  139.         ;     cpu type is a 80186                                             ;
  140.         ;   else                                                              ;
  141.         ;     cpu type is a 8086                                              ;
  142.         ;---------------------------------------------------------------------;
  143.         PUSH               CX
  144.         MOV                AX, 0FFFFh
  145.         MOV                CL, 33
  146.         SHL                AX, CL
  147.         POP                CX
  148.         JNZ                check_for_80186
  149.  
  150. check_for_8086:
  151.         ;---------------------------------------------------------------------;
  152.         ;   Cpu type is an 8086.                                              ;
  153.         ;---------------------------------------------------------------------;
  154.         MOV                AX, 86h
  155.         POPF
  156.         RET
  157.  
  158. check_for_80186:
  159.         ;---------------------------------------------------------------------;
  160.         ;   Cpu type is an 80186.                                             ;
  161.         ;---------------------------------------------------------------------;
  162.         MOV                AX, 186h
  163.         POPF
  164.         RET
  165.  
  166. check_for_80286:
  167.         ;---------------------------------------------------------------------;
  168.         ;   Attempt to set FLAG bits 14-12 (NT and IOPL bits).                ;
  169.         ;---------------------------------------------------------------------;
  170.         MOV                AX, 7000h
  171.         PUSH               AX
  172.         POPF
  173.         PUSHF
  174.         POP                AX
  175.  
  176.         ;---------------------------------------------------------------------;
  177.         ;   If NT & IOPL bits are not set then                                ;
  178.         ;     cpu type is and 80286                                           ;
  179.         ;---------------------------------------------------------------------;
  180.         AND                AX, 7000h
  181.         JNZ                check_for_80386
  182.         MOV                AX, 286h
  183.         POPF
  184.         RET
  185.  
  186. check_for_80386:
  187.         ;---------------------------------------------------------------------;
  188.         ;   Cpu type is an 80386                                              ;
  189.         ;---------------------------------------------------------------------;
  190.         MOV                AX, 386h
  191.         POPF
  192.         RET
  193.  
  194. get_cpu_type                ENDP
  195. CODE    ENDS
  196.         END    CPU
  197.                                              
  198.  
  199.  
  200.