ftp.ee.pdx.edu/2014.02.ftp.ee.pdx.edu.tar/ftp.ee.pdx.edu/pub/users/harry/cse509/TicTacToe.st

Text File | 2002-02-25 | 14KB | 441 lines

Morph subclass: #TicTacToeMorph
    instanceVariableNames: 'whoMovesNext winningLine squares selectedSquare highlightedSquare '
    classVariableNames: 'HighlightOForm HighlightXForm OForm XForm '
    poolDictionaries: ''
    category: 'TicTacToe'!
!TicTacToeMorph commentStamp: 'HHP 2/25/2002 11:41' prior: 0!
Each instance of this class is a Morph that can be used to play the Tic-Tac-Toe game.  The Morph shows the Tic-Tac-Toe board, any X's and O's that have been played, a RESET button, and a QUIT button.  The user(s) will place both X's and O's by clicking on board squares; the computer does not participate as a player.

Instance Variables:
    squares                an Array of 9 integers giving current board state: 0=empty; 1=X; 2=O
    whoMovesNext        1=X moves next; 2=O moves next
    winningLine        an integer, 1..8, telling which winning line; 0=no winner
    selectedSquare        an integer, 1..11, giving which button has been mouse-down'ed
    highlightedSquare    an integer, 1..11, telling which button should be highlighted

Class Variables:
    XForm                a square Form showing the image of an X
    OForm                a square Form showing the image of an O
    HighlightXForm        a square Form showing the highlighted image of an X
    HighlightOForm        a square Form showing the highlighted image of an O

Harry Porter - 02/24/02
!


!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 15:01'!
highlightedSquare
    ^ highlightedSquare! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 15:01'!
highlightedSquare: int
    highlightedSquare _ int! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 15:01'!
selectedSquare
    ^ selectedSquare! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 15:01'!
selectedSquare: int
    selectedSquare _ int! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 14:20'!
squares
    ^ squares! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 14:20'!
squares: arrayOfInt
    squares _ arrayOfInt! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 14:15'!
whoMovesNext
    ^ whoMovesNext! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 14:14'!
whoMovesNext: int
    whoMovesNext _ int! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 14:15'!
winningLine
    ^ winningLine! !

!TicTacToeMorph methodsFor: 'accessing' stamp: 'HHP 2/23/2002 14:14'!
winningLine: int
    winningLine _ int! !


!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:25'!
checkGameOver

"This method checks to see if the game is over.  If there is a winner, it sets 'winningLine' to 1-8 to indicate which winning line to draw."

    | test |

    test _ [ :x :y :z :line |
        (((squares at: x) = (squares at: y)) &
        ((squares at: y) = (squares at: z)) &
        ((squares at: x) ~= 0)) ifTrue: [
            winningLine _ line.
        ].
    ].
    test value: 1 value: 4 value: 7 value: 1.
    test value: 2 value: 5 value: 8 value: 2.
    test value: 3 value: 6 value: 9 value: 3.
    test value: 1 value: 2 value: 3 value: 4.
    test value: 4 value: 5 value: 6 value: 5.
    test value: 7 value: 8 value: 9 value: 6.
    test value: 1 value: 5 value: 9 value: 7.
    test value: 3 value: 5 value: 7 value: 8.
! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:27'!
drawOn: aCanvas

