home *** CD-ROM | disk | FTP | other *** search
/ Frostbyte's 1980s DOS Shareware Collection / floppyshareware.zip / floppyshareware / USCX / DOSUT-16.ZIP / DRVTEST.BAS < prev    next >
BASIC Source File  |  1984-02-23  |  2KB  |  53 lines
  1.  
  2.  
  3. 10  'DISK DRIVE TEST
  4. 20  'JOE McDERMOTT - DECEMBER 1982
  5. 25  'NORTH JERSEY IBM PC CLUB
  6. 30  '
  7. 40  'THE PROGRAM CREATES A SERIES OF SEQUENTIAL FILES
  8. 50  'IT WRITES DATA TO THEM AND READS IT BACK FOR VERIFICATION
  9. 60  'FINALLY THE TEST FILES ARE ERASED/
  10. 70  'THE FILES ARE OF THE FORM "XXX.TST" WHERE "XXX" ARE THREE LETTERS
  11. 80  'CHOSEN AT RANDOM, E.G. "EBG.TST","CXU.TST"
  12. 90  '
  13. 100  NUMFILES=40        'NUMBER OF FILES THAT WILL BE CREATED
  14. 110  DIM FS$(NUMFILES)  'ARRAY FOR STORING FILESPECS
  15. 120  FTYPE$=".TST"      'FILE EXTENSION USED IN THE TEST
  16. 130  INPUT"DRIVE TO BE TESTED ";DD$
  17. 140  DD$=DD$+":"
  18. 150  '
  19. 160  INPUT"*** INSERT DISK AND PRESS `ENTER' ***",Z$
  20. 170  '
  21. 180  '   ---------- CREATE FILES ----------
  22. 190  FOR I=1 TO NUMFILES
  23. 200    FILENAME$ = CHR$(RND*26+64)+CHR$(RND*26+64)+CHR$(RND*26+64)
  24. 205    FS$(I)=DD$+FILENAME$+FTYPE$
  25. 210    PRINT"CREATING: ";FS$(I);" #";I
  26. 220    OPEN "O",1,FS$(I)           'CREATE DIRECTORY ENTRY
  27. 230    PRINT#1,STRING$(255,"*")    'WRITE DATA TO FILE
  28. 240    PRINT#1,STRING$(255,"*")
  29. 250    PRINT#1,STRING$(255,"*")
  30. 260    CLOSE 1
  31. 270  NEXT I
  32. 280  '   ---------- READ BACK FILES -----------
  33. 290  FOR I=1 TO NUMFILES
  34. 300    PRINT"READING: ";FS$(I);" #";I
  35. 310    OPEN "I",1,FS$(I)
  36. 320    INPUT#1,L$:PRINT LEFT$(L$,75)
  37. 330    INPUT#1,L$:PRINT LEFT$(L$,75)
  38. 335    INPUT#1,L$:PRINT LEFT$(L$,75)
  39. 340    CLOSE 1
  40. 350  NEXT I
  41. 360  '   ---------- ERASE FILES ----------
  42. 370  FOR I=1 TO NUMFILES
  43. 380    PRINT"ERASING: ";FS$(I)
  44. 390    KILL FS$(I)
  45. 400  NEXT I
  46. 410  END  'OF PROGRAM
  47.  
  48. ---------
  49. 370  FOR I=1 TO NUMFILES
  50. 380    PRINT"ERASING: ";FS$(I)
  51. 390    KILL FS$(I)
  52. 400  NEXT I
  53. 410