home *** CD-ROM | disk | FTP | other *** search
/ ftp.ee.pdx.edu / 2014.02.ftp.ee.pdx.edu.tar / ftp.ee.pdx.edu / pub / users / Harry / Blitz / OSProject / p2 / Switch.s < prev    next >
Text File  |  2009-03-26  |  3KB  |  91 lines
  1. ! BLITZ OS - Switch.s
  2. !
  3. ! Harry Porter  -  12/07/03
  4. !                  03/24/09
  5. !
  6. ! The following functions are implemented in this file:
  7. !
  8.     .export    Switch
  9.     .export    ThreadStartUp
  10. !
  11. ! The following functions are imported:
  12. !
  13.     .import    _P_Thread_ThreadStartMain
  14.     .import    _P_Thread_ThreadFinish
  15. !
  16.     .text
  17.  
  18.  
  19. ! 
  20. ! ===============  ThreadStartUp  ===============
  21. ! 
  22. ! external ThreadStartUp ()
  23. !
  24. ! This routine is where each Thread begins execution.  The Fork function
  25. ! will place the starting address of this routine into the Thread object
  26. ! so that Switch will "return" to this address, thereby making a jump to
  27. ! the first instruction of this routine.  This routine will initialize
  28. ! all registers needed by high-level KPL code (namely r12 & r14) and will
  29. ! then call the KPL function "ThreadStartMain".  ThreadStartMain will invoke
  30. ! the "main" function of the thread. ThreadStartMain  will never return.
  31. ! 
  32. ThreadStartUp:
  33.         mov    r0,r14                ! Clear the FP register
  34.         mov    r0,r12                ! Clear the Catch Stack pointer
  35.         call    _P_Thread_ThreadStartMain    ! Call ThreadStartMain
  36. ThreadHang:    debug                    ! Should never reach this point
  37.         jmp    ThreadHang            ! .
  38.  
  39.  
  40.  
  41. ! 
  42. ! ===============  Switch  ===============
  43. ! 
  44. ! external Switch (prevThread, nextThread: ptr to Thread)
  45. !
  46. ! This routine is passed ptrs to 2 Thread objects.  Each Thread object
  47. ! contains a place to store the state of the machine.  This includes:
  48. !    r2-r14
  49. !    stackTop (r15)
  50. ! This routine switches the state from one thread to the next and returns.
  51. ! Of course it will be returning to a different invocation, since the thread
  52. ! will have been switched.
  53. !
  54. ! This routine trashes r1.
  55. ! 
  56. Switch:
  57.         load    [r15+4],r1        ! Move the prevThread into r1
  58.         add    r1,16,r1        ! Make r1 point to r1.regs
  59.         store    r2,[r1+0]        ! Save r2..r14 in r1.regs
  60.         store    r3,[r1+4]        ! .
  61.         store    r4,[r1+8]        ! .
  62.         store    r5,[r1+12]        ! .
  63.         store    r6,[r1+16]        ! .
  64.         store    r7,[r1+20]        ! .
  65.         store    r8,[r1+24]        ! .
  66.         store    r9,[r1+28]        ! .
  67.         store    r10,[r1+32]        ! .
  68.         store    r11,[r1+36]        ! .
  69.         store    r12,[r1+40]        ! .
  70.         store    r13,[r1+44]        ! .
  71.         store    r14,[r1+48]        ! .
  72.         store    r15,[r1+52]        ! Save r15 in r1.stackTop
  73.  
  74.         load    [r15+8],r1        ! Move the nextThread into r1
  75.         add    r1,16,r1        ! Make r1 point to r1.regs
  76.         load    [r1+0],r2        ! Restore r2..r14 from r1.regs
  77.         load    [r1+4],r3        ! .
  78.         load    [r1+8],r4        ! .
  79.         load    [r1+12],r5        ! .
  80.         load    [r1+16],r6        ! .
  81.         load    [r1+20],r7        ! .
  82.         load    [r1+24],r8        ! .
  83.         load    [r1+28],r9        ! .
  84.         load    [r1+32],r10        ! .
  85.         load    [r1+36],r11        ! .
  86.         load    [r1+40],r12        ! .
  87.         load    [r1+44],r13        ! .
  88.         load    [r1+48],r14        ! .
  89.         load    [r1+52],r15        ! Restore r15 from r1.stackTop
  90.         ret
  91.