home *** CD-ROM | disk | FTP | other *** search
/ ftp.ee.pdx.edu / 2014.02.ftp.ee.pdx.edu.tar / ftp.ee.pdx.edu / pub / users / Harry / Blitz / version-1-0 / OSProject / p2 / Switch.s < prev    next >
Text File  |  2006-04-05  |  3KB  |  94 lines
  1. ! BLITZ OS - Switch.s
  2. !
  3. ! Harry Porter  -  12/07/03
  4. !
  5. ! The following functions are implemented in this file:
  6. !
  7.     .export    Switch
  8.     .export    ThreadStartUp
  9. !
  10. ! The following functions are imported:
  11. !
  12.     .import    _P_Thread_ThreadStart
  13.     .import    _P_Thread_ThreadFinish
  14. !
  15.     .text
  16.  
  17.  
  18. ! 
  19. ! ===============  ThreadStartUp  ===============
  20. ! 
  21. ! external ThreadStartUp ()
  22. !
  23. ! Upon entry, r2 points to the main function for the new thread and r3
  24. ! contains an integer argument.  This routine will call ThreadStart.
  25. ! When that returns, it will call the main function, passing the argument.
  26. ! When and if that returns, this routine will call ThreadFinish.
  27. ! ThreadFinish will not return.
  28. ! 
  29. ThreadStartUp:
  30.         mov    r0,r14            ! Clear the FP register
  31.         mov    r0,r12            ! Clear the Catch Stack pointer
  32.         push    r3            ! Push argument to "fun"
  33.         push    r2            ! Push ptr to "fun"
  34.         call    _P_Thread_ThreadStart    ! Call ThreadStart
  35.         pop    r1            ! Pop ptr to "fun"
  36.         call    r1            ! .  and call it
  37.         pop    r1            ! Pop argument
  38.         call    _P_Thread_ThreadFinish    ! Call ThreadFinish
  39. ThreadHang:    debug                ! Should never reach this point
  40.         jmp    ThreadHang        ! .
  41.  
  42.  
  43.  
  44. ! 
  45. ! ===============  Switch  ===============
  46. ! 
  47. ! external Switch (prevThread, nextThread: ptr to Thread)
  48. !
  49. ! This routine is passed ptrs to 2 Thread objects.  Each Thread object
  50. ! contains a place to store the state of the machine.  This includes:
  51. !    r2-r14
  52. !    stackTop (r15)
  53. ! This routine switches the state from one thread to the next and returns.
  54. ! Of course it will be returning to a different invocation, since the thread
  55. ! will have been switched.
  56. !
  57. ! This routine trashes r1.
  58. ! 
  59. Switch:
  60.         load    [r15+4],r1        ! Move the prevThread into r1
  61.         add    r1,16,r1        ! Make r1 point to r1.regs
  62.         store    r2,[r1+0]        ! Save r2..r14 in r1.regs
  63.         store    r3,[r1+4]        ! .
  64.         store    r4,[r1+8]        ! .
  65.         store    r5,[r1+12]        ! .
  66.         store    r6,[r1+16]        ! .
  67.         store    r7,[r1+20]        ! .
  68.         store    r8,[r1+24]        ! .
  69.         store    r9,[r1+28]        ! .
  70.         store    r10,[r1+32]        ! .
  71.         store    r11,[r1+36]        ! .
  72.         store    r12,[r1+40]        ! .
  73.         store    r13,[r1+44]        ! .
  74.         store    r14,[r1+48]        ! .
  75.         store    r15,[r1+52]        ! Save r15 in r1.stackTop
  76.  
  77.         load    [r15+8],r1        ! Move the nextThread into r1
  78.         add    r1,16,r1        ! Make r1 point to r1.regs
  79.         load    [r1+0],r2        ! Restore r2..r14 from r1.regs
  80.         load    [r1+4],r3        ! .
  81.         load    [r1+8],r4        ! .
  82.         load    [r1+12],r5        ! .
  83.         load    [r1+16],r6        ! .
  84.         load    [r1+20],r7        ! .
  85.         load    [r1+24],r8        ! .
  86.         load    [r1+28],r9        ! .
  87.         load    [r1+32],r10        ! .
  88.         load    [r1+36],r11        ! .
  89.         load    [r1+40],r12        ! .
  90.         load    [r1+44],r13        ! .
  91.         load    [r1+48],r14        ! .
  92.         load    [r1+52],r15        ! Restore r15 from r1.stackTop
  93.         ret
  94.