home *** CD-ROM | disk | FTP | other *** search
/ Internet MPEG Audio Archive / IMAA.mdf / UTIL / DOS / SOX10C / SOUND2AU.COM < prev    next >
Encoding:
Text File  |  1993-09-30  |  1.5 KB  |  53 lines
  1. $   FVER = 'F$Verify(0)'
  2. $ !
  3. $ ! Sound2Au.Com
  4. $ ! translate a variety of sound formats into Sun .au format (compatible with
  5. $ ! DECsound) via SOX and SOUND2SUN.
  6. $ !
  7. $ ! sound2sun was written by Rich Gopstein and Harris Corporation.
  8. $ !
  9. $ ! SOX is part of the Sound Tools package written and distributed by
  10. $ !     Lance Norskog, et. al.
  11. $ !
  12. $ ! Usage
  13. $ !    @sound2au file_name [frequency]
  14. $ !
  15. $ ! where:
  16. $ !    file_name = filename template (may contain wildcards)
  17. $ !    frequency = sampling frequency (default 11000 Hz)
  18. $ !
  19. $ ! Modification History
  20. $ !    14 Dec 1992, K. S. Kubo, Created
  21. $ !
  22. $   If P1 .Eqs. "" THEN GOTO USAGE_EXIT
  23. $ !
  24. $   FTMPL     = F$Parse(P1,"*.SND;")
  25. $   If F$TrnLnm("SOX_DIR") .Nes. "" Then Goto MORE_DEFS
  26. $   SDIR = F$Element(0, "]", F$Environment("PROCEDURE")) + "]"
  27. $   Define/NoLog SOX_DIR 'SDIR'
  28. $ MORE_DEFS:
  29. $   SOX       = "$ SOX_DIR:SOX"
  30. $   SOUND2SUN    = "$ SOX_DIR:SOUND2SUN"
  31. $   ONAME    = ""
  32. $   If P2 .Nes. "" Then SOUND2SUN = SOUND2SUN + " -f ''P2'"
  33. $ LOOP:
  34. $   FNAME = F$Search(FTMPL)
  35. $   If FNAME .Eqs. "" Then Goto REAL_EXIT
  36. $   If FNAME .Eqs. ONAME Then Goto REAL_EXIT
  37. $   ONAME = FNAME
  38. $   VER   = F$Parse(FNAME,,,"VERSION")
  39. $   FTYPE = F$Parse(FNAME,,,"TYPE")
  40. $   FNAME = FNAME - VER - ";"    ! strip version number off
  41. $   BNAME = FNAME - FTYPE    ! get the base name
  42. $   SOX 'FNAME' -t .raw -u -b 'BNAME'.raw
  43. $   SOUND2SUN 'BNAME'.raw 'BNAME'.au
  44. $   Delete/NoLog 'BNAME'.raw;
  45. $   Goto LOOP
  46. $ !
  47. $ USAGE_EXIT:
  48. $   Write Sys$Output "Usage:  @SOUND2AU file_name"
  49. $ !
  50. $ REAL_EXIT:
  51. $   FVER = F$Verify('FVER')
  52. $   EXIT 
  53.