home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Frostbyte's 1980s DOS Shareware Collection
/
floppyshareware.zip
/
floppyshareware
/
APOG
/
ASM5.ZIP
/
PRSET.ASM
< prev
next >
Wrap
Assembly Source File
|
1990-06-15
|
25KB
|
494 lines
;===========================================================
; PrSet -- Memory-resident printer setup utility
;===========================================================
; Compile with MASM 5.1 or TASM 1.0 or 2.0
;
; Save as PRSET.ASM
; Compile: MASM prset;
; LINK prset;
;
; Use these 2 lines for Borland's TASM:
; QUIRKS
; MASM51
;===========================================================
MAX_CHOICES = 20 ;Maximum printer choices
POP_SHIFT = 0Ah ;Left-shift / Alt
POP_KEY = 19h ; P
P_ATTRIB = 70h ;Vid. attr. used during popup
PRNT_NUM = 0 ;Use for LPT1
MSG_LEN = 41 ;Length of option message + 1
CODE_LEN = 11 ;Max. # of printer codes per line +1
V_ROWS = 25 ;Number of display rows we'll use
V_COLS = 80 ;Number of display columns we'll use
;===========================================================
; Define segments and order of segments
;===========================================================
.SEQ ;Keep segments in this order
bios_mem segment at 0000h
bios_mem ends
tsr_group group tsr_seg, tsr_stack, prt_data
tsr_seg segment word
tsr_seg ends
tsr_stack segment stack word
dw 1feh dup (?)
tsr_sp dw ?
tsr_stack ends
prt_data segment para
prt_data ends
init_code segment para ;Must be aligned on a paragraph
init_code ends
init_data segment word
init_data ends
;===========================================================
; Define absolute segment to give us access to low-memory BIOS data
;===========================================================
bios_mem segment at 0000h
org 417h
b_shift db ? ;Keyboard control #1
org 449h
b_mode db ? ;Current video mode
b_cols dw ? ;Columns on screen
b_buflen dw ? ;Length of video buffer
b_bufaddr dw ? ;Offset of current page buffer
b_cursor dw 8 dup (?) ;Cursor loc. on each page
b_cursize dw ? ;Cursor size info.
b_apage db ? ;Active page
bios_mem ends
;===========================================================
; Data for display screen & printer setup
;===========================================================
prt_data segment
entry struc
desc db MSG_LEN dup (?) ;Room for option's display,
prt db CODE_LEN dup (?) ; code count, & codes
entry ends
OPT_LENGTH = MSG_LEN + CODE_LEN
; DO NOT ALTER THE FOLLOW db DECLARATIONS! -- PRINST uses them to know
; where to include the uer's printer codes into the .EXE file
db 'PRINTER OPTIONS:'
db MAX_CHOICES
db MSG_LEN
db CODE_LEN
option_1 equ $
entry MAX_CHOICES dup (<>)
m1 db " <ESC> to end",0
m2 db " Your choice ==> ",0
tsr_title db ' PC Resource Printer Setup Utility',0
prt_data ends
;===========================================================
; Data for TSR-portion of program
;===========================================================
tsr_seg segment
assume nothing
even
irp x,<08,09,10,13,14,16,17>;;Create storage for 7 captured
old_&x equ this dword ;; interrupt vectors
old_&x&_off dw ?
old_&x&_seg dw ?
endm
popup_gate dw 0 ;Gate to stop recursion and
;calls during vital interrupts
popup_req dw 0 ;Set when popup requested
save_sp dw ? ;Save caller's stack pointer
save_ss dw ? ; and stack segment
vid_off dw ? ;Offset of physical vid. buffer
vid_seg dw ? ;Segment of vid. buffer
cursor_loc dw ? ;Cursor column
active_pg db ? ;Active video page
save_buf dw V_ROWS * V_COLS dup (?) ;Buffer to save video image
;===========================================================
; New Interrupt Services:
; Int 10h: Video services
; Int 13h: Disk I/O
; Int 14h: Serial Port I/O
; Int 16h: Keyboard Request
; Int 17h: Parallel Port I/O
;===========================================================
irp x,<10,13,14,16,17> ;Don't pop up during these!
assume cs:tsr_seg
new_&x proc far
assume cs:tsr_seg
pushf ;;Simulate an Int call
inc cs:[popup_gate] ;;Set our flag
call cs:[old_&x&] ;;Call original service
sti ;;Be sure interrupts are on
pushf ;;Save returned flags
dec cs:[popup_gate] ;;Reset our flag
popf ;;Recover interrupt's flags
retf 2 ;;Fake IRET that keeps flags
new_&x endp
endm
;===========================================================
; New Interrupt Service:
; Int 08h: Timer interrupt
;===========================================================
new_08 proc far ;popup, when ready, on timer tick
assume cs:tsr_seg
pushf ;Simulate interrupt call
call cs:[old_08] ;Call previous service
sti ;Allow interrupts
test cs:[popup_req],-1 ;Popup requested?
jz end_08 ;No -- continue
test cs:[popup_gate],-1 ;Popup ok?
jnz end_08 ;No -- forget it
inc cs:[popup_gate] ;Else set the gate to stop recursion
call popup ; and then pop up
mov cs:[popup_req],0 ;Clear request gate
dec cs:[popup_gate] ; and popup gate
end_08: iret ;Back to caller
new_08 endp
;===========================================================
; New Interrupt Service:
; Int 09h: Keyboard
;===========================================================
new_09 proc far ;Test for popup keys
push ax ;Save AX register
in al,60h ;Get keystroke
cmp al,POP_KEY ;Our key?
je test_shift ;Yes -- test shift keys
end_09: pop ax ;else recover AX
jmp dword ptr cs:[old_09] ;Let previous owner handle it
test_shift:
push ds ;Save DS
sub ax,ax ;AX = 0
mov ds,ax ;Set DS==> bios memory
assume ds:bios_mem
mov al,[b_shift] ;Get shift byte
pop ds ;We're done with DS
assume ds:nothing
and al,POP_SHIFT ;Mask off extra bits
cmp al,POP_SHIFT ;Right value?
jne end_09 ;No -- continue
in al,61h ;Else get keyboard ctrl lines
mov ah,al ; and save them
or al,80h ;Set 'enable kbd' bit
out 61h,al ;Send it out
mov al,ah ;Get original control values
out 61h,al ;Send them out
mov al,20h ;End-of-interrupt signal
out 20h,al ;Show end of hardware interrupt
inc cs:[popup_req] ;Show we want to popup
pop ax ;Recover AX
iret ;Return from interrupt
new_09 endp
;===========================================================
; Popup here on user's request when it is safe to do so.
; It is NOT safe to use any DOS services during this popup!
;===========================================================
popup proc near
assume ds:nothing, es:nothing
push ax ;Save AX on app.'s stack
cli ;No interrupts now
mov cs:[save_ss],ss ;Save app.'s stack
mov cs:[save_sp],sp
mov ax,tsr_stack
mov ss,ax
mov sp,offset tsr_sp
sti
pushf ;Save flags
irp x,<bx,cx,dx,di,si,bp,ds,es>
push &x ;;Save registers
endm
cld ;Don't forget the direction flag!
sub ax,ax
mov ds,ax ;DS ==> bios_mem
assume ds:bios_mem
mov bp,[b_cols] ;Get columns on screen
;BP will never change during popup!
mov si,[b_bufaddr] ;SI = offset to screen
mov cs:[vid_off],si ; and save it
mov al,[b_apage] ;Get video page
mov cs:[active_pg],al ; and save it
add ax,ax ;AX = vid page * 2
mov di,offset b_cursor ;DS:DI ==> cursor location info
add di,ax ;DS:DI ==> info for this page
mov ax,[di] ;Get cursor position
mov cs:[cursor_loc],ax ; and save it
mov al,[b_mode] ;Get video mode
assume ds:nothing
cmp al,1 ;40-cols?
jbe pop_done ;Yes -- forget everything
cmp al,3 ;80-cols or more in color?
jbe @F ;Yes -- looks okay
cmp al,7 ;80-col mono?
jne pop_done ;No -- skip if graphics
@@: call save_scrn ;Save user's screen
call set_printer ;Now reset printer
call restore_scrn ;Restore the screen
pop_done:
assume ds:nothing, es:nothing
irp x,<es,ds,bp,si,di,dx,cx,bx>
pop &x ;;Recover registers
endm
popf ; Restore everything
cli ;No interrupts for now
mov ss,cs:[save_ss] ;Restore orig. stack
mov sp,cs:[save_sp]
sti ;Interrupts back on
pop ax ;Recover AX
ret
popup endp
;===========================================================
; Save the foreground screen and move cursor off screen
;===========================================================
save_scrn proc near ;Entry: AL = video mode
;BP = screen columns
;SI = b_bufaddr
assume ds:nothing, es:tsr_seg
push si ;Save screen pointer
mov di,0b800h ;Assume color text mode
cmp al,7 ;Mono text?
jne @F ;No -- go
mov di,0b000h ;Yes -- load mono segment
@@: mov ds,di ;DS ==> screen
mov cs:[vid_seg],di ; and save for later
mov bx,tsr_seg ;Get our segment
mov es,bx ; into ES
mov di,offset save_buf ;ES:DI ==> buffer to save screen
mov dx,V_ROWS ;Rows to save
@@: push si ;Save screen pointer
mov cx,V_COLS ;Columns to save
rep movsw ;Move one row to buffer
pop si ;Recover orig. screen pointer
add si,bp ;SI ==> next screen row
add si,bp
dec dx ;Count this row
jnz @B ;Repeat for all rows
pop si ;Recover pointer
mov bh,es:[active_pg] ;Get video page
mov dx,V_ROWS shl 8 + 0 ;First invisible row, column 0
mov ah,2 ;BIOS func.: set cursor posn
int 10h ;Call video BIOS
ret
assume ds:nothing, es:nothing
save_scrn endp
;===========================================================
; Restore the foreground screen and cursor
;===========================================================
restore_scrn proc near ;Entry: BP = cols on screen
assume ds:tsr_seg, es:nothing
mov ax,tsr_seg
mov ds,ax ;DS ==> our data area
mov es,[vid_seg]
mov di,[vid_off] ;ES:DI ==> video buffer
mov si,offset save_buf ;DS:SI ==> save buffer
mov dx,V_ROWS ;Rows to restore
@@: push di ;Save screen pointer
mov cx,V_COLS ;Columns to restore
rep movsw ;Restore 1 row
pop di
add di,bp ;DI ==> next row on screen
add di,bp
dec dx ;Count this row
jnz @B ;Repeat until done
mov bh,[active_pg] ;Get page number
mov dx,[cursor_loc] ;Get original cursor location
mov ah,2 ;BIOS func.: set cursor posn.
int 10h
ret
assume ds:nothing
restore_scrn endp
;===========================================================
; Clear the screen with our display attribute
;===========================================================
set_screen proc near ;Set screen to our attributes
assume ds:tsr_seg, es:nothing
mov ax,tsr_seg
mov ds,ax ;DS ==> our data
mov es,[vid_seg]
mov di,[vid_off] ;ES:DI ==> video buffer
mov dx,V_ROWS ;Rows to set
mov ah,P_ATTRIB ;AH = new attribute
mov al,' ' ;Clear screen to all spaces
@@: push di ;Save screen pointer
mov cx,V_COLS ;Columns to set
rep stosw ;Set one row
pop di
add di,bp ;DI ==> next row on screen
add di,bp
dec dx ;Count this row
jnz @B ;Repeat until done
ret
assume ds:nothing
set_screen endp
;===========================================================
; Get user's choice & send command to the printer
;===========================================================
set_printer proc near
assume ds:tsr_seg, es:nothing
mov ax,tsr_seg
mov ds,ax ;DS ==> our data
call set_screen ;Clear display screen
call disp_opts ;Display options
call get_choice ;Get choice
jc @F ;Go if no choice
call to_printer ;Send code to printer
@@: ret ;Then end
set_printer endp
;===========================================================
; Display list of options
;===========================================================
disp_opts proc near ;Display user's options
mov ax,prt_data
mov es,ax ;ES ==> data for screen & printer
assume es:prt_data
mov si,offset tsr_title ;ES:SI ==> string to print
mov dx,0 ;DH, DL = row & column
call print_string ;Print it
mov dx,2 SHL 8 + 8 ;Row 2, Col 8
mov cx,MAX_CHOICES ;Number of choices
mov si,offset option_1 ;ES:SI ==> option table
@@: call print_string ;Print the string
inc dh ;Move to next row
add si,OPT_LENGTH ;Move to next option
loop @B ;Display all options
mov si,offset m1
call print_string
inc dh
mov si,offset m2
call print_string
assume es:nothing
ret
disp_opts endp
;===========================================================
; Print an ASCIIZ string directly to video memory
;===========================================================
print_string proc near ;On Entry: ES:SI ==> ASCIIZ string
;DH = row, DL = col to print
irp x,<dx,di,si,ds,es> ;Save registers we'll change
push &x
endm
sub ax,ax
mov al,dh ;AX = row number
mul bp ;AX = bytes to begin. of row
shl ax,1 ;AX = beg. of row
sub dh,dh ;DX = col #
add ax,dx
add ax,dx ;AX = offset on screen
add ax,[vid_off] ;AX = absolute screen offset
mov di,ax
mov ah,P_ATTRIB ;AH = attribute for screen
mov bx,[vid_seg]
push es
pop ds ;DS:SI ==> string
mov es,bx ;ES:DI ==> screen
@@: lodsb ;Get char. from string
and al,al ;Is it 0?
jz @F ;Yes -- go
stosw ;Else store char. & attrib.
jmp @B ; and repeat
@@: irp x,<es,ds,si,di,dx> ;Restore registers
pop &x
endm
ret
print_string endp
;===========================================================
; Get the user's option from the keyboard
;===========================================================
get_choice proc near
@@: mov ah,1 ;Keystroke waiting?
int 16h ;Ask BIOS
jz @F ;No -- go
mov ah,0 ;Else get key
int 16h ; from BIOS
jmp @B ;Until no type-ahead
@@: mov ah,0 ;Now wait for keystroke
int 16h
cmp al,'a' ;If lower-case, convert
jb @F ;Go if not
cmp al,'z' ;Test upper limit
ja @F ;Go if not 'a' - 'z'
sub al,32 ;Convert to upper-case
@@: cmp al,27 ;ESCape?
jne @F ;No -- go
stc ;On ESC, set carry flag
ret ; and leave
@@: sub al,'A' ;A = 0, B = 1, etc.
cmp al,MAX_CHOICES ;Valid choice?
jae get_choice ;No -- get another
clc ;Clear carry flag
ret ;Else return with AL = choice
get_choice endp ; and CF clear
;===========================================================
; Send command codes to the printer
;===========================================================
to_printer proc near ;On entry, AL = user's choice
mov bx,prt_data
mov es,bx ;ES ==> data for screen & printer
assume es:prt_data
mov si,offset option_1.prt ;SI ==> 1st option choice
mov cl,al
sub ch,ch ;CX = user's choice
jcxz send_out ;Go if choice 0
@@: add si,OPT_LENGTH ;Else move SI to next choice
loop @B ;Until SI ==> user's choice
send_out:
sub cx,cx ;CX = 0
mov cl,ES:[si] ;CX = bytes to send
jcxz prt_end ;Go if none
mov dx,PRNT_NUM ;DX = printer number
@@: inc si ;ES:SI ==> Next data byte
mov al,es:[si] ;Get byte to send
sub ah,ah ;AH = 0: Send byte to printer
int 17h ;Send it out
test ah,1 ;Time out?
jnz prt_end ;Yes -- leave
loop @B ;Else loop for all bytes
prt_end:
assume es:nothing
ret
to_printer endp
tsr_seg ends ;End of resident code & data
;===========================================================
; Initialization Routines -- removed from memory after startup
;===========================================================
init_code segment
assume cs:init_code, ds:nothing, es:nothing, ss:tsr_stack
install proc near
push es ;Save PSP segment
mov ax,tsr_seg ;Get TSR segment
mov ds,ax
assume ds:tsr_seg
mov ah,35h ;DOS Func: get interrupt vector
irp x,<08,09,10,13,14,16,17> ;;Get and save interrupt vectors
mov al,&x&h ;;Inter. number in AL
int 21h ;;Call DOS
mov [old_&x&_off],bx ;;Save offset
mov [old_&x&_seg],es ;; and segment
endm
mov ah,25h ;DOS Func: set interrupt vector
irp x,<08,09,10,13,14,16,17> ;;Set new interrupt vectors
mov al,&x&h ;;Interrupt number in AL
mov dx,offset new_&x ;;DS:DX has vector address
int 21h
endm
mov ax,init_data ;Get segment for initial data
mov ds,ax ;Into DS
assume ds:init_data
mov dx,offset hello ;Print sign-on message
mov ah,9 ;Print a string
int 21h ; via DOS
pop ax ;Get segment of PSP
mov dx,init_code ;Beginning of throw-away area
sub dx,ax ;AX = paras - 1 to keep
inc dx ;DX = paragraphs to keep
mov ax,3100h ;Term. but stay resident
int 21h ;Back to DOS
install endp
init_code ends
;===========================================================
; Installation Data
;===========================================================
init_data segment
CR = 13
LF = 10
hello db "PC Resource's Printer Setup Utility",CR,LF
db " has been installed in memory.",CR,LF,CR,LF
db "Press <Left-Shift><Alt><P> to set up your printer.",CR,LF
db CR,LF
db "You can modify this program to work with your printer",CR,LF
db "by running PRINST.",CR,LF,CR,LF,'$'
init_data ends
end install
