home *** CD-ROM | disk | FTP | other *** search
/ Frostbyte's 1980s DOS Shareware Collection / floppyshareware.zip / floppyshareware / USCX / GAMES-06.ZIP / CIAGAME.BAS < prev    next >
BASIC Source File  |  1982-10-26  |  16KB  |  245 lines
  1. 1 REM  Translated from TRS-80 version on CPMNET BBS
  2. 2 REM  Pete Wohlmut 10-3-82
  3. 3 DEF SEG= &H40
  4. 4 POKE(&H17),PEEK(&H17) OR &H20  ' set Num Lock
  5. 5 POKE (&H17),PEEK(&H17) OR &H40 ' set Caps Lock
  6. 6 DEF SEG
  7. 10 CLEAR:CLS:RANDOMIZE:DEFINT A-Z:GOTO 40
  8. 20 Z9=0:FOR R=1 TO 50:IF V1$=N$(R) AND (N(R)=LO OR N(R)=-1) THEN Z9=1:RETURN
  9. 30 NEXT:PRINT"I DON'T SEE THAT HERE.":Z9=2:RETURN
  10. 40 PRINT "        C.I.A  ADVENTURE"
  11. 50 DIM N1$(50),N$(50),N(50),V$(18),LO(30,4),LO$(30):FL=1:DR=0:DG=-1:T=0:EL=0:BU=0:DO=0:CA=0:BA=0:TE=0:GL=0
  12. 60 PA=0:RO=0:FOR R=1 TO 5:R1=INT(9*RND(9)):CO$=CO$+STR$(R1):NEXT:LO=1:A9$=">"+STRING$(62,"-")+"<"
  13. 70 R=LEN(CO$):CO$=RIGHT$(CO$,R-1)
  14. 80 FOR R=1 TO 50:READ N1$(R),N$(R),N(R):NEXT
  15. 90 FOR R=1 TO 30:READ LO$(R),LO(R,1),LO(R,2),LO(R,3),LO(R,4):NEXT
  16. 100 FOR R=1 TO 18:READ V$(R):NEXT
  17. 110 REM
  18. 120 PRINT"WE ARE ";LO$(LO);"."
  19. 130 FOR R=1 TO 46:IF N(R)=LO THEN PRINT"I CAN SEE ";N1$(R);"."
  20. 140 NEXT:B=0:FOR R=1 TO 4:IF LO(LO,R)>0 THEN B=1
  21. 150 NEXT:IF B=0 THEN 200
  22. 160 PRINT"WE COULD EASILY GO: ";:IF LO(LO,1)>0 THEN PRINT"NORTH  ";
  23. 170 IF LO(LO,2)>0 THEN PRINT"SOUTH  ";
  24. 180 IF LO(LO,3)>0 THEN PRINT"EAST  ";
  25. 190 IF LO(LO,4)>0 THEN PRINT"WEST  ";
  26. 200 PRINT:PRINT A9$
  27. 210 T=T+1:IF DG>0 THEN DG=DG-1
  28. 220 IF T=1 THEN INPUT"ENTER YOUR NAME PARTNER";NA$
  29. 230 GOTO 1760
  30. 240 N=0:FOR R=1 TO 46:IF N(R)=-1 THEN N=N+1
  31. 250 NEXT
  32. 260 PRINT:INPUT"WHAT DO YOU THINK WE SHOULD DO";A$
  33. 270 GOSUB 1890:V$=LEFT$(A$,3):GOSUB 1950:FOR R=1 TO 18:IF V$=V$(R) THEN 300 ELSE NEXT
  34. 280 IF V$="ORD" THEN 2210
  35. 290 PRINT"I DON'T KNOW HOW TO DO THAT.":GOTO 260
  36. 300 IF V$="QUI" THEN 1650
  37. 310 V=R:FOR R=1 TO LEN(A$):IF MID$(A$,R,1)=" " THEN 360 ELSE NEXT
  38. 320 IF V$="LOO" THEN 110
  39. 330 IF V$="BON" THEN 1670
  40. 340 IF V$="INV" THEN 1690
  41. 350 PRINT"PLEASE USE 2 WORD COMMANDS SO I CAN UNDERSTAND YOU.":GOTO 260
  42. 360 V1$=MID$(A$,R+1,3):FOR R=1 TO 49:IF V1$=N$(R) THEN 390 ELSE NEXT
  43. 370 IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 390
  44. 380 PRINT"I DON'T KNOW WHAT IT IS YOU ARE TALKING ABOUT.":GOTO 260
  45. 390 ON V GOTO 400,530,620,680,800,840,1040,1140,1300,1320,1360,1450,1490,1540,1600,1650,1670,1690
  46. 400 IF V1$="NOR" AND LO(LO,1)>0 THEN LO=LO(LO,1):GOTO 110
  47. 410 IF V1$="SOU" AND LO(LO,2)>0 THEN LO=LO(LO,2):GOTO 110
  48. 420 IF V1$="EAS" AND LO(LO,3)>0 THEN LO=LO(LO,3):GOTO 110
  49. 430 IF V1$="WES" AND LO(LO,4)>0 THEN LO=LO(LO,4):GOTO 110
  50. 440 IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 520
  51. 450 GOSUB 20:IF Z9=2 THEN 210
  52. 460 IF R=8 THEN LO=5:GOTO 110
  53. 470 IF R=37 AND RO=1 AND LO=20 THEN LO=21:GOTO 110
  54. 480 IF R=10 THEN LO=11:GOTO 110
  55. 490 IF R=14 THEN LO=13:GOTO 110
  56. 500 IF R=33 THEN LO=3:GOTO 110
  57. 510 IF R=34 AND DO=1 THEN LO=9:GOTO 110
  58. 520 PRINT"I CAN'T GO THAT WAY AT THE MOMENT.":GOTO 210
  59. 530 GOSUB 20:IF Z9=2 THEN 210
  60. 540 IF R=2 OR R=3 OR R=4 OR R=6 OR R=15 OR R=16 OR R=20 OR R=21 OR R=22 OR R=23 OR R=25 OR R=26 OR R=27 OR R=28 OR R=30 OR R=31 OR R=37 OR R=39 OR R=40 OR R=42 OR R=44 OR R=45 OR R=46 THEN 560
  61. 550 PRINT"I CAN'T CARRY THAT!":GOTO 210
  62. 560 IF N(R)=-1 THEN PRINT"I ALREADY HAVE IT.":GOTO 210
  63. 570 IF N>=5 THEN PRINT"I CAN'T CARRY ANYMORE.":GOTO 210
  64. 580 PRINT"O.K.":N(R)=-1
  65. 590 IF V1$="PAI" AND PA=0 THEN PRINT"SOMETHING FELL FROM THE FRAME!":N(31)=LO:PA=1
  66. 600 IF V1$="TEL" THEN TE=0
  67. 610 GOTO 210
  68. 620 FOR R=1 TO 46:IF V1$=N$(R) AND N(R)=-1 THEN 640 ELSE NEXT
  69. 630 PRINT"I DON'T SEEM TO BE CARRYING IT.":GOTO 210
  70. 640 IF R=30 THEN PRINT"I DROPPED THE CUP BUT IT BROKE INTO SMALL PEICES.":PRINT"THE COFFEE SOAKED INTO THE GROUND.":N(30)=0:DR=0:GOTO 210
  71. 650 IF R=45 THEN GL=0
  72. 660 IF R=31 AND N(30)=-1 THEN PRINT"O.K. I DROPPED IT.":PRINT"BUT IT FELL IN THE COFFEE!":N(31)=0:DR=1:GOTO 210
  73. 670 PRINT"O.K. I DROPPED IT.":N(R)=LO:GOTO 210
  74. 680 IF V1$="BUT" AND LO=3 AND DO=0 THEN PRINT"THE DOORS OPEN WITH A WHOOSH!":DO=1:GOTO 210
  75. 690 IF N(46)=-1 AND V1$="BUT" THEN PRINT"I PUSH THE BUTTON ON THE BOX AND":GOTO 770
  76. 700 GOSUB 20
  77. 710 IF Z9=2 THEN 210
  78. 720 IF R=17 AND GL<>1 THEN PRINT"THERE'S ELECTRICITY COURSING THRU THE SQUARE!":PRINT"I'M BEING ELECTROCUTED!":GOTO 2330
  79. 730 IF R=35 AND BU=0 THEN PRINT"THE BUTTON ON THE WALL GOES IN .....":PRINT"CLICK! SOMETHING SEEMS DIFFFERENT NOW.":BU=1:GOTO 210
  80. 740 IF R=47 AND FL<>1 THEN LO(9,1)=3:FL=1:GOTO 790
  81. 750 IF R=48 AND FL<>2 THEN LO(9,1)=8:FL=2:GOTO 790
  82. 760 IF R=49 AND FL<>3 THEN LO(9,1)=10:FL=3:GOTO 790
  83. 770 IF N(46)=-1 AND (LO=6 OR LO=29)THEN PRINT"THERE IS A BLINDING FLASH....":FORR=1TO3000:NEXT:LO=1:FL=1:LO(9,1)=3:GOTO 110
  84. 780 PRINT"NOTHING HAPPENS.":GOTO 210
  85. 790 PRINT"THE DOORS CLOSE AND I FEEL AS IF THE ROOM IS MOVING.":PRINT"SUDDENLY THE DOORS OPEN AGAIN.":FOR R=1 TO 5000:NEXT:GOTO 110
  86. 800 GOSUB 20:IF Z9=2 THEN 210
  87. 810 IF R=18 AND GL<>1 THEN PRINT"THE LEVER HAS ELECTRICITY COURSING THRU IT!":PRINT"I'M BEING ELECTROCUTED!":GOTO 2330
  88. 820 IF R=18 AND EL=0 THEN PRINT"THE LEVER GOES ALL THE WAY UP AND CLICKS.":PRINT"SOMETHING SEEMS DIFFERENT NOW.":EL=1:GOTO 210
  89. 830 PRINT"NOTHING HAPPENS.":GOTO 210
  90. 840 REM
  91. 850 IF V1$="DRA" AND LO=5 THEN PRINT"IT LOOKS FRAGILE.":GOTO 210
  92. 860 GOSUB 20:IF Z9=2 THEN 210
  93. 870 IF R=1 AND BA<>1 THEN PRINT"THERE'S NO POWER FOR IT.":GOTO 210
  94. 880 IF R=1 AND TE<>1 THEN PRINT"THERE'S NO T.V. TO WATCH ON.":GOTO 210
  95. 890 IF R=6 THEN PRINT"IT LOOKS HEAVY.":GOTO 210
  96. 900 IF R=7 THEN PRINT"IT'S LOCKED.":GOTO 210
  97. 910 IF R=13 THEN PRINT"IT'S A VERY STRONG BAG.":GOTO 210
  98. 920 IF R=19 THEN PRINT"I CAN SEE A LOCKED DRAWER IN IT.":GOTO 210
  99. 930 IF R=22 OR R=27 THEN PRINT"THERE'S WRITING ON IT.":GOTO 210
  100. 940 IF R=34 AND DO=1 THEN PRINT"THE DOORS ARE OPEN.":GOTO 210
  101. 950 IF R=24 THEN PRINT"I CAN SEE A GLEAMING STONE IN IT.":GOTO 210
  102. 960 IF R=9 THEN PRINT"THERE IS A SMALL SLIT NEAR THE DOOR.":GOTO 210
  103. 970 IF R=34 THEN PRINT"THERE'S A BUTTON NEAR THE DOORS.":GOTO 210
  104. 980 IF R=41 AND BU=1 THEN PRINT"THE SCREEN IS DARK.":GOTO 210
  105. 990 IF R=41 THEN PRINT"I SEE A METAL PIT 1000'S OF FEET DEEP ON ONE MONITOR.":PRINT"ON THE OTHER SIDE OF THE PIT,I SEE A LARGE HOOK.":GOTO 210
  106. 1000 IF R=43 AND BU=1 THEN PRINT"THE SCREEN IS DARK.":GOTO 210
  107. 1010 IF R=43 THEN PRINT"I SEE A ROOM WITH A CASE ON A PEDESTAL IN IT.":GOTO 210
  108. 1020 IF R=44 THEN PRINT"I SEE A PICTURE OF A GRINNING JACKAL.":GOTO 210
  109. 1030 PRINT"I SEE NOTHING OF INTEREST.":GOTO 210
  110. 1040 GOSUB 20:IF Z9=2 THEN 210
  111. 1050 IF R<>3 AND R<>2 AND R<>4 AND R<>28 THEN PRINT"I CAN'T INSERT THAT!":GOTO 210
  112. 1060 INPUT"TELL ME, IN ONE WORD, INTO WHAT";A3$:A3$=LEFT$(A3$,3)
  113. 1070 R1=R:V1$=A3$:GOSUB 20:IF Z9=2 THEN 210
  114. 1080 IF R1=3 AND R=1 THEN PRINT"O.K.":BA=1:N(3)=0:BA=1:GOTO 210
  115. 1090 IF R1=4 AND R=50 AND DG<=0 THEN PRINT"THE GUARD WON'T LET ME!":GOTO 210
  116. 1100 IF R1=2 AND R=1 THEN PRINT"O.K. THE TAPE IS IN THE RECORDER.":N(2)=0:TA=1:GOTO 210
  117. 1110 IF R1=4 AND R=50 THEN PRINT"POP! A SECTION OF THE WALL OPENS.....":PRINT"REVEALING SOMETHING VERY INTERESTING.":N(4)=0:N(5)=LO:GOTO 210
  118. 1120 IF R1=28 AND R=29 THEN PRINT"POP! A CUP OF COFFEE COMES OUT OF THE MACHINE.":N(28)=0:N(30)=LO:GOTO 210
  119. 1130 PRINT"NOTHING HAPPENED.":GOTO 210
  120. 1140 REM
  121. 1150 IF V1$="DRA" AND LO=5 AND N(23)=0 THEN PRINT"IT's STUCK.":GOTO 210
  122. 1160 GOSUB 20:IF Z9=2 THEN 210
  123. 1170 IF R=7 OR R=9 OR R=13 OR R=15 OR R=23 OR R=32 OR R=5 THEN 1190
  124. 1180 PRINT"I CAN'T OPEN THAT!":GOTO 210
  125. 1190 IF R=7 AND N(16)=-1 THEN PRINT"O.K. I OPENED THE DOOR.":N(7)=0:N(8)=4:GOTO 210
  126. 1200 IF R=9 THEN PRINT"I CAN'T. IT DOESN'T WORK.":GOTO 210
  127. 1210 IF R=13 AND N(16)=-1 THEN PRINT"O.K. THE CLOSET IS OPENED.":N(13)=0:N(14)=14:GOTO 210
  128. 1220 IF R=15 THEN PRINT"I CAN'T. IT'S TOO STRONG.":GOTO 210
  129. 1230 IF R=23 THEN PRINT"IT'S STUCK.":GOTO 210
  130. 1240 IF R=32 AND N(28)=0 AND N(4)=0 AND SC=1 THEN PRINT "I OPEN THE SCULPTURE.":PRINT"SOMETHING FALLS OUT.":N(28)=LO:N(4)=LO:GOTO 210
  131. 1250 IF R<>5 THEN 1290
  132. 1260 INPUT"WHAT'S THE COMBINATION";C$
  133. 1270 IF C$=CO$ THEN PRINT"THE DOOR IS SLOWLY OPENING.":N(5)=0:N(9)=0:N(10)=10:GOTO 210
  134. 1280 PRINT"YOU MUST HAVE THE WRONG COMBINATION OR YOU ARE NOT":PRINT"SAYING IT RIGHT.":GOTO 210
  135. 1290 PRINT"I CAN'T DO THAT......YET!":GOTO 210
  136. 1300 IF V1$="GLO" AND N(45)=-1 THEN PRINT"O.K. I'M NOW WEARING THE GLOVES.":GL=1:GOTO 210
  137. 1310 PRINT"I CAN'T WEAR THAT!":GOTO 210
  138. 1320 IF V1$<>"SIG" AND V1$<>"NOT" THEN PRINT"I CAN'T READ THAT.":GOTO 210
  139. 1330 GOSUB 20:IF Z9=2 THEN 210
  140. 1340 IF R=22 THEN PRINT"IT SAYS:":PRINT NA$;",":PRINT"  WE HAVE DISCOVERED ONE OF CHAOSES SECRET WORDS.":PRINT"IT IS: BOND-007- .TO BE USED IN A -TASTEFUL- SITUATION.":GOTO 210
  141. 1350 IF R=27 THEN PRINT"IT SAYS: WATCH OUT! DANGEROUS!":GOTO 210
  142. 1360 IF V1$<>"REC" THEN PRINT"I CAN'T START THAT.":GOTO 210
  143. 1370 GOSUB 20:IF Z9=2 THEN 210
  144. 1380 IF BA<>1 OR TE<>1 OR TA<>1 THEN 1440
  145. 1390 PRINT"THE RECORDER STARTS UP AND PRESENTS A SHORT MESSAGE:"
  146. 1400 PRINTNA$;","
  147. 1410 PRINT"WE HAVE UNCOVERED A NUMBER THAT MAY HELP YOU."
  148. 1420 PRINT"THAT NUMBER IS:";CO$;". PLEASE WATCH OUT FOR HIDDEN TRAPS."
  149. 1430 PRINT"ALSO, THERE IS SOMETHING IN THE SCULPTURE.":SC=1:GOTO 210
  150. 1440 PRINT"NOTHING HAPPENED.":GOTO 210
  151. 1450 IF V1$<>"DRA" THEN PRINT"I'M TRYING TO BREAK IT, BUT I CAN'T.":GOTO 210
  152. 1460 IF N(6)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  153. 1470 IF LO=5 THEN PRINT"IT'S HARD....BUT I GOT IT. TWO THINGS FELL OUT.":N(3)=LO:N(22)=LO:N(23)=LO:GOTO 210
  154. 1480 PRINT"NOTHING HAPPENS.":GOTO 210
  155. 1490 GOSUB 20:IF Z9=2 THEN 210
  156. 1500 IF R<>15 AND R<>24 THEN PRINT"I'M TRYING. IT DOESN'T WORK.":GOTO 210
  157. 1510 IF N(25)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  158. 1520 IF R=15 THEN PRINT"RIP! THE BAG GOES TO PIECES, AND SOMETHING FALLS OUT!":N(15)=0:N(2)=LO:GOTO 210
  159. 1530 IF R=24 THEN PRINT"I CUT THE CASE AND REACH IN TO PULL SOMETHING OUT.":N(26)=-1:GOTO 210
  160. 1540 IF V1$<>"ROP" THEN PRINT"I CAN'T THROW THAT.":GOTO 210
  161. 1550 IF N(37)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  162. 1560 INPUT"TELL ME,IN ONE WORD,AT WHAT";A3$:A3$=LEFT$(A3$,3)
  163. 1570 IF A3$<>"HOO" THEN PRINT"O.K. I THREW IT.":N(37)=LO:GOTO 210
  164. 1580 IF LO<>20 THEN PRINT"I CAN'T DO THAT YET.":GOTO 210
  165. 1590 PRINT"I THREW THE ROPE AND IT SNAGGED ON THE HOOK.":RO=1:N(37)=LO:GOTO 210
  166. 1600 IF V1$<>"TEL" THEN PRINT"I CAN'T CONNECT THAT.":GOTO 210
  167. 1610 IF N(40)<>LO THEN PRINT"I DON'T SEE THE TELEVISION HERE.":GOTO 210
  168. 1620 IF TE=1 THEN PRINT"I DID THAT ALREADY.":GOTO 210
  169. 1630 IF LO<>2 THEN PRINT"I CAN'T DO THAT....YET!":GOTO 210
  170. 1640 PRINT"O.K. THE T.V. IS CONNECTED.":TE=1:GOTO 210
  171. 1650 PRINT"WHAT? YOU WOULD LEAVE ME HERE TO DIE ALONE?"
  172. 1660 PRINT"JUST FOR THAT, I'M GOING TO DESTROY THE GAME.":PRINT:PRINT:PRINT:PRINT"BOOOOOOOOOOOOM!":FOR R=1 TO 5000:NEXT:GOTO 2370
  173. 1670 IF LO=14 THEN PRINT"WHOOPS! A TRAP DOOR OPENED UNDERNEATH ME AND":PRINT"I FIND MYSELF FALLING.":FOR R=1 TO 4000:NEXT:LO=17:GOTO 110
  174. 1680 PRINT"NOTHING HAPPENED.":GOTO 210
  175. 1690 Z8=0:PRINT"WE ARE PRESENTLY CARRYING:":FOR R=1 TO 46
  176. 1700 IF N(R)<>-1 THEN 1730
  177. 1710 PRINT N1$(R);:IF R=45 AND GL=1 THEN PRINT". WHICH I'M WEARING."ELSE PRINT" "
  178. 1720 Z8=1
  179. 1730 NEXT
  180. 1740 IF Z8=0 THEN PRINT"NOTHING"
  181. 1750 GOTO 210
  182. 1760 IF LO=3 AND N(39)=-1 THEN PRINT"THE DOOR MAN LOOKS AT MY BADGE AND THEN THROWS ME OUT.":FOR R=1 TO 5000:NEXT:LO=1:GOTO 110
  183. 1770 IF LO=10 AND N(42)<>-1 THEN PRINT"THE GUARD LOOKS AT ME SUSPICIOUSLY, THEN THROWS ME BACK.":FOR R=1 TO 4000:NEXT:LO=9:GOTO 110
  184. 1780 IF LO=6 AND BU<>1 THEN PRINT"SIRENS GO OFF ALL AROUND ME!":PRINT"GUARDS RUN IN AND SHOOT ME TO DEATH!":GOTO 2330
  185. 1790 IF LO=11 AND EL<>1 THEN PRINT"THE FLOOR IS WIRED WITH ELECDRICITY!":PRINT"I'M BEING ELECTROCUTED!":GOTO 2330
  186. 1800 IF LO=10 AND N(30)=-1 AND DR=1 THEN PRINT"THE GUARD TAKES MY COFFEE":PRINT"AND FALLS TO SLEEP RIGHT AWAY.":DG=5+INT(10*RND(10)):N(11)=0:N(12)=10:DR=0:N(30)=0:GOTO 240
  187. 1810 IF DG=0 THEN PRINT"I HEAR A NOISE LIKE SOMEONE IS YAWNING.":N(11)=10:N(12)=0:GU=-2:DG=-1:GOTO 240
  188. 1820 IF LO=1 AND N(26)=-1 THEN PRINT"HURRAY! YOU'VE RECOVERED THE RUBY!":PRINT"YOU WIN!":GOTO 2350
  189. 1830 IF T>375 THEN PRINT"I THINK THEY ARE ON TO ME....I HEAR NOISES."
  190. 1840 IF T=400 THEN PRINT"OH NO! THEY CAUGHT UP TO ME! HELP! THEY'RE PULLING OUT GUNS!":GOTO 2330
  191. 1850 IF T=1 THEN PRINT"WRITING ON THE WALL SAYS:":PRINT"IF YOU WANT INSTRUCTIONS TYPE:ORDERS PLEASE"
  192. 1860 IF LO=6 AND LO(6,2)<>0 THEN PRINT"A SECRET DOOR SLAMS DOWN BEHIND ME!":LO(6,2)=0:GOTO 240
  193. 1870 IF LO=10 AND GU=-2 THEN PRINT"THE GUARD DRAWS HIS GUN AND SHOOTS ME!":GOTO 2330
  194. 1880 GOTO 240
  195. 1890 IF A$="N" THEN A$="GO NORTH":RETURN
  196. 1900 IF A$="S" THEN A$="GO SOUTH":RETURN
  197. 1910 IF A$="E" THEN A$="GO EAST":RETURN
  198. 1920 IF A$="W" THEN A$="GO WEST":RETURN
  199. 1930 IF A$="I" THEN A$="INV":RETURN
  200. 1940 RETURN
  201. 1950 IF V$="WAL" OR V$="RUN" THEN V$="GO ":RETURN
  202. 1960 IF V$="TAK" OR V$="CAR" THEN V$="GET":RETURN
  203. 1970 IF V$="LEA" THEN V$="DRO":RETURN
  204. 1980 IF V$="PRE" THEN V$="PUS":RETURN
  205. 1990 IF V$="EXA" THEN V$="LOO":RETURN
  206. 2000 IF V$="PUT" THEN V$="INS":RETURN
  207. 2010 IF V$="UNL" THEN V$="OPE":RETURN
  208. 2020 IF V$="PLA" THEN V$="STA":RETURN
  209. 2030 IF V$="SMA" THEN V$="BRE":RETURN
  210. 2040 IF V$="ATT" THEN V$="CON":RETURN
  211. 2050 IF V$="LIS" THEN V$="INV":RETURN
  212. 2060 RETURN
  213. 2070 DATA A VIDEO CASSETTE RECORDER,REC,2,A VIDEO TAPE,TAP,0,A LARGE BATTERY,BAT,0,A BLANK CREDIT CARD,CAR,0,AN ELECTRONIC LOCK,LOC,0,AN ELABORATE PAPER WEIGHT,WEI,5,A LOCKED WOODEN DOOR,DOO,4,AN OPEN WOODEN DOOR,DOO,0,A SOLID LOOKING DOOR,DOO,10
  214. 2080 DATA AN OPEN DOOR,DOO,0,AN ALERT SECURITY GUARD,GUA,10,A SLEEPING SECURITY GUARD,GUA,0,A LOCKED MAINTENANCE CLOSET,CLO,14,A MAINTENANCE CLOSET,CLO,0,A PLASTIC BAG,BAG,13,AN OLDE FASHIONED KEY,KEY,9,A SMALL METAL SQUARE ON THE WALL,SQU,16
  215. 2090 DATA A LEVER ON THE SQUARE,LEV,16,AN OLD MAHOGANY DESK,DES,5,A BROOM,BRO,13,A DUSTPAN,DUS,13,A SPIRAL NOTEBOOK,NOT,0,A MAHOGANY DRAWER,DRA,0,A GLASS CASE ON A PEDESTAL,CAS,6,A RAZOR BLADE,BLA,27,A VERY LARGE RUBY,RUB,0,A SIGN ON THE SQUARE
  216. 2100 DATA SIG,16,A QUARTER,QUA,0,A COFFEE MACHINE,MAC,8,A CUP OF STEAMING HOT COFFEE,CUP,0,A SMALL CAPSULE,CAP,0,A LARGE SCULPTURE,SCU,3,A TALL OFFICE BUILDING,BUI,1,A PAIR OF SLIDING DOORS,DOO,3,A LARGE BUTTON ON THE WALL
  217. 2110 DATA BUT,29,A PANEL OF BUTTONS NUMBERED ONE THRU THREE,PAN,9,A STRONG NYLON ROPE,ROP,17,A LARGE HOOK WITH A ROPE HANGING FROM IT,HOO,21,A C.I.A. IDENTIFICATION BADGE,BAD,-1,A PORTABLE TELEVISION,TEL,7
  218. 2120 DATA A BANK OF MONITORS,MON,7,A CHAOS I.D. CARD
  219. 2130 DATA CAR,30,A BANK OF MONITORS,MON,19,A SMALL PAINTING,PAI,23,A PAIR OF RUBBER GLOVES,GLO,13,A BOX WITH A BUTTON ON IT,BOX,24,ONE,ONE,9,TWO,TWO,9,THREE,THR,9,SLIT,SLI,10,ON A BUSY STREET,0,0,0,0,IN A VISITOR'S ROOM,0,0,3,0
  220. 2140 DATA IN THE LOBBY OF THE BUILDING,1,0,4,2,IN A DINGY ANTE ROOM,0,0,0,3
  221. 2150 DATA IN THE COMPANY PRESIDENT'S OFFICE,0,0,0,4,IN A SMALL SOUND PROOFED CUBICLE,0,12,0,0,IN A SECURITY OFFICE,0,0,8,0,IN A SMALL HALLWAY,0,14,9,7,IN A SMALL ROOM,3,0,0,0,IN A SHORT CORRIDOR,0,15,0,9,IN A HALLWAY MADE OF METAL,0,0,12,10
  222. 2160 DATA IN A SMALL PLAIN ROOM,6,0,0,11
  223. 2170 DATA IN A MAINTENANCE CLOSET,0,0,14,0,IN A CAFETERIA,8,0,0,0,IN A SIDE CORRIDOR,10,0,16,0,IN A POWER GENERATOR ROOM,0,0,0,15,IN A SUB-BASEMENT BELOW THE CHUTE,0,0,18,0,IN THE ENTRANCE TO THE SECRET COMPLEX,0,20,19,17
  224. 2180 DATA IN A SECRET MONITORING ROOM,0,0,0,18,ON A LEDGE IN FRONT OF A METAL PIT 1000'S OF FEET DEEP,18,0,0,0,ON THE OTHER SIDE OF THE PIT,0,0,22,0,IN A LONG CORRIDOR,0,25,23,21,IN A LARGE ROOM,0,26,0,22,IN A SECRET LABORATORY,0,0,25,0
  225. 2190 DATA IN A NARROW CROSS CORRIDOR,22,0,0,24,IN A CROSS EXAMINATION ROOM,23,28,0,0,IN A SMALL BATHROOM,0,0,28,0,IN THE OFFICE OF THE CHIEF OF CHAOS,26,30,0,27,IN THE CHAOS CONTROL ROOM,0,0,30,0,NEAR THE END OF THE COMPLEX,28,0,0,29
  226. 2200 DATA "GO ",GET,DRO,PUS,PUL,LOO,INS,OPE,WEA,REA,STA,BRE,CUT,THR,CON,QUI,BON,INV
  227. 2210 PRINT"YOUR MISSION,";NA$;",IS TO RECOVER A RUBY THAT IS BEING"
  228. 2220 PRINT"USED IN TOP SECRET GOVERNMENT PROJECTS AS A PART IN A"
  229. 2230 PRINT"LASER PROJECTOR."
  230. 2240 PRINT"  YOU WILL HAVE A PARTNER WHO IS NOT TOO BRIGHT AND NEEDS"
  231. 2250 PRINT"YOU TO TELL HIM WHAT TO DO. USE TWO WORD COMMANDS LIKE:"
  232. 2260 PRINT:PRINT"              GET NOTEBOOK   GO WEST  LOOK DOOR"
  233. 2270 PRINT:PRINT"SOME COMMANDS USE ONLY ONE WORD. EXAMPLE: INVENTORY"
  234. 2280 PRINT"  IF YOU WANT TO SEE CHANGES IN YOUR SURROUNDINGS TYPE: LOOK"
  235. 2290 PRINT"THE RUBY HAS BEEN CAPTURED BY A SECRET SPY RING KNOWN AS"
  236. 2300 PRINT"CHAOS. WE SUSPECT THEY ARE UNDER COVER SOMEWHERE IN THIS"
  237. 2310 PRINT"NEIGHBORHOOD. GOOD LUCK!"
  238. 2320 GOTO 240
  239. 2330 FOR R=1 TO 5000:NEXT:PRINT"I'M DEAD!"
  240. 2340 PRINT"YOU DIDN'T WIN."
  241. 2350 INPUT"WOULD YOU LIKE TO TRY AGAIN (Y/N)";Z$
  242. 2360 IF Z$="Y" THEN RUN
  243. 2370 END
  244. "I'M DEAD!"
  245. 2340 PRINT"YOU DIDN'T WIN