home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Inside Multimedia 1995 July
/
IMM0795.ISO
/
share
/
os2
/
docsboot
/
os2fixup.cmd
< prev
next >
Wrap
OS/2 REXX Batch file
|
1994-11-01
|
8KB
|
195 lines
@echo off
set os2src=Z:\12345678.9AB\
if "%os2src%"=="Z:\12345678.9AB\" goto OkayToRun
echo.
echo [Error : Environment space too small. Increasing size.]
echo [If you see this message more than once, abort and try to run this batch
echo from a clean system boot disc.]
echo.
%comspec% /c %0 %1 %2 %3 %4 %5 %6 %7 %8 %9
goto QuitNow
:OkayToRun
cls
echo DocsBoot+ Installability fixup for OS/2 v2.0, v2.1, v3.0; version 1.10
echo Copyright 1994 Zac Schroff, all rights reserved.
echo.
if "%1"=="" goto Help
if "%1"=="F" goto Floppy
if "%1"=="f" goto Floppy
if "%1"=="C" goto CDROM
if "%1"=="c" goto CDROM
goto Help
:Floppy
if not exist .\FDISK.EXE goto FailFile
if "%2"=="" goto Help
echo.
:FChk
echo Please insert your OS/2 Disc #1 into the %2 floppy drive and
pause
if exist %2\FDISK1.COM goto Already
if not exist %2\FDISK.COM goto FChk
echo.
echo Renaming.
ren %2\FDISK.COM FDISK1.COM >nul
if not exist %2\FDISK1.COM goto Fail
echo Copying.
if not exist FDISK.EXE goto FailFile
copy .\FDISK.EXE %2\FDISK.COM >nul
if errorlevel 1 goto Fail
if not exist %2\FDISK.COM goto Fail
echo Finished.
goto Finish
:CDROM
if not exist .\FDISK.EXE goto FailFile
if "%2"=="" goto Help
if "%3"=="" goto Help
:CChk
echo Please make sure the OS/2 installation CD-ROM is in the %3 CD-ROM drive and
pause
if not exist %3\os2se20.src goto CChk
if exist %3\os2se20\disk_0\*.* set os2src=\os2se20\
if exist %3\os2se21\disk_0\*.* set os2src=\os2se21\
if exist %3\os2image\disk_0\*.* set os2src=\os2image\
echo.
echo [Copying files from %3%os2src%]
echo.
echo This will take a while. Please wait...
if exist %2\os2se20.src del %2\os2se20.src > nul
if not exist %3\os2se20.src goto FailFile
if not exist %3%os2src%disk_0\*.* goto FailVers
xcopy %3\os2se20.src %2\ > nul
if errorlevel 1 goto Fail
if not exist %2\os2se20.src goto FailWrite
xcopy /s %3%os2src%*.* %2%os2src% > nul
if errorlevel 1 goto Fail
if not exist %2%os2src%disk_1\fdisk.com goto Fail
if exist %2%os2src%disk_1\fdisk1.com del %2%os2src%disk_1\fdisk1.com > nul
ren %2%os2src%disk_1\fdisk.com fdisk1.com > nul
if not exist %2%os2src%disk_1\fdisk1.com goto Fail
copy .\fdisk.exe %2%os2src%disk_1\fdisk.com > nul
if errorlevel 1 goto Fail
if not exist %2%os2src%disk_1\fdisk.com goto Fail
goto Finish
:Already
echo.
echo This disc appears to already be modified. You should already be able to
echo install from it.
goto Finish
:FailVers
echo.
echo The installation failed. The OS/2 installation discs were not in the expected
echo directory. Please contact the author of this program (see the DocsBoot+
echo documentation) for an update, and mention which version of OS/2 you are trying
echo to install. Sorry for the inconvenience.
goto End
:FailFile
echo.
echo The installation failed. A required file was not found on the source disc.
goto End
:Fail
:FailWrite
echo.
echo The installation failed. There may not be enough room on the target disc, or
echo some error may have occurred.
goto End
:Finish
echo.
echo READ THIS BEFORE CONTINUING!!!! THIS IS VERY IMPORTANT!!!!
echo.
echo When you install OS/2, things will work more or less normally. When asked
echo if you want to install to C:, select no (you will be placed in FDISK). If
echo you need to do any partitioning, do so now. If not, exit FDISK now. You will
echo be placed at a blank screen. Type the letter ONLY of the desired install drive
echo and press [Enter]. The install process will resume.
echo.
echo There may be problems with the places in the installation when the installer
echo needs to reboot the system. If it says press [Enter] to reboot and you have
echo done so a couple of times, just press [Ctrl-Alt-Delete]. It's okay, really.
echo The install process will continue after the reboot, as it usually does.
echo.
echo If you are running multiple physical drives (I usually suggest this), OS/2
echo should be installed on the primary partition on the secondary drive. This
echo allows DOS, *ix, et cetera the primary partition on the primary drive, which
echo many other operating systems require. If you install OS/2 on an extended
echo partition then decide to add another drive later, you might need to reinstall.
echo.
echo Sorry about the blank screen instead of a a real prompt for the install drive.
echo I am working on resolving this (it may be partly because of my compiler).
echo.
set os2src=
goto QuitNow
:Help
echo.
echo This program patches the OS/2 installation process so you can install to drives
echo other than C: without having to install the BootManager. Note that DocsBoot+
echo or some similar package must be installed on your system or else installing to
echo some drive other than C: will fail.
echo.
echo OS/2 normally assumes that there is no way to boot anything other than the
echo primary partition on the primary drive, unless IBM's BootManager is present.
echo While this is USUALLY true, I think it is a weakness, and it should display a
echo warning instead of simply refusing to install.
echo.
echo This installs a program which gets around this by emulating the functionality
echo of the FDISK utility, but which allows OS/2 to install to drives other than C:.
echo.
pause
echo.
echo If you are installing from floppies, you need to use this syntax :
echo.
echo OS2Fixup F InstallSourceDrive:
echo.
echo for example, OS2Fixup F A: will modify the install disc in drive A:
echo.
echo This modifies the installation discs, so you should only run this on a
echo non-write-protected BACKUP COPY of the installation discs. It only modifies the
echo second disc (disc 1), so that is the only one you really need, if you are
echo really short on floppies (though you REALLY should install from a copy).
echo.
pause
echo.
echo If you are installing from CD-ROM, you may have some problems. This procedure
echo modifies the installation discs so that an intercept can be installed around
echo the FDISK utility. On CD-ROM, this is impossible. In order to still allow
echo convenient install, there is an alternative. If you have a partition other
echo than the one being installed to with about 30MB free, this program can make
echo if look enough like the CD-ROM that OS/2 will install from it. This is slightly
echo slower than installing from the CD-ROM (since the data must be read twice and
echo written twice), but it is nearly as convenient, and you can install from the
echo same drive again later. You can also add MMPM/2 or other options from the
echo CD-ROM later, if you wish.
echo.
echo If you do not have a partition with at least 30MB free (other than the one
echo you want to install to), you will need to install from floppies instead.
echo Note the floppy documentation here and see your OS/2 manuals for information
echo on making the install discs.
echo.
pause
echo.
echo To set up this sort of arrangement you need to use this syntax :
echo.
echo OS2Fixup C HardDisc: CDROM:
echo.
echo for example, OS2Fixup C J: M: will copy the important files from the
echo CD-ROM in drive M: to hard disc J:, and modify them there, so the
echo installation can be performed from the hard disc. The CD-ROM should then
echo be removed from the CD-ROM drive, until the installation process is
echo complete.
echo.
echo Note that you probably will not be allowed to install to the same partition as
echo you specified here for the CD-ROM files.
echo.
:Summary
pause
echo.
echo Summary :
echo.
echo To modify a floppy installer : OS2Fixup F BootFloppy:
echo.
echo To modify a CD-ROM installer : OS2Fixup C HardDisc: CDROM:
:End
echo.
echo.
set os2src=
:QuitNow