home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Freelog 14
/
Freelog014.iso
/
SeriePov
/
Igloo_Tex.pov
< prev
next >
Wrap
Text File
|
2000-09-03
|
10KB
|
302 lines
// Persistence of Vision Ray Tracer Scene Description File
// File: .pov
// Vers: 3.1
// Desc: Tutoriel sur l'Igloo-4
// Date: 01/08/00
// Auth: Alonso Eusebio Pablo pour Freelog #13 DPpresse
// DΘsolΘ: merci α LOHIRIAN pour le correctif sur les opΘration AND, OR, XOR,
// j'ai horreur d'Θcrire des bΩtises.
//-----------------------------------------DECLARATIONS--------------------------------------------
#version 3.1 // Permet d'utiliser les instructions propre α Pov v 3.1
global_settings { assumed_gamma 1.0 } // definition du Gamma
//-------------------------------Inclusions Standard de POV-Ray------------------------------------
#include "colors.inc" // Declaration des couleurs standard
#include "textures.inc" // Declaration des textures standard
//---------------------------------DEFINITION DE LA CAMERA-----------------------------------------
camera
{ // debut de la camera
location <2.5, 1.0, -2.0> // position de la camera <X Y Z>
look_at <0.0, 0.0, 0.0> // point de mire <X Y Z>
} // fin de la camera
//----------------------------------FOND DE CIEL---------------------------------------------------
sky_sphere // sphere infinie
{ // debut du ciel
pigment // pigment de la sphere
{
granite // texture "Granite"
turbulence 0.1 // turbulence de la texture
color_map { // table des couleurs α utiliser
[0.3 rgb <0.2, 0.3, 1>] // taux de variation de la couleur suivi d'une couleur bleue
[1.0 rgb 1] // taux de variation de la couleur suivi d'une couleur blanche
}
scale .75 // mise α l'Θchelle de la texture
}
} // fin du ciel
//------------------------------ZONE LUMINEUSE STANDARD--------------------------------------------
light_source
{ // debut de la source lumineuse
0*x // position initiale de la lumiere
color rgb 1.0 // couleur de la lumiere
area_light
<8, 0, 0> <0, 0, 8> // zone couverte par la lumiere (x * z)
4, 4 // nombre total de lumiers dans la zone (4x*4z = 16)
adaptive 0 // 0,1,2,3...
jitter // ajoute un effet tamise aleatoire
translate <40, 80, -40> // <x y z> translation de la zone de lumiΦre depuis son point d'origine
} // fin de la source lumineuse
//--------------------------------------BANQUISE---------------------------------------------------
// DΘclaration des couleurs utilisΘes par la texture
#declare Monbleue = color red 0.196078 green 0.6 blue 0.8;
#declare Monblanc = rgb 1;
#declare Mongris = White*0.70;
// DΘclaration de la texture "Givre"
#declare Givre = pigment {
wrinkles // utilisation de la texture "Wrinkles"
turbulence 0.1 // turbulence de la texture
lambda 2.2 // taux de lambda
omega 0.707 // taux d'omega
color_map { // dΘclaration de la table des couleurs
[0.20 Monbleue * 0.85 ] // taux de variation de la couleur suivi de la couleur
[0.50 Monblanc ] // taux de variation de la couleur suivi de la couleur
[1.00 Mongris ] // taux de variation de la couleur suivi de la couleur
}
scale <0.5, 0.15, 1> // mise α l'Θchelle de la texture
}
plane // Definition d'un plan infini
{
y, // <X Y Z> normale de la surface,ici le vecteur Y
0.0 // distance entre l'origine et la surface normale
hollow on // autorise un pigment
pigment // texture simulant la neige boueuse
{
Givre // utilisation de la texture givre
}
}
//----------------------------L'OBJET "IGLOO"------------------------------------------------------
//------- Objet BolΘen "Brut" qui sera usinΘ
#declare Brut = union { // OpΘration OR (merci α LOHIRIAN pour le correctif)
sphere // insertion d'une sphere
{
<0, 0, 0> // centre <X Y Z>
1.1 // rayon
}
cylinder // insertion d'un cylindre
{
0*x, 1.0*x, 0.8 // depart, arrivee, rayon
}
cylinder // insertion d'un deuxieme cylindre
{
1.0*x, 1.3*x, 0.9 // depart, arrivee, rayon
}
} // fin de l'object Brut
//------- Objet BolΘen "Outil" qui servira d'outil
#declare Outil = union {
box // Insertion d'un parallΘlΘpipΦde
{
<-1.4, -1.4, -1.4> // premier sommet <X1 Y1 Z1>
< 1.4, 0, 1.4> // sommet opposΘ <X2 Y2 Z2>
}
sphere // insertion d'une sphΦre
{
<0, 0, 0> // centre <X Y Z>
1 // rayon
}
cylinder // insertion d'un cylindre
{
0*x, 1.4*x, 0.7 // dΘpart, arrivΘe, rayon
}
} // Fin de l'objet "Outil"
//------- OpΘration "Brut" NOT "Outil" = "Igloo"
#declare Igloo = difference
{
object { Brut}
object { Outil}
}
//--------------------INSERTION DE L'OBJET "IGLOO" DANS LA SCENE---------------------------------
object { Igloo //insertion de l'objet portant le label:"Igloo"
pigment // texture de l'Igloo
{
brick color Gray, color White // briques blanches avec joints gris
brick_size <0.3,0.3,0.3> // taille des blocs
mortar 0.03 // epaisseur des joints
}
// insertion d'une BumpMap sur l'igloo
normal { // dΘclare l'utilisation d'une BumpMap
bump_map
{
tga "Igloo.tga" // type et image α utiliser (iff/gif/tga/png/sys)
map_type 0 // type de projection 0=plane, 1=sphΘrique, 2=cylindrique, 5=torre
interpolate 4 // type d'interpolation 0=sans, 1=lineaire, 2=bilineaire, 4=normale
bump_size 2 // taille de l'ΘlΘvation de 0...3
}
rotate <0, -45, 0> // rotation α -45░ selon l'axe y du plan de projection
}
} // fin de l'insertion de l'Igloo
//------------------CREATION DU SAPIN--------------------------------------------------------------
// DΘclaration de la texture "Tronc"
#declare Tronc = pigment {
wood // utilisation de la texture "Wood"
turbulence 0.02 // turbulence
scale 0.01 // mise α l'Θchelle
translate <10, 0, 0> // translation de la texture
}
// DΘclaration de la texture "Feuillage"
#declare Feuillage = pigment {
granite // utilisation de la texture "Granite"
turbulence 0.1
color_map {
[0.3 rgb <0, .3, 0>]
[0.3 rgb 1]
[1.0 rgb 2]
}
scale .075
}
//
#declare sapin = union { //dΘclartion d'une opΘration "OR" dont le rΘsultat se nome "sapin"
cylinder // tronc
{
0*y, 0.5*y, .05
pigment {
Tronc // utilisation de la texture "Tronc"
}
}
cone // c⌠ne de base
{
0.7*y, 0.0, // Disque au sommet et rayon
0.5*y, .25 // Disque a la base et rayon
pigment {
Feuillage // utilisation de la texture "Feuillage"
}
}
cone // c⌠ne du milieu
{
.95*y, 0.0,
0.65*y, .20
pigment {
Feuillage // utilisation de la texture "Feuillage"
}
}
cone // c⌠ne du sommet
{
1.1*y, 0.0,
0.9*y, .08
pigment {
Feuillage // utilisation de la texture "Feuillage"
}
}
} // Fin de la definition du sapin
//--------------------------INSERTION DU SAPIN DANS LA SCENE---------------------------------------
object { sapin
translate <1., .0, -1.6> // <dX dY dZ> translation du sapin
} // fin de l'insertion du sapin
//-------------------------PANCARTE----------------------------------------------------------------
#declare pancarte = union
{
box // boite constituant la pancarte
{
<-0.25, .30, -0.03> // coin1 <X1 Y1 Z1>
< 0.25, .85, 0.0> // coin2 <X2 Y2 Z2>
pigment {
//**********ATTENTION!!!!! J'ai utilisΘ pour la pancarte une image en 340x250
// les rΘglages qui suivent sont en consΘquence.
// si vous changez les dimension il faudra modifier le scrip.
image_map // image maps dans le plan X-Y
{
tga "EAT.tga" // type et fichier image (iff/gif/tga/png/sys)
map_type 0 // projection plane
interpolate 4 // interpolation normale
once // ne pas rΘpΘter n'utiliser la texture qu'une seule fois,
// important ce qui est hors de la texturte est invisible
} // fin de l'image_map
translate <-.5, .85, 0.> // translation de l'image sur le support
scale .4 // mise α l'Θchelle de la texture
} // fin du pigment
} // fin de la boite
cylinder // pied 1
{
0*y, 0.5*y, .02
pigment {
Tronc // utilisation de la texture "Tronc"
}
translate <-.1, .0, 0.>
}
cylinder // pied 2
{
0*y, 0.5*y, .02
pigment {
Tronc // utilisation de la texture "Tronc"
}
translate <.1, .0, .0>
}
}
//--------------------------INSERTION DE LA PANCARTE DANS LA SCENE---------------------------------
object { pancarte
rotate <0, -35, 0> // rotation de la pancarte pour la positionner face α la camΘra, de biais
translate <1.4, .0, -1.2> // translation de la pancarte vers sa position dΘfinitive
} // fin de l'insertion de la pancarte
//---------------------------Ouf! c'est tout pour ce mois-ci---------------------------------------