home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / tar-1.11.8-src.tgz / tar.out / fsf / tar / intl / linux-msg.sed < prev    next >
Text File  |  1996-09-28  |  2KB  |  90 lines
  1. # po-to-msg.sed - Convert Uniforum style .po file to Linux style .msg file
  2. # Copyright (C) 1995 Free Software Foundation, Inc.
  3. # Ulrich Drepper <drepper@gnu.ai.mit.edu>, 1995.
  4. #
  5. # This program is free software; you can redistribute it and/or modify
  6. # it under the terms of the GNU General Public License as published by
  7. # the Free Software Foundation; either version 2, or (at your option)
  8. # any later version.
  9. #
  10. # This program is distributed in the hope that it will be useful,
  11. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. # GNU General Public License for more details.
  14. #
  15. # You should have received a copy of the GNU General Public License
  16. # along with this program; if not, write to the Free Software
  17. # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.  */
  18. #
  19. #
  20. # The first directive in the .msg should be the definition of the
  21. # message set number.  We use always set number 1.
  22. #
  23. 1 {
  24.   i\
  25. $set 1 # Automatically created by po-to-msg
  26.   h
  27.   s/.*/0/
  28.   x
  29. }
  30. #
  31. # Mitch's old catalog format does not allow comments.
  32. # 
  33. # We copy the original message as a comment into the .msg file.
  34. #
  35. /^msgid/ {
  36.   s/msgid[     ]*"//
  37.   /"$/!s/$/ ... (more lines following)"/
  38.   x
  39. # The following nice solution is by
  40. # Bruno <Haible@ma2s2.mathematik.uni-karlsruhe.de>
  41.   td
  42. # Increment a decimal number in pattern space.
  43. # First hide trailing `9' digits.
  44.   :d
  45.   s/9\(_*\)$/_\1/
  46.   td
  47. # Assure at least one digit is available.
  48.   s/^\(_*\)$/0\1/
  49. # Increment the last digit.
  50.   s/8\(_*\)$/9\1/
  51.   s/7\(_*\)$/8\1/
  52.   s/6\(_*\)$/7\1/
  53.   s/5\(_*\)$/6\1/
  54.   s/4\(_*\)$/5\1/
  55.   s/3\(_*\)$/4\1/
  56.   s/2\(_*\)$/3\1/
  57.   s/1\(_*\)$/2\1/
  58.   s/0\(_*\)$/1\1/
  59. # Convert the hidden `9' digits to `0's.
  60.   s/_/0/g
  61.   x
  62.   G
  63.   s/\(.*\)"\n0*\(.*\)/$ #\2 Original Message:(\1)/p
  64. }
  65. #
  66. # The .msg file contains, other then the .po file, only the translations
  67. # but each given a unique ID.  Starting from 1 and incrementing by 1 for
  68. # each message we assign them to the messages.
  69. # It is important that the .po file used to generate the cat-id-tbl.c file
  70. # (with po-to-tbl) is the same as the one used here.  (At least the order
  71. # of declarations must not be changed.)
  72. #
  73. /^msgstr/ {
  74.   s/msgstr[     ]*"/# /
  75. # Yes, this jump IS necessary :)
  76.   ta
  77.   :a
  78.   s/\\$/\\/
  79.   tc
  80.   bb
  81.   :c
  82.   n
  83.   s/\\$/\\/
  84.   tc
  85.   :b
  86.   s/\(.*\)"$/\1/
  87.   p
  88. }
  89. d
  90.