home *** CD-ROM | disk | FTP | other *** search
/ Freelog 34 / Freelog034.iso / Graphisme3D / City / DEFCITY.POV < prev    next >
Encoding:
Text File  |  1999-02-01  |  1.9 KB  |  52 lines
  1. // CITY GENERATOR: DEFAULT CITY
  2. // This scene shows the default city objects and options, under different
  3. // lighting conditions (including the city_night option).
  4. //
  5. // This scene should be rendered as a four-frame, non-cyclic animation.
  6.  
  7. // CAMERA AND ENVIRONMENT
  8.    camera {location <90, 30, -140> look_at <10, 25, 0> angle 50}
  9.    plane {y, -.01 pigment {rgb <0, .2, 0>}}
  10.  
  11.    #switch (int(clock*3))
  12.    #case (0)    // Morning
  13.       light_source {<6000, 500, -1000> rgb <.8, .7, .6>}
  14.       default {finish {ambient <.3, .3, .25> diffuse .7}}
  15.       fog {fog_type 2 rgb <.6, .6, .5> distance 5000 fog_alt 500}
  16.       sky_sphere {pigment {gradient y pigment_map {
  17.          [0 rgb 1]
  18.          [.1 wrinkles color_map {[.5 rgb 1] [.7 rgb <.4, .5, .6>]} scale .1]
  19.          [.15 wrinkles color_map {[.1 rgb 1] [.4 rgb <.4, .5, .6>]} scale .1]
  20.          [.2 rgb <.4, .5, .6>]}}}
  21.       #break
  22.  
  23.    #case (1)    // Daytime
  24.       light_source {<3000, 6000, -7000> rgb 1}
  25.       default {finish {ambient .4 diffuse .7}}
  26.       fog {fog_type 2 rgb <.6, .75, .9> distance 5000 fog_alt 1000}
  27.       sky_sphere {pigment {granite color_map {
  28.          [.4 rgb <.3, .5, .8>] [.7 rgb .9]}
  29.          scale <1, .7, 1>}}
  30.       #break
  31.  
  32.    #case (2)    // Sunset
  33.       #declare city_night = true;
  34.       #declare windows_lit = .2;
  35.       light_source {<-5000, 1000, -2000> rgb <.8, .6, .3>}
  36.       default {finish {ambient <.3, .2, .25> diffuse .7}}
  37.       fog {fog_type 2 rgb <.9, .8, .5> distance 5000 fog_alt 500}
  38.       sky_sphere {pigment {wrinkles color_map {
  39.          [.4 rgb <.7, .2, .4>] [.8 rgb <.9, .5, .4>]}
  40.          scale <.4, .04, .4>}}
  41.       #break
  42.  
  43.    #case (3)    // Night
  44.       #declare city_night = true;
  45.       #declare windows_lit = .5;
  46.       light_source {<-6000, 500, -3000> rgb <.2, .25, .3>}
  47.       fog {fog_type 2 rgb <.1, .15, .2> distance 5000 fog_alt 500}
  48.    #end
  49.  
  50. // GENERATE DEFAULT CITY
  51.    #include "CITY"
  52.