home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / autoconf-2.10-base.tgz / autoconf-2.10.tar / fsf / autoconf / acspecific.m4 < prev    next >
M4 Source File  |  1996-03-21  |  61KB  |  2,001 lines
  1. dnl Macros that test for specific features.
  2. dnl This file is part of Autoconf.
  3. dnl Copyright (C) 1992, 1993, 1994, 1995, 1996 Free Software Foundation, Inc.
  4. dnl
  5. dnl This program is free software; you can redistribute it and/or modify
  6. dnl it under the terms of the GNU General Public License as published by
  7. dnl the Free Software Foundation; either version 2, or (at your option)
  8. dnl any later version.
  9. dnl
  10. dnl This program is distributed in the hope that it will be useful,
  11. dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. dnl GNU General Public License for more details.
  14. dnl
  15. dnl You should have received a copy of the GNU General Public License
  16. dnl along with this program; if not, write to the Free Software
  17. dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  18. dnl
  19. dnl As a special exception, the Free Software Foundation gives unlimited
  20. dnl permission to copy, distribute and modify the configure scripts that
  21. dnl are the output of Autoconf.  You need not follow the terms of the GNU
  22. dnl General Public License when using or distributing such scripts, even
  23. dnl though portions of the text of Autoconf appear in them.  The GNU
  24. dnl General Public License (GPL) does govern all other use of the material
  25. dnl that constitutes the Autoconf program.
  26. dnl
  27. dnl Certain portions of the Autoconf source text are designed to be copied
  28. dnl (in certain cases, depending on the input) into the output of
  29. dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  30. dnl source text consists of comments plus executable code that decides which
  31. dnl of the data portions to output in any given case.  We call these
  32. dnl comments and executable code the "non-data" portions.  Autoconf never
  33. dnl copies any of the non-data portions into its output.
  34. dnl
  35. dnl This special exception to the GPL applies to versions of Autoconf
  36. dnl released by the Free Software Foundation.  When you make and
  37. dnl distribute a modified version of Autoconf, you may extend this special
  38. dnl exception to the GPL to apply to your modified version as well, *unless*
  39. dnl your modified version has the potential to copy into its output some
  40. dnl of the text that was the non-data portion of the version that you started
  41. dnl with.  (In other words, unless your change moves or copies text from
  42. dnl the non-data portions to the data portions.)  If your modification has
  43. dnl such potential, you must delete any notice of this special exception
  44. dnl to the GPL from your modified version.
  45. dnl
  46. dnl Written by David MacKenzie, with help from
  47. dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  48. dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  49.  
  50.  
  51. dnl ### Checks for programs
  52.  
  53.  
  54. dnl Check whether to use -n, \c, or newline-tab to separate
  55. dnl checking messages from result messages.
  56. dnl Idea borrowed from dist 3.0.
  57. dnl Internal use only.
  58. AC_DEFUN(AC_PROG_ECHO_N,
  59. [if (echo "testing\c"; echo 1,2,3) | grep c >/dev/null; then
  60.   # Stardent Vistra SVR4 grep lacks -e, says ghazi@caip.rutgers.edu.
  61.   if (echo -n testing; echo 1,2,3) | sed s/-n/xn/ | grep xn >/dev/null; then
  62.     ac_n= ac_c='
  63. ' ac_t='    '
  64.   else
  65.     ac_n=-n ac_c= ac_t=
  66.   fi
  67. else
  68.   ac_n= ac_c='\c' ac_t=
  69. fi
  70. ])
  71.  
  72. AC_DEFUN(AC_PROG_CC,
  73. [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  74. AC_CHECK_PROG(CC, gcc, gcc)
  75. if test -z "$CC"; then
  76.   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  77.   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  78. fi
  79.  
  80. AC_CACHE_CHECK(whether we are using GNU C, ac_cv_prog_gcc,
  81. [dnl The semicolon is to pacify NeXT's syntax-checking cpp.
  82. cat > conftest.c <<EOF
  83. #ifdef __GNUC__
  84.   yes;
  85. #endif
  86. EOF
  87. if AC_TRY_COMMAND(${CC-cc} -E conftest.c) | egrep yes >/dev/null 2>&1; then
  88.   ac_cv_prog_gcc=yes
  89. else
  90.   ac_cv_prog_gcc=no
  91. fi])
  92. if test $ac_cv_prog_gcc = yes; then
  93.   GCC=yes
  94.   if test "${CFLAGS+set}" != set; then
  95.     AC_CACHE_CHECK(whether ${CC-cc} accepts -g, ac_cv_prog_gcc_g,
  96. [echo 'void f(){}' > conftest.c
  97. if test -z "`${CC-cc} -g -c conftest.c 2>&1`"; then
  98.   ac_cv_prog_gcc_g=yes
  99. else
  100.   ac_cv_prog_gcc_g=no
  101. fi
  102. rm -f conftest*
  103. ])
  104.     if test $ac_cv_prog_gcc_g = yes; then
  105.       CFLAGS="-g -O"
  106.     else
  107.       CFLAGS="-O"
  108.     fi
  109.   fi
  110. else
  111.   GCC=
  112.   test "${CFLAGS+set}" = set || CFLAGS="-g"
  113. fi
  114. ])
  115.  
  116. AC_DEFUN(AC_PROG_CXX,
  117. [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
  118. AC_CHECK_PROGS(CXX, $CCC c++ g++ gcc CC cxx, gcc)
  119.  
  120. AC_CACHE_CHECK(whether we are using GNU C++, ac_cv_prog_gxx,
  121. [dnl The semicolon is to pacify NeXT's syntax-checking cpp.
  122. cat > conftest.C <<EOF
  123. #ifdef __GNUC__
  124.   yes;
  125. #endif
  126. EOF
  127. if AC_TRY_COMMAND(${CXX-g++} -E conftest.C) | egrep yes >/dev/null 2>&1; then
  128.   ac_cv_prog_gxx=yes
  129. else
  130.   ac_cv_prog_gxx=no
  131. fi])
  132. if test $ac_cv_prog_gxx = yes; then
  133.   GXX=yes
  134.   if test "${CXXFLAGS+set}" != set; then
  135.     AC_CACHE_CHECK(whether ${CXX-g++} accepts -g, ac_cv_prog_gxx_g,
  136. [echo 'void f(){}' > conftest.cc
  137. if test -z "`${CXX-g++} -g -c conftest.cc 2>&1`"; then
  138.   ac_cv_prog_gxx_g=yes
  139. else
  140.   ac_cv_prog_gxx_g=no
  141. fi
  142. rm -f conftest*
  143. ])
  144. dnl
  145.     if test $ac_cv_prog_gxx_g = yes; then
  146.       CXXFLAGS="-g -O"
  147.     else
  148.       CXXFLAGS="-O"
  149.     fi
  150.   fi
  151. else
  152.   GXX=
  153.   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
  154. fi
  155. ])
  156.  
  157. AC_DEFUN(AC_PROG_GCC_TRADITIONAL,
  158. [AC_REQUIRE([AC_PROG_CC])dnl
  159. AC_REQUIRE([AC_PROG_CPP])dnl
  160. if test $ac_cv_prog_gcc = yes; then
  161.     AC_CACHE_CHECK(whether ${CC-cc} needs -traditional,
  162.       ac_cv_prog_gcc_traditional,
  163. [  ac_pattern="Autoconf.*'x'"
  164.   AC_EGREP_CPP($ac_pattern, [#include <sgtty.h>
  165. Autoconf TIOCGETP],
  166.   ac_cv_prog_gcc_traditional=yes, ac_cv_prog_gcc_traditional=no)
  167.  
  168.   if test $ac_cv_prog_gcc_traditional = no; then
  169.     AC_EGREP_CPP($ac_pattern, [#include <termio.h>
  170. Autoconf TCGETA],
  171.     ac_cv_prog_gcc_traditional=yes)
  172.   fi])
  173.   if test $ac_cv_prog_gcc_traditional = yes; then
  174.     CC="$CC -traditional"
  175.   fi
  176. fi
  177. ])
  178.  
  179. AC_DEFUN(AC_PROG_CC_C_O,
  180. [if test "x$CC" != xcc; then
  181.   AC_MSG_CHECKING(whether $CC and cc understand -c and -o together)
  182. else
  183.   AC_MSG_CHECKING(whether cc understands -c and -o together)
  184. fi
  185. set dummy $CC; ac_cc="`echo [$]2 |
  186. changequote(, )dnl
  187.                sed -e 's/[^a-zA-Z0-9_]/_/g' -e 's/^[0-9]/_/'`"
  188. changequote([, ])dnl
  189. AC_CACHE_VAL(ac_cv_prog_cc_${ac_cc}_c_o,
  190. [echo 'foo(){}' > conftest.c
  191. # Make sure it works both with $CC and with simple cc.
  192. # We do the test twice because some compilers refuse to overwrite an
  193. # existing .o file with -o, though they will create one.
  194. ac_try='${CC-cc} -c conftest.c -o conftest.o 1>&AC_FD_CC'
  195. if AC_TRY_EVAL(ac_try) &&
  196.    test -f conftest.o && AC_TRY_EVAL(ac_try);
  197. then
  198.   eval ac_cv_prog_cc_${ac_cc}_c_o=yes
  199.   if test "x$CC" != xcc; then
  200.     # Test first that cc exists at all.
  201.     if AC_TRY_COMMAND(cc -c conftest.c 1>&AC_FD_CC); then
  202.       ac_try='cc -c conftest.c -o conftest.o 1>&AC_FD_CC'
  203.       if AC_TRY_EVAL(ac_try) &&
  204.      test -f conftest.o && AC_TRY_EVAL(ac_try);
  205.       then
  206.         # cc works too.
  207.         :
  208.       else
  209.         # cc exists but doesn't like -o.
  210.         eval ac_cv_prog_cc_${ac_cc}_c_o=no
  211.       fi
  212.     fi
  213.   fi
  214. else
  215.   eval ac_cv_prog_cc_${ac_cc}_c_o=no
  216. fi
  217. rm -f conftest*
  218. ])dnl
  219. if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = yes"; then
  220.   AC_MSG_RESULT(yes)
  221. else
  222.   AC_MSG_RESULT(no)
  223.   AC_DEFINE(NO_MINUS_C_MINUS_O)
  224. fi
  225. ])
  226.  
  227. dnl Define SET_MAKE to set ${MAKE} if make doesn't.
  228. AC_DEFUN(AC_PROG_MAKE_SET,
  229. [AC_MSG_CHECKING(whether ${MAKE-make} sets \${MAKE})
  230. set dummy ${MAKE-make}; ac_make=[$]2
  231. AC_CACHE_VAL(ac_cv_prog_make_${ac_make}_set,
  232. [cat > conftestmake <<\EOF
  233. all:
  234.     @echo 'ac_maketemp="${MAKE}"'
  235. EOF
  236. changequote(, )dnl
  237. # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  238. eval `${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  239. changequote([, ])dnl
  240. if test -n "$ac_maketemp"; then
  241.   eval ac_cv_prog_make_${ac_make}_set=yes
  242. else
  243.   eval ac_cv_prog_make_${ac_make}_set=no
  244. fi
  245. rm -f conftestmake])dnl
  246. if eval "test \"`echo '$ac_cv_prog_make_'${ac_make}_set`\" = yes"; then
  247.   AC_MSG_RESULT(yes)
  248.   SET_MAKE=
  249. else
  250.   AC_MSG_RESULT(no)
  251.   SET_MAKE="MAKE=${MAKE-make}"
  252. fi
  253. AC_SUBST([SET_MAKE])dnl
  254. ])
  255.  
  256. AC_DEFUN(AC_PROG_RANLIB,
  257. [AC_CHECK_PROG(RANLIB, ranlib, ranlib, :)])
  258.  
  259. dnl Check for mawk first since it's generally faster.
  260. AC_DEFUN(AC_PROG_AWK,
  261. [AC_CHECK_PROGS(AWK, mawk gawk nawk awk, )])
  262.  
  263. AC_DEFUN(AC_PROG_YACC,
  264. [AC_CHECK_PROGS(YACC, 'bison -y' byacc, yacc)])
  265.  
  266. AC_DEFUN(AC_PROG_CPP,
  267. [AC_MSG_CHECKING(how to run the C preprocessor)
  268. # On Suns, sometimes $CPP names a directory.
  269. if test -n "$CPP" && test -d "$CPP"; then
  270.   CPP=
  271. fi
  272. if test -z "$CPP"; then
  273. AC_CACHE_VAL(ac_cv_prog_CPP,
  274. [  # This must be in double quotes, not single quotes, because CPP may get
  275.   # substituted into the Makefile and "${CC-cc}" will confuse make.
  276.   CPP="${CC-cc} -E"
  277.   # On the NeXT, cc -E runs the code through the compiler's parser,
  278.   # not just through cpp.
  279. dnl Use a header file that comes with gcc, so configuring glibc
  280. dnl with a fresh cross-compiler works.
  281.   AC_TRY_CPP([#include <assert.h>
  282. Syntax Error], ,
  283.   CPP="${CC-cc} -E -traditional-cpp"
  284.   AC_TRY_CPP([#include <assert.h>
  285. Syntax Error], , CPP=/lib/cpp))
  286.   ac_cv_prog_CPP="$CPP"])dnl
  287.   CPP="$ac_cv_prog_CPP"
  288. else
  289.   ac_cv_prog_CPP="$CPP"
  290. fi
  291. AC_MSG_RESULT($CPP)
  292. AC_SUBST(CPP)dnl
  293. ])
  294.  
  295. AC_DEFUN(AC_PROG_CXXCPP,
  296. [AC_MSG_CHECKING(how to run the C++ preprocessor)
  297. if test -z "$CXXCPP"; then
  298. AC_CACHE_VAL(ac_cv_prog_CXXCPP,
  299. [AC_LANG_SAVE[]dnl
  300. AC_LANG_CPLUSPLUS[]dnl
  301.   CXXCPP="${CXX-g++} -E"
  302.   AC_TRY_CPP([#include <stdlib.h>], , CXXCPP=/lib/cpp)
  303.   ac_cv_prog_CXXCPP="$CXXCPP"
  304. AC_LANG_RESTORE[]dnl
  305. fi])dnl
  306. CXXCPP="$ac_cv_prog_CXXCPP"
  307. AC_MSG_RESULT($CXXCPP)
  308. AC_SUBST(CXXCPP)dnl
  309. ])
  310.  
  311. dnl Require finding the C or C++ preprocessor, whichever is the
  312. dnl current language.
  313. AC_DEFUN(AC_REQUIRE_CPP,
  314. [ifelse(AC_LANG, C, [AC_REQUIRE([AC_PROG_CPP])], [AC_REQUIRE([AC_PROG_CXXCPP])])])
  315.  
  316. AC_DEFUN(AC_PROG_LEX,
  317. [AC_CHECK_PROG(LEX, flex, flex, lex)
  318. if test -z "$LEXLIB"
  319. then
  320.   case "$LEX" in
  321.   flex*) ac_lib=fl ;;
  322.   *) ac_lib=l ;;
  323.   esac
  324.   AC_CHECK_LIB($ac_lib, yywrap, LEXLIB="-l$ac_lib")
  325. fi
  326. AC_SUBST(LEXLIB)])
  327.  
  328. dnl Check if lex declares yytext as a char * by default, not a char[].
  329. undefine([AC_DECL_YYTEXT])
  330. AC_DEFUN(AC_DECL_YYTEXT,
  331. [AC_REQUIRE_CPP()dnl
  332. AC_REQUIRE([AC_PROG_LEX])dnl
  333. AC_CACHE_CHECK(lex output file root, ac_cv_prog_lex_root,
  334. [# The minimal lex program is just a single line: %%.  But some broken lexes
  335. # (Solaris, I think it was) want two %% lines, so accommodate them.
  336. echo '%%
  337. %%' | $LEX
  338. if test -f lex.yy.c; then
  339.   ac_cv_prog_lex_root=lex.yy
  340. elif test -f lexyy.c; then
  341.   ac_cv_prog_lex_root=lexyy
  342. else
  343.   AC_MSG_ERROR(cannot find output from $LEX; giving up)
  344. fi])
  345. LEX_OUTPUT_ROOT=$ac_cv_prog_lex_root
  346. AC_SUBST(LEX_OUTPUT_ROOT)dnl
  347.  
  348. AC_CACHE_CHECK(whether yytext is a pointer, ac_cv_prog_lex_yytext_pointer,
  349. [# POSIX says lex can declare yytext either as a pointer or an array; the
  350. # default is implementation-dependent. Figure out which it is, since
  351. # not all implementations provide the %pointer and %array declarations.
  352. ac_cv_prog_lex_yytext_pointer=no
  353. echo 'extern char *yytext;' >>$LEX_OUTPUT_ROOT.c
  354. ac_save_LIBS="$LIBS"
  355. LIBS="$LIBS $LEXLIB"
  356. AC_TRY_LINK(`cat $LEX_OUTPUT_ROOT.c`, , ac_cv_prog_lex_yytext_pointer=yes)
  357. LIBS="$ac_save_LIBS"
  358. rm -f "${LEX_OUTPUT_ROOT}.c"])
  359. dnl
  360. if test $ac_cv_prog_lex_yytext_pointer = yes; then
  361.   AC_DEFINE(YYTEXT_POINTER)
  362. fi
  363. ])
  364.  
  365. AC_DEFUN(AC_PROG_INSTALL,
  366. [AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
  367. # Find a good install program.  We prefer a C program (faster),
  368. # so one script is as good as another.  But avoid the broken or
  369. # incompatible versions:
  370. # SysV /etc/install, /usr/sbin/install
  371. # SunOS /usr/etc/install
  372. # IRIX /sbin/install
  373. # AIX /bin/install
  374. # AFS /usr/afsws/bin/install, which mishandles nonexistent args
  375. # SVR4 /usr/ucb/install, which tries to use the nonexistent group "staff"
  376. # ./install, which can be erroneously created by make from ./install.sh.
  377. AC_MSG_CHECKING(for a BSD compatible install)
  378. if test -z "$INSTALL"; then
  379. AC_CACHE_VAL(ac_cv_path_install,
  380. [  IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
  381.   for ac_dir in $PATH; do
  382.     # Account for people who put trailing slashes in PATH elements.
  383.     case "$ac_dir/" in
  384.     /|./|.//|/etc/*|/usr/sbin/*|/usr/etc/*|/sbin/*|/usr/afsws/bin/*|/usr/ucb/*) ;;
  385.     *)
  386.       # OSF1 and SCO ODT 3.0 have their own names for install.
  387.       for ac_prog in ginstall installbsd scoinst install; do
  388.         if test -f $ac_dir/$ac_prog; then
  389.       if test $ac_prog = install &&
  390.             grep dspmsg $ac_dir/$ac_prog >/dev/null 2>&1; then
  391.         # AIX install.  It has an incompatible calling convention.
  392.         # OSF/1 installbsd also uses dspmsg, but is usable.
  393.         :
  394.       else
  395.         ac_cv_path_install="$ac_dir/$ac_prog -c"
  396.         break 2
  397.       fi
  398.     fi
  399.       done
  400.       ;;
  401.     esac
  402.   done
  403.   IFS="$ac_save_ifs"
  404. ])dnl
  405.   if test "${ac_cv_path_install+set}" = set; then
  406.     INSTALL="$ac_cv_path_install"
  407.   else
  408.     # As a last resort, use the slow shell script.  We don't cache a
  409.     # path for INSTALL within a source directory, because that will
  410.     # break other packages using the cache if that directory is
  411.     # removed, or if the path is relative.
  412.     INSTALL="$ac_install_sh"
  413.   fi
  414. fi
  415. dnl We do special magic for INSTALL instead of AC_SUBST, to get
  416. dnl relative paths right.
  417. AC_MSG_RESULT($INSTALL)
  418.  
  419. # Use test -z because SunOS4 sh mishandles braces in ${var-val}.
  420. # It thinks the first close brace ends the variable substitution.
  421. test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
  422. AC_SUBST(INSTALL_PROGRAM)dnl
  423.  
  424. test -z "$INSTALL_DATA" && INSTALL_DATA='${INSTALL} -m 644'
  425. AC_SUBST(INSTALL_DATA)dnl
  426. ])
  427.  
  428. AC_DEFUN(AC_PROG_LN_S,
  429. [AC_MSG_CHECKING(whether ln -s works)
  430. AC_CACHE_VAL(ac_cv_prog_LN_S,
  431. [rm -f conftestdata
  432. if ln -s X conftestdata 2>/dev/null
  433. then
  434.   rm -f conftestdata
  435.   ac_cv_prog_LN_S="ln -s"
  436. else
  437.   ac_cv_prog_LN_S=ln
  438. fi])dnl
  439. LN_S="$ac_cv_prog_LN_S"
  440. if test "$ac_cv_prog_LN_S" = "ln -s"; then
  441.   AC_MSG_RESULT(yes)
  442. else
  443.   AC_MSG_RESULT(no)
  444. fi
  445. AC_SUBST(LN_S)dnl
  446. ])
  447.  
  448. define(AC_RSH,
  449. [errprint(__file__:__line__: [$0] has been removed; replace it with equivalent code
  450. )m4exit(4)])
  451.  
  452.  
  453. dnl ### Checks for header files
  454.  
  455.  
  456. AC_DEFUN(AC_HEADER_STDC,
  457. [AC_REQUIRE_CPP()dnl
  458. AC_CACHE_CHECK(for ANSI C header files, ac_cv_header_stdc,
  459. [AC_TRY_CPP([#include <stdlib.h>
  460. #include <stdarg.h>
  461. #include <string.h>
  462. #include <float.h>], ac_cv_header_stdc=yes, ac_cv_header_stdc=no)
  463.  
  464. if test $ac_cv_header_stdc = yes; then
  465.   # SunOS 4.x string.h does not declare mem*, contrary to ANSI.
  466. AC_EGREP_HEADER(memchr, string.h, , ac_cv_header_stdc=no)
  467. fi
  468.  
  469. if test $ac_cv_header_stdc = yes; then
  470.   # ISC 2.0.2 stdlib.h does not declare free, contrary to ANSI.
  471. AC_EGREP_HEADER(free, stdlib.h, , ac_cv_header_stdc=no)
  472. fi
  473.  
  474. if test $ac_cv_header_stdc = yes; then
  475.   # /bin/cc in Irix-4.0.5 gets non-ANSI ctype macros unless using -ansi.
  476. AC_TRY_RUN([#include <ctype.h>
  477. #define ISLOWER(c) ('a' <= (c) && (c) <= 'z')
  478. #define TOUPPER(c) (ISLOWER(c) ? 'A' + ((c) - 'a') : (c))
  479. #define XOR(e, f) (((e) && !(f)) || (!(e) && (f)))
  480. int main () { int i; for (i = 0; i < 256; i++)
  481. if (XOR (islower (i), ISLOWER (i)) || toupper (i) != TOUPPER (i)) exit(2);
  482. exit (0); }
  483. ], , ac_cv_header_stdc=no, :)
  484. fi])
  485. if test $ac_cv_header_stdc = yes; then
  486.   AC_DEFINE(STDC_HEADERS)
  487. fi
  488. ])
  489.  
  490. AC_DEFUN(AC_UNISTD_H,
  491. [AC_OBSOLETE([$0], [; instead use AC_CHECK_HEADERS(unistd.h)])dnl
  492. AC_CHECK_HEADER(unistd.h, AC_DEFINE(HAVE_UNISTD_H))])
  493.  
  494. AC_DEFUN(AC_USG,
  495. [AC_OBSOLETE([$0],
  496.   [; instead use AC_CHECK_HEADERS(string.h) and HAVE_STRING_H])dnl
  497. AC_MSG_CHECKING([for BSD string and memory functions])
  498. AC_TRY_LINK([#include <strings.h>], [rindex(0, 0); bzero(0, 0);],
  499.   [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no); AC_DEFINE(USG)])])
  500.  
  501.  
  502. dnl If memchr and the like aren't declared in <string.h>, include <memory.h>.
  503. dnl To avoid problems, don't check for gcc2 built-ins.
  504. AC_DEFUN(AC_MEMORY_H,
  505. [AC_OBSOLETE([$0], [; instead use AC_CHECK_HEADERS(memory.h) and HAVE_MEMORY_H])dnl
  506. AC_MSG_CHECKING(whether string.h declares mem functions)
  507. AC_EGREP_HEADER(memchr, string.h, ac_found=yes, ac_found=no)
  508. AC_MSG_RESULT($ac_found)
  509. if test $ac_found = no; then
  510.   AC_CHECK_HEADER(memory.h, [AC_DEFINE(NEED_MEMORY_H)])
  511. fi
  512. ])
  513.  
  514. AC_DEFUN(AC_HEADER_MAJOR,
  515. [AC_CACHE_CHECK(whether sys/types.h defines makedev,
  516.   ac_cv_header_sys_types_h_makedev,
  517. [AC_TRY_LINK([#include <sys/types.h>], [return makedev(0, 0);],
  518.   ac_cv_header_sys_types_h_makedev=yes, ac_cv_header_sys_types_h_makedev=no)
  519. ])
  520.  
  521. if test $ac_cv_header_sys_types_h_makedev = no; then
  522. AC_CHECK_HEADER(sys/mkdev.h, [AC_DEFINE(MAJOR_IN_MKDEV)])
  523.  
  524.   if test $ac_cv_header_sys_mkdev_h = no; then
  525. AC_CHECK_HEADER(sys/sysmacros.h, [AC_DEFINE(MAJOR_IN_SYSMACROS)])
  526.   fi
  527. fi
  528. ])
  529.  
  530. AC_DEFUN(AC_HEADER_DIRENT,
  531. [ac_header_dirent=no
  532. AC_CHECK_HEADERS_DIRENT(dirent.h sys/ndir.h sys/dir.h ndir.h,
  533.   [ac_header_dirent=$ac_hdr; break])
  534. # Two versions of opendir et al. are in -ldir and -lx on SCO Xenix.
  535. if test $ac_header_dirent = dirent.h; then
  536. AC_CHECK_LIB(dir, opendir, LIBS="$LIBS -ldir")
  537. else
  538. AC_CHECK_LIB(x, opendir, LIBS="$LIBS -lx")
  539. fi
  540. ])
  541.  
  542. dnl Like AC_CHECK_HEADER, except also make sure that HEADER-FILE
  543. dnl defines the type `DIR'.  dirent.h on NextStep 3.2 doesn't.
  544. dnl AC_CHECK_HEADER_DIRENT(HEADER-FILE, ACTION-IF-FOUND)
  545. AC_DEFUN(AC_CHECK_HEADER_DIRENT,
  546. [ac_safe=`echo "$1" | tr './\055' '___'`
  547. AC_MSG_CHECKING([for $1 that defines DIR])
  548. AC_CACHE_VAL(ac_cv_header_dirent_$ac_safe,
  549. [AC_TRY_COMPILE([#include <sys/types.h>
  550. #include <$1>], [DIR *dirp = 0;],
  551.   eval "ac_cv_header_dirent_$ac_safe=yes",
  552.   eval "ac_cv_header_dirent_$ac_safe=no")])dnl
  553. if eval "test \"`echo '$ac_cv_header_dirent_'$ac_safe`\" = yes"; then
  554.   AC_MSG_RESULT(yes)
  555.   $2
  556. else
  557.   AC_MSG_RESULT(no)
  558. fi
  559. ])
  560.  
  561. dnl Like AC_CHECK_HEADERS, except succeed only for a HEADER-FILE that
  562. dnl defines `DIR'.
  563. dnl AC_CHECK_HEADERS_DIRENT(HEADER-FILE... [, ACTION])
  564. define(AC_CHECK_HEADERS_DIRENT,
  565. [for ac_hdr in $1
  566. do
  567. AC_CHECK_HEADER_DIRENT($ac_hdr,
  568. [changequote(, )dnl
  569.   ac_tr_hdr=HAVE_`echo $ac_hdr | tr 'abcdedfghijklmnopqrstuvwxyz./\055' 'ABCDEDFGHIJKLMNOPQRSTUVWXYZ___'`
  570. changequote([, ])dnl
  571.   AC_DEFINE_UNQUOTED($ac_tr_hdr) $2])dnl
  572. done])
  573.  
  574. AC_DEFUN(AC_DIR_HEADER,
  575. [AC_OBSOLETE([$0], [; instead use AC_HEADER_DIRENT])dnl
  576. ac_header_dirent=no
  577. for ac_hdr in dirent.h sys/ndir.h sys/dir.h ndir.h; do
  578.   AC_CHECK_HEADER_DIRENT($ac_hdr, [ac_header_dirent=$ac_hdr; break])
  579. done
  580.  
  581. case "$ac_header_dirent" in
  582. dirent.h) AC_DEFINE(DIRENT) ;;
  583. sys/ndir.h) AC_DEFINE(SYSNDIR) ;;
  584. sys/dir.h) AC_DEFINE(SYSDIR) ;;
  585. ndir.h) AC_DEFINE(NDIR) ;;
  586. esac
  587.  
  588. AC_CACHE_CHECK(whether closedir returns void, ac_cv_func_closedir_void,
  589. [AC_TRY_RUN([#include <sys/types.h>
  590. #include <$ac_header_dirent>
  591. int closedir(); main() { exit(closedir(opendir(".")) != 0); }],
  592.   ac_cv_func_closedir_void=no, ac_cv_func_closedir_void=yes, ac_cv_func_closedir_void=yes)])
  593. if test $ac_cv_func_closedir_void = yes; then
  594.   AC_DEFINE(VOID_CLOSEDIR)
  595. fi
  596. ])
  597.  
  598. AC_DEFUN(AC_HEADER_STAT,
  599. [AC_CACHE_CHECK(whether stat file-mode macros are broken,
  600.   ac_cv_header_stat_broken,
  601. [AC_EGREP_CPP([You lose], [#include <sys/types.h>
  602. #include <sys/stat.h>
  603.  
  604. #if defined(S_ISBLK) && defined(S_IFDIR)
  605. # if S_ISBLK (S_IFDIR)
  606. You lose.
  607. # endif
  608. #endif
  609.  
  610. #if defined(S_ISBLK) && defined(S_IFCHR)
  611. # if S_ISBLK (S_IFCHR)
  612. You lose.
  613. # endif
  614. #endif
  615.  
  616. #if defined(S_ISLNK) && defined(S_IFREG)
  617. # if S_ISLNK (S_IFREG)
  618. You lose.
  619. # endif
  620. #endif
  621.  
  622. #if defined(S_ISSOCK) && defined(S_IFREG)
  623. # if S_ISSOCK (S_IFREG)
  624. You lose.
  625. # endif
  626. #endif
  627. ], ac_cv_header_stat_broken=yes, ac_cv_header_stat_broken=no)])
  628. if test $ac_cv_header_stat_broken = yes; then
  629.   AC_DEFINE(STAT_MACROS_BROKEN)
  630. fi
  631. ])
  632.  
  633. AC_DEFUN(AC_DECL_SYS_SIGLIST,
  634. [AC_CACHE_CHECK([for sys_siglist declaration in signal.h or unistd.h],
  635.   ac_cv_decl_sys_siglist,
  636. [AC_TRY_COMPILE([#include <sys/types.h>
  637. #include <signal.h>
  638. /* NetBSD declares sys_siglist in unistd.h.  */
  639. #ifdef HAVE_UNISTD_H
  640. #include <unistd.h>
  641. #endif], [char *msg = *(sys_siglist + 1);],
  642.   ac_cv_decl_sys_siglist=yes, ac_cv_decl_sys_siglist=no)])
  643. if test $ac_cv_decl_sys_siglist = yes; then
  644.   AC_DEFINE(SYS_SIGLIST_DECLARED)
  645. fi
  646. ])
  647.  
  648. AC_DEFUN(AC_HEADER_SYS_WAIT,
  649. [AC_CACHE_CHECK([for sys/wait.h that is POSIX.1 compatible],
  650.   ac_cv_header_sys_wait_h,
  651. [AC_TRY_COMPILE([#include <sys/types.h>
  652. #include <sys/wait.h>
  653. #ifndef WEXITSTATUS
  654. #define WEXITSTATUS(stat_val) ((unsigned)(stat_val) >> 8)
  655. #endif
  656. #ifndef WIFEXITED
  657. #define WIFEXITED(stat_val) (((stat_val) & 255) == 0)
  658. #endif], [int s;
  659. wait (&s);
  660. s = WIFEXITED (s) ? WEXITSTATUS (s) : 1;],
  661. ac_cv_header_sys_wait_h=yes, ac_cv_header_sys_wait_h=no)])
  662. if test $ac_cv_header_sys_wait_h = yes; then
  663.   AC_DEFINE(HAVE_SYS_WAIT_H)
  664. fi
  665. ])
  666.  
  667.  
  668. dnl ### Checks for typedefs
  669.  
  670.  
  671. AC_DEFUN(AC_TYPE_GETGROUPS,
  672. [AC_REQUIRE([AC_TYPE_UID_T])dnl
  673. AC_CACHE_CHECK(type of array argument to getgroups, ac_cv_type_getgroups,
  674. [AC_TRY_RUN(
  675. changequote(<<, >>)dnl
  676. <<
  677. /* Thanks to Mike Rendell for this test.  */
  678. #include <sys/types.h>
  679. #define NGID 256
  680. #undef MAX
  681. #define MAX(x, y) ((x) > (y) ? (x) : (y))
  682. main()
  683. {
  684.   gid_t gidset[NGID];
  685.   int i, n;
  686.   union { gid_t gval; long lval; }  val;
  687.  
  688.   val.lval = -1;
  689.   for (i = 0; i < NGID; i++)
  690.     gidset[i] = val.gval;
  691.   n = getgroups (sizeof (gidset) / MAX (sizeof (int), sizeof (gid_t)) - 1,
  692.                  gidset);
  693.   /* Exit non-zero if getgroups seems to require an array of ints.  This
  694.      happens when gid_t is short but getgroups modifies an array of ints.  */
  695.   exit ((n > 0 && gidset[n] != val.gval) ? 1 : 0);
  696. }
  697. >>,
  698. changequote([, ])dnl
  699.   ac_cv_type_getgroups=gid_t, ac_cv_type_getgroups=int,
  700.   ac_cv_type_getgroups=cross)
  701. if test $ac_cv_type_getgroups = cross; then
  702.   dnl When we can't run the test program (we are cross compiling), presume
  703.   dnl that <unistd.h> has either an accurate prototype for getgroups or none.
  704.   dnl Old systems without prototypes probably use int.
  705.   AC_EGREP_HEADER([getgroups.*int.*gid_t], unistd.h,
  706.           ac_cv_type_getgroups=gid_t, ac_cv_type_getgroups=int)
  707. fi])
  708. AC_DEFINE_UNQUOTED(GETGROUPS_T, $ac_cv_type_getgroups)
  709. ])
  710.  
  711. AC_DEFUN(AC_TYPE_UID_T,
  712. [AC_CACHE_CHECK(for uid_t in sys/types.h, ac_cv_type_uid_t,
  713. [AC_EGREP_HEADER(uid_t, sys/types.h,
  714.   ac_cv_type_uid_t=yes, ac_cv_type_uid_t=no)])
  715. if test $ac_cv_type_uid_t = no; then
  716.   AC_DEFINE(uid_t, int)
  717.   AC_DEFINE(gid_t, int)
  718. fi
  719. ])
  720.  
  721. AC_DEFUN(AC_TYPE_SIZE_T,
  722. [AC_CHECK_TYPE(size_t, unsigned)])
  723.  
  724. AC_DEFUN(AC_TYPE_PID_T,
  725. [AC_CHECK_TYPE(pid_t, int)])
  726.  
  727. AC_DEFUN(AC_TYPE_OFF_T,
  728. [AC_CHECK_TYPE(off_t, long)])
  729.  
  730. AC_DEFUN(AC_TYPE_MODE_T,
  731. [AC_CHECK_TYPE(mode_t, int)])
  732.  
  733. dnl Note that identifiers starting with SIG are reserved by ANSI C.
  734. AC_DEFUN(AC_TYPE_SIGNAL,
  735. [AC_CACHE_CHECK([return type of signal handlers], ac_cv_type_signal,
  736. [AC_TRY_COMPILE([#include <sys/types.h>
  737. #include <signal.h>
  738. #ifdef signal
  739. #undef signal
  740. #endif
  741. #ifdef __cplusplus
  742. extern "C" void (*signal (int, void (*)(int)))(int);
  743. #else
  744. void (*signal ()) ();
  745. #endif
  746. ],
  747. [int i;], ac_cv_type_signal=void, ac_cv_type_signal=int)])
  748. AC_DEFINE_UNQUOTED(RETSIGTYPE, $ac_cv_type_signal)
  749. ])
  750.  
  751.  
  752. dnl ### Checks for functions
  753.  
  754.  
  755. AC_DEFUN(AC_FUNC_CLOSEDIR_VOID,
  756. [AC_REQUIRE([AC_HEADER_DIRENT])dnl
  757. AC_CACHE_CHECK(whether closedir returns void, ac_cv_func_closedir_void,
  758. [AC_TRY_RUN([#include <sys/types.h>
  759. #include <$ac_header_dirent>
  760. int closedir(); main() { exit(closedir(opendir(".")) != 0); }],
  761.   ac_cv_func_closedir_void=no, ac_cv_func_closedir_void=yes, ac_cv_func_closedir_void=yes)])
  762. if test $ac_cv_func_closedir_void = yes; then
  763.   AC_DEFINE(CLOSEDIR_VOID)
  764. fi
  765. ])
  766.  
  767. AC_DEFUN(AC_FUNC_MMAP,
  768. [AC_CHECK_FUNCS(valloc getpagesize)
  769. AC_CACHE_CHECK(for working mmap, ac_cv_func_mmap,
  770. [AC_TRY_RUN([
  771. /* Thanks to Mike Haertel and Jim Avera for this test. */
  772. #include <sys/types.h>
  773. #include <fcntl.h>
  774. #include <sys/mman.h>
  775.  
  776. #ifndef HAVE_GETPAGESIZE
  777. # include <sys/param.h>
  778. # ifdef EXEC_PAGESIZE
  779. #  define getpagesize() EXEC_PAGESIZE
  780. # else
  781. #  ifdef NBPG
  782. #   define getpagesize() NBPG * CLSIZE
  783. #   ifndef CLSIZE
  784. #    define CLSIZE 1
  785. #   endif
  786. #  else
  787. #   ifdef NBPC
  788. #    define getpagesize() NBPC
  789. #   else
  790. #    define getpagesize() PAGESIZE /* SVR4 */
  791. #   endif
  792. #  endif
  793. # endif
  794. #endif
  795.  
  796. #ifndef HAVE_VALLOC
  797. # define valloc malloc
  798. #endif
  799.  
  800. #ifdef __cplusplus
  801. extern "C" { void *valloc(unsigned), *malloc(unsigned); }
  802. #else
  803. char *valloc(), *malloc();
  804. #endif
  805.  
  806. int
  807. main()
  808. {
  809.   char *buf1, *buf2, *buf3;
  810.   int i = getpagesize(), j;
  811.   int i2 = i * 2;
  812.   int fd;
  813.  
  814.   buf1 = (char *)valloc(i2);
  815.   buf2 = (char *)valloc(i);
  816.   buf3 = (char *)malloc(i2);
  817.   for (j = 0; j < i2; ++j)
  818.     *(buf1 + j) = rand();
  819.   fd = open("conftestmmap", O_CREAT | O_RDWR, 0666);
  820.   write(fd, buf1, i2);
  821.   mmap(buf2, i, PROT_READ | PROT_WRITE, MAP_FIXED | MAP_PRIVATE, fd, 0);
  822.   for (j = 0; j < i; ++j)
  823.     if (*(buf1 + j) != *(buf2 + j))
  824.       exit(1);
  825.   lseek(fd, (long)i, 0);
  826.   read(fd, buf2, i); /* read into mapped memory -- file should not change */
  827.   /* (it does in i386 SVR4.0 - Jim Avera, jima@netcom.com) */
  828.   lseek(fd, (long)0, 0);
  829.   read(fd, buf3, i2);
  830.   for (j = 0; j < i2; ++j)
  831.     if (*(buf1 + j) != *(buf3 + j))
  832.       exit(1);
  833.   exit(0);
  834. }
  835. ], ac_cv_func_mmap=yes, ac_cv_func_mmap=no, ac_cv_func_mmap=no)])
  836. if test $ac_cv_func_mmap = yes; then
  837.   AC_DEFINE(HAVE_MMAP)
  838. fi
  839. ])
  840.  
  841. AC_DEFUN(AC_FUNC_GETPGRP,
  842. [AC_CACHE_CHECK(whether getpgrp takes no argument, ac_cv_func_getpgrp_void,
  843. [AC_TRY_RUN([
  844. /*
  845.  * If this system has a BSD-style getpgrp(),
  846.  * which takes a pid argument, exit unsuccessfully.
  847.  *
  848.  * Snarfed from Chet Ramey's bash pgrp.c test program
  849.  */
  850. #include <stdio.h>
  851. #include <sys/types.h>
  852.  
  853. int     pid;
  854. int     pg1, pg2, pg3, pg4;
  855. int     ng, np, s, child;
  856.  
  857. main()
  858. {
  859.         pid = getpid();
  860.         pg1 = getpgrp(0);
  861.         pg2 = getpgrp();
  862.         pg3 = getpgrp(pid);
  863.         pg4 = getpgrp(1);
  864.  
  865.         /*
  866.          * If all of these values are the same, it's pretty sure that
  867.          * we're on a system that ignores getpgrp's first argument.
  868.          */
  869.         if (pg2 == pg4 && pg1 == pg3 && pg2 == pg3)
  870.                 exit(0);
  871.  
  872.         child = fork();
  873.         if (child < 0)
  874.                 exit(1);
  875.         else if (child == 0) {
  876.                 np = getpid();
  877.                 /*
  878.                  * If this is Sys V, this will not work; pgrp will be
  879.                  * set to np because setpgrp just changes a pgrp to be
  880.                  * the same as the pid.
  881.                  */
  882.                 setpgrp(np, pg1);
  883.                 ng = getpgrp(0);        /* Same result for Sys V and BSD */
  884.                 if (ng == pg1) {
  885.                         exit(1);
  886.                 } else {
  887.                         exit(0);
  888.                 }
  889.         } else {
  890.                 wait(&s);
  891.                 exit(s>>8);
  892.         }
  893. }
  894. ], ac_cv_func_getpgrp_void=yes, ac_cv_func_getpgrp_void=no,
  895.    AC_MSG_ERROR(cannot check getpgrp if cross compiling))
  896. ])
  897. if test $ac_cv_func_getpgrp_void = yes; then
  898.   AC_DEFINE(GETPGRP_VOID)
  899. fi
  900. ])
  901.  
  902. AC_DEFUN(AC_FUNC_VPRINTF,
  903. [AC_CHECK_FUNC(vprintf, AC_DEFINE(HAVE_VPRINTF))
  904. if test "$ac_cv_func_vprintf" != yes; then
  905. AC_CHECK_FUNC(_doprnt, AC_DEFINE(HAVE_DOPRNT))
  906. fi
  907. ])
  908.  
  909. AC_DEFUN(AC_FUNC_VFORK,
  910. [AC_REQUIRE([AC_TYPE_PID_T])dnl
  911. AC_CHECK_HEADER(vfork.h, AC_DEFINE(HAVE_VFORK_H))
  912. AC_CACHE_CHECK(for working vfork, ac_cv_func_vfork,
  913. [AC_TRY_RUN([/* Thanks to Paul Eggert for this test.  */
  914. #include <stdio.h>
  915. #include <sys/types.h>
  916. #include <sys/stat.h>
  917. #ifdef HAVE_UNISTD_H
  918. #include <unistd.h>
  919. #endif
  920. #ifdef HAVE_VFORK_H
  921. #include <vfork.h>
  922. #endif
  923. /* On some sparc systems, changes by the child to local and incoming
  924.    argument registers are propagated back to the parent.
  925.    The compiler is told about this with #include <vfork.h>,
  926.    but some compilers (e.g. gcc -O) don't grok <vfork.h>.
  927.    Test for this by using a static variable whose address
  928.    is put into a register that is clobbered by the vfork.  */
  929. static
  930. #ifdef __cplusplus
  931. sparc_address_test (int arg)
  932. #else
  933. sparc_address_test (arg) int arg;
  934. #endif
  935. {
  936.   static pid_t child;
  937.   if (!child) {
  938.     child = vfork ();
  939.     if (child < 0)
  940.       perror ("vfork");
  941.     if (!child) {
  942.       arg = getpid();
  943.       write(-1, "", 0);
  944.       _exit (arg);
  945.     }
  946.   }
  947. }
  948. main() {
  949.   pid_t parent = getpid ();
  950.   pid_t child;
  951.  
  952.   sparc_address_test ();
  953.  
  954.   child = vfork ();
  955.  
  956.   if (child == 0) {
  957.     /* Here is another test for sparc vfork register problems.
  958.        This test uses lots of local variables, at least
  959.        as many local variables as main has allocated so far
  960.        including compiler temporaries.  4 locals are enough for
  961.        gcc 1.40.3 on a Solaris 4.1.3 sparc, but we use 8 to be safe.
  962.        A buggy compiler should reuse the register of parent
  963.        for one of the local variables, since it will think that
  964.        parent can't possibly be used any more in this routine.
  965.        Assigning to the local variable will thus munge parent
  966.        in the parent process.  */
  967.     pid_t
  968.       p = getpid(), p1 = getpid(), p2 = getpid(), p3 = getpid(),
  969.       p4 = getpid(), p5 = getpid(), p6 = getpid(), p7 = getpid();
  970.     /* Convince the compiler that p..p7 are live; otherwise, it might
  971.        use the same hardware register for all 8 local variables.  */
  972.     if (p != p1 || p != p2 || p != p3 || p != p4
  973.     || p != p5 || p != p6 || p != p7)
  974.       _exit(1);
  975.  
  976.     /* On some systems (e.g. IRIX 3.3),
  977.        vfork doesn't separate parent from child file descriptors.
  978.        If the child closes a descriptor before it execs or exits,
  979.        this munges the parent's descriptor as well.
  980.        Test for this by closing stdout in the child.  */
  981.     _exit(close(fileno(stdout)) != 0);
  982.   } else {
  983.     int status;
  984.     struct stat st;
  985.  
  986.     while (wait(&status) != child)
  987.       ;
  988.     exit(
  989.      /* Was there some problem with vforking?  */
  990.      child < 0
  991.  
  992.      /* Did the child fail?  (This shouldn't happen.)  */
  993.      || status
  994.  
  995.      /* Did the vfork/compiler bug occur?  */
  996.      || parent != getpid()
  997.  
  998.      /* Did the file descriptor bug occur?  */
  999.      || fstat(fileno(stdout), &st) != 0
  1000.      );
  1001.   }
  1002. }],
  1003. ac_cv_func_vfork=yes, ac_cv_func_vfork=no, AC_CHECK_FUNC(vfork))])
  1004. if test $ac_cv_func_vfork = no; then
  1005.   AC_DEFINE(vfork, fork)
  1006. fi
  1007. ])
  1008.  
  1009. AC_DEFUN(AC_FUNC_WAIT3,
  1010. [AC_CACHE_CHECK(for wait3 that fills in rusage, ac_cv_func_wait3,
  1011. [AC_TRY_RUN([#include <sys/types.h>
  1012. #include <sys/time.h>
  1013. #include <sys/resource.h>
  1014. #include <stdio.h>
  1015. /* HP-UX has wait3 but does not fill in rusage at all.  */
  1016. main() {
  1017.   struct rusage r;
  1018.   int i;
  1019.   /* Use a field that we can force nonzero --
  1020.      voluntary context switches.
  1021.      For systems like NeXT and OSF/1 that don't set it,
  1022.      also use the system CPU time.  And page faults (I/O) for Linux.  */
  1023.   r.ru_nvcsw = 0;
  1024.   r.ru_stime.tv_sec = 0;
  1025.   r.ru_stime.tv_usec = 0;
  1026.   r.ru_majflt = r.ru_minflt = 0;
  1027.   switch (fork()) {
  1028.   case 0: /* Child.  */
  1029.     sleep(1); /* Give up the CPU.  */
  1030.     _exit(0);
  1031.   case -1: _exit(0); /* What can we do?  */
  1032.   default: /* Parent.  */
  1033.     wait3(&i, 0, &r);
  1034.     sleep(2); /* Avoid "text file busy" from rm on fast HP-UX machines.  */
  1035.     exit(r.ru_nvcsw == 0 && r.ru_majflt == 0 && r.ru_minflt == 0
  1036.      && r.ru_stime.tv_sec == 0 && r.ru_stime.tv_usec == 0);
  1037.   }
  1038. }], ac_cv_func_wait3=yes, ac_cv_func_wait3=no, ac_cv_func_wait3=no)])
  1039. if test $ac_cv_func_wait3 = yes; then
  1040.   AC_DEFINE(HAVE_WAIT3)
  1041. fi
  1042. ])
  1043.  
  1044. AC_DEFUN(AC_FUNC_ALLOCA,
  1045. [AC_REQUIRE_CPP()dnl Set CPP; we run AC_EGREP_CPP conditionally.
  1046. # The Ultrix 4.2 mips builtin alloca declared by alloca.h only works
  1047. # for constant arguments.  Useless!
  1048. AC_CACHE_CHECK([for working alloca.h], ac_cv_header_alloca_h,
  1049. [AC_TRY_LINK([#include <alloca.h>], [char *p = alloca(2 * sizeof(int));],
  1050.   ac_cv_header_alloca_h=yes, ac_cv_header_alloca_h=no)])
  1051. if test $ac_cv_header_alloca_h = yes; then
  1052.   AC_DEFINE(HAVE_ALLOCA_H)
  1053. fi
  1054.  
  1055. AC_CACHE_CHECK([for alloca], ac_cv_func_alloca,
  1056. [AC_TRY_LINK([
  1057. #ifdef __GNUC__
  1058. # define alloca __builtin_alloca
  1059. #else
  1060. # if HAVE_ALLOCA_H
  1061. #  include <alloca.h>
  1062. # else
  1063. #  ifdef _AIX
  1064.  #pragma alloca
  1065. #  else
  1066. #   ifndef alloca /* predefined by HP cc +Olibcalls */
  1067. char *alloca ();
  1068. #   endif
  1069. #  endif
  1070. # endif
  1071. #endif
  1072. ], [char *p = (char *) alloca(1);],
  1073.   ac_cv_func_alloca=yes, ac_cv_func_alloca=no)])
  1074. if test $ac_cv_func_alloca = yes; then
  1075.   AC_DEFINE(HAVE_ALLOCA)
  1076. fi
  1077.  
  1078. if test $ac_cv_func_alloca = no; then
  1079.   # The SVR3 libPW and SVR4 libucb both contain incompatible functions
  1080.   # that cause trouble.  Some versions do not even contain alloca or
  1081.   # contain a buggy version.  If you still want to use their alloca,
  1082.   # use ar to extract alloca.o from them instead of compiling alloca.c.
  1083.   ALLOCA=alloca.o
  1084.   AC_DEFINE(C_ALLOCA)
  1085.  
  1086. AC_CACHE_CHECK(whether alloca needs Cray hooks, ac_cv_os_cray,
  1087. [AC_EGREP_CPP(webecray,
  1088. [#if defined(CRAY) && ! defined(CRAY2)
  1089. webecray
  1090. #else
  1091. wenotbecray
  1092. #endif
  1093. ], ac_cv_os_cray=yes, ac_cv_os_cray=no)])
  1094. if test $ac_cv_os_cray = yes; then
  1095. for ac_func in _getb67 GETB67 getb67; do
  1096.   AC_CHECK_FUNC($ac_func, [AC_DEFINE_UNQUOTED(CRAY_STACKSEG_END, $ac_func)
  1097.   break])
  1098. done
  1099. fi
  1100.  
  1101. AC_CACHE_CHECK(stack direction for C alloca, ac_cv_c_stack_direction,
  1102. [AC_TRY_RUN([find_stack_direction ()
  1103. {
  1104.   static char *addr = 0;
  1105.   auto char dummy;
  1106.   if (addr == 0)
  1107.     {
  1108.       addr = &dummy;
  1109.       return find_stack_direction ();
  1110.     }
  1111.   else
  1112.     return (&dummy > addr) ? 1 : -1;
  1113. }
  1114. main ()
  1115. {
  1116.   exit (find_stack_direction() < 0);
  1117. }], ac_cv_c_stack_direction=1, ac_cv_c_stack_direction=-1,
  1118.   ac_cv_c_stack_direction=0)])
  1119. AC_DEFINE_UNQUOTED(STACK_DIRECTION, $ac_cv_c_stack_direction)
  1120. fi
  1121. AC_SUBST(ALLOCA)dnl
  1122. ])
  1123.  
  1124. AC_DEFUN(AC_FUNC_GETLOADAVG,
  1125. [ac_have_func=no # yes means we've found a way to get the load average.
  1126.  
  1127. # Some systems with -lutil have (and need) -lkvm as well, some do not.
  1128. # On Solaris, -lkvm requires nlist from -lelf, so check that first
  1129. # to get the right answer into the cache.
  1130. AC_CHECK_LIB(elf, elf_begin, LIBS="-lelf $LIBS")
  1131. AC_CHECK_LIB(kvm, kvm_open, LIBS="-lkvm $LIBS")
  1132. # Check for the 4.4BSD definition of getloadavg.
  1133. AC_CHECK_LIB(util, getloadavg,
  1134.   [LIBS="-lutil $LIBS" ac_have_func=yes ac_cv_func_getloadavg_setgid=yes])
  1135.  
  1136. if test $ac_have_func = no; then
  1137.   # There is a commonly available library for RS/6000 AIX.
  1138.   # Since it is not a standard part of AIX, it might be installed locally.
  1139.   ac_save_LIBS="$LIBS" LIBS="-L/usr/local/lib $LIBS"
  1140.   AC_CHECK_LIB(getloadavg, getloadavg,
  1141.     LIBS="-lgetloadavg $LIBS", LIBS="$ac_save_LIBS")
  1142. fi
  1143.  
  1144. # Make sure it is really in the library, if we think we found it.
  1145. AC_REPLACE_FUNCS(getloadavg)
  1146.  
  1147. if test $ac_cv_func_getloadavg = yes; then
  1148.   AC_DEFINE(HAVE_GETLOADAVG)
  1149.   ac_have_func=yes
  1150. else
  1151.   # Figure out what our getloadavg.c needs.
  1152.   ac_have_func=no
  1153.   AC_CHECK_HEADER(sys/dg_sys_info.h,
  1154.   [ac_have_func=yes; AC_DEFINE(DGUX)
  1155.   AC_CHECK_LIB(dgc, dg_sys_info)])
  1156.  
  1157.   # We cannot check for <dwarf.h>, because Solaris 2 does not use dwarf (it
  1158.   # uses stabs), but it is still SVR4.  We cannot check for <elf.h> because
  1159.   # Irix 4.0.5F has the header but not the library.
  1160.   if test $ac_have_func = no && test $ac_cv_lib_elf_elf_begin = yes; then
  1161.     ac_have_func=yes; AC_DEFINE(SVR4)
  1162.   fi
  1163.  
  1164.   if test $ac_have_func = no; then
  1165.     AC_CHECK_HEADER(inq_stats/cpustats.h,
  1166.     [ac_have_func=yes; AC_DEFINE(UMAX)
  1167.     AC_DEFINE(UMAX4_3)])
  1168.   fi
  1169.  
  1170.   if test $ac_have_func = no; then
  1171.     AC_CHECK_HEADER(sys/cpustats.h,
  1172.     [ac_have_func=yes; AC_DEFINE(UMAX)])
  1173.   fi
  1174.  
  1175.   if test $ac_have_func = no; then
  1176.     AC_CHECK_HEADERS(mach/mach.h)
  1177.   fi
  1178.  
  1179.   AC_CHECK_HEADER(nlist.h,
  1180.   [AC_DEFINE(NLIST_STRUCT)
  1181.   AC_CACHE_CHECK([for n_un in struct nlist], ac_cv_struct_nlist_n_un,
  1182.   [AC_TRY_COMPILE([#include <nlist.h>],
  1183.   [struct nlist n; n.n_un.n_name = 0;],
  1184.   ac_cv_struct_nlist_n_un=yes, ac_cv_struct_nlist_n_un=no)])
  1185.   if test $ac_cv_struct_nlist_n_un = yes; then
  1186.     AC_DEFINE(NLIST_NAME_UNION)
  1187.   fi
  1188.   ])dnl
  1189. fi # Do not have getloadavg in system libraries.
  1190.  
  1191. # Some definitions of getloadavg require that the program be installed setgid.
  1192. dnl FIXME Don't hardwire the path of getloadavg.c in the top-level directory.
  1193. AC_CACHE_CHECK(whether getloadavg requires setgid,
  1194.   ac_cv_func_getloadavg_setgid,
  1195. [AC_EGREP_CPP([Yowza Am I SETGID yet],
  1196. [#include "$srcdir/getloadavg.c"
  1197. #ifdef LDAV_PRIVILEGED
  1198. Yowza Am I SETGID yet
  1199. #endif],
  1200.   ac_cv_func_getloadavg_setgid=yes, ac_cv_func_getloadavg_setgid=no)])
  1201. if test $ac_cv_func_getloadavg_setgid = yes; then
  1202.   NEED_SETGID=true; AC_DEFINE(GETLOADAVG_PRIVILEGED)
  1203. else
  1204.   NEED_SETGID=false
  1205. fi
  1206. AC_SUBST(NEED_SETGID)dnl
  1207.  
  1208. if test $ac_cv_func_getloadavg_setgid = yes; then
  1209.   AC_CACHE_CHECK(group of /dev/kmem, ac_cv_group_kmem,
  1210. [changequote(, )dnl
  1211.   # On Solaris, /dev/kmem is a symlink.  Get info on the real file.
  1212.   ac_ls_output=`ls -lgL /dev/kmem 2>/dev/null`
  1213.   # If we got an error (system does not support symlinks), try without -L.
  1214.   test -z "$ac_ls_output" && ac_ls_output=`ls -lg /dev/kmem`
  1215.   ac_cv_group_kmem=`echo $ac_ls_output \
  1216.     | sed -ne 's/[     ][     ]*/ /g;
  1217.            s/^.[sSrwx-]* *[0-9]* *\([^0-9]*\)  *.*/\1/;
  1218.            / /s/.* //;p;'`
  1219. changequote([, ])dnl
  1220. ])
  1221.   KMEM_GROUP=$ac_cv_group_kmem
  1222. fi
  1223. AC_SUBST(KMEM_GROUP)dnl
  1224. ])
  1225.  
  1226. AC_DEFUN(AC_FUNC_UTIME_NULL,
  1227. [AC_CACHE_CHECK(whether utime accepts a null argument, ac_cv_func_utime_null,
  1228. [rm -f conftestdata; > conftestdata
  1229. # Sequent interprets utime(file, 0) to mean use start of epoch.  Wrong.
  1230. AC_TRY_RUN([#include <sys/types.h>
  1231. #include <sys/stat.h>
  1232. main() {
  1233. struct stat s, t;
  1234. exit(!(stat ("conftestdata", &s) == 0 && utime("conftestdata", (long *)0) == 0
  1235. && stat("conftestdata", &t) == 0 && t.st_mtime >= s.st_mtime
  1236. && t.st_mtime - s.st_mtime < 120));
  1237. }], ac_cv_func_utime_null=yes, ac_cv_func_utime_null=no,
  1238.   ac_cv_func_utime_null=no)
  1239. rm -f core core.* *.core])
  1240. if test $ac_cv_func_utime_null = yes; then
  1241.   AC_DEFINE(HAVE_UTIME_NULL)
  1242. fi
  1243. ])
  1244.  
  1245. AC_DEFUN(AC_FUNC_STRCOLL,
  1246. [AC_CACHE_CHECK(for strcoll, ac_cv_func_strcoll,
  1247. [AC_TRY_RUN([#include <string.h>
  1248. main ()
  1249. {
  1250.   exit (strcoll ("abc", "def") >= 0 ||
  1251.     strcoll ("ABC", "DEF") >= 0 ||
  1252.     strcoll ("123", "456") >= 0);
  1253. }], ac_cv_func_strcoll=yes, ac_cv_func_strcoll=no, ac_cv_func_strcoll=no)])
  1254. if test $ac_cv_func_strcoll = yes; then
  1255.   AC_DEFINE(HAVE_STRCOLL)
  1256. fi
  1257. ])
  1258.  
  1259. AC_DEFUN(AC_FUNC_SETVBUF_REVERSED,
  1260. [AC_CACHE_CHECK(whether setvbuf arguments are reversed,
  1261.   ac_cv_func_setvbuf_reversed,
  1262. [AC_TRY_RUN([#include <stdio.h>
  1263. /* If setvbuf has the reversed format, exit 0. */
  1264. main () {
  1265.   /* This call has the arguments reversed.
  1266.      A reversed system may check and see that the address of main
  1267.      is not _IOLBF, _IONBF, or _IOFBF, and return nonzero.  */
  1268.   if (setvbuf(stdout, _IOLBF, (char *) main, BUFSIZ) != 0)
  1269.     exit(1);
  1270.   putc('\r', stdout);
  1271.   exit(0);            /* Non-reversed systems segv here.  */
  1272. }], ac_cv_func_setvbuf_reversed=yes, ac_cv_func_setvbuf_reversed=no)
  1273. rm -f core core.* *.core])
  1274. if test $ac_cv_func_setvbuf_reversed = yes; then
  1275.   AC_DEFINE(SETVBUF_REVERSED)
  1276. fi
  1277. ])
  1278.  
  1279. AC_DEFUN(AC_FUNC_GETMNTENT,
  1280. [# getmntent is in -lsun on Irix 4, -lseq on Dynix/PTX, -lgen on Unixware.
  1281. AC_CHECK_LIB(sun, getmntent, LIBS="-lsun $LIBS",
  1282.   [AC_CHECK_LIB(seq, getmntent, LIBS="-lseq $LIBS",
  1283.     [AC_CHECK_LIB(gen, getmntent, LIBS="-lgen $LIBS")])])
  1284. AC_CHECK_FUNC(getmntent, [AC_DEFINE(HAVE_GETMNTENT)])])
  1285.  
  1286. AC_DEFUN(AC_FUNC_STRFTIME,
  1287. [# strftime is in -lintl on SCO UNIX.
  1288. AC_CHECK_LIB(intl, strftime, LIBS="-lintl $LIBS")
  1289. AC_CHECK_FUNC(strftime, [AC_DEFINE(HAVE_STRFTIME)])])
  1290.  
  1291. AC_DEFUN(AC_FUNC_MEMCMP,
  1292. [AC_CACHE_CHECK(for 8-bit clean memcmp, ac_cv_func_memcmp,
  1293. [AC_TRY_RUN([
  1294. main()
  1295. {
  1296.   char c0 = 0x40, c1 = 0x80, c2 = 0x81;
  1297.   exit(memcmp(&c0, &c2, 1) < 0 && memcmp(&c1, &c2, 1) < 0 ? 0 : 1);
  1298. }
  1299. ], ac_cv_func_memcmp=yes, ac_cv_func_memcmp=no, ac_cv_func_memcmp=no)])
  1300. test $ac_cv_func_memcmp = no && LIBOBJS="$LIBOBJS memcmp.o"
  1301. AC_SUBST(LIBOBJS)dnl
  1302. ])
  1303.  
  1304.  
  1305. dnl ### Checks for structure members
  1306.  
  1307.  
  1308. AC_DEFUN(AC_HEADER_TIME,
  1309. [AC_CACHE_CHECK([whether time.h and sys/time.h may both be included],
  1310.   ac_cv_header_time,
  1311. [AC_TRY_COMPILE([#include <sys/types.h>
  1312. #include <sys/time.h>
  1313. #include <time.h>],
  1314. [struct tm *tp;], ac_cv_header_time=yes, ac_cv_header_time=no)])
  1315. if test $ac_cv_header_time = yes; then
  1316.   AC_DEFINE(TIME_WITH_SYS_TIME)
  1317. fi
  1318. ])
  1319.  
  1320. AC_DEFUN(AC_STRUCT_TM,
  1321. [AC_CACHE_CHECK([whether struct tm is in sys/time.h or time.h],
  1322.   ac_cv_struct_tm,
  1323. [AC_TRY_COMPILE([#include <sys/types.h>
  1324. #include <time.h>],
  1325. [struct tm *tp; tp->tm_sec;],
  1326.   ac_cv_struct_tm=time.h, ac_cv_struct_tm=sys/time.h)])
  1327. if test $ac_cv_struct_tm = sys/time.h; then
  1328.   AC_DEFINE(TM_IN_SYS_TIME)
  1329. fi
  1330. ])
  1331.  
  1332. AC_DEFUN(AC_STRUCT_TIMEZONE,
  1333. [AC_REQUIRE([AC_STRUCT_TM])dnl
  1334. AC_CACHE_CHECK([for tm_zone in struct tm], ac_cv_struct_tm_zone,
  1335. [AC_TRY_COMPILE([#include <sys/types.h>
  1336. #include <$ac_cv_struct_tm>], [struct tm tm; tm.tm_zone;],
  1337.   ac_cv_struct_tm_zone=yes, ac_cv_struct_tm_zone=no)])
  1338. if test "$ac_cv_struct_tm_zone" = yes; then
  1339.   AC_DEFINE(HAVE_TM_ZONE)
  1340. else
  1341.   AC_CACHE_CHECK(for tzname, ac_cv_var_tzname,
  1342. [AC_TRY_LINK(
  1343. changequote(<<, >>)dnl
  1344. <<#include <time.h>
  1345. #ifndef tzname /* For SGI.  */
  1346. extern char *tzname[]; /* RS6000 and others reject char **tzname.  */
  1347. #endif>>,
  1348. changequote([, ])dnl
  1349. [atoi(*tzname);], ac_cv_var_tzname=yes, ac_cv_var_tzname=no)])
  1350.   if test $ac_cv_var_tzname = yes; then
  1351.     AC_DEFINE(HAVE_TZNAME)
  1352.   fi
  1353. fi
  1354. ])
  1355.  
  1356. AC_DEFUN(AC_STRUCT_ST_BLOCKS,
  1357. [AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
  1358. [AC_TRY_COMPILE([#include <sys/types.h>
  1359. #include <sys/stat.h>], [struct stat s; s.st_blocks;],
  1360. ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
  1361. if test $ac_cv_struct_st_blocks = yes; then
  1362.   AC_DEFINE(HAVE_ST_BLOCKS)
  1363. else
  1364.   LIBOBJS="$LIBOBJS fileblocks.o"
  1365. fi
  1366. AC_SUBST(LIBOBJS)dnl
  1367. ])
  1368.  
  1369. AC_DEFUN(AC_STRUCT_ST_BLKSIZE,
  1370. [AC_CACHE_CHECK([for st_blksize in struct stat], ac_cv_struct_st_blksize,
  1371. [AC_TRY_COMPILE([#include <sys/types.h>
  1372. #include <sys/stat.h>], [struct stat s; s.st_blksize;],
  1373. ac_cv_struct_st_blksize=yes, ac_cv_struct_st_blksize=no)])
  1374. if test $ac_cv_struct_st_blksize = yes; then
  1375.   AC_DEFINE(HAVE_ST_BLKSIZE)
  1376. fi
  1377. ])
  1378.  
  1379. AC_DEFUN(AC_STRUCT_ST_RDEV,
  1380. [AC_CACHE_CHECK([for st_rdev in struct stat], ac_cv_struct_st_rdev,
  1381. [AC_TRY_COMPILE([#include <sys/types.h>
  1382. #include <sys/stat.h>], [struct stat s; s.st_rdev;],
  1383. ac_cv_struct_st_rdev=yes, ac_cv_struct_st_rdev=no)])
  1384. if test $ac_cv_struct_st_rdev = yes; then
  1385.   AC_DEFINE(HAVE_ST_RDEV)
  1386. fi
  1387. ])
  1388.  
  1389.  
  1390. dnl ### Checks for compiler characteristics
  1391.  
  1392.  
  1393. AC_DEFUN(AC_C_CROSS,
  1394. [# If we cannot run a trivial program, we must be cross compiling.
  1395. AC_CACHE_CHECK(whether cross-compiling, ac_cv_c_cross,
  1396. [AC_TRY_RUN([main(){return(0);}],
  1397.   ac_cv_c_cross=no, ac_cv_c_cross=yes, ac_cv_c_cross=yes)])
  1398. cross_compiling=$ac_cv_c_cross
  1399. ])
  1400.  
  1401. AC_DEFUN(AC_C_CHAR_UNSIGNED,
  1402. [AC_CACHE_CHECK(whether char is unsigned, ac_cv_c_char_unsigned,
  1403. [if test "$GCC" = yes; then
  1404.   # GCC predefines this symbol on systems where it applies.
  1405. AC_EGREP_CPP(yes,
  1406. [#ifdef __CHAR_UNSIGNED__
  1407.   yes
  1408. #endif
  1409. ], ac_cv_c_char_unsigned=yes, ac_cv_c_char_unsigned=no)
  1410. else
  1411. AC_TRY_RUN(
  1412. [/* volatile prevents gcc2 from optimizing the test away on sparcs.  */
  1413. #if !defined(__STDC__) || __STDC__ != 1
  1414. #define volatile
  1415. #endif
  1416. main() {
  1417.   volatile char c = 255; exit(c < 0);
  1418. }], ac_cv_c_char_unsigned=yes, ac_cv_c_char_unsigned=no)
  1419. fi])
  1420. if test $ac_cv_c_char_unsigned = yes && test "$GCC" != yes; then
  1421.   AC_DEFINE(__CHAR_UNSIGNED__)
  1422. fi
  1423. ])
  1424.  
  1425. AC_DEFUN(AC_C_LONG_DOUBLE,
  1426. [AC_CACHE_CHECK(for long double, ac_cv_c_long_double,
  1427. [if test "$GCC" = yes; then
  1428.   ac_cv_c_long_double=yes
  1429. else
  1430. AC_TRY_RUN([int main() {
  1431. /* The Stardent Vistra knows sizeof(long double), but does not support it.  */
  1432. long double foo = 0.0;
  1433. /* On Ultrix 4.3 cc, long double is 4 and double is 8.  */
  1434. exit(sizeof(long double) < sizeof(double)); }],
  1435. ac_cv_c_long_double=yes, ac_cv_c_long_double=no)
  1436. fi])
  1437. if test $ac_cv_c_long_double = yes; then
  1438.   AC_DEFINE(HAVE_LONG_DOUBLE)
  1439. fi
  1440. ])
  1441.  
  1442. AC_DEFUN(AC_INT_16_BITS,
  1443. [AC_OBSOLETE([$0], [; instead use AC_CHECK_SIZEOF(int)])dnl
  1444. AC_MSG_CHECKING(whether int is 16 bits)
  1445. AC_TRY_RUN([main() { exit(sizeof(int) != 2); }],
  1446.  [AC_MSG_RESULT(yes)
  1447.  AC_DEFINE(INT_16_BITS)], AC_MSG_RESULT(no))
  1448. ])
  1449.  
  1450. AC_DEFUN(AC_LONG_64_BITS,
  1451. [AC_OBSOLETE([$0], [; instead use AC_CHECK_SIZEOF(long)])dnl
  1452. AC_MSG_CHECKING(whether long int is 64 bits)
  1453. AC_TRY_RUN([main() { exit(sizeof(long int) != 8); }],
  1454.  [AC_MSG_RESULT(yes)
  1455.  AC_DEFINE(LONG_64_BITS)], AC_MSG_RESULT(no))
  1456. ])
  1457.  
  1458. AC_DEFUN(AC_C_BIGENDIAN,
  1459. [AC_CACHE_CHECK(whether byte ordering is bigendian, ac_cv_c_bigendian,
  1460. [ac_cv_c_bigendian=unknown
  1461. # See if sys/param.h defines the BYTE_ORDER macro.
  1462. AC_TRY_COMPILE([#include <sys/types.h>
  1463. #include <sys/param.h>], [
  1464. #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
  1465.  bogus endian macros
  1466. #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
  1467. AC_TRY_COMPILE([#include <sys/types.h>
  1468. #include <sys/param.h>], [
  1469. #if BYTE_ORDER != BIG_ENDIAN
  1470.  not big endian
  1471. #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
  1472. if test $ac_cv_c_bigendian = unknown; then
  1473. AC_TRY_RUN([main () {
  1474.   /* Are we little or big endian?  From Harbison&Steele.  */
  1475.   union
  1476.   {
  1477.     long l;
  1478.     char c[sizeof (long)];
  1479.   } u;
  1480.   u.l = 1;
  1481.   exit (u.c[sizeof (long) - 1] == 1);
  1482. }], ac_cv_c_bigendian=no, ac_cv_c_bigendian=yes)
  1483. fi])
  1484. if test $ac_cv_c_bigendian = yes; then
  1485.   AC_DEFINE(WORDS_BIGENDIAN)
  1486. fi
  1487. ])
  1488.  
  1489. dnl Do nothing if the compiler accepts the inline keyword.
  1490. dnl Otherwise define inline to __inline__ or __inline if one of those work,
  1491. dnl otherwise define inline to be empty.
  1492. AC_DEFUN(AC_C_INLINE,
  1493. [AC_CACHE_CHECK([for inline], ac_cv_c_inline,
  1494. [ac_cv_c_inline=no
  1495. for ac_kw in inline __inline__ __inline; do
  1496.   AC_TRY_COMPILE(, [} $ac_kw foo() {], [ac_cv_c_inline=$ac_kw; break])
  1497. done
  1498. ])
  1499. case "$ac_cv_c_inline" in
  1500.   inline | yes) ;;
  1501.   no) AC_DEFINE(inline, ) ;;
  1502.   *)  AC_DEFINE_UNQUOTED(inline, $ac_cv_c_inline) ;;
  1503. esac
  1504. ])
  1505.  
  1506. AC_DEFUN(AC_C_CONST,
  1507. [dnl This message is consistent in form with the other checking messages,
  1508. dnl and with the result message.
  1509. AC_CACHE_CHECK([for working const], ac_cv_c_const,
  1510. [AC_TRY_COMPILE(,
  1511. changequote(<<, >>)dnl
  1512. <<
  1513. /* Ultrix mips cc rejects this.  */
  1514. typedef int charset[2]; const charset x;
  1515. /* SunOS 4.1.1 cc rejects this.  */
  1516. char const *const *ccp;
  1517. char **p;
  1518. /* NEC SVR4.0.2 mips cc rejects this.  */
  1519. struct point {int x, y;};
  1520. static struct point const zero = {0,0};
  1521. /* AIX XL C 1.02.0.0 rejects this.
  1522.    It does not let you subtract one const X* pointer from another in an arm
  1523.    of an if-expression whose if-part is not a constant expression */
  1524. const char *g = "string";
  1525. ccp = &g + (g ? g-g : 0);
  1526. /* HPUX 7.0 cc rejects these. */
  1527. ++ccp;
  1528. p = (char**) ccp;
  1529. ccp = (char const *const *) p;
  1530. { /* SCO 3.2v4 cc rejects this.  */
  1531.   char *t;
  1532.   char const *s = 0 ? (char *) 0 : (char const *) 0;
  1533.  
  1534.   *t++ = 0;
  1535. }
  1536. { /* Someone thinks the Sun supposedly-ANSI compiler will reject this.  */
  1537.   int x[] = {25, 17};
  1538.   const int *foo = &x[0];
  1539.   ++foo;
  1540. }
  1541. { /* Sun SC1.0 ANSI compiler rejects this -- but not the above. */
  1542.   typedef const int *iptr;
  1543.   iptr p = 0;
  1544.   ++p;
  1545. }
  1546. { /* AIX XL C 1.02.0.0 rejects this saying
  1547.      "k.c", line 2.27: 1506-025 (S) Operand must be a modifiable lvalue. */
  1548.   struct s { int j; const int *ap[3]; };
  1549.   struct s *b; b->j = 5;
  1550. }
  1551. { /* ULTRIX-32 V3.1 (Rev 9) vcc rejects this */
  1552.   const int foo = 10;
  1553. }
  1554. >>,
  1555. changequote([, ])dnl
  1556. ac_cv_c_const=yes, ac_cv_c_const=no)])
  1557. if test $ac_cv_c_const = no; then
  1558.   AC_DEFINE(const, )
  1559. fi
  1560. ])
  1561.  
  1562. define(AC_ARG_ARRAY,
  1563. [errprint(__file__:__line__: [$0] has been removed; don't do unportable things with arguments
  1564. )m4exit(4)])
  1565.  
  1566.  
  1567. dnl ### Checks for operating system services
  1568.  
  1569.  
  1570. AC_DEFUN(AC_SYS_INTERPRETER,
  1571. [# Pull the hash mark out of the macro call to avoid m4 problems.
  1572. ac_msg="whether #! works in shell scripts"
  1573. AC_CACHE_CHECK($ac_msg, ac_cv_sys_interpreter,
  1574. [echo '#! /bin/cat
  1575. exit 69
  1576. ' > conftest
  1577. chmod u+x conftest
  1578. (SHELL=/bin/sh; export SHELL; ./conftest >/dev/null)
  1579. if test $? -ne 69; then
  1580.    ac_cv_sys_interpreter=yes
  1581. else
  1582.    ac_cv_sys_interpreter=no
  1583. fi
  1584. rm -f conftest])
  1585. ])
  1586.  
  1587. define(AC_HAVE_POUNDBANG,
  1588. [errprint(__file__:__line__: [$0 has been replaced by AC_SYS_INTERPRETER, taking no arguments
  1589. ])m4exit(4)])
  1590.  
  1591. AC_DEFUN(AC_SYS_LONG_FILE_NAMES,
  1592. [AC_CACHE_CHECK(for long file names, ac_cv_sys_long_file_names,
  1593. [ac_cv_sys_long_file_names=yes
  1594. # Test for long file names in all the places we know might matter:
  1595. #      .        the current directory, where building will happen
  1596. #      /tmp        where it might want to write temporary files
  1597. #      /var/tmp        likewise
  1598. #      /usr/tmp        likewise
  1599. #      $prefix/lib    where we will be installing things
  1600. #      $exec_prefix/lib    likewise
  1601. # eval it to expand exec_prefix.
  1602. for ac_dir in `eval echo . /tmp /var/tmp /usr/tmp $prefix/lib $exec_prefix/lib` ; do
  1603.   test -d $ac_dir || continue
  1604.   test -w $ac_dir || continue # It is less confusing to not echo anything here.
  1605.   (echo 1 > $ac_dir/conftest9012345) 2>/dev/null
  1606.   (echo 2 > $ac_dir/conftest9012346) 2>/dev/null
  1607.   val=`cat $ac_dir/conftest9012345 2>/dev/null`
  1608.   if test ! -f $ac_dir/conftest9012345 || test "$val" != 1; then
  1609.     ac_cv_sys_long_file_names=no
  1610.     rm -f $ac_dir/conftest9012345 $ac_dir/conftest9012346 2>/dev/null
  1611.     break
  1612.   fi
  1613.   rm -f $ac_dir/conftest9012345 $ac_dir/conftest9012346 2>/dev/null
  1614. done])
  1615. if test $ac_cv_sys_long_file_names = yes; then
  1616.   AC_DEFINE(HAVE_LONG_FILE_NAMES)
  1617. fi
  1618. ])
  1619.  
  1620. AC_DEFUN(AC_SYS_RESTARTABLE_SYSCALLS,
  1621. [AC_CACHE_CHECK(for restartable system calls, ac_cv_sys_restartable_syscalls,
  1622. [AC_TRY_RUN(
  1623. [/* Exit 0 (true) if wait returns something other than -1,
  1624.    i.e. the pid of the child, which means that wait was restarted
  1625.    after getting the signal.  */
  1626. #include <sys/types.h>
  1627. #include <signal.h>
  1628. ucatch (isig) { }
  1629. main () {
  1630.   int i = fork (), status;
  1631.   if (i == 0) { sleep (3); kill (getppid (), SIGINT); sleep (3); exit (0); }
  1632.   signal (SIGINT, ucatch);
  1633.   status = wait(&i);
  1634.   if (status == -1) wait(&i);
  1635.   exit (status == -1);
  1636. }
  1637. ], ac_cv_sys_restartable_syscalls=yes, ac_cv_sys_restartable_syscalls=no)])
  1638. if test $ac_cv_sys_restartable_syscalls = yes; then
  1639.   AC_DEFINE(HAVE_RESTARTABLE_SYSCALLS)
  1640. fi
  1641. ])
  1642.  
  1643. AC_DEFUN(AC_PATH_X,
  1644. [AC_REQUIRE_CPP()dnl Set CPP; we run AC_PATH_X_DIRECT conditionally.
  1645. # If we find X, set shell vars x_includes and x_libraries to the
  1646. # paths, otherwise set no_x=yes.
  1647. # Uses ac_ vars as temps to allow command line to override cache and checks.
  1648. # --without-x overrides everything else, but does not touch the cache.
  1649. AC_MSG_CHECKING(for X)
  1650.  
  1651. AC_ARG_WITH(x, [  --with-x                use the X Window System])
  1652. # $have_x is `yes', `no', `disabled', or empty when we do not yet know.
  1653. if test "x$with_x" = xno; then
  1654.   # The user explicitly disabled X.
  1655.   have_x=disabled
  1656. else
  1657.   if test "x$x_includes" != xNONE && test "x$x_libraries" != xNONE; then
  1658.     # Both variables are already set.
  1659.     have_x=yes
  1660.   else
  1661. AC_CACHE_VAL(ac_cv_have_x,
  1662. [# One or both of the vars are not set, and there is no cached value.
  1663. ac_x_includes=NO ac_x_libraries=NO
  1664. AC_PATH_X_XMKMF
  1665. AC_PATH_X_DIRECT
  1666. if test "$ac_x_includes" = NO || test "$ac_x_libraries" = NO; then
  1667.   # Didn't find X anywhere.  Cache the known absence of X.
  1668.   ac_cv_have_x="have_x=no"
  1669. else
  1670.   # Record where we found X for the cache.
  1671.   ac_cv_have_x="have_x=yes \
  1672.             ac_x_includes=$ac_x_includes ac_x_libraries=$ac_x_libraries"
  1673. fi])dnl
  1674.   fi
  1675.   eval "$ac_cv_have_x"
  1676. fi # $with_x != no
  1677.  
  1678. if test "$have_x" != yes; then
  1679.   AC_MSG_RESULT($have_x)
  1680.   no_x=yes
  1681. else
  1682.   # If each of the values was on the command line, it overrides each guess.
  1683.   test "x$x_includes" = xNONE && x_includes=$ac_x_includes
  1684.   test "x$x_libraries" = xNONE && x_libraries=$ac_x_libraries
  1685.   # Update the cache value to reflect the command line values.
  1686.   ac_cv_have_x="have_x=yes \
  1687.         ac_x_includes=$x_includes ac_x_libraries=$x_libraries"
  1688.   AC_MSG_RESULT([libraries $x_libraries, headers $x_includes])
  1689. fi
  1690. ])
  1691.  
  1692. dnl Internal subroutine of AC_PATH_X.
  1693. dnl Set ac_x_includes and/or ac_x_libraries.
  1694. AC_DEFUN(AC_PATH_X_XMKMF,
  1695. [rm -fr conftestdir
  1696. if mkdir conftestdir; then
  1697.   cd conftestdir
  1698.   # Make sure to not put "make" in the Imakefile rules, since we grep it out.
  1699.   cat > Imakefile <<'EOF'
  1700. acfindx:
  1701.     @echo 'ac_im_incroot="${INCROOT}"; ac_im_usrlibdir="${USRLIBDIR}"; ac_im_libdir="${LIBDIR}"'
  1702. EOF
  1703.   if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
  1704.     # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  1705.     eval `${MAKE-make} acfindx 2>/dev/null | grep -v make`
  1706.     # Open Windows xmkmf reportedly sets LIBDIR instead of USRLIBDIR.
  1707.     for ac_extension in a so sl; do
  1708.       if test ! -f $ac_im_usrlibdir/libX11.$ac_extension &&
  1709.         test -f $ac_im_libdir/libX11.$ac_extension; then
  1710.         ac_im_usrlibdir=$ac_im_libdir; break
  1711.       fi
  1712.     done
  1713.     # Screen out bogus values from the imake configuration.
  1714.     case "$ac_im_incroot" in
  1715.     /usr/include) ;;
  1716.     *) test -f "$ac_im_incroot/X11/Xos.h" && ac_x_includes="$ac_im_incroot" ;;
  1717.     esac
  1718.     case "$ac_im_usrlibdir" in
  1719.     /usr/lib | /lib) ;;
  1720.     *) test -d "$ac_im_usrlibdir" && ac_x_libraries="$ac_im_usrlibdir" ;;
  1721.     esac
  1722.   fi
  1723.   cd ..
  1724.   rm -fr conftestdir
  1725. fi
  1726. ])
  1727.  
  1728. dnl Internal subroutine of AC_PATH_X.
  1729. dnl Set ac_x_includes and/or ac_x_libraries.
  1730. AC_DEFUN(AC_PATH_X_DIRECT,
  1731. [if test "$ac_x_includes" = NO; then
  1732.   # Guess where to find include files, by looking for this one X11 .h file.
  1733.   test -z "$x_direct_test_include" && x_direct_test_include=X11/Intrinsic.h
  1734.  
  1735.   # First, try using that file with no special directory specified.
  1736. AC_TRY_CPP([#include <$x_direct_test_include>],
  1737. [# We can compile using X headers with no special include directory.
  1738. ac_x_includes=],
  1739. [# Look for the header file in a standard set of common directories.
  1740.   for ac_dir in               \
  1741.     /usr/X11R6/include        \
  1742.     /usr/X11R5/include        \
  1743.     /usr/X11R4/include        \
  1744.                               \
  1745.     /usr/include/X11R6        \
  1746.     /usr/include/X11R5        \
  1747.     /usr/include/X11R4        \
  1748.                               \
  1749.     /usr/local/X11R6/include  \
  1750.     /usr/local/X11R5/include  \
  1751.     /usr/local/X11R4/include  \
  1752.                               \
  1753.     /usr/local/include/X11R6  \
  1754.     /usr/local/include/X11R5  \
  1755.     /usr/local/include/X11R4  \
  1756.                               \
  1757.     /usr/X11/include          \
  1758.     /usr/include/X11          \
  1759.     /usr/local/X11/include    \
  1760.     /usr/local/include/X11    \
  1761.                               \
  1762.     /usr/X386/include         \
  1763.     /usr/x386/include         \
  1764.     /usr/XFree86/include/X11  \
  1765.                               \
  1766.     /usr/include              \
  1767.     /usr/local/include        \
  1768.     /usr/unsupported/include  \
  1769.     /usr/athena/include       \
  1770.     /usr/local/x11r5/include  \
  1771.     /usr/lpp/Xamples/include  \
  1772.                               \
  1773.     /usr/openwin/include      \
  1774.     /usr/openwin/share/include \
  1775.     ; \
  1776.   do
  1777.     if test -r "$ac_dir/$x_direct_test_include"; then
  1778.       ac_x_includes=$ac_dir
  1779.       break
  1780.     fi
  1781.   done])
  1782. fi # $ac_x_includes = NO
  1783.  
  1784. if test "$ac_x_libraries" = NO; then
  1785.   # Check for the libraries.
  1786.  
  1787.   test -z "$x_direct_test_library" && x_direct_test_library=Xt
  1788.   test -z "$x_direct_test_function" && x_direct_test_function=XtMalloc
  1789.  
  1790.   # See if we find them without any special options.
  1791.   # Don't add to $LIBS permanently.
  1792.   ac_save_LIBS="$LIBS"
  1793.   LIBS="-l$x_direct_test_library $LIBS"
  1794. AC_TRY_LINK(, [${x_direct_test_function}()],
  1795. [LIBS="$ac_save_LIBS"
  1796. # We can link X programs with no special library path.
  1797. ac_x_libraries=],
  1798. [LIBS="$ac_save_LIBS"
  1799. # First see if replacing the include by lib works.
  1800. for ac_dir in `echo "$ac_x_includes" | sed s/include/lib/` \
  1801.     /usr/X11R6/lib        \
  1802.     /usr/X11R5/lib        \
  1803.     /usr/X11R4/lib        \
  1804.                           \
  1805.     /usr/lib/X11R6        \
  1806.     /usr/lib/X11R5        \
  1807.     /usr/lib/X11R4        \
  1808.                           \
  1809.     /usr/local/X11R6/lib  \
  1810.     /usr/local/X11R5/lib  \
  1811.     /usr/local/X11R4/lib  \
  1812.                           \
  1813.     /usr/local/lib/X11R6  \
  1814.     /usr/local/lib/X11R5  \
  1815.     /usr/local/lib/X11R4  \
  1816.                           \
  1817.     /usr/X11/lib          \
  1818.     /usr/lib/X11          \
  1819.     /usr/local/X11/lib    \
  1820.     /usr/local/lib/X11    \
  1821.                           \
  1822.     /usr/X386/lib         \
  1823.     /usr/x386/lib         \
  1824.     /usr/XFree86/lib/X11  \
  1825.                           \
  1826.     /usr/lib              \
  1827.     /usr/local/lib        \
  1828.     /usr/unsupported/lib  \
  1829.     /usr/athena/lib       \
  1830.     /usr/local/x11r5/lib  \
  1831.     /usr/lpp/Xamples/lib  \
  1832.                           \
  1833.     /usr/openwin/lib      \
  1834.     /usr/openwin/share/lib \
  1835.     ; \
  1836. do
  1837. dnl XXX Shouldn't this really use AC_TRY_LINK to be portable & robust??
  1838.   for ac_extension in a so sl; do
  1839.     if test -r $ac_dir/lib${x_direct_test_library}.$ac_extension; then
  1840.       ac_x_libraries=$ac_dir
  1841.       break 2
  1842.     fi
  1843.   done
  1844. done])
  1845. fi # $ac_x_libraries = NO
  1846. ])
  1847.  
  1848. dnl Find additional X libraries, magic flags, etc.
  1849. AC_DEFUN(AC_PATH_XTRA,
  1850. [AC_REQUIRE([AC_ISC_POSIX])dnl
  1851. AC_REQUIRE([AC_PATH_X])dnl
  1852. if test "$no_x" = yes; then
  1853.   # Not all programs may use this symbol, but it does not hurt to define it.
  1854.   X_CFLAGS="$X_CFLAGS -DX_DISPLAY_MISSING"
  1855. else
  1856.   if test -n "$x_includes"; then
  1857.     X_CFLAGS="$X_CFLAGS -I$x_includes"
  1858.   fi
  1859.  
  1860.   # It would be nice to have a more robust check for the -R ld option than
  1861.   # just checking for Solaris.
  1862.   # It would also be nice to do this for all -L options, not just this one.
  1863.   if test -n "$x_libraries"; then
  1864.     X_LIBS="$X_LIBS -L$x_libraries"
  1865.     if test "`(uname) 2>/dev/null`" = SunOS &&
  1866.       uname -r | grep '^5' >/dev/null; then
  1867.       X_LIBS="$X_LIBS -R $x_libraries"
  1868.     fi
  1869.   fi
  1870.  
  1871.   # Check for libraries that X11R6 Xt/Xaw programs need.
  1872.  
  1873.   ac_save_LDFLAGS="$LDFLAGS"
  1874.   LDFLAGS="$LDFLAGS -L$x_libraries"
  1875.   # SM needs ICE to (dynamically) link under SunOS 4.x (so we have to
  1876.   # check for ICE first), but we must link in the order -lSM -lICE or
  1877.   # we get undefined symbols.  So assume we have SM if we have ICE.
  1878.   # These have to be linked with before -lX11, unlike the other
  1879.   # libraries we check for below, so use a different variable.
  1880.   #  --interran@uluru.Stanford.EDU, kb@cs.umb.edu.
  1881.   AC_CHECK_LIB(ICE, IceConnectionNumber,
  1882.     [X_PRE_LIBS="$X_PRE_LIBS -lSM -lICE"])
  1883.   LDFLAGS="$ac_save_LDFLAGS"
  1884.  
  1885.   # Check for system-dependent libraries X programs must link with.
  1886.  
  1887.   if test "$ISC" = yes; then
  1888.     X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl_s -linet"
  1889.   else
  1890.     # Martyn.Johnson@cl.cam.ac.uk says this is needed for Ultrix, if the X
  1891.     # libraries were built with DECnet support.  And karl@cs.umb.edu says
  1892.     # the Alpha needs dnet_stub (dnet does not exist).
  1893.     AC_CHECK_LIB(dnet, dnet_ntoa, [X_EXTRA_LIBS="$X_EXTRA_LIBS -ldnet"])
  1894.     if test $ac_cv_lib_dnet_dnet_ntoa = no; then
  1895.       AC_CHECK_LIB(dnet_stub, dnet_ntoa,
  1896.         [X_EXTRA_LIBS="$X_EXTRA_LIBS -ldnet_stub"])
  1897.     fi
  1898.  
  1899.     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
  1900.     # to get the SysV transport functions.
  1901.     # Not sure which flavor of 386 UNIX this is, but it seems harmless to
  1902.     # check for it.
  1903.     AC_CHECK_LIB(nsl, t_accept, [X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl"])
  1904.  
  1905.     # lieder@skyler.mavd.honeywell.com says without -lsocket,
  1906.     # socket/setsockopt and other routines are undefined under SCO ODT 2.0.
  1907.     # But -lsocket is broken on IRIX, according to simon@lia.di.epfl.ch.
  1908.     if test "`(uname) 2>/dev/null`" != IRIX; then
  1909.       AC_CHECK_LIB(socket, socket, [X_EXTRA_LIBS="$X_EXTRA_LIBS -lsocket"])
  1910.     fi
  1911.   fi
  1912. fi
  1913. AC_SUBST(X_CFLAGS)dnl
  1914. AC_SUBST(X_PRE_LIBS)dnl
  1915. AC_SUBST(X_LIBS)dnl
  1916. AC_SUBST(X_EXTRA_LIBS)dnl
  1917. ])
  1918.  
  1919.  
  1920. dnl ### Checks for UNIX variants
  1921. dnl These are kludges which should be replaced by a single POSIX check.
  1922. dnl They aren't cached, to discourage their use.
  1923.  
  1924.  
  1925. AC_DEFUN(AC_AIX,
  1926. [AC_BEFORE([$0], [AC_TRY_COMPILE])dnl
  1927. AC_BEFORE([$0], [AC_TRY_LINK])dnl
  1928. AC_BEFORE([$0], [AC_TRY_RUN])dnl
  1929. AC_MSG_CHECKING(for AIX)
  1930. AC_EGREP_CPP(yes,
  1931. [#ifdef _AIX
  1932.   yes
  1933. #endif
  1934. ], [AC_MSG_RESULT(yes); AC_DEFINE(_ALL_SOURCE)], AC_MSG_RESULT(no))
  1935. ])
  1936.  
  1937. AC_DEFUN(AC_MINIX,
  1938. [AC_BEFORE([$0], [AC_TRY_COMPILE])dnl
  1939. AC_BEFORE([$0], [AC_TRY_LINK])dnl
  1940. AC_BEFORE([$0], [AC_TRY_RUN])dnl
  1941. AC_CHECK_HEADER(minix/config.h, MINIX=yes, MINIX=)
  1942. if test "$MINIX" = yes; then
  1943.   AC_DEFINE(_POSIX_SOURCE)
  1944.   AC_DEFINE(_POSIX_1_SOURCE, 2)
  1945.   AC_DEFINE(_MINIX)
  1946. fi
  1947. ])
  1948.  
  1949. AC_DEFUN(AC_ISC_POSIX,
  1950. [AC_BEFORE([$0], [AC_TRY_COMPILE])dnl
  1951. AC_BEFORE([$0], [AC_TRY_LINK])dnl
  1952. AC_BEFORE([$0], [AC_TRY_RUN])dnl
  1953. AC_MSG_CHECKING(for POSIXized ISC)
  1954. if test -d /etc/conf/kconfig.d &&
  1955.   grep _POSIX_VERSION [/usr/include/sys/unistd.h] >/dev/null 2>&1
  1956. then
  1957.   AC_MSG_RESULT(yes)
  1958.   ISC=yes # If later tests want to check for ISC.
  1959.   AC_DEFINE(_POSIX_SOURCE)
  1960.   if test "$GCC" = yes; then
  1961.     CC="$CC -posix"
  1962.   else
  1963.     CC="$CC -Xp"
  1964.   fi
  1965. else
  1966.   AC_MSG_RESULT(no)
  1967.   ISC=
  1968. fi
  1969. ])
  1970.  
  1971. AC_DEFUN(AC_XENIX_DIR,
  1972. [AC_OBSOLETE([$0], [; instead use AC_HEADER_DIRENT])dnl
  1973. AC_REQUIRE([AC_DIR_HEADER])dnl
  1974. AC_MSG_CHECKING(for Xenix)
  1975. AC_EGREP_CPP(yes,
  1976. [#if defined(M_XENIX) && !defined(M_UNIX)
  1977.   yes
  1978. #endif
  1979. ], [AC_MSG_RESULT(yes); XENIX=yes], [AC_MSG_RESULT(no); XENIX=])
  1980. if test "$XENIX" = yes; then
  1981.   # Make sure -ldir precedes -lx.
  1982.   test $ac_header_dirent = dirent.h && LIBS="-ldir $LIBS"
  1983.   LIBS="$LIBS -lx"
  1984. fi
  1985. ])
  1986.  
  1987. AC_DEFUN(AC_DYNIX_SEQ,
  1988. [AC_OBSOLETE([$0], [; instead use AC_FUNC_GETMNTENT])dnl
  1989. AC_CHECK_LIB(seq, getmntent, LIBS="-lseq $LIBS")
  1990. ])
  1991.  
  1992. AC_DEFUN(AC_IRIX_SUN,
  1993. [AC_OBSOLETE([$0], [; instead use AC_FUNC_GETMNTENT or AC_CHECK_LIB(sun, getpwnam)])dnl
  1994. AC_CHECK_LIB(sun, getmntent, LIBS="-lsun $LIBS")
  1995. ])
  1996.  
  1997. AC_DEFUN(AC_SCO_INTL,
  1998. [AC_OBSOLETE([$0], [; instead use AC_FUNC_STRFTIME])dnl
  1999. AC_CHECK_LIB(intl, strftime, LIBS="-lintl $LIBS")
  2000. ])
  2001.