home *** CD-ROM | disk | FTP | other *** search
/ Frostbyte's 1980s DOS Shareware Collection / floppyshareware.zip / floppyshareware / TCOMM / DMATFNTS.ZIP / MATH12.BAS < prev    next >
Encoding:
BASIC Source File  |  1987-10-22  |  3.0 KB  |  61 lines
  1. 10  ' Copyright (C) James H. Bradley, 1987. Release 1.0.
  2. 20  ' This shareware product may be copied only as set out in the associated
  3. 30  ' documentation, which must accompany unchanged all copies of this and
  4. 40  ' associated products.
  5. 50  ' Contact James H. Bradley, 106 Portland Road, Atlantic Highlands,
  6. 60  ' New Jersey 07716, U.S.A. The registration fee is $30 U.S.
  7. 70  '
  8. 80  OPEN "math12" FOR OUTPUT AS #1
  9. 90  OPEN "data12" FOR INPUT AS #2
  10. 100 INPUT #2, FLAG%,S$   'Read and discard the comments in the data file
  11. 110 LINE INPUT #2, S$ : S$ = ""
  12. 120 PRINT #1, CHR$(27);"M"; 'Select 12 cpi
  13. 130 PRINT #1, CHR$(27);"x";CHR$(1); 'Select letter quality mode
  14. 140 PRINT #1, CHR$(28);"I";CHR$(1); 'Select IBM character set with Greek, etc.
  15. 150 PRINT #1, CHR$(27);":";CHR$(0);CHR$(0);CHR$(0) 'Copy IBM character set
  16. 160 IF FLAG% =< 0 THEN 310 ' Skip all printing
  17. 170 PRINT #1, "      MATH12 Release 1.0. Copyright (C) James H. Bradley 1987"
  18. 180 PRINT #1, "      Guide for typists and proof-readers."
  19. 190 PRINT #1, " "
  20. 200 PRINT #1, "    The following characters are available in the IBM set"
  21. 210 PRINT #1,"    ¬ = NOT               Γ = Cap GAMMA     Σ = Cap SIGMA     Φ = Cap PHI"
  22. 220 PRINT #1,"    ∩ = EXCLUSION         Θ = Cap THETA     Ω = Cap OMEGA"
  23. 230 PRINT #1,"    « = ?                 α = ALPHA         ß = BETA          δ = DELTA"
  24. 240 PRINT #1,"    » = ?                 ε = EPSILON       ⁿ = ETA           µ = MU"
  25. 250 PRINT #1,"    │ = LONG VERT. BAR    π = PI            σ = SIGMA         τ = TAU"
  26. 260 PRINT #1,"    ║ = LONG DOUBLE BAR   φ = PHI"
  27. 270 PRINT #1,"    ┴ = ORTHOGONAL        ≡ = IDENTICAL     ÷ = DIVISION      ° = DEGREE"
  28. 280 PRINT #1,"    ± = PLUS OR MINUS     √ = ROOT          ■ = TERMINATOR    ∙ · = TWO DOT SIZES"
  29. 290 PRINT #1,"    ≥ = GREATER OR EQUAL  ≤ = LESS OR EQUAL ≈ = APPROX. EQUAL"
  30. 300 PRINT #1, " "
  31. 310 K = 1 'Line counter for 2-column output if selected
  32. 320 FOR J = 1 TO 100
  33. 330 IF EOF(2) THEN 540
  34. 340 PRINT #1, CHR$(27);"&";CHR$(0); 'One or more user-defined characters follow
  35. 350 INPUT #2,L$
  36. 360 L% = ASC(L$)
  37. 370 S$ = S$ + CHR$(L%)
  38. 380 PRINT #1, CHR$(L%);CHR$(L%); 'Give the local range of characters to be replaced
  39. 390 PRINT #1, CHR$(3);CHR$(24);CHR$(3); '3 blanks left, 24 cols. data, 3 blanks
  40. 400 PRINT L$
  41. 410 FOR I = 1 TO 24*3 'Range must agree with 12 cpi letter quality modes and
  42. 420 ' the above 3-24-3 definition
  43. 430 INPUT #2, A
  44. 440 PRINT #1, CHR$(A);
  45. 450 NEXT I
  46. 460 IF FLAG% =< 0 THEN 530
  47. 470 PRINT #1,CHR$(27);"%";CHR$(1);"    ";CHR$(L%);CHR$(27);"%";CHR$(0);" = ";
  48. 480 IF K = 2 THEN 510
  49. 490 K = 2: PRINT #1, USING "\                                    \";L$;
  50. 500 GOTO 530
  51. 510 K =1
  52. 520 PRINT #1, L$
  53. 530 NEXT J
  54. 540 IF FLAG% =< 0 THEN 590
  55. 550 PRINT #1, CHR$(27);"%";CHR$(0) 'Select built-in IBM character set
  56. 560 PRINT #1, "    ";S$
  57. 570 PRINT #1, CHR$(27);"%";CHR$(1);"    ";S$ 'Select user character set
  58. 580 PRINT #1, CHR$(27);"%";CHR$(0) 'Select built-in IBM character set
  59. 590 SYSTEM
  60. 600 END
  61.