"This method draws the board in the current state.  The current state includes
    -- Where there are X's and O's, as given by 'squares'
    -- Whether there is anything highlighted, as given by highlightedSquare
    -- Whose move is next, as given by whoMovesNext"

    | top bottom left right x1 x2 x3 y1 y2 y3 posOfSquares rect form |

    "Draw the background."
    super extent: 128@188.
    aCanvas
        frameAndFillRectangle: bounds
        fillColor: Color yellow
        borderWidth: 4
        topLeftColor: Color yellow darker
        bottomRightColor: Color yellow darker darker darker darker darker.

    "Draw the board's lines"
    top _ bounds origin y + 14.
    bottom _ bounds origin y + 112.
    left _ bounds origin x + 14.
    right _ bounds origin x + 112.
    x1 _ bounds origin x + 46.
    x2 _ bounds origin x + 81.
    y1 _ bounds origin y + 46.
    y2 _ bounds origin y + 81.
    aCanvas line: x1@top to: x1@bottom width: 3 color: Color black.
    aCanvas line: x2@top to: x2@bottom width: 3 color: Color black.
    aCanvas line: left@y1 to: right@y1 width: 3 color: Color black.
    aCanvas line: left@y2 to: right@y2 width: 3 color: Color black.

    "Draw the X's and the O's that have been placed so far."
    posOfSquares _ self positionsOfSquares.
    1 to: 9 do: [ :i |
        ((squares at: i) = 1) ifTrue: [
            aCanvas drawImage: XForm at: ((posOfSquares at: i) origin).
        ] ifFalse: [((squares at: i) = 2) ifTrue: [
            aCanvas drawImage: OForm at: ((posOfSquares at: i) origin).
        ]].
    ].

    "If any square is currently highlighted, draw it."
    ((highlightedSquare > 0) & (highlightedSquare <= 9)) ifTrue: [
        (whoMovesNext = 1) ifTrue: [
            form _ HighlightXForm.
        ] ifFalse: [
            form _ HighlightOForm.
        ].
        aCanvas drawImage: form at: ((posOfSquares at: highlightedSquare) origin).
    ].

    "Draw the winning line, if any."
    x1 _ bounds origin x + 29.
    x2 _ bounds origin x + 64.
    x3 _ bounds origin x + 99.
    y1 _ bounds origin y + 29.
    y2 _ bounds origin y + 64.
    y3 _ bounds origin y + 99.
    (winningLine = 1) ifTrue: [
        aCanvas line: x1@top to: x1@bottom width: 2 color: Color red.
    ].
    (winningLine = 2) ifTrue: [
        aCanvas line: x2@top to: x2@bottom width: 2 color: Color red.
    ].
    (winningLine = 3) ifTrue: [
        aCanvas line: x3@top to: x3@bottom width: 2 color: Color red.
    ].
    (winningLine = 4) ifTrue: [
        aCanvas line: left@y1 to: right@y1 width: 2 color: Color red.
    ].
    (winningLine = 5) ifTrue: [
        aCanvas line: left@y2 to: right@y2 width: 2 color: Color red.
    ].
    (winningLine = 6) ifTrue: [
        aCanvas line: left@y3 to: right@y3 width: 2 color: Color red.
    ].
    (winningLine = 7) ifTrue: [
        aCanvas line: left@top to: right@bottom width: 2 color: Color red.
    ].
    (winningLine = 8) ifTrue: [
        aCanvas line: left@bottom to: right@top width: 2 color: Color red.
    ].

    "Draw the RESET button, either normal or highlighted."
    rect _ (bounds origin + (14@124)) extent: 100@20.
    (highlightedSquare = 10) ifTrue: [
        aCanvas
            frameAndFillRectangle: rect
            fillColor: Color red darker darker
            borderWidth: 3
            topLeftColor: Color red darker darker darker darker darker
            bottomRightColor: Color red lighter.
    ] ifFalse: [
        aCanvas
            frameAndFillRectangle: rect
            fillColor: Color red lighter lighter
            borderWidth: 3
            topLeftColor: Color red lighter lighter lighter
            bottomRightColor: Color red darker darker.
    ].
    aCanvas text: 'Reset' at: (rect origin + (35@4)) font: nil color: Color black.

    "Draw the QUIT button, either normal or highlighted."
    rect _ (bounds origin + (14@154)) extent: 100@20.
    (highlightedSquare = 11) ifTrue: [
        aCanvas
            frameAndFillRectangle: rect
            fillColor: Color red darker darker
            borderWidth: 3
            topLeftColor: Color red darker darker darker darker darker
            bottomRightColor: Color red lighter.
    ] ifFalse: [
        aCanvas
            frameAndFillRectangle: rect
            fillColor: Color red lighter lighter
            borderWidth: 3
            topLeftColor: Color red lighter lighter lighter
            bottomRightColor: Color red darker darker.
    ].
    aCanvas text: 'Quit' at: (rect origin + (39@4)) font: nil color: Color black.
! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:27'!
handlesMouseDown: evt

"Return true if the mouse is within one of the button areas.  Otherwise let the user drag the morph around."

    | mousePos posOfSquares |

    mousePos _ evt cursorPoint.
    posOfSquares _ self positionsOfSquares.
    posOfSquares withIndexDo: [ :rect :i |
        (rect containsPoint: mousePos) ifTrue: [
            ^ true
        ].
    ].
    ^ false! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:16'!
makeMove: i

"This method is passed a move to make (1-9).  It checks to see if this is a legal move and, if so, updates the data to make that move.  It also checks to see if the game is over."

    squares at: i put: whoMovesNext.
    (whoMovesNext = 1) ifTrue: [
        whoMovesNext _ 2.
    ] ifFalse: [
        whoMovesNext _ 1.
    ].
    self checkGameOver.
! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:31'!
mouseDown: evt

"When the user presses the mouse button, see if it is in a square or one of the buttons.  If in a square, check to see if this would be a legal move, and return if not.  Highlight the square, by setting 'highlightedSquare' to the button number 1..11 and sending 'self changed'.  Also set 'selectedSquare' to this same number, to remember the focus."

    | mousePos posOfSquares |

    mousePos _ evt cursorPoint.
    posOfSquares _ self positionsOfSquares.
    posOfSquares withIndexDo: [ :rect :i |
        (rect containsPoint: mousePos) ifTrue: [
            (i <= 9) ifTrue: [
                ((squares at: i) = 0) ifTrue: [
                    (winningLine ~= 0) ifTrue: [^self].
                    selectedSquare _ i.
                    highlightedSquare _ i.
                ].
            ] ifFalse: [
                selectedSquare _ i.
                highlightedSquare _ i.
            ].
        ]
    ].
    self changed.! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:23'!
mouseMove: evt

"The mouse has moved.  If the mouse is now in the 'selectedSquare', set 'highlightedSquare' to that same number.  Otherwise, set 'highlightedSquare' to zero."

    | mousePos oldHighlighted posOfSquares |

    oldHighlighted _ highlightedSquare.
    highlightedSquare _ 0.
    mousePos _ evt cursorPoint.
    posOfSquares _ self positionsOfSquares.
    posOfSquares withIndexDo: [ :rect :i |
        (rect containsPoint: mousePos) ifTrue: [
            (selectedSquare = i) ifTrue: [
                highlightedSquare _ i.
            ].
        ]
    ].
    (oldHighlighted = highlightedSquare) ifFalse: [
        self changed.
    ].
! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:24'!
mouseUp: evt

"When the user releases the mouse button, see if it is in the 'selectedSquare'.  If so, make a move to that square, or do the button action, whichever is appropriate."

    | mousePos posOfSquares |

    mousePos _ evt cursorPoint.
    posOfSquares _ self positionsOfSquares.
    posOfSquares withIndexDo: [ :rect :i |
        (rect containsPoint: mousePos) ifTrue: [
            (selectedSquare = i) ifTrue: [
                (i <= 9) ifTrue: [
                    self makeMove: i.
                ].
                (i = 10) ifTrue: [
                    self resetState.
                ].
                (i = 11) ifTrue: [
                    self delete.
                ].
            ].
        ]
    ].
    selectedSquare _ 0.
    highlightedSquare _ 0.
    self changed.! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:32'!
positionsOfSquares

"Return an array of 11 rectangles.  Each describes the current position of one of the 9 squares or one of the two buttons."

    | a x1 x2 x3 y1 y2 y3 |

    x1 _ bounds origin x + 14.
    x2 _ bounds origin x + 49.
    x3 _ bounds origin x + 84.
    y1 _ bounds origin y + 14.
    y2 _ bounds origin y + 49.
    y3 _ bounds origin y + 84.
    a _ Array new: 11.
    a at: 1 put: (x1@y1 extent: 30@30);
        at: 2 put: (x2@y1 extent: 30@30);
        at: 3 put: (x3@y1 extent: 30@30);
        at: 4 put: (x1@y2 extent: 30@30);
        at: 5 put: (x2@y2 extent: 30@30);
        at: 6 put: (x3@y2 extent: 30@30);
        at: 7 put: (x1@y3 extent: 30@30);
        at: 8 put: (x2@y3 extent: 30@30);
        at: 9 put: (x3@y3 extent: 30@30);
        at: 10 put: ((bounds origin + (14@124)) extent: 100@20);        "RESET Button"
        at: 11 put: ((bounds origin + (14@154)) extent: 100@20).        "QUIT Button"
    ^ a
! !

!TicTacToeMorph methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:32'!
resetState

"Reset the state to a new game."

    whoMovesNext _ 1.                        "1=X; 2=O"
    winningLine _ 0.                        "0=no winner yet; 1..8=various winning lines"
    squares _ #(0 0 0 0 0 0 0 0 0) copy.        "0=empty; 1=X; 2=O"
    highlightedSquare _ 0.                    "1-9=a square; 10=RESET button; 11=QUIT button"
    selectedSquare _ 0.                        "1-9=a square; 10=RESET button; 11=QUIT button"
! !

"-- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- -- "!

TicTacToeMorph class
    instanceVariableNames: ''!

!TicTacToeMorph class methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:42'!
initialize

"Initialize the following class variables to appropriate Forms, in order to make displaying faster:
    XForm
    HighlightXForm
    OForm
    HighlightOForm"

"TicTacToeMorph initialize."

    | p dot aCircle |

    "Create the image of the 'X'."
    XForm _ Form extent: 30@30 depth: 16.
    XForm fill: XForm boundingBox rule: Form over fillColor: Color yellow.
    p _ Pen newOnForm: XForm.
    p color: Color green darker darker darker darker.
    p roundNib: 3.
    p goto: 2@2.
    p down.
    p goto: 26@26.
    p up.
    p goto: 2@26.
    p down.
    p goto: 26@2.

    "Create the highlighted image of the 'X'."
    HighlightXForm _ Form extent: 30@30 depth: 16.
    HighlightXForm fill: HighlightXForm boundingBox rule: Form over fillColor: Color yellow.
    p _ Pen newOnForm: HighlightXForm.
    p color: Color yellow darker darker.
    p roundNib: 3.
    p goto: 2@2.
    p down.
    p goto: 26@26.
    p up.
    p goto: 2@26.
    p down.
    p goto: 26@2.

    "Create the image of the 'O'."
    OForm _ Form extent: 30@30 depth: 16.
    OForm fill: OForm boundingBox rule: Form over fillColor: Color yellow.
    dot _ Form extent: 3@3 depth: 16.
    dot fill: dot boundingBox rule: Form over fillColor: Color blue darker darker darker darker.
    aCircle _ Circle new.
    aCircle form: dot.
    aCircle radius: 14.
    aCircle center: 13@13.
    aCircle displayOn: OForm.

    "Create the highlighted image of the 'O'."
    HighlightOForm _ Form extent: 30@30 depth: 16.
    HighlightOForm fill: HighlightOForm boundingBox rule: Form over fillColor: Color yellow.
    dot _ Form extent: 3@3 depth: 16.
    dot fill: dot boundingBox rule: Form over fillColor: Color yellow darker darker.
    aCircle _ Circle new.
    aCircle form: dot.
    aCircle radius: 14.
    aCircle center: 13@13.
    aCircle displayOn: HighlightOForm.
! !

!TicTacToeMorph class methodsFor: 'misc' stamp: 'HHP 2/24/2002 23:37'!
new

"Create a new TicTacToeMorph and initialize it."

    | aTicTacToe |

    aTicTacToe _ super new.
    aTicTacToe resetState.
    ^ aTicTacToe! !

TicTacToeMorph initialize